home *** CD-ROM | disk | FTP | other *** search
/ vim.ftp.fu-berlin.de / 2015-02-03.vim.ftp.fu-berlin.de.tar / vim.ftp.fu-berlin.de / runtime / dos / ftplugin / fortran.vim < prev    next >
Encoding:
Text File  |  2012-05-31  |  4.3 KB  |  124 lines
  1. " Vim settings file
  2. " Language:    Fortran 2008 (and older: Fortran 2003, 95, 90, 77, 66)
  3. " Version:    0.48
  4. " Last Change:    2012 Apr. 18
  5. " Maintainer:    Ajit J. Thakkar <ajit@unb.ca>; <http://www.unb.ca/chem/ajit/>
  6. " Usage:    Do :help fortran-plugin from Vim
  7. " Credits:
  8. " Useful suggestions were made by Stefano Zacchiroli, Hendrik Merx, and Ben
  9. " Fritz.
  10.  
  11. " Only do these settings when not done yet for this buffer
  12. if exists("b:did_ftplugin")
  13.   finish
  14. endif
  15.  
  16. let s:cposet=&cpoptions
  17. set cpoptions&vim
  18.  
  19. " Don't do other file type settings for this buffer
  20. let b:did_ftplugin = 1
  21.  
  22. " Determine whether this is a fixed or free format source file
  23. " if this hasn't been done yet
  24. if !exists("b:fortran_fixed_source")
  25.   if exists("fortran_free_source")
  26.     " User guarantees free source form
  27.     let b:fortran_fixed_source = 0
  28.   elseif exists("fortran_fixed_source")
  29.     " User guarantees fixed source form
  30.     let b:fortran_fixed_source = 1
  31.   else
  32.     " Modern Fortran allows both fixed and free source form
  33.     " assume fixed source form unless signs of free source form
  34.     " are detected in the first five columns of the first s:lmax lines
  35.     " Detection becomes more accurate and time-consuming if more lines
  36.     " are checked. Increase the limit below if you keep lots of comments at
  37.     " the very top of each file and you have a fast computer
  38.     let s:lmax = 500
  39.     if ( s:lmax > line("$") )
  40.       let s:lmax = line("$")
  41.     endif
  42.     let b:fortran_fixed_source = 1
  43.     let s:ln=1
  44.     while s:ln <= s:lmax
  45.       let s:test = strpart(getline(s:ln),0,5)
  46.       if s:test !~ '^[Cc*]' && s:test !~ '^ *[!#]' && s:test =~ '[^ 0-9\t]' && s:test !~ '^[ 0-9]*\t'
  47.     let b:fortran_fixed_source = 0
  48.     break
  49.       endif
  50.       let s:ln = s:ln + 1
  51.     endwhile
  52.     unlet! s:lmax s:ln s:test
  53.   endif
  54. endif
  55.  
  56. " Set comments and textwidth according to source type
  57. if (b:fortran_fixed_source == 1)
  58.   setlocal comments=:!,:*,:C
  59.   " Fixed format requires a textwidth of 72 for code
  60.   setlocal tw=72
  61.   " If you need to add "&" on continued lines so that the code is
  62.   " compatible with both free and fixed format, then you should do so
  63.   " in column 73 and uncomment the next line
  64.   " setlocal tw=73
  65. else
  66.   setlocal comments=:!
  67.   " Free format allows a textwidth of 132 for code but 80 is more usual
  68.   setlocal tw=80
  69. endif
  70.  
  71. " Set commentstring for foldmethod=marker
  72. setlocal cms=!%s
  73.  
  74. " Tabs are not a good idea in Fortran so the default is to expand tabs
  75. if !exists("fortran_have_tabs")
  76.   setlocal expandtab
  77. endif
  78.  
  79. " Set 'formatoptions' to break comment and text lines but allow long lines
  80. setlocal fo+=tcql
  81.  
  82. setlocal include=^\\c#\\=\\s*include\\s\\+
  83. setlocal suffixesadd+=.f08,.f03,.f95,.f90,.for,.f,.F,.f77,.ftn,.fpp
  84.  
  85. " Define patterns for the matchit plugin
  86. if !exists("b:match_words")
  87.   let s:notend = '\%(\<end\s\+\)\@<!'
  88.   let s:notselect = '\%(\<select\s\+\)\@<!'
  89.   let s:notelse = '\%(\<end\s\+\|\<else\s\+\)\@<!'
  90.   let s:notprocedure = '\%(\s\+procedure\>\)\@!'
  91.   let b:match_ignorecase = 1
  92.   let b:match_words =
  93.     \ '(:),' .
  94.     \ '\<select\s*case\>:' . s:notselect. '\<case\>:\<end\s*select\>,' .
  95.     \ s:notelse . '\<if\s*(.\+)\s*then\>:' .
  96.     \ '\<else\s*\%(if\s*(.\+)\s*then\)\=\>:\<end\s*if\>,'.
  97.     \ 'do\s\+\(\d\+\):\%(^\s*\)\@<=\1\s,'.
  98.     \ s:notend . '\<do\>:\<end\s*do\>,'.
  99.     \ s:notelse . '\<where\>:\<elsewhere\>:\<end\s*where\>,'.
  100.     \ s:notend . '\<type\s*[^(]:\<end\s*type\>,'.
  101.     \ s:notend . '\<forall\>:\<end\s*forall\>,'.
  102.     \ s:notend . '\<associate\>:\<end\s*associate\>,'.
  103.     \ s:notend . '\<enum\>:\<end\s*enum\>,'.
  104.     \ s:notend . '\<interface\>:\<end\s*interface\>,'.
  105.     \ s:notend . '\<subroutine\>:\<end\s*subroutine\>,'.
  106.     \ s:notend . '\<function\>:\<end\s*function\>,'.
  107.     \ s:notend . '\<module\>' . s:notprocedure . ':\<end\s*module\>,'.
  108.     \ s:notend . '\<program\>:\<end\s*program\>'
  109. endif
  110.  
  111. " File filters for :browse e
  112. if has("gui_win32") && !exists("b:browsefilter")
  113.   let b:browsefilter = "Fortran Files (*.f;*.for;*.f77;*.f90;*.f95;*.f03;*.f08;*.fpp;*.ftn)\t*.f;*.for;*.f77;*.f90;*.f95;*.f03;*.f08;*.fpp;*.ftn\n" .
  114.     \ "All Files (*.*)\t*.*\n"
  115. endif
  116.  
  117. let b:undo_ftplugin = "setl fo< com< tw< cms< et< inc<"
  118.     \ . "| unlet! b:match_ignorecase b:match_words b:browsefilter"
  119.  
  120. let &cpoptions=s:cposet
  121. unlet s:cposet
  122.  
  123. " vim:sw=2
  124.