GelbeSeiten Berlin 1995 - 1996/Image.iso/sprinter/shared.dir/00600_Main.ls

Text File | 1995-06-23 | 7.5 KB | 310 lines

on startMovie
end

on enterFrame
  global nowScreen, ScreenList, screenType
  set screenInfo to getAt(ScreenList, nowScreen)
  set screenType to item 3 of screenInfo
end

on exitFrame
  global screenType
  if screenType = "standard" then
    if the frameLabel = "<" then
      go(the frame)
    end if
  else
    if screenType = "nothing" then
      goScreen("next")
    else
      if screenType = "loop" then
        if the frameLabel = "<" then
          go(marker(-1))
        end if
      else
        if screenType = "splitScreen" then
          splitScreen_exitFrame()
        else
          if screenType = "doubleSplit" then
            doubleSplit_exitFrame()
          else
            if screenType = "animation" then
              animation_exitFrame()
            else
              if screenType = "rollover" then
                rollover_exitFrame()
              else
                if screenType = "tabelle" then
                  tabelle_exitFrame()
                end if
              end if
            end if
          end if
        end if
      end if
    end if
  end if
end

on mouseDown
  global screenType, click
  set click to the clickOn
  if screenType = "splitScreen" then
    splitScreen_mouseDown()
  else
    if screenType = "doubleSplit" then
      doubleSplit_mouseDown()
    end if
  end if
end

on mouseUp
  global screenType, click
  set click to the clickOn
  if the castNum of sprite click > 0 then
    set clickName to the name of cast the castNum of sprite click
    if clickName = "nextScreen" then
      goScreen("next")
    else
      if clickName = "prevScreen" then
        goScreen("prev")
      else
        if clickName = "menuScreen" then
          goScreen("menu")
        else
          if clickName = "indexScreen" then
            goScreen("index")
          end if
        end if
      end if
    end if
  end if
  if screenType = "animation" then
    animation_mouseUp()
  else
    if screenType = "tabelle" then
      tabelle_mouseUp()
    end if
  end if
end

on splitScreen_exitFrame
  if the stillDown = 1 then
    go(the frame)
  else
    go(marker(0))
  end if
end

on splitScreen_mouseDown
  global click, splitScreen
  if (click >= splitScreen) and (click <= (splitScreen + 3)) then
    go(the frame + click - (splitScreen - 1))
  end if
end

on doubleSplit_exitFrame
  if (the stillDown = 1) and (the frame = (marker(0) + 1)) then
    go(the frame)
  else
    if the frameLabel = "<" then
      go(marker(-1))
    else
      if the frame > (marker(0) + 1) then
        nothing()
      else
        go(marker(0))
      end if
    end if
  end if
end

on doubleSplit_mouseDown
  global click, splitScreen
  if click = splitScreen then
    go(the frame + 1)
  else
    if click = (splitScreen + 1) then
      go(the frame + 2)
    end if
  end if
end

on animation_exitFrame
  global animationButtons, animationDirection, animationMode
  if char 1 of the frameLabel = "<" then
    set animationDirection to -1
    set animationMode to 0
    go(the frame)
  else
    if the frameLabel <> EMPTY then
      set animationDirection to 1
      set animationMode to 0
      go(the frame)
    else
      if animationMode = 0 then
        go(the frame)
      else
        if animationDirection = -1 then
          go(the frame - 1)
        else
          if animationDirection = 1 then
            go(the frame + 1)
          end if
        end if
      end if
    end if
  end if
end

on animation_mouseUp
  global click, animationButtons, animationDirection, animationMode
  if the castNum of sprite click > 0 then
    set clickName to the name of cast the castNum of sprite click
    if clickName = "ani.rew" then
      set animationDirection to -1
      set animationMode to 0
      go(the frame - 1)
    else
      if (clickName = "ani.start/stop") and (animationMode = 0) then
        set animationMode to 1
        go(the frame + animationDirection)
      else
        if (clickName = "ani.start/stop") and (animationMode = 1) then
          set animationMode to 0
          go(the frame)
        else
          if clickName = "ani.for" then
            set animationDirection to 1
            set animationMode to 0
            go(the frame + 1)
          end if
        end if
      end if
    end if
  end if
end

on rollover_exitFrame
  global rollOverStart
  repeat with counter = 0 to 20
    if the castNum of sprite (rollOverStart + counter) = 0 then
      exit repeat
    end if
    if rollOver(rollOverStart + counter) = 1 then
      go(marker(0) + counter)
    end if
  end repeat
  go(the frame)
end

on tabelle_exitFrame
  global rollOverStart
  if the frame > marker(0) then
    repeat with counter = 0 to 20
      if the castNum of sprite (rollOverStart + counter) = 0 then
        exit repeat
      end if
      if rollOver(rollOverStart + counter) = 1 then
        go(marker(0) + counter + 1)
      end if
    end repeat
  end if
  go(the frame)
end

on tabelle_mouseUp
  global click
  if the castNum of sprite click > 0 then
    set clickName to the name of cast the castNum of sprite click
    if (clickName = "Special") and (the frame = marker(0)) then
      go(the frame + 1)
    else
      if clickName = "Special" then
        go(marker(0))
      end if
    end if
  end if
end

on goScreen screen
  global nowScreen, indexScreen, menuScreen, ScreenList
  put screen
  hiliteButton()
  if screen = "next" then
    if nowScreen < count(ScreenList) then
      set nowScreen to nowScreen + 1
    end if
  else
    if screen = "prev" then
      if nowScreen > 1 then
        set nowScreen to nowScreen - 1
      end if
    else
      if screen = "menu" then
        go("abflug")
        set nowScreen to menuScreen
      else
        if screen = "index" then
          set nowScreen to indexScreen
        else
          if stringp(screen) = 0 then
            set nowScreen to screen
          else
            if stringp(screen) = 1 then
              repeat with counter = 1 to count(ScreenList)
                if item 1 of getAt(ScreenList, counter) = screen then
                  set nowScreen to counter
                  exit repeat
                end if
              end repeat
            end if
          end if
        end if
      end if
    end if
  end if
  set screenInfo to getAt(ScreenList, nowScreen)
  set labelName to item 1 of screenInfo
  set movieName to item 2 of screenInfo
  if nowScreen > 1 then
    set screenInfo to getAt(ScreenList, nowScreen - 1)
    if item 3 of screenInfo = "animation" then
      preLoad(marker(-2), marker(-1))
    end if
  end if
  if nowScreen < count(ScreenList) then
    set screenInfo to getAt(ScreenList, nowScreen + 1)
    if item 3 of screenInfo = "animation" then
      preLoad(marker(1), marker(2))
    end if
  end if
  if the movieName = movieName then
    put labelName
    go(labelName)
  else
    go(labelName, movieName)
  end if
end

on hiliteButton
  global click
  if the castNum of sprite click > 0 then
    set clickName to the name of cast the castNum of sprite click
    put clickName
    put click
    repeat with counter = 26 to 28
      if sprite click intersects counter then
        set button to counter
        set buttonName to the name of cast the castNum of sprite button
        put buttonName
      end if
    end repeat
    set the castNum of sprite click to the number of cast (clickName & ".shadow")
    set the castNum of sprite button to the number of cast (buttonName & ".shadow")
    updateStage()
    set the castNum of sprite click to the number of cast clickName
    set the castNum of sprite button to the number of cast buttonName
  end if
end