home *** CD-ROM | disk | FTP | other *** search
/ Il CD di internet / CD.iso / SOURCE / AP / JED / JED097-1.TAR / jed / lib / edt.sl < prev    next >
Encoding:
Text File  |  1994-12-12  |  12.8 KB  |  485 lines
  1. %% EDT emulation for JED  -- Application Keypad.
  2. %%
  3. %%  To load this, put the line:  "edt.sl" evalfile
  4. %%   in your jed.rc (.jedrc) file
  5. %%
  6. %% Here the user gets to choose the action of the 'subs' key (Gold-enter)
  7. %% By default, it behaves as EDT.  By putting the next line in JED.RC, this
  8. %% key is bound to a more conventional query replace
  9. %% setkey ("replace_cmd",    "^[OP^[OM");  %% subs (query replace)
  10. %%
  11. %% The default binding for the quote keys (", ') is 'text_smart_quote'.
  12. %% Most users do not seem to like this so it is unset here.
  13.   setkey("self_insert_cmd",    "\"");
  14.   setkey("self_insert_cmd",    "'");
  15. %%
  16. %% In addition, if you want the ^H key to move to the beginning of line
  17. %% then uncomment the next two lines.
  18. %    unsetkey("^H");
  19. %  setkey("beg_of_line",    "^H");  %% beginning of line
  20. %% By default, these are bound
  21. %% to help functions (man page, etc...).
  22.  
  23. %% conventional subs key definition:
  24.   setkey("edt_subs",    "^[OP^[OM");  %% subs (edt style)
  25.  
  26. #ifdef MSDOS OS2
  27. NUMLOCK_IS_GOLD = 1; %% This sets the numlock key on the 'application keypad'
  28. #endif
  29.  
  30.   set_status_line("(Jed %v) EDT: %b   (%m%a%n%o)  %p,%c   Advance   %t", 1);
  31.  
  32. %%
  33. %% Escape sequences for EDT keypad:
  34. %%
  35. %% FP1 = ^[OP       FP2 = ^[OQ      FP3 = ^[OR       PF4 = ^[OS
  36. %%   7 = ^[Ow         8 = ^[Ox        9 = ^[Oy         - = ^[Om
  37. %%   4 = ^[Ot         5 = ^[Ou        6 = ^[Ov         , = ^[Ol
  38. %%   1 = ^[Oq         2 = ^[Or        3 = ^[Os
  39. %%            0 = ^[Op            . = ^[On         enter = ^[OM
  40.  
  41. WANT_EOB = 1;
  42. #ifdef UNIX VMS
  43.   tt_send("\e=");   % turn on application keypad
  44. #endif
  45.  
  46. !if (is_defined("Edt_Loaded"))
  47. { 
  48.    variable Edt_Loaded;
  49.    variable edt_pbuf;    %% a real buffer
  50.    edt_pbuf = " <edt>";
  51.    whatbuf();
  52.    setbuf(edt_pbuf);
  53.    sw2buf(());
  54. } 
  55.  
  56.  
  57. %% unset some of default jed keys--- lose window capability on "^W" one
  58. %% unsetkey ("^W");
  59. %% setkey ("redraw", "^W");
  60.  
  61. %% unsetkey("^K"); unsetkey %%-- unset this, we lose kill line in emacs.sl
  62. unsetkey("^U");             %% emacs.sl rebinds this to digit-arg
  63.  
  64. %% Give user ability to exit via GOLD-Q, GOLD-E
  65.   setkey("exit_jed", "^[OPQ");
  66.   setkey("exit_jed", "^[OPE");
  67. define quit() {exit_jed()}
  68. define exit() {exit_jed()}
  69.  
  70. %%
  71. %%  Gold-Gold to toggle keypad state
  72. %%
  73. #ifdef MSDOS OS2
  74.  unsetkey("^@;");
  75.   setkey("edt_togglekp",  "^@;");    %% IBM F1 key
  76. #endif
  77.  
  78. variable Edt_Keypad;  Edt_Keypad = 1;
  79.  
  80. define edt_togglekp ()
  81. {
  82.    variable on, off;
  83. #ifdef VMS UNIX
  84.    off = "Numeric.";  on =  "Application.";
  85. #else
  86.    on = "Gold ON"; off = "Gold OFF";
  87.    NUMLOCK_IS_GOLD = not(NUMLOCK_IS_GOLD);
  88. #endif
  89.  
  90. #ifdef UNIX VMS
  91.    if (Edt_Keypad) { off; "\e>" } else {on; "\e="}  tt_send(());
  92. #else
  93.    if (Edt_Keypad) off; else on;
  94. #endif
  95.    message(());
  96.    Edt_Keypad = not(Edt_Keypad);
  97. }
  98.  
  99.   setkey("edt_togglekp",    "^[OP^[OP");    %% Gold-Gold toggles keypad
  100. %  setkey("self_insert_cmd", "^I");    %% tab inserts tab.
  101.   setkey("edt_delbol",    "^U");    %% delete to bol
  102.   setkey("edt_help",    "^[OQ");    %% help
  103.   setkey("edt_findnxt",    "^[OR");    %% findnxt
  104.   setkey("edt_ldel",    "^[OS");    %% del l
  105.   setkey("edt_cdel",    "^[Ol");    %% del c
  106.   setkey("edt_wdel",    "^[Om");    %% del w
  107.   setkey("smart_set_mark_cmd",    "^[On");    %% select
  108.   setkey("edt_line",    "^[Op");    %% line
  109.   setkey("edt_word",    "^[Oq");    %% word
  110.   setkey("edt_eol",    "^[Or");    %% eol
  111.   setkey("edt_char",    "^[Os");    %% char
  112.   setkey("edt_advance",    "^[Ot");    %% advance
  113.   setkey("edt_backup",    "^[Ou");    %% backup
  114.   setkey("edt_cut",    "^[Ov");    %% cut
  115.   setkey("edt_page",    "^[Ow");    %% page
  116.   setkey("edt_sect",    "^[Ox");    %% sect
  117.   setkey("edt_append",    "^[Oy");    %% append
  118.   setkey("edt_help",    "^[OP^[OQ");    %% help
  119.   setkey("edt_find",    "^[OP^[OR");    %% find
  120.   setkey("edt_uldel",    "^[OP^[OS");    %% udel l
  121.   setkey("edt_ucdel",    "^[OP^[Ol");    %% udel c
  122.   setkey("edt_uwdel",    "^[OP^[Om");    %% udel w
  123.   setkey("edt_reset",    "^[OP^[On");    %% reset
  124.   setkey("edt_oline",    "^[OP^[Op");    %% open line
  125.   setkey("edt_chgcase",    "^[OP^[Oq");    %% chgcase
  126.   setkey("edt_deleol",    "^[OP^[Or");    %% deleol
  127. %%
  128. %%  There are two possible definitions for the specins key.  Let's choose
  129. %%  the edt one though I prefer the other
  130. %%
  131.   setkey("edt_specins",   "^[OP^[Os");    %% specins
  132. %  setkey("quoted_insert",    "^[OP^[Os");    %% specins
  133.   setkey("eob",        "^[OP^[Ot");    %% bottom
  134.   setkey("beg_of_buffer",    "^[OP^[Ou");    %% top
  135.   setkey("edt_paste",    "^[OP^[Ov");    %% paste
  136.   setkey("evaluate_cmd",    "^[OP^[Ow");    %% cmd
  137.   setkey("format_paragraph", "^[OP^[Ox");    %% fill
  138.   setkey("edt_replace",    "^[OP^[Oy");    %% replace
  139.   setkey("exit_mini",    "^[OM");    %% enter
  140. %%
  141. %% the enter key requires some care--- it MUST be put in the minibuffer
  142. %%   keymap.  But this is not created until AFTER the init files are loaded
  143. %%   so that it inherits user definitions.  The above line puts it in the
  144. %%   global map so that it behaves properly there.  The same applies to
  145. %%   the 'reset' command.
  146. %%
  147. %% The above comment WAS true in versions prior to 0.81.  Now it is possible
  148. %% to achieve the desired effect in the startup_hook.  I think it is time to 
  149. %% think of a way to chain functions.  That is, I would like to define a 
  150. %% function that startup_hook will call without explicitly modifying startup
  151. %% hook and not destroying other hooks in the process.  Thus, startup_hook
  152. %% should consist of a chain of functions to execute.
  153. %%
  154.  if (keymap_p("Mini_Map"))
  155.    { 
  156.       definekey("exit_mini", "^[OM", "Mini_Map");    %% enter
  157.       definekey("edt_reset", "^[OP^[On","Mini_Map"); %% reset
  158.    }
  159. %%
  160. %%  In EDT, a command may be repeated by GOLD number.  Lets have that too
  161. %%
  162.  _for (0, 9, 1) 
  163.     {
  164.        =$0;
  165.        setkey("digit_arg", strcat("\eOP", string($0)));
  166.     }
  167.  
  168. %% These are the keys on the vt220 keyboard
  169.   setkey("edt_find",          "^[[1~");    %%differs from vt220.sl
  170.   setkey("yank",            "^[[2~");    
  171.   setkey("kill_region",        "^[[3~");    
  172.   setkey("smart_set_mark_cmd",        "^[[4~");    
  173.   setkey("page_up",        "^[[5~");    
  174.   setkey("page_down",        "^[[6~");    
  175. %  setkey(evaluate_cmd",        "^[[29~");    
  176.   setkey("emacs_escape_x",    "^[[29~");    
  177.   setkey("edt_help",        "^[[28~");    
  178. %%
  179. %%  Finally some definitions for scrolling the screen left/right
  180. %%
  181.   setkey("beg_of_buffer", "^[OP^[[A");    % gold ^
  182.   setkey("eob",           "^[OP^[[B");    % gold v
  183.   setkey("scroll_left",   "^[OP^[[C");    % gold ->
  184.   setkey("scroll_right",  "^[OP^[[D");    % gold <-
  185.  
  186. %% The major complication is the direction.  Here it is:
  187. variable edt_dir; edt_dir = 1;
  188.  
  189. %!%ADVANCE - (4)
  190. %!%Sets the current direction to forward for the CHAR, WORD, LINE, EOL, PAGE,
  191. %!%SECT, SUBS, FIND, and FNDNXT keys.  ADVANCE means that movement will be
  192. %!%toward the end of the buffer; that is, to the right and down.
  193. define edt_advance()
  194. {
  195.    edt_dir = 1;
  196.   set_status_line("(Jed %v) EDT: %b   (%m%n%o)  %p,%c    Advance   %t", 1);
  197. }
  198.  
  199. %!%BACKUP - (5)
  200. %!%Sets the cursor direction to backward for the CHAR, WORD, LINE, EOL, PAGE,
  201. %!%SECT, SUBS, FIND, and FNDNXT keys.  BACKUP means that movement will be
  202. %!%toward the beginning of the buffer% that is, to the left and up.
  203. define edt_backup()
  204. {
  205.    edt_dir = -1;
  206.   set_status_line("(Jed %v) EDT: %b   (%m%n%o)  %p,%c    Backup    %t", 1);
  207. }
  208.  
  209. %% other buffers:  not buffers but strings except the char buffer which is int
  210. variable edt_wbuf, edt_lbuf, edt_cbuf;
  211. edt_wbuf = Null_String; edt_lbuf = Null_String; edt_cbuf = 0;
  212.  
  213. %% character (un)deletion
  214. define edt_cdel()
  215. {  
  216.    !if (eobp()) { edt_cbuf = what_char(); del(); }
  217. }
  218. define edt_ucdel()
  219. {
  220.    if (edt_cbuf) { insert_char (edt_cbuf); go_left(1); } 
  221. }
  222.  
  223. define edt_word()
  224. {
  225.    if (edt_dir == 1)
  226.      {
  227.     if (eolp()) return(go_right(1));
  228.     skip_word_chars(); skip_non_word_chars();
  229.      }
  230.    else
  231.      {
  232.     if (bolp()) return (go_left(1));
  233.     bskip_non_word_chars(); bskip_word_chars();
  234.      } 
  235. }
  236.  
  237. %!%DEL W - (-)
  238. %!%Deletes text from the cursor to the beginning of the next word, storing the
  239. %!%text in the delete word buffer.
  240. define edt_wdel()
  241. {
  242.    push_mark(); push_mark(); 
  243.    edt_word();            %% use whatever edt_word does as a region
  244.    edt_wbuf = bufsubstr();
  245.    del_region();
  246. }
  247.  
  248. %% another one from Clive Page.
  249. define edt_specins()
  250. {
  251.    insert_char (integer(read_mini("char code (decimal):", "27", Null_String)));
  252. }
  253.  
  254. %!%UND W - (GOLD -) 
  255. %!%Inserts the contents of the delete word buffer directly to the left of the
  256. %!%cursor.
  257. define edt_uwdel()
  258. {
  259.    push_spot(); insert (edt_wbuf); pop_spot();
  260. }
  261.  
  262. %% aparantly deleol also saves what it did in buffer...
  263. define edt_deleol()
  264. {
  265.    push_mark(); push_mark(); eol(); edt_lbuf = bufsubstr(); del_region();
  266. }
  267. define edt_delbol()
  268. {
  269.    push_mark(); push_mark(); bol(); edt_lbuf = bufsubstr(); del_region();
  270. }
  271.  
  272. %% the line
  273.  
  274. %!%DEL L - (PF4) 
  275. %!%Deletes text from the cursor position to the end of the current line, including
  276. %!%the line terminator.  If the cursor is positioned at the beginning of a line,
  277. %!%the entire line is deleted.  The deleted text is saved in the delete line
  278. %!%buffer.
  279. define edt_ldel()
  280. {
  281.    push_mark(); push_mark();
  282.    eol(); go_right(1);
  283.    edt_lbuf = bufsubstr();
  284.    del_region();
  285. }
  286.  
  287. %!%UND L - (GOLD PF4)
  288. %!%Inserts the contents of the delete line buffer directly to the left of the
  289. %!%cursor.
  290. define edt_uldel()
  291. {
  292.    push_spot(); insert (edt_lbuf); pop_spot();
  293. }
  294.  
  295. %!%FIND - (GOLD PF3) 
  296. %!%Searches for an occurrence of a string.  Press the FIND key and then enter the
  297. %!%string using the main keyboard.  End the string by pressing either the ADVANCE
  298. %!%or BACKUP key to set the direction of the search, or the ENTER key to search in
  299. %!%the current direction.
  300. define edt_find()
  301. {
  302.    if (edt_dir == 1) search_forward (); else search_backward ();
  303. }
  304.  
  305. %!%FNDNXT - (PF3)
  306. %!%Searches for the next occurrence of the search string previously entered with
  307. %!%the FIND key.  The direction of the search is the current one (ADVANCE or
  308. %!%BACKUP).
  309. define edt_findnxt()
  310. {
  311.    variable r, found;
  312.    r = 0;
  313.    if (strlen(LAST_SEARCH))
  314.      { 
  315.     if (edt_dir == 1)
  316.       {
  317.          r = right(1);
  318.          found = fsearch(LAST_SEARCH);
  319.       }
  320.     else found = bsearch(LAST_SEARCH);
  321.     !if (found)
  322.       { 
  323.          go_left(r);
  324.          error("Not Found.");
  325.       }
  326.      }
  327.    else error ("Find What?")
  328. }
  329.  
  330. %!%SECT - (8) 
  331. %!%Moves the cursor 16 lines (one section) forward or backward, depending on the
  332. %!%current direction (see ADVANCE and BACKUP).  The cursor is moved to the
  333. %!%beginning of the appropriate line.
  334. define edt_sect()
  335. {
  336.    if (edt_dir == 1) go_down(16); else go_up(16);
  337.    bol();
  338. }
  339.  
  340. define edt_eol()
  341. {
  342.    if (edt_dir == 1)
  343.      {
  344.     if (eolp()) go_down(1);
  345.      }
  346.    else go_up(1);
  347.    eol();
  348. }
  349.  
  350. define edt_line()
  351. {
  352.    if (edt_dir > 0) go_down(1); 
  353.    else if (bolp()) go_up(1);
  354.    bol();
  355. }
  356.  
  357. define edt_char()
  358. {
  359.    if (edt_dir == 1) go_right(1); else go_left(1);
  360. }
  361.  
  362. define edt_oline()
  363. {
  364.    newline(); go_left(1);
  365. }
  366.  
  367. %% reset also pops marks.
  368. define edt_reset()
  369. {
  370.    edt_advance();
  371.    while(markp()) pop_mark(0);
  372.    call ("kbd_quit");
  373. }
  374.  
  375. %% edt page searches for a form feed.  However, real edt allows user to
  376. %% change this.
  377.  
  378. %!%PAGE - (7)
  379. %!%Moves the cursor to the top of a page.  A page is defined by a delimiter
  380. %!%string, which can be set by the SET ENTITY command.  The default page
  381. %!%delimiter is the formfeed character (CTRL/L).
  382. define edt_page()
  383. {
  384.    variable ret, ff;
  385.    ff = char(12);
  386.    if (edt_dir == 1) ret = fsearch(ff); else ret = bsearch(ff);
  387.    if (ret) recenter(1);
  388. }
  389.  
  390. define edt_cut()
  391. {
  392.    variable b;
  393.    !if (dupmark()) return;
  394.    b = whatbuf();
  395.    setbuf(edt_pbuf);
  396.    erase_buffer();
  397.    setbuf(b);
  398.    copy_region(edt_pbuf);
  399.    del_region();
  400. }
  401. define edt_paste() 
  402. {
  403.    insbuf(edt_pbuf);
  404. }
  405.  
  406. %% Although not documented in EDT online help, this deletes the region.
  407. %!%APPEND - (9) 
  408. %!%Moves the select range to the end of the PASTE buffer.  The select range is all
  409. %!%the text between the selected position (see SELECT) and the current cursor
  410. %!%position.  If no SELECT has been made and the cursor is positioned on the
  411. %!%current search string, that string is appended.
  412. define edt_append()
  413. {
  414.    variable b;
  415.    b = whatbuf();
  416.    setbuf(edt_pbuf);
  417.    eob();
  418.    setbuf(b);
  419.    if (dupmark())
  420.      {
  421.     copy_region(edt_pbuf);
  422.     del_region();
  423.      }
  424.    else error("No Region.");
  425. }
  426.  
  427. define edt_replace()
  428. {
  429.    del_region(); edt_paste();
  430. }
  431.  
  432. %% a real edt_subs function
  433. %% deletes search string, substitutes what is in the pastebuffer and finds
  434. %% the next.
  435. define edt_subs()
  436. {
  437.    if (looking_at(LAST_SEARCH))
  438.      {
  439.     deln (strlen(LAST_SEARCH));
  440.     edt_paste();
  441.     !if (looking_at (LAST_SEARCH)) edt_findnxt();
  442.      }
  443.    else error("Select range not active.")
  444. }
  445.  
  446.  
  447. %% a help for the help key
  448. define edt_help()
  449. {
  450.    jed_easy_help("edt.hlp");
  451. }
  452.  
  453. %% Chngcase
  454. define edt_chgcase()
  455. {
  456.    variable n;
  457.    !if (markp())
  458.      {
  459.     push_mark();
  460.     n = strlen(LAST_SEARCH);
  461.     if (n and looking_at(LAST_SEARCH)) go_right(n);
  462.     else if (edt_dir == 1) go_right(1); 
  463.     else go_left(1);
  464.      }
  465.    xform_region('X');
  466. }
  467.  
  468. %% is this a better defn of what edt_replace should be?
  469. %!%REPLACE - (GOLD 9)
  470. %!%Deletes the select range and replaces it with the contents of the PASTE 
  471. %!%buffer.
  472. define edt_replace()
  473. {
  474.    variable n;
  475.    n = strlen(LAST_SEARCH);
  476.  
  477.    if (n and looking_at(LAST_SEARCH)) deln (n);
  478.    else 
  479.      {
  480.     !if (markp()) error("Select range not active.");
  481.     del_region();
  482.      }
  483.    edt_paste();
  484. }
  485.