home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / bsd_srcs / lib / libc / tahoe / gen / setjmp.s < prev    next >
Encoding:
Text File  |  1991-04-12  |  3.4 KB  |  105 lines
  1. /*
  2.  * Copyright (c) 1988 Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * This code is derived from software contributed to Berkeley by
  6.  * Computer Consoles Inc.
  7.  *
  8.  * Redistribution and use in source and binary forms, with or without
  9.  * modification, are permitted provided that the following conditions
  10.  * are met:
  11.  * 1. Redistributions of source code must retain the above copyright
  12.  *    notice, this list of conditions and the following disclaimer.
  13.  * 2. Redistributions in binary form must reproduce the above copyright
  14.  *    notice, this list of conditions and the following disclaimer in the
  15.  *    documentation and/or other materials provided with the distribution.
  16.  * 3. All advertising materials mentioning features or use of this software
  17.  *    must display the following acknowledgement:
  18.  *    This product includes software developed by the University of
  19.  *    California, Berkeley and its contributors.
  20.  * 4. Neither the name of the University nor the names of its contributors
  21.  *    may be used to endorse or promote products derived from this software
  22.  *    without specific prior written permission.
  23.  *
  24.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34.  * SUCH DAMAGE.
  35.  */
  36.  
  37. #if defined(LIBC_SCCS) && !defined(lint)
  38.     .asciz "@(#)setjmp.s    5.1 (Berkeley) 1/30/91"
  39. #endif /* LIBC_SCCS and not lint */
  40.  
  41. /*
  42.  * C library -- setjmp, longjmp
  43.  *
  44.  *    longjmp(a,v)
  45.  * will generate a "return(v)" from
  46.  * the last call to
  47.  *    setjmp(a)
  48.  * by restoring registers from the stack,
  49.  * previous signal mask, and doing a return.
  50.  */
  51.  
  52. #include "DEFS.h"
  53.  
  54. ENTRY(setjmp, R6)
  55.     movl    4(fp),r6        # construct sigcontext
  56.     movab    -8(sp),sp        # space for current struct sigstack
  57.     pushal    (sp)            # get current values
  58.     pushl    $0            # no new values
  59.     callf    $16,_sigstack        # pop args plus signal stack value
  60.     movl    (sp)+,(r6)        # save onsigstack status of caller
  61.     pushl    $0
  62.     callf    $8,_sigblock        # get signal mask
  63.     movl    r0,4(r6)        # save signal mask of caller
  64.     addl3    $8,fp,8(r6)        # save stack pointer of caller
  65.     movl    (fp),12(r6)        # save frame pointer of caller
  66.     movl    -8(fp),20(r6)        # save pc of caller
  67.     movpsl    24(r6)            # save psl of caller
  68.     clrl    r0
  69.     ret
  70.  
  71. ENTRY(longjmp, 0)
  72.     movl    8(fp),r0        # return(v)
  73.     movl    4(fp),r1        # fetch buffer
  74.     tstl    12(r1)
  75.     beql    botch
  76. loop:
  77.     cmpl    12(r1),(fp)
  78.     beql    done
  79.     blssu    botch
  80.     movl    $loop,-8(fp)
  81.     ret                # pop another frame
  82.  
  83. done:
  84.     cmpb    *-8(fp),reiins        # returning to an "rei"?
  85.     bneq    1f
  86.     movab    3f,-8(fp)        # do return w/ psl-pc pop
  87.     brw    2f
  88. 1:
  89.     movab    4f,-8(fp)        # do standard return
  90. 2:
  91.     ret                # unwind stack before signals enabled
  92. 3:
  93.     addl2    $8,sp            # compensate for PSL-PC push
  94. 4:
  95.     pushl    r1            # pointer to sigcontext
  96.     callf    $4,_sigreturn        # restore previous context
  97.                     # we should never return
  98.  
  99. botch:
  100.     callf    $4,_longjmperror
  101.     halt
  102.  
  103.     .data
  104. reiins:    rei
  105.