Chip: Windows 95/WIN95_CD.ISO/sharewar/internet/qmodem/scripts.z/MAKEGEN3.QSC

Text File | 1995-07-20 | 9.7 KB | 279 lines

'
' This script is used to automatically create and add new dialing directory
' entry for GEnie.
'
'--------------------------------------------------------=[ Constants    ]=-
const WS_BORDER       = 0x00800000
const WS_VSCROLL      = 0x00200000
const WS_TABSTOP      = 0x00010000
const LB_RESETCONTENT = 0x0184
const LB_GETTEXT      = 0x0189
const LB_SETTABSTOPS  = 0x0192
const LBS_NOTIFY      = 0x0001
const LBS_SORT        = 0x0002
const LBS_USETABSTOPS = 0x0080
const LBS_STANDARD    = LBS_NOTIFY+WS_BORDER+WS_VSCROLL+WS_TABSTOP
const CB_GETLBTEXT    = 0x0148
const CB_RESETCONTENT = 0x014B

'---------------------------------------------------------------------------=[ Dialogs      ]=-
dialog Generator 5, 10, 205, 240
  caption "GENie Script Maker"
  groupbox "User Information", -1, 10, 10, 185, 55
  rtext "Your User Id", -1, 15, 25, 50, 15
  userid as edittext 101, 70, 25, 95, 15
  rtext "Your Password", -1, 15, 45, 50, 15
  password as edittext 102, 70, 45, 95, 15
  groupbox "Phone Information",-1, 10, 70, 185,75
  ltext "Phone Number", -1, 15,105, 70, 15
  areacode as edittext 103,100,105, 25, 15
  number as edittext   104,130,105, 60, 15
  ltext "Country"  ,    -1, 15,125, 40, 15
  country as combobox  105, 60,125,130, 50,LBS_STANDARD+LBS_SORT
  pushbutton "Search Phone Database", 112, 100, 85, 90, 15
  groupbox "Connection Information",-1,10,155,185,55
  ltext "Modem",        -1, 15,170, 40, 15
  modem as combobox    106, 60,170,130, 50
  ltext "Service",      -1, 15,190, 40, 15
  service as combobox  107, 60,190,130, 50
  defpushbutton "Make Script", 114, 15, 220, 50, 14
  pushbutton "Cancel", IDCANCEL, 75, 220, 50, 14
  pushbutton "Help", 113, 135, 220, 50, 14
end dialog

dialog phonesearch 6, 15, 310, 110
  caption "Search Phone Number List"
  ltext "Area Code",-1, 15,5,40,15
  scode as edittext 603,60,5,20,15
  ltext "Baud Rate",-1, 85,5,40,15
  srate as edittext 604,130,5,30,15
  ltext "State    ",-1,165,5,40,15
  sstate as edittext 605,210,5,20,15
  groupbox "Phone Number       City                        State           Supported Baud Rates",-1,10,20,290,65
  sresult as listbox 507,15,30,280,60,LBS_STANDARD+LBS_USETABSTOPS
  pushbutton "OK",IDOK,70,90,50,15
  pushbutton "Cancel",IDCANCEL,130,90,50,15
  pushbutton "Search",606,190,90,50,15
end dialog

dialog ServicesHelp 6, 15, 194, 119
  caption "Online Services Help"
  defpushbutton "OK", IDOK, 72, 97, 50, 14
  groupbox "", -1, 4, 4, 185, 86
  ltext "GEnie Script Generator is used to automaticallu create a script to call GENie.", -1, 10, 10, 170, 25
  ltext "Fill in User Name, Password, Area Code, Number, Country Code, and Modem.", -1, 10, 35, 170, 25
  ltext "The search button allows you search for numbers matching an area code.", -1, 10, 60, 170, 25
end dialog

'-----------------------------------------------------------------------=[ Type Declarations ]=-
type tabrecord
  tabs(1 to 3) as integer
end type

'-----------------------------------------------------------------------=[ Declarations      ]=-
declare Sub SendDlgItemMessageText lib "user32" alias "SendDlgItemMessageA" (hwnd as integer, id as integer, message as integer, wparam as integer, lparam as string)
declare function SendDlgItemMessageInt  lib "user32" alias "SendDlgItemMessageA" (hwnd as integer, id as integer, message as integer, wparam as integer, lparam as long) as long
declare function SendDlgItemMessageTab Lib "User32" Alias "SendDlgItemMessageA" (Hwnd as integer, Id as integer, Msg as integer, Wparam as integer, lparam as TabRecord) as integer

'-----------------------------------------------------------------------=[ Variables         ]=-
dim readstring as string
dim cinfo as countryinfo
dim sl as Generator
dim found as integer
dim count as integer
dim scriptname as string
dim n as string
dim search as phonesearch
dim searchname as string

'-----------------------------------------------------------------------=[ Functions         ]=-
function Generator.id(105) as integer
  n = spc(255)
  SendDlgItemMessageText (hwindow,105,CB_GETLBTEXT,country,n)
end function

function phonesearch.id(507) as integer
  n = spc(255)
  SendDlgItemMessageText (hwindow,507,LB_GETTEXT,sresult,n)
  dialogresult = IDOK
end function

function phonesearch.id(606) as integer
  dim sendmess as integer, totalfound as integer
  dim sfound as boolean

  if not ((scode = "") and (srate = "") and (sstate = "")) then
    totalfound = 0
    sendmess = SendDlgItemMessageInt (hwindow,507,LB_RESETCONTENT,0,0)
    if exists (searchname) then
      open searchname for input as #1
      do while not (eof (1))
        sfound = false
        input #1,readstring
        if (scode <> "") then
          if (srate <> "") then
            if (sstate <> "") then
              if (left (readstring,3) = scode) and (instr (mid (readstring,38,23),srate) <> 0) and (mid (readstring,35,2) = sstate) then sfound = true
            else
              if (left (readstring,3) = scode) and (instr (mid (readstring,38,23),srate) <> 0) then sfound = true
            end if
          else
            if (sstate <> "") then
              if (left (readstring,3) = scode) and (mid (readstring,35,2) = sstate) then sfound = true
            else
              if (left (readstring,3) = scode) then sfound = true
            end if
          end if
        else
          if (srate <> "") then
            if (sstate <> "") then
              if (instr (mid (readstring,38,23),srate) <> 0) and (mid (readstring,35,2) = sstate) then sfound = true
            else
              if (instr (mid (readstring,38,23),srate) <> 0) then sfound = true
            end if
          else
            if (sstate <> "") then
              if (mid (readstring,35,2) = sstate) then sfound = true
            end if
          end if
        end if
        if sfound then
          readstring = left (readstring,12)+chr(9)+mid(readstring,14,20)+chr(9)+mid(readstring,35,2)+chr(9)+mid(readstring,38,25)
          addlistboxitem (hwindow,507,readstring)
          totalfound = totalfound + 1
          sfound = false
        end if
      loop
      close #1
    end if
    if totalfound = 0 then
      addlistboxitem (hwindow,507,"No Records Found Matching Search Criteria!")
    end if
  else
    msgbox "You must select an Area Code, Baud Rate, and/or State to search"
  end if
  scode = ""
  srate = ""
  sstate = ""
end function

function GetUniqueScriptName(prefix as string) as string
  dim scrname as string
  scrname = ConfigScriptPath + "\" + prefix + ".QSC"
  dim i as integer
  i = 0
  do while exists(scrname)
    i = i + 1
    scrname = ConfigScriptPath + "\" + prefix + str(i) + ".QSC"
  loop
  GetUniqueScriptName = scrname
end function

function Generator.id(113) as integer
  dim help as ServicesHelp
  dialogbox help
end function

function Generator.id(112) as integer
  if sl.service = 0 then searchname = configscriptpath+"\geniereg.dat"
  if sl.service = 1 then searchname = configscriptpath+"\geniespr.dat"
  if dialogbox (search) = IDOK then
    if n <> "" then
      sl.areacode = left (n,3)
      sl.number   = mid  (n,5,8)
    end if
  end if
end function

function Generator.id(114) as integer
  if userid = "" then
    msgbox "You need to fill in your User ID."
    exit function
  end if

  if password = "" then
    msgbox "You need to fill in your password."
    exit function
  end if

  if (number = "") or (areacode = "") then
    msgbox "You need to fill in a phone number."
    exit function
  end if

  DialogResult = IDOK
end function

'---------------------------------------------------------------------------=[ Subroutines  ]=-
sub phonesearch.init
  dim t as tabrecord, result1 as integer
  t.tabs(1) =  60
  t.tabs(2) =  120
  t.tabs(3) =  140
  result1 = SendDlgItemMessageTab (HWindow, 507, LB_SETTABSTOPS, 3, t)
end sub

sub Generator.init
  userid   = ""
  password = ""
  areacode = ""
  number   = ""
  for count = 1 to getmodemcount
    addcomboboxitem (hwindow,106,getmodemname (count - 1))
  next count
  modem = 0
  addcomboboxitem (hwindow,107,"Standard GENie Connection")
  addcomboboxitem (hwindow,107,"GENie Connection Using SprintNet")
  service = 0
  if getfirstcountry (cinfo) then
    do
      readstring = pad (cinfo.name,150)+pad(str(cinfo.countryid),5)+pad(str(cinfo.countrycode),5)
      addcomboboxitem (hwindow,105,readstring)
    loop until not (getnextcountry (cinfo))
  end if
end sub

sub CreateGEnieScript
  print #1, "striphibit on"
  print #1, "duplex off"
  print #1, "delay 2"
  print #1, "send ""HHH"";"
  print #1, "waitfor ""U#="""
  print #1, "send lastconnectuserid + "","" + lastconnectpassword"
end sub

'---------------------------------------------------------------------------=[ Main         ]=-
MAIN:

if dialogbox(sl) = IDOK then
  scriptname = GetUniqueScriptName("genie")
  open scriptname for output as #1
  CreateGEnieScript
  close #1
  dim entry as phoneentry
  entry.name = "GEnie"
  entry.areacode = sl.areacode
  entry.number(1) = sl.number
  entry.userid = sl.userid
  entry.password = sl.password
  entry.scriptfile = scriptname
  entry.emulation = ansi
  entry.protocol = zmodem
  entry.iconrespath = "bbsicons.dll"
  entry.iconresid = 3
  entry.useareacountry = 1
  entry.tapidevice = getmodemname (sl.modem)
  entry.countryid   = val(mid(n,151,5))
  entry.countrycode = val(mid(n,156,5))
  if updatephoneentry (entry) then
    msgbox ("GEnie Entry Modified With New Information")
  else
    addphoneentry (entry)
    msgbox ("Phone directory entry for GEnie created.")
  end if
end if

catch err_fileopen
  msgbox "Could not create script: " + scriptname
  goto main