home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Internet Tools 1993 July / Internet Tools.iso / RockRidge / mail / metamail / bin / showexternal < prev    next >
Encoding:
Text File  |  1993-05-18  |  5.8 KB  |  239 lines
  1. #!/bin/csh -f
  2. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  3. # 
  4. # Permission to use, copy, modify, and distribute this material 
  5. # for any purpose and without fee is hereby granted, provided 
  6. # that the above copyright notice and this permission notice 
  7. # appear in all copies, and that the name of Bellcore not be 
  8. # used in advertising or publicity pertaining to this 
  9. # material without the specific, prior written permission 
  10. # of an authorized representative of Bellcore.  BELLCORE 
  11. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  12. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  13. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  14. # 
  15.  
  16. onintr cleanup
  17. if (! $?METAMAIL_TMPDIR) then
  18.     set METAMAIL_TMPDIR=/tmp
  19. endif
  20. if (! $?FTP) then
  21.     set FTP=ftp
  22. endif
  23.  
  24. if ($#argv <3) then
  25.     echo "Usage: showexternal body-file access-type name [site [directory [mode [server]]]]"
  26.     exit -1
  27. endif
  28. set bodyfile=$1
  29. set atype=`echo $2 | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
  30. set name=$3
  31. if ($#argv > 3) then
  32.     set site=$4
  33. else 
  34.     set site=""
  35. endif
  36. if ($#argv > 4) then
  37.     set dir=$5
  38. else
  39.     set dir=""
  40. endif
  41. if ($#argv > 5) then
  42.     set mode=$6
  43. else
  44.     set mode=""
  45. endif
  46. if ($#argv > 6) then
  47.     set server=$7
  48. else
  49.     set server=""
  50. endif
  51.  
  52. if ("$server" == "" && $atype == "mail-server") then
  53. # Backward compatibility with some broken stuff
  54.     set server=${name}@${site}
  55.     echo WARNING -- old style mailserver syntax, using server $server
  56. endif
  57.  
  58. set ctype="`grep -i content-type: $bodyfile | sed -e 's/............: //'`"
  59. if ("$ctype" == "") set ctype="text/plain"
  60. set cenc=`grep -i content-transfer-encoding: $bodyfile | sed -e 's/.........................: //'`
  61. set username=""
  62. set pass=""
  63. set TMPDIR=${METAMAIL_TMPDIR}/XXXternal.$$
  64. mkdir $TMPDIR
  65. pushd $TMPDIR
  66. set NEWNAME="mm.ext.$$"
  67. set NEEDSCONFIRMATION=1
  68. switch ("$atype")
  69.     case anon-ftp:
  70.     echo "This mail message contains a POINTER (reference) to data that is "
  71.     echo not included in the message itself.  Rather, the data can be retrieved 
  72.     echo automatically using  anonymous FTP to a site on the network.
  73.     breaksw
  74.     case ftp:
  75.     echo "This mail message contains a POINTER (reference) to data that is "
  76.     echo not included in the message itself.  Rather, the data can be retrieved 
  77.     echo automatically using  the FTP protocol to a site on the network.
  78.     breaksw
  79.     case mail-server:  
  80.     cat > ${METAMAIL_TMPDIR}/ext.junk.$$ <<!
  81. This mail message contains a POINTER (reference) to data that is 
  82. not included in the message itself.  Rather, the data can be retrieved 
  83. by sending a special mail message to a mail server on the network.
  84. However, doing this automatically is slightly dangerous, because  someone
  85. might be using this mechanism to cause YOU to send obnoxious mail.
  86. For that reason, the mail message that WOULD be sent is being shown to you
  87. first for your approval.
  88.  
  89. This is the message that will be sent if you choose to go ahead and
  90. retreive the external data:
  91.  
  92. To: ${server}
  93. Subject: Automated Mail Server Request
  94.  
  95. !
  96.     cat $bodyfile >> ${METAMAIL_TMPDIR}/ext.junk.$$
  97.     more ${METAMAIL_TMPDIR}/ext.junk.$$
  98.     rm ${METAMAIL_TMPDIR}/ext.junk.$$
  99.     breaksw
  100.     default:
  101.     # IGNORE ALL THE OTHERS -- AUTOMATIC FOR LOCAL-FILE, AFS.
  102.     set NEEDSCONFIRMATION=0
  103. endsw
  104.  
  105. if ($NEEDSCONFIRMATION) then
  106.     echo ""
  107.     echo -n "Do you want to proceed with retrieving the external data [y] ? "
  108.     set ANS=$<
  109.     if ("$ANS" =~ n* ||  "$ANS" =~ N* ) then
  110.         rm -rf $TMPDIR
  111.         exit 0
  112.     endif
  113. endif
  114.  
  115. switch ("$atype")
  116.     case anon-ftp:
  117.     set username=anonymous
  118.     set pass=`whoami`@`hostname`
  119.     # DROP THROUGH
  120.     case ftp:
  121.     if ("$site" == "") then
  122.         echo -n "Site for ftp access: "
  123.         set site=$<
  124.     endif
  125.     if ("$username" == "") then
  126.         echo -n "User name at site ${site}: "
  127.         set username=$<
  128.     endif
  129.     if ("$pass" == "") then
  130.         echo -n "Password for user $username at site ${site}: "
  131.         stty -echo
  132.         set pass=$<
  133.         stty echo
  134.         echo ""
  135.     endif
  136.     if ("$dir" == "") then
  137.         set DIRCMD=""
  138.     else
  139.         set DIRCMD="cd $dir"
  140.     endif
  141.     if ("$mode" == "") then
  142.         set MODECMD=""
  143.     else
  144.         set MODECMD="type $mode"
  145.     endif
  146.     echo OBTAINING MESSAGE BODY USING FTP
  147.     echo SITE: $site USER $username
  148.     $FTP -n <<!
  149. open $site
  150. user $username $pass
  151. $DIRCMD
  152. $MODECMD
  153. get $name $NEWNAME
  154. quit
  155. !
  156.     if (! -e $NEWNAME) then
  157.         echo FTP failed.
  158.         rm -rf $TMPDIR
  159.         exit -1
  160.     endif
  161.     breaksw
  162.     case afs:
  163.     case local-file:
  164.     if (! -e $name) then
  165.         echo local file not found
  166.         rm -rf $TMPDIR
  167.         exit -1
  168.     endif
  169.         set NEWNAME=$name
  170.     echo GETTING BODY FROM FILE NAMED: $NEWNAME
  171.     breaksw
  172.     case mail-server:  # A very special case
  173.     if ("$bodyfile" == "") then
  174.         echo mail-server access-type requires a body file
  175.         rm -rf $TMPDIR
  176.         exit -1
  177.     endif
  178.     echo Subject: Automated Mail Server Request > $NEWNAME
  179.     echo To: ${server} >> $NEWNAME
  180.     echo "" >> $NEWNAME
  181.     cat $bodyfile >> $NEWNAME
  182.     /usr/lib/sendmail -t  < $NEWNAME
  183.     if ($status) then
  184.         echo sendmail failed
  185.         cd ${METAMAIL_TMPDIR}
  186.         rm -rf $TMPDIR
  187.         exit -1
  188.     endif
  189.     cd ${METAMAIL_TMPDIR}
  190.     rm -rf $TMPDIR
  191.     echo Your $ctype data has been requested from a mail server.
  192.     exit 0
  193.     default:
  194.     echo UNRECOGNIZED ACCESS-TYPE
  195.     rm -rf $TMPDIR
  196.     exit -1
  197. endsw
  198. if ($cenc == base64) then
  199.     mimencode -u -b < $NEWNAME > OUT
  200.     mv OUT $NEWNAME
  201. else if ($cenc == quoted-printable) then
  202.     mimencode -u -q < $NEWNAME > OUT
  203.     mv OUT $NEWNAME
  204. endif
  205.  
  206. popd
  207. if ($atype == "local-file") then
  208.     metamail -b -c "$ctype" $NEWNAME
  209. else
  210.     metamail -b -c "$ctype" $TMPDIR/$NEWNAME
  211. endif
  212.  
  213. if ($status) then
  214.     echo metamail failed
  215.     cd ${METAMAIL_TMPDIR}
  216.     rm -rf $TMPDIR
  217.     exit -1
  218. endif
  219.  
  220. if ($NEWNAME != $name) then
  221.     echo ""
  222.     echo The data just displayed is stored in the file $TMPDIR/$NEWNAME
  223.     echo "Do you want to delete it?"
  224.     rm -i $TMPDIR/$NEWNAME
  225. endif
  226.  
  227. if (! -e ${TMPDIR}/${NEWNAME}) then
  228.     cd ${METAMAIL_TMPDIR}
  229.     rmdir $TMPDIR
  230. endif
  231. exit 0
  232.  
  233. cleanup:
  234. cd ${METAMAIL_TMPDIR}
  235. if (-e $TMPDIR) then    
  236.     rmdir $TMPDIR
  237. endif
  238. exit -1
  239.