home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Internet Tools 1993 July / Internet Tools.iso / RockRidge / mail / metamail / bin / metasend < prev    next >
Encoding:
Text File  |  1993-05-10  |  9.6 KB  |  325 lines
  1. #!/bin/csh -f
  2. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  3. # 
  4. # Permission to use, copy, modify, and distribute this material 
  5. # for any purpose and without fee is hereby granted, provided 
  6. # that the above copyright notice and this permission notice 
  7. # appear in all copies, and that the name of Bellcore not be 
  8. # used in advertising or publicity pertaining to this 
  9. # material without the specific, prior written permission 
  10. # of an authorized representative of Bellcore.  BELLCORE 
  11. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  12. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  13. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  14. #
  15.  
  16. if (! $?METAMAIL_TMPDIR) then
  17.     set METAMAIL_TMPDIR=/tmp
  18. endif
  19.  
  20. set idctr=0
  21. set MustDelete=0
  22. set batchmode=0
  23. set multipart = 1
  24. set splitsize = 100000
  25. while ($#argv > 0)
  26.     switch ("$1")
  27.         case "-S":
  28.             shift
  29.             if ($#argv == 0) then
  30.                 echo "-S requires a following argument, the SPLIT threshhold"
  31.                 exit
  32.             endif
  33.             set splitsize=$1
  34.             shift
  35.             breaksw
  36.         case "-b":
  37.             # Batch mode -- ALL args must be on command line
  38.             set batchmode = 1
  39.             shift
  40.             breaksw
  41.         case "-c":
  42.             shift
  43.             if ($#argv == 0) then
  44.                 echo "-c requires a following argument, the CC address"
  45.                 exit
  46.             endif
  47.             set cc=$1
  48.             shift
  49.             breaksw
  50.         case "-s":
  51.             shift
  52.             if ($#argv == 0) then
  53.                 echo "-s requires a following argument, the SUBJECT"
  54.                 exit
  55.             endif
  56.             set subject="$1"
  57.             shift
  58.             breaksw
  59.         case "-t":
  60.             shift
  61.             if ($#argv == 0) then
  62.                 echo "-t requires a following argument, the TO address"
  63.                 exit
  64.             endif
  65.             set to="$1"
  66.             shift
  67.             breaksw
  68.         case "-e":
  69.             shift
  70.             if ($#argv == 0) then
  71.                 echo "-e requires a following argument, the ENCODING value"
  72.                 exit
  73.             endif
  74.             set encode=$1
  75.             if ($encode == "base64") then
  76.         set encodingprog = "mimencode -b"
  77.             else if ($encode == "x-uue") then
  78.             set encodingprog = "uuencode mail-body"
  79.             else if ($encode == "7bit") then
  80.             set encodingprog = cat
  81.            else
  82.             set encodingprog = "mimencode -q"
  83.             set encode = "quoted-printable"
  84.            endif 
  85.            shift
  86.             breaksw
  87.         case "-f":
  88.             shift
  89.             if ($#argv == 0) then
  90.                 echo "-f requires a following argument, the DATA FILE"
  91.                 exit
  92.             endif
  93.             set datafile=$1
  94.             if (! -e  $datafile) then
  95.                 echo The file $datafile does not exist.
  96.                 exit
  97.             endif
  98.             shift
  99.             breaksw
  100.         case "-m":
  101.             shift
  102.             if ($#argv == 0) then
  103.                 echo "-m requires a following argument, the MIME CONTENT-TYPE"
  104.                 exit
  105.             endif
  106. #            set ctyperaw = $1
  107. #            set  ctype=`echo $ctyperaw | tr \" \'`
  108.     set ctype = $1
  109.             shift
  110.             breaksw
  111.         case "-z":
  112.             set MustDelete=1
  113.             shift
  114.             breaksw
  115.         case "-n":
  116.     if ( ! $?ctype || ! $?datafile) then
  117.         echo One part is incomplete -- each part needs at least -f and -m
  118.         exit 1
  119.     endif
  120.     if (! $?encode) then
  121.             if ("$ctype" =~ text*) then
  122.                   set encodingprog = "mimencode -q"
  123.         set encode = "quoted-printable"
  124.             else
  125.                 set encode = base64
  126.                 set encodingprog = "mimencode -b"
  127.             endif
  128.     endif
  129.     set ctype${multipart} = $ctype
  130.     set datafile${multipart} = $datafile
  131.     set encode${multipart} = $encode
  132.     set encodingprog${multipart} = "$encodingprog"
  133.     unset ctype
  134.     unset datafile
  135.     unset encode
  136.     unset encodingprog
  137.             @  multipart++
  138.     shift
  139.     breaksw
  140.         default:
  141.             echo UNRECOGNIZED METASEND OPTION: $1
  142.             exit
  143.     endsw
  144. end
  145. if ($batchmode == 0) then
  146.     if (! $?to) then
  147.         echo -n "To: "
  148.         set to = $<
  149.     endif
  150.     if (! $?subject) then
  151.         echo -n "Subject: "
  152.         set subject = $<
  153.     endif
  154.     if (! $?cc) then
  155.         echo -n "CC: "
  156.         set cc = $<
  157.     endif
  158. anotherpart:
  159.     if (! $?ctype) then
  160.         echo -n "Content-type: "
  161. #        set ctyperaw = $<
  162. #        set  ctype=`echo $ctyperaw | tr \" \'`
  163.         set ctype = $<
  164.     endif
  165. #    if ($ctype != $ctyperaw)  echo Double  quotes not allowed, using $ctype
  166.     if (! $?datafile) then
  167.         getfile:
  168.         echo -n "Name of file containing $ctype data: "
  169.         set datafile = $<
  170.         if (! -e  $datafile) then
  171.             echo The file $datafile does not exist.
  172.             goto getfile
  173.         endif
  174.     endif
  175.     if (! $?encode) then
  176.         retry:
  177.         echo "Do you want to encode this data for sending through the mail?"
  178.         echo "  1 -- No, it is already in 7 bit ASCII"
  179.         echo "  2 -- Yes, encode in base64 (most efficient)"
  180.         echo "  3 -- Yes, encode in quoted-printable (less efficient, more readable)"
  181.         echo "  4 -- Yes, encode it using uuencode (not standard, being phased out)"
  182.         set encode=$<
  183.         switch ("$encode")
  184.             case 1:
  185.                 set encodingprog = cat
  186.       set encode = 7bit
  187.                 breaksw
  188.             case 2:
  189.                 set encodingprog = "mimencode -b"
  190.       set encode = base64
  191.                 breaksw
  192.             case 3:
  193.                 set encodingprog = "mimencode -q"
  194.       set encode = quoted-printable
  195.                 breaksw
  196.             case 4:
  197.                 set encodingprog = "uuencode $datafile"
  198.       set encode = x-uue
  199.                 breaksw
  200.             default:
  201.                 echo Unrecognized answer, please try again.
  202.                 goto retry
  203.         endsw
  204.     endif
  205.     echo -n "Do you want to include another file too (y/n) [n] ? "
  206.     set ans=$<
  207.     if  ("$ans" =~ y*) then
  208.     set ctype${multipart} = $ctype
  209.     set datafile${multipart} = $datafile
  210.     set encode${multipart} = $encode
  211.     set encodingprog${multipart} = "$encodingprog"
  212.     unset ctype
  213.     unset datafile
  214.     unset encode
  215.     unset encodingprog
  216.             @  multipart++
  217.             goto anotherpart
  218.      endif
  219. else
  220.     if (! $?to || ! $?subject || ! $?ctype || ! $?datafile) then
  221.         echo metasend: in batch mode, -t, -s, -f, and -m are all required
  222.         exit
  223.     endif
  224.     if (! -e  $datafile) then
  225.         echo metasend:  The file $datafile does not exist
  226.         exit
  227.     endif
  228.     if (! $?cc) set cc=""
  229. #     if ($ctype != $ctyperaw)  echo Double  quotes not allowed, using $ctype
  230.     if (! $?encode) then
  231.         if ("$ctype" =~ text*) then
  232.     set encodingprog = "mimencode -q"
  233.     set encode = "quoted-printable"
  234.         else
  235.             set encodingprog = "mimencode -b"
  236.             set encode = base64
  237.         endif
  238.     else if ($encode == "base64") then
  239.         set encodingprog = "mimencode -b"
  240.     else if ($encode == "x-uue") then
  241.         set encodingprog = "uuencode mail-body"
  242.     else if ($encode == "7bit") then
  243.         set encodingprog = cat
  244.     else
  245.         set encodingprog = "mimencode -q"
  246.         set encode = "quoted-printable"
  247.     endif
  248. endif
  249.  
  250. if (! $?encode) then
  251.         if ("$ctype" =~ text*) then
  252.     set encode = "quoted-printable"
  253.     set encodingprog = "mimencode -q"
  254.         else
  255.             set encode = base64
  256.             set encodingprog = "mimencode -b"
  257.         endif
  258. endif
  259. set ctype${multipart} = $ctype
  260. set datafile${multipart} = $datafile
  261. set encode${multipart} = $encode
  262. set encodingprog${multipart} = "$encodingprog"
  263.  
  264. set fname = ${METAMAIL_TMPDIR}/metasend.$$
  265. echo "To: " "$to" > $fname
  266. echo "Subject: " "$subject" >> $fname
  267. echo "CC: " "$cc" >> $fname
  268. echo "MIME-Version: 1.0" >> $fname
  269. set hname = `hostname`
  270. if ($multipart > 1) then
  271.     set  boundary = ${hname}.$$.`date | tr "  " .`
  272.     set newid=`date | tr " :" "__"`
  273.     echo "Content-ID: <${newid}_$idctr@${hname}>"   >> $fname
  274.     @ idctr++
  275.     echo "Content-type: multipart/mixed;" >> $fname
  276.     echo "    boundary="\"$boundary\" >> $fname
  277.     echo "" >> $fname
  278.     echo "This is  a multimedia message in MIME  format.  If you are reading this" >> $fname
  279.     echo "prefix, your mail reader does  not understand MIME.  You may wish" >> $fname
  280.     echo "to look into upgrading to a newer version of  your mail reader." >> $fname
  281.     set i=1
  282.     set junkfile=${METAMAIL_TMPDIR}/mmjunk.$$
  283.     while  ($multipart >= $i)
  284.     echo --$boundary >> $fname
  285.               set newid=`date | tr " :" "__"`
  286.               echo "Content-ID: <${newid}_$idctr@${hname}>"   >> $fname
  287.     @ idctr++
  288.     echo -n Content-type: >>$fname
  289.     echo echo \$ctype$i \>\>  $fname > $junkfile
  290.     source $junkfile 
  291.     echo -n Content-Transfer-Encoding: >>$fname
  292.     echo echo \$encode$i \>\> $fname > $junkfile
  293.     source $junkfile 
  294.     echo ""  >> $fname
  295.     echo \$encodingprog$i \< \$datafile$i \>\> $fname > $junkfile
  296.     source $junkfile 
  297.     @ i++
  298.     end
  299.     rm $junkfile
  300.     echo --${boundary}-- >> $fname
  301.     echo "" >> $fname
  302. else 
  303.     set newid=`date | tr " :" "__"`
  304.     echo "Content-ID: <${newid}_$idctr@${hname}>"   >> $fname
  305.     @ idctr++
  306.     echo "Content-type: " $ctype >> $fname
  307.     echo "Content-Transfer-Encoding: " $encode >> $fname
  308.     echo  "" >> $fname
  309.     $encodingprog < $datafile >> $fname
  310.     # Ensure last line has trailing carraige return
  311.     echo "" >> $fname
  312. endif
  313. if ($batchmode == 0) echo -n "Delivering mail, please wait...  "
  314. splitmail -s $splitsize -d $fname
  315. if (! $status) then
  316.     if ($batchmode == 0) echo "Mail delivery apparently succeeded."
  317.     rm $fname
  318. else if ($MustDelete == 1) then
  319.     echo Mail delivery failed
  320.     rm $fname
  321. else
  322.     echo Mail delivery failed, draft mail is in $fname
  323. endif
  324.  
  325.