home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / bsd_srcs / lib / libc / vax / string / index.s < prev    next >
Encoding:
Text File  |  1991-04-12  |  3.0 KB  |  100 lines

  1. /*
  2.  * Copyright (c) 1980 Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * Redistribution and use in source and binary forms, with or without
  6.  * modification, are permitted provided that the following conditions
  7.  * are met:
  8.  * 1. Redistributions of source code must retain the above copyright
  9.  *    notice, this list of conditions and the following disclaimer.
  10.  * 2. Redistributions in binary form must reproduce the above copyright
  11.  *    notice, this list of conditions and the following disclaimer in the
  12.  *    documentation and/or other materials provided with the distribution.
  13.  * 3. All advertising materials mentioning features or use of this software
  14.  *    must display the following acknowledgement:
  15.  *    This product includes software developed by the University of
  16.  *    California, Berkeley and its contributors.
  17.  * 4. Neither the name of the University nor the names of its contributors
  18.  *    may be used to endorse or promote products derived from this software
  19.  *    without specific prior written permission.
  20.  *
  21.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31.  * SUCH DAMAGE.
  32.  */
  33.  
  34. #if defined(LIBC_SCCS) && !defined(lint)
  35.     .asciz "@(#)index.s    5.6 (Berkeley) 6/1/90"
  36. #endif /* LIBC_SCCS and not lint */
  37.  
  38. /*
  39.  * Find the first occurence of c in the string cp.
  40.  * Return pointer to match or null pointer.
  41.  *
  42.  * char *
  43.  * index(cp, c)
  44.  *    char *cp, c;
  45.  */
  46. #include "DEFS.h"
  47.  
  48. ENTRY(index, 0)
  49.     movq    4(ap),r1    # r1 = cp; r2 = c
  50.     tstl    r2        # check for special case c == '\0'
  51.     bneq    2f
  52. 1:
  53.     locc    $0,$65535,(r1)    # just find end of string
  54.     beql    1b        # still looking
  55.     movl    r1,r0        # found it
  56.     ret
  57. 2:
  58.     moval    tbl,r3        # r3 = address of table
  59.     bbss    $0,(r3),5f    # insure not reentering
  60.     movab    (r3)[r2],r5    # table entry for c
  61.     incb    (r5)
  62.     movzwl    $65535,r4    # fast access
  63. 3:
  64.     scanc    r4,(r1),(r3),$1    # look for c or '\0'
  65.     beql    3b        # still looking
  66.     movl    r1,r0        # return pointer to char
  67.     tstb    (r0)        #    if have found '\0'
  68.     bneq    4f
  69.     clrl    r0        # else return 0
  70. 4:
  71.     clrb    (r5)        # clean up table
  72.     clrb    (r3)
  73.     ret
  74.  
  75.     .data
  76. tbl:    .space    256
  77.     .text
  78.  
  79. /*
  80.  * Reentrant, but slower version of index
  81.  */
  82. 5:
  83.     movl    r1,r3
  84. 6:
  85.     locc    $0,$65535,(r3)    # look for '\0'
  86.     bneq    7f
  87.     locc    r2,$65535,(r3)    # look for c
  88.     bneq    8f
  89.     movl    r1,r3        # reset pointer and ...
  90.     jbr    6b        # ... try again
  91. 7:
  92.     subl3    r3,r1,r4    # length of short block
  93.     incl    r4        # +1 for '\0'
  94.     locc    r2,r4,(r3)    # look for c
  95.     bneq    8f
  96.     ret
  97. 8:
  98.     movl    r1,r0        # return pointer to char
  99.     ret
  100.