Asymetrix Demo/Asymetrix.iso/prg/mtb30/advanced.ats

Text File | 1994-07-11 | 60.8 KB | 2,024 lines

ACTION    "Open a file using Common Open Dialog"
BEHAVIOR    "Opens a file that the user has chosen."
CATEGORY    Files
HANDLERS    buttonClick, buttonUp, buttonDown, buttonDoubleClick, rightButtonDown, rightButtonUp, rightButtonDoubleClick
ARG    caption    is    "Open"
ARG    prompt    is    "Choose the file to open"
ARG    extension    is    "*.txt"
ARG    Directory    is    "."
{
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg("$$Directory","$$extension","$$prompt","$$caption")
    if it <> null
        clear sysError
        openfile it
        if sysError <> null
            request "The file"&&it&&"could not be opened"
        end if
    end if
    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

SCRIPT "Insert a textline"
BEHAVIOR "Use if you need to insert a single line and maintain the fields sorted order."
CATEGORY Text
{
to get insertLine txt,newLine
    if txt is null
        return newLine
    end
    set start to 1  -- first textline
    set tlc to textlinecount(txt)
    set ending to tlc -- last textline
    local insertSpot
    while start <= ending
        set midPoint to (start+ending) div 2
        set middleLine to textline midPoint of txt
        conditions
            when newLine < middleLine as text
                -- start looking at values less than current midPoint
                set ending to midPoint-1
                set insertSpot to midPoint
            when newLine > middleLine as text
                -- start looking at values greater than current midPoint
                set start to midPoint+1
                set insertSpot to midPoint+1
            else
                -- the item already exists
                set insertSpot to midPoint
                break while
        end
    end
    if insertSpot > tlc
        put newLine before textline insertSpot of txt
    else
        put newLine&crlf before textline insertSpot of txt
    end
    return txt
end
}

SCRIPT "Get the name of MRU file"
BEHAVIOR "A method for getting the name of any of the MRU (most recently used) files listed at the bottom of the author level file menu."
CATEGORIES Files
{
to handle loadFile mAlias      -- possible custom message
-- Pass mAlias in from menuItemSelected.
-- See page 13-30 of the ToolBook User Manual for an example
        linkDLL sysToolBookDirectory & "tb30WIN.DLL"
            STRING     getIniVar(STRING,STRING,STRING)
                           -- section, item, file
        end linkDLL

        get getIniVar("files", mAlias, "toolbook.ini")
        request it
--        go to page 1 of book it    -- same as default behavior
        unlinkDLL sysToolBookDirectory & "tb30WIN.DLL"
end loadFile
}

ACTION    "Show or hide object(s) with transition"
BEHAVIOR    "Allows user to $$show an object with a transition effect"
CATEGORIES    Effects
ARG speed  oneOf  "slow,normal,fast" is "normal"
ARG effect oneOf     "blinds,dissolve,drip,fade,iris,push,puzzle,rain,slide,spiral,split,tear,turnPage,wipe,zoom"  is "fade"
ARG myObjects is     "objects of this page"     help "Set to a reference ($$myObjects) to an object or objects."
ARG show oneOf "show,hide" is "show"    help "Show hidden objects or hide shown objects."

{
-- This script works fine as is, but there are so many
-- variations, consider doing a little experimentation.
      set sysSuspendMessages to TRUE
    linkDLL "USER"
        int LockWindowUpdate(WORD)
    end    linkDLL
    set pObjList to $$myObjects
    if pObjList is Null and object of self is not in "page,background,book"
        set pObjList to self
    end if
    set sysLockScreen to true
    while (pObjList is not NULL)
        pop pObjList
        $$show it
    end

 -- Reset sysLockScreen, get rid of Windows' Paint message:
     get LockWindowUpdate(sysClientHandle)
    sysLockScreen = false
    get lockWindowUpdate(0)

    transition "$$effect $$speed" to this page
    unlinkDLL "USER"
}

SCRIPT    "Convert textlines to a list"
BEHAVIOR    "This handler converts a string delimited by CRLF's to a list delimited by commas."
CATEGORIES    Text
{
to get textLinesToList txt
    local STACK lst
    step i from textlinecount(txt) to 1 by - 1
        push textline i of txt onto lst
    end
    return lst
end textLinesToList
}

SCRIPT "Display 1-D array values"
BEHAVIOR "Displays the contents of a one-dimensional array."
CATEGORY Data
{
to handle request1DArray x[]
    local retval
    set d to dimensions(x)
    step i from 1 to d
        put x[i] after retval
        if i < d
            put crlf after retval
        end    if
    end    step
    request retval
end    request1DArray
}

SCRIPT "Display 2-D array values"
BEHAVIOR "Displays the contents of a two-dimensional array."
CATEGORY Data
{
  to handle request2DArray x[][]
    local retval
    set d to dimensions(x)
    step i from 1 to item 1 of d
        step j from 1 to item 2 of d
            put x[i][j] after retval
            if j < item 2 of d
                put tab after retval
            end    if
        end    step
        if i < item 1 of d
            put crlf after retval
        end    if
    end    step
    request retval
 end request2DArray
}

SCRIPT "Sorting a 1-D array"
BEHAVIOR "This is an OpenScript implementation of the standard recursive quick sort."
CATEGORIES Data
{
-- The next three handlers make up a
-- standard recursive QuickSort.
to handle quicksort fArray[] by reference
    system s_noSwap
    set s_noSwap to 0
    send quicksrt fArray, 1, dimensions ( fArray )
end    quicksort

to handle quicksrt fArray[] by reference, lo, hi
    system  s_noSwap
    if hi > lo
        send swap  fArray, lo, ((lo+hi) div 2)
        set lst to lo
        step i from (lo+1) to hi
            if fArray[i] < fArray[lo] as text
                increment lst
                send swap fArray, lst, i
            else
                increment s_noswap
            end
        end
        send swap fArray,lo,lst
           send quicksrt fArray, lo, lst-1
        send quicksrt fArray, lst+1,hi
       end
end    quicksrt

to handle swap fArray[] by reference, x, y
    local temp
    set temp to fArray[x]
    set fArray[x] to fArray[y]
    set fArray[y] to temp
end    swap
}

SCRIPT "Sorting a 2-D array"
BEHAVIOR "This is an OpenScript implementation of the standard recursive quick sort adjusted for two dimensions."
CATEGORIES Data
{
-- keep in mind that arrays are passed by reference, not by value
--
to handle twoDquicksort fArray[][] by reference,sortColumn,dtype
    system stbk_noSwap

    set stbk_noSwap to 0
    send twoDquicksrt fArray, 1, item 1 of dimensions(fArray),sortColumn,dtype
end

to handle twoDquicksrt fArray[][] by reference, lo, hi,sortColumn,dtype
    system  stbk_noSwap
    if hi > lo
        send swap  fArray, lo, ((lo+hi) div 2)
        set lst to lo
        step i from (lo+1) to hi
            conditions
                when dtype is "text"
                    set test to fArray[i][sortColumn] < fArray[lo][sortColumn] as text
                when dtype is "date"
                    set test to fArray[i][sortColumn] < fArray[lo][sortColumn] as date
                else
                    set test to fArray[i][sortColumn] < fArray[lo][sortColumn] as number
            end
            if test
                increment lst
                send swap fArray, lst, i
            else
                increment stbk_noswap
            end if
        end step
        send swap fArray,lo,lst

           send twoDquicksrt fArray, lo, lst-1,sortColumn,dtype
        send twoDquicksrt fArray, lst+1,hi,sortColumn,dtype
       end
end

to handle swap fArray[][] by reference, a, b
    local temp
    step i from 1 to item 2 of dimensions (fArray)
        set temp to farray[a][i]
        set farray[a][i] to farray[b][i]
        set farray[b][i] to temp
    end
end
}

SCRIPT "Using a RECT structure"
BEHAVIOR  "The following functions are useful for dealing with windows functions that require or return a RECT structure."
CATEGORIES Data
{
-- lst is a list of 4 integers
-- pRect is a locked pointer to 8 bytes
to handle setRect lst,pRect
    step i from 0 to 6 by 2
        pop lst
        get pointerInt(i,pRect,it)
    end
end

-- pRect is a locked pointer to 8 bytes
to get getRect pRect
    local retval
    step i from 6 to 0 by -2
        push pointerInt(i,pRect) onto retval
    end
    return retval
end
}

SCRIPT "Using Windows pointers"
BEHAVIOR "The following functions are helpful if you need to allocate a pointer for calling a Windows function."
CATEGORIES Windows
{
-- the link statements for needed functions below
to handle linkMemFunctions
    linkDLL "KERNEL"
        WORD     GlobalAlloc(WORD,DWORD)
        WORD     GlobalFree(WORD)
        WORD     GlobalHandle(WORD)
        POINTER GlobalLock(WORD)
        WORD     GlobalUnlock(WORD)
    end linkDLL
end    linkMemFunctions

to get getWinPointer nSize
    local word hMem
    local retValue
    hMem = GlobalAlloc(66,nSize)
    return GlobalLock(hMem)
end getWinPointer

to get freeWinPointer pMem
    local word hMem, retValue
    hMem = GlobalHandle(item 1 of pMem)
    retValue = GlobalUnlock(hMem)
    return GlobalFree(hMem)
end    freeWinPointer
}

ACTION    "Create shuffled array"
BEHAVIOR    "Creates an array with the elements 1 to $$num (num) in a random order."
CATEGORIES     Data
ARG    num is    "52"    help    "Enter the number of elements to be shuffled."
{
    local INT result[$$num]
    local LOGICAL table[$$num]

    set i to 1
    while i <= $$num
        set x to random($$num)
        if table[x] is not true
            set table[x] to true
            set result[i] to x
            increment i
        end    if
    end while
}

ACTION    "Find text in a list box"
BEHAVIOR    "Searches a list box (single or multi-select) for some text and selects the line that the text is on."
CATEGORIES    Text
ARG    searchText    is "What are you looking for?" help "Place your text here or modify the script accordingly."
ARG fieldName is "searchField" help "Set this to the name of the list box you want to search."
{
    set searchtext to "$$searchText"
--     or try
--     ask "What text would you like to search for?" with \
--    "$$searchText"
--     if it is null or it is "Cancel"
--        break
--    else
--         set searchText to it
--    end if
    set sysLockScreen to TRUE
    set oldFT to fieldType of field "$$fieldName"
    set fieldType of field "$$fieldName" to wordWrap
    search for searchText
    get item 3 of selectedTextState
    set fieldType of field "$$fieldName" to oldFT
     if it <> NULL
        set selectedTextLines of field "$$fieldName" to it
        set scroll of field "$$fieldName" to it - 1
    else
        request QUOTE & searchText & QUOTE && "was not found."
    end if
}

SCRIPT "Limit the length of an entry"
BEHAVIOR "When a key is pressed, this handler checks that the charCount of the text of the field is within the limits specified in the script."
CATEGORY Data
{
-- does not allow entry of more than specified
-- amount of characters. Place this hander in a field.
to handle keyChar keyPressed
    local INT maxCharAllowed
    local INT currentCount
    maxCharAllowed = 10
    currentCount = charCount(my text)
    if (currentCount >= maxCharAllowed) \
     or (keyPressed = keyEnter and currentCount >= \
     maxCharAllowed - 1)
        beep 1
    else
        forward
    end    if
end    keyChar
}


SCRIPT "Enable overwrite in a field"
BEHAVIOR "Allows a field to toggle between Insert and Overwrite mode common to many word processors."
CATEGORY Text
{
to handle keyDown key
    system LOGICAL overWriteFlag
    if key is keyInsert
        set overWriteFlag to not overWriteFlag
    end if
    forward
end    keyDown

to handle keyChar key
    system LOGICAL overWriteFlag
    set sysLockScreen to true

    if overWriteFlag and (key <> keyBack)
        send clear
    end if
    forward
end    keyChar
}

ACTION    "Sum the lines in a text field"
BEHAVIOR    "This script adds the numbers on each line in the text field $$numbers and puts the result in the text field $$total."
CATEGORIES    Math
ARG    numbers    is    "numbers"    help "The name of the field that has the numbers in it."
ARG    total    is    "total"    help "The name of the field that will have the total in it."
{
    set total to 0
    step i from 1 to textLineCount(text of field "$$numbers")
        set temp to (textline i of text of field "$$numbers")
        set total to total + temp
    end
    put total into text of field "$$total"
}

SCRIPT "Get the sine from points"
BEHAVIOR "Get the sine of an angle as described by two points and the default coordinate system."
CATEGORY Math
{
to get sinFromPoints x1,x2,y1,y2
    x = abs(x2 - x1)
    y = abs(y2 - y1)
    conditions
    when x = 0
        r = 1
    when y = 0
        r = 0
    else
    -- this is where your high school algebra comes back to you
        r = y/sqrt(x^2 + y^2)
    end conditions
    if y2 < y1
        r = -r
    end if
    return r
end sinFromPoints
}

SCRIPT "Get the cosine from points"
BEHAVIOR "Get the cosine of an angle as described by two points and the default coordinate system."
CATEGORY Math
{
to get cosFromPoints x1,x2,y1,y2
    x = abs(x2 - x1)
    y = abs(y2 - y1)
    conditions
    when x = 0
        r = 0
    when y = 0
        r = 1
    else
    -- this is where your high school algebra comes back to you
        r = x/sqrt(x^2 + y^2)
    end conditions
    if x2 < x1
        r = -r
    end if
    return r
end cosFromPoints
}

SCRIPT "Get the angle between points"
BEHAVIOR "Returns the angle between a point on a vector (like an animation) and another point (like a mouse click)."
CATEGORY  Math
{
to get myAngle loc, obj, vector
    -- loc is (possibly) where the mouse was clicked
    -- obj is an object reference to something (moving?) on a
    -- vector, which is really a direction defined by a point, so it's a point
    -- like this:

    -- . vector
    --  \      . loc
     --   \    /
    --    \  /
    --       . obj

    -- what's the angle?
    -- returns angle in radians

    system s_2PI,s_PIdiv2
    -- only calculate these once
    if s_2PI is null
        set s_2PI to 2 * PI
    end if

    if s_PIdiv2 is null
        set s_PIdiv2 to PI/2
    end if

    -- see "Get the center of an object"
    set yCenter to objectCenter (obj)
    pop yCenter into xCenter
    set yOffset to loc
    pop yOffset into xOffset
    -- You may want these next two as system variables, because
    -- they're no likely to change.
    set yVec to vector
    pop yVec into xVec
    --     see "Get the cosine from points" and "Get the sine from points"
    set mouseSin to (sinFromPoints(xCenter,yCenter,xOffset,yOffset))
    set mouseCos to (cosFromPoints(xCenter,yCenter,xOffset,yOffset))
    set vecSin to (sinFromPoints(xCenter,yCenter,xVec,yVec))
    set vecCos to (cosFromPoints(xCenter,yCenter,xVec,yVec))

--    angle between them is: arctan(x2/y2) - arctan(x1/y1)
    set myAngle to ((aTan2(vecCos,vecSin)) - (aTan2(mouseCos,mouseSin)) + s_PIdiv2) -- adjust quadrant

 -- determine the quadrant
    if myAngle > PI
        if myAngle > s_2PI
            set myAngle to myAngle mod s_2PI
        else
            set myAngle to (myAngle mod PI) - PI
        end if
    end if
    return myAngle
end myAngle
}

SCRIPT "Search and replace text"
BEHAVIOR "This function searches 'txt' for all occurrences of 'searchString' and replaces it with 'replaceString'."
CATEGORIES Utilities
{
-- this function searches txt for all occurrences of searchString
-- and replaces it with replaceString.
-- If asWord is true, replaceString replaces searchString only where
-- searchString appears as a word.
-- (A word is defined as a string that is preceded and followed by
-- either the beginning or end of txt, or by any character in the
-- wordDelimit string.  The wordDelimit string contains
-- space, tab, crlf, and common punctuation and mathematical operators.)

to get searchReplace txt,searchFor,replaceWith,asWord
    if asWord is null
        set asWord to "false"
    end if
    runningTotal = 1
    totalChars=charcount(txt)
    searchLen=charcount(searchFor)
    replaceLen=charcount(replaceWith)
    -- this string contains all characters that are legally adjacent
    -- to a word.
    wordDelimit = " " & tab & crlf & "-+*/<>,()[];^=&.?':" & quote
    while runningTotal <= totalChars
        set curTxt to chars runningTotal to totalChars of txt
        curOffset = offset(searchFor,curTxt)
        if curOffset = 0
            break while
        else
            startPos = (runningTotal+curOffset-1)
            endPos = (runningTotal+curOffset+searchLen-2)
            if asWord is true
                -- test if this occurance is an isolated word:
                if not ((startPos = 1 or char (startPos - 1) \
                 of txt is in wordDelimit) and\
                 (endPos = totalChars or char endPos + 1 \
                 of txt is in wordDelimit))
                     increment runningTotal by curOffset+searchLen-1
                    continue while
                end if
            end    if
            set chars startPos to endPos of txt to replaceWith
            increment runningTotal by curOffset+replaceLen-1
            increment totalChars by replaceLen - searchLen
        end    if
    end    while
    return txt
end    searchReplace
}

SCRIPT "Change the behavior of the Back command"
BEHAVIOR "Provides an alternative to the standard behavior of ToolBook's 'Back' command"
CATEGORY Navigation
{
to handle enterApplication
    system s_backMessageSent
    -- initialize system variable
    s_backMessageSent = false
    -- turn off syshistory
    syshistoryrecord = false
    clear syshistory
    forward
end enterApplication

to handle leavePage
    system s_backMessageSent
    -- only puts page on syshistory if navigation is *not* initiated by BACK
    if targetWindow is mainWindow
        if s_backMessageSent is false
            push this page onto syshistory
        else
            s_backMessageSent = false
        end
    end if
    forward
end leavePage

to handle back
    system s_backMessageSent
    if itemcount(syshistory) > 0
        s_backMessageSent = true
        pop syshistory
        in mainwindow
            go to it
        end in
    else
        request "You are already all the way back."
    end if
end back
}

SCRIPT "Multi-select field becomes extend-select"
BEHAVIOR "This script will make a multi-select field much more versatile, acting like a single-select, multi-select or extend-select"
CATEGORIES Utilities
{
to handle buttonDown loc,isShift,isControl
    -- Script in field to be ExtendSelect
    -- Click without shift, then click with shift for extended selection
    -- Hold ctrl for normal multi-select
    -- Without shift or control for normal single-select
    system WORD s_shiftStart
     -- fieldType must be multiSelect for this to work
    if fieldType of self <> "multiSelect"
        fieldType of self = multiSelect
    end if
     sysLockScreen = TRUE
    conditions
    when isShift
        if s_shiftStart is not null
            shiftEnd = item 1 of textFromPoint(loc)
            if shiftEnd < s_shiftStart
                counter = -1
            else
                counter = 1
            end if
            clear my selectedTextlines
            step i from s_shiftStart to shiftEnd by counter
                push i onto my selectedTextlines
            end step
        end if
        break buttonDown
    when not isControl
        clear my selectedTextlines
        my selectedTextlines = item 1 of textFromPoint(loc)
        sysLockScreen = FALSE
    end conditions
    s_shiftStart = item 1 of textFromPoint(loc)
    forward
end buttonDown
}

SCRIPT "Drag objects"
BEHAVIOR "Easy way to drag objects around at reader level."
CATEGORY Utilities
{
to handle buttonDown loc
    local STACK bnds,mouseOffset
    linkDLL "user"
        int getsystemmetrics(int)
    end    linkDLL

    -- check if the user has swapped mouse buttons.
    if getsystemmetrics(23) >0
        set leftMouseButton to keyRightButton
    else
        set leftMouseButton to keyLeftButton
    end    if

    unlinkDLL "user"
    set bnds to bounds of target
    set mouseOffset to item 1 of loc - item 1 of bnds,\
      item 2 of loc - item 2 of bnds

    while keystate(leftMouseButton)is down
        newloc = sysMousePosition
        if newLoc <> loc
            set position of target to \
              item 1 of newLoc-item 1 of mouseOffset,\
              item 2 of newLoc-item 2 of mouseOffset
            set loc to newLoc
        end    if
    end while
end    buttonDown
}

SCRIPT    "Draw a selection rectangle"
BEHAVIOR    "Draws a selection rectangle (rubber band) for selecting and clearing objects at reader level."
CATEGORIES    Draw
{
to handle buttonDown loc
    system xy
    set myObj to objectFromPoint (loc)
    if myObj = NULL or object of parent of myObj = background
        draw rectangle from loc to loc
        set name of selection to "selectionRectangle"
        set transparent of selection to TRUE
        set lineStyle of selection to dotted
        set xy to position of selection
    end if

end buttonDown


to handle buttonStillDown
    send drawSelectionRectangle
end buttonStillDown

to handle buttonUp
    if selectionRectangleDrawn of this page <> TRUE
        break
    end if
    set x to item 1 of bounds of selection
    set y to item 2 of bounds of selection
    set cx to item 3 of bounds of selection
    set cy to item 4 of bounds of selection
    step i from 1 to itemCount (objects of this page)
        if x < item 1 of bounds of item i of objects of this page and \
            y < item 2 of bounds of item i of objects of this page and \
            cx > item 3 of bounds of item i of objects of this page and \
            cy > item 4 of bounds of item i of objects of this page

            extend select item i of objects of this page
        end if
    end step
    if itemCount (selection) >= 2 -- 1 = selectionRectangle
        -- modify this clause for different behavior
        request "Delete all enclosed objects?" with "Yes" or "No"
        if it = "Yes"
            send clear
        else
            set selection to rectangle "selectionRectangle"
            send clear
        end if
    else
        set selection to rectangle "selectionRectangle"
        send clear
    end if
end buttonUp

to handle drawSelectionRectangle
    system xy
    set selectionRectangleDrawn of this page to TRUE
    if item 1 of sysMousePosition < item 1 of xy and \
        item 2 of sysMousePosition > item 2 of xy
        set thirdQuadrant to TRUE
    else
        set thirdQuadrant to FALSE
    end if

    if item 1 of sysMousePosition > item 1 of xy and \
        item 2 of sysMousePosition < item 2 of xy
        set firstQuadrant to TRUE
    else
        set firstQuadrant to FALSE
    end if

    conditions
      when not thirdQuadrant and not firstQuadrant
          set temp to xy
         set item 3 of temp to item 1 of sysMousePosition
         set item 4 of temp to item 2 of sysMousePosition

      when thirdQuadrant and not firstQuadrant
          set temp to sysMousePosition
          set item 2 of temp to item 2 of xy
          set item 3 of temp to item 1 of xy
          set item 4 of temp to item 2 of sysMousePosition

     when not thirdQuadrant and firstQuadrant
         set temp to sysMousePosition
         set item 1 of temp to item 1 of xy
         set item 3 of temp to item 1 of sysMousePosition
         set item 4 of temp to item 2 of xy

    end conditions
    set bounds of selection to temp
end drawSelectionRectangle
}

SCRIPT    "Resize a polypoint object"
BEHAVIOR    "This handler will proportionally size any polygon, irregularPolygon, line, angledLine, or curve."
CATEGORIES    Draw
{
-- Proportionally resizes current object by percentage:
-- Example: to make a polygon 90% of its original size,
-- you'd call this function like this:
-- send resize polygon "foo",.9

to handle resize curObj,amount
    set b to bounds of curobj
    -- get center of object
    set cx to item 1 of b + (item 3 of b - item 1 of b) /2
    set cy to item 2 of b + (item 4 of b - item 2 of b) /2
    -- make sure object has settable vertices
    set curObjType to object of curObj
    if curObjType is not in \
     "polygon,irregularPolygon,line,angledLine,curve"
        break
    end    if
    set v to vertices of curObj
    -- walk through vertices, convert to polar, resize each vector,
    -- convert back
    step i from 1 to itemCount(v) by 2
        set x to item i of v
        set y to item i+1 of v
        -- x,y distance of each point from center
        set dx to x-cx
        set dy to y-cy
        -- find length and angle of vector:
        -- atan2 is undefined at x=0,y=0:
        if dx=0 and dy=0
            set radians to 0
            set h to 0
        else
            -- resize occurs here
            set h to hypotenuse(dx,dy)*amount
            set radians to atan2(dy,dx)
        end    if
        set item i of v to cx+cos(radians)*h
        set item i+1 of v to cy+sin(radians)*h
    end    step
    set vertices of curObj to v
end resize
}

SCRIPT    "Search and replace in all a book's scripts"
BEHAVIOR    "Searches through all the scripts of a book for a string and replaces it."
CATEGORIES    Debug
{
to handle SearchNReplace
    set sysTimeFormat to "seconds"
    local szBackgroundName
    clear sysError
    ask "Enter text to be replaced:"
    if sysError <> "cancel" and it is not null
        set textToReplace to it
    else
        break buttonUp
    end    if
    ask "Enter text to replace" && textToReplace && "with:"
    if sysError <> "cancel" and it is not null
        set replaceText to it
    else
        break buttonUp
    end    if
    set startTime to sysTime
    set sysCursor to 4
    if script of this book contains textToReplace
        step i from 1 to wordCount(script of this book)
            if word i of script of this book = textToReplace as text
                put replaceText into word i of script of this book
            end    if
        end    step
    end    if
    step n from 1 to pageCount of this book
        go to page n
        step i from 1 to itemCount(objects of this page)
            if script of item i of objects of this page contains textToReplace
                step j from 1 to wordCount(script of item i of objects of this page)
                    if word j of script of item i of objects of this page = textToReplace as text
                        put replaceText into word j of script of item i of objects of this page
                    end    if
                end    step
            end if
            if object of item i of objects of this page is group
                get groupReplace(item i of objects of this page, \
                        textToReplace,replaceText)
            end    if
        end    step
        if uniqueName of this background <> szBackgroundName as text
            set szBackgroundName to uniqueName of this background
            step i from 1 to itemCount(objects of this background)
                if script of item i of objects of this background contains textToReplace
                    step j from 1 to wordCount(script of item i of objects of this background)
                        if word j of script of item i of objects of this background = textToReplace as text
                            put replaceText into word j of script of item i of objects of this background
                        end    if
                    end    step
                end if
                if object of item i of objects of this background is group
                    get groupReplace(item i of objects of this background, \
                            textToReplace,replaceText)
                end    if
            end
            if script of this background contains textToReplace
                step i from 1 to wordCount(script of this background)
                    if word i of script of this background = textToReplace as text
                        put replaceText into word i of script of this background
                    end    if
                end    step
            end    if
        end    if
        if script of this page contains textToReplace
            step i from 1 to wordCount(script of this page)
                if word i of script of this page = textToReplace as text
                    put replaceText into word i of script of this page
                end    if
            end    step
        end    if
    end    step
    request "Elapsed: " && sysTime - startTime && "seconds."
    set sysCursor to default
end    SearchNReplace

to get groupReplace groupID,textToReplace,replaceText
    step i from 1 to itemCount(objects of groupID)
        if script of item i of objects of groupID contains textToReplace
            step n from 1 to wordCount(script of item i of objects of groupID)
                if word n of script of item i of objects of groupID = textToReplace as text
                    put replaceText into word n of script of item i of objects \
                            of groupID
                end    if
            end    step
        end    if
        if object of item i of objects of groupID is group
            get groupReplace(item i of objects of groupID,textToReplace, \
                    replaceText)
        end    if
    end    step
    return true
end    groupReplace
}

SCRIPT "Compact a ToolBook file"
BEHAVIOR "Automates the process of doing garbage collection on a book. Guaranteed to work."
CATEGORY Debug
{
-- from the scrap book
to handle compactBook
    LOCAL lpMem, tempFile
    LOCAL INT status

    send linkDlls
    lpMem = getWinPointer(192)
    if lpMem = NULL
        break to system
    end

    sysCursor = 4
    status = GetTempFileName(0,"tbk",0,lpMem)
    tempFile = pointerString(0,lpMem)
    fileName = name of this book
    save as tempFile,TRUE
    save as fileName,TRUE
    get freeWinPointer(lpMem)
    get removeFile(tempFile)
    syscursor = default
end    compactBook


to handle linkDlls
    linkDLL "kernel"
        WORD    globalAlloc         (WORD,DWORD)
        WORD    globalFree           (WORD)
        POINTER globalLock           (WORD)
        WORD    globalUnlock         (WORD)
        WORD    globalReAlloc       (WORD,DWORD,WORD)
        WORD     globalHandle        (INT)
        INT     getTempFileName        (INT,STRING,WORD,POINTER)
    end    linkDLL

    linkDLL sysToolBookDirectory & "tb30dos.dll"
        INT     removeFile             (STRING)
    end linkDLL
end    linkDLLs


to get getWinPointer memChunk
    LOCAL memHandle, lPointer

    memHandle = globalAlloc(66, memChunk)    -- FIXED,ZEROINIT
    if memHandle = NULL
        return NULL
    end    if

    lPointer = globalLock(memHandle)
    if lPointer = NULL
        return NULL
    end    if

    return lPointer
end    getWinPointer


to get freeWinPointer lpointer
    LOCAL WORD memHandle
    LOCAL INT status
    LOCAL LOGICAL passFlag

    passFlag = TRUE

    if lpointer = NULL or item 1 of lpointer < 0
        return FALSE
    end    if

    memHandle = globalHandle(item 1 of lpointer)

    status = globalUnlock(memHandle)
    if status <> 0
        passFlag = FALSE
    else
        status = globalFree(memHandle)
        if status <> 0
            passFlag = FALSE
        end    if
    end    if
    return passFlag
end    freeWinPointer
}

SCRIPT "Unpack a DWord to three bytes"
BEHAVIOR    "Takes a DWord and unpacks it into three bytes. Useful for getting colors and MIDI messages from Windows."
CATEGORIES    Utilities
{
to get explicitByte packedDWord
    r = (packeddword mod 256)
    g = (packeddword mod 65536) bitShiftRight 8
    b = packeddword bitShiftRight 16
    push b onto it
    push g onto it
    push r onto it
    return it
end    explicitByte
}

SCRIPT "Pack three bytes into a DWord"
BEHAVIOR    "Takes three bytes and packs them into a DWord. Useful for sending colors and MIDI messages to Windows."
CATEGORIES    Utilities
{
to get packDWord rgb
    set r to item 1 of rgb
    set g to item 2 of rgb
    set b to item 3 of rgb
    set it to r + (g bitShiftLeft 8) + (b bitshiftLeft 16)
    return it
end    packDWord
}
ACTION    "Create a link to timeGetTime()"
BEHAVIOR    "Create a link to timeGetTime() for timing events. This is a better timer than getTickCount."
CATEGORY    Windows
{
    linkdll "mmSystem"
        DWORD timeGetTime()
    end
}

ACTION    "Flash screen"
BEHAVIOR    "Causes the ToolBook window to flash $$times times at a rate of approx. $$speed flashes per second."
CATEGORIES    Effects
ARG times is "5"  help "Can be any number of times."
ARG    speed is "100"    help "The larger the number, the faster it flashes."
{
--to handle flash  -- suggested custom message
    linkDLL "kernel"
          word     globalAlloc(word,dword)
        pointer globalLock(word)
        word     globalUnlock(word)
        word     globalFree(word)
    end    linkDLL

   linkDLL "user"
        word     invertRect(word,pointer)
        word     getClientRect(word,pointer)
        word     getDC(word)
        int     releaseDC(word,word)
    end    linkDLL

    set vHmem to globalAlloc(66, 8)
    set vPtrMem to globalLock(vHmem)
    get getClientRect(sysClientHandle,vPtrMem)
    set vHDC to getDC(sysClientHandle)
    set newSpeed to 1000/$$speed

    step i from 1 to $$times
        get invertRect(vHDC,vPtrMem)
        pause newSpeed ticks
        get invertRect(vHDC,vPtrMem)
        pause newSpeed ticks
    end step

    get releaseDC (sysClientHandle,vHDC)
    get GlobalUnlock(vHmem)
    get GlobalFree(vHmem)
    unlinkDLL "kernel"
    unlinkDLL "user"
--end
}

SCRIPT    "Find the execution time"
BEHAVIOR    "Use these two handlers to make timing tests. They will automatically compare two tests run in a row."
CATEGORIES    Debug
{
to handle startTime
    system s_testTime
    linkDLL "mmSystem"
        DWORD timeGetTime()
    end    linkDLL
    set s_testTime to timeGetTime()
end    startTime

to handle showElapsedTime
    system s_testTime, s_lastTestTime

    set thisTestTime to (timeGetTime() - s_testTime) / 1000
    format number thisTestTime as "#.0"

    set prompt to "This test took" && thisTestTime && "seconds."
    if s_lastTestTime <> 0 and s_lastTestTime is not null
        get (thisTestTime - s_lastTestTime)
        set deltaTime to (it / min(s_lastTestTime,thisTestTime)) * 100
        format number deltaTime as "#.0"
        if deltaTime <> 0

            conditions
            when deltaTime < 0
                set relation to "faster"
            when deltaTime > 0
                set relation to "slower"
            end    conditions

            get abs(deltaTime)
            format number it as "#.0"
            put " It was" && it & "%" && relation &&\
              "than the previous test." after prompt
        end    if
    end    if
    request prompt
    set s_lastTestTime to thisTestTime
    unlinkDLL "mmSystem" -- decrement refCount
end    showElapsedTime
}

SCRIPT "Initialize a conversation with Excel"
BEHAVIOR "This function will run Excel if it is not running already.  If a filename is passed to this function it will tell Excel to load that file if it is not loaded already."
CATEGORY Windows
{
to get InitializeExcel fileNameToRun

    -- Get the current status of Excel
    getRemote "Status" application "Excel" topic "System"

    -- If it failed because there is no server
    -- run excel
    if item 1 of sysError = "Failed: No Server"
        linkDLL sysToolBookDirectory & "tb30win.dll"
            INT yieldApp()
        end linkDLL
        run "excel.exe" && fileNameToRun
        -- give excel a break
        get yieldApp()
        getRemote "Status" application "Excel" topic "System"
        unlinkDLL sysToolBookDirectory & "tb30win.dll"
      end    if

      -- getRemote status should return Ready
    if it <> "Ready"
        return FALSE
    end if

       -- Make sure that it is not minimized
    executeRemote "[App.Restore()]" application "excel"

    -- If no file has been specified then return successfully
    if fileNameToRun = NULL
        return TRUE
    end if

    -- Check to see if fFileName is open and, if so,
    -- make it active
    executeRemote "[Activate(""" & fileNameToRun & """)]" \
     application "excel" topic fileNameToRun

    -- If it failed because there is no server then try
    -- opening the file
    if item 1 of sysError = "Failed: No Server"
        executeRemote "[Open(""" & fileNameToRun & """)]" \
         application "excel"
    end if

    -- If sysError is OK then success
    if item 1 of sysError = "OK"
        return TRUE
    end if
    return FALSE
end    InitializeExcel
}

SCRIPT "Bring a ToolBook window to the front"
BEHAVIOR "Dynamically brings a ToolBook window to the front. Useful when running different ToolBook applications from a central book."
CATEGORY Windows
{
to handle bringWindowToFront appNameToRun

    linkDLL "user"
        --bringWindowToTop is a Windows function that
        --puts the Window whose window handle is passed to it
        --in front of all the other windows.
        INT bringWindowToTop(WORD)
    end linkDLL

    --getRemote returns 9 separate items in sysError
    --item 1 is the status of the remote request
       getRemote "sysWindowHandle" application  toolBook topic appNameToRun
    if (item 1 of sysError) is "OK"
        get bringWindowToTop(it)
        --bringWindowToTop doesn't size to page or even
        --restore it
        executeRemote "send SizeToPage" application toolbook \
         topic appNameToRun
    else
        --the app isn't running, so we'll start it
        run appNameToRun
    end if

    unlinkDLL "user"
end bringWindowToFront
}

SCRIPT    "Get the screen resolution"
BEHAVIOR    "Sets the variable screenResolution to the screen resolution."
CATEGORY    Windows
{
to get screenRes
    local hRes, vRes, screenResolution

    linkDLL sysToolBookDirectory & "tb30win.dll"
        INT horizontalDisplayRes()
        INT verticalDisplayRes()
    end    linkDLL
    set hRes to horizontalDisplayRes()
    set vRes to verticalDisplayRes()

    push vRes onto screenResolution  -- item 2 is verticle resolution
    push hRes onto screenResolution  -- item 1 is horizontal resolution

    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return screenResolution
end screenRes
}

SCRIPT "Get the resolution of the printer"
BEHAVIOR "Returns the dot per inch that the printer prints"
CATEGORY Windows
{
to get printerRes
    linkDll "GDI"
        WORD     createIC    (STRING,STRING,STRING,STRING)
        INT    getDeviceCaps    (WORD,INT)
        INT     deleteDC     (WORD)
    end linkDLL

    linkDLL sysToolBookDirectory & "tb30win.dll"
        STRING GetWinIniVar     (STRING, STRING)
    end linkDLL

    LOGPIXELSX = 88 -- Windows constants
    LOGPIXELSY = 90

    driverInfo = getWinIniVar("windows", "device")
    deviceName = item 1 of driverInfo

    if deviceName is NULL
        set sysError to "There is no printer attached."
        unlinkDLL "GDI"
        unlinkDLL sysToolBookDirectory & "tb30win.dll"
        return NULL
    end if

    deviceFile = item 2 of driverInfo
    devicePort = item 3 of driverInfo

    hDC = createIC(deviceFile,deviceName,devicePort,NULL)
    prnXRes = getDeviceCaps(hDC,LOGPIXELSX)
    prnYRes = getDeviceCaps(hDC,LOGPIXELSY)
    get deleteDC(hDC)

    unlinkDLL "GDI"
    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return prnXRes & "," & prnYRes
end printerRes
}

SCRIPT "Get the display resolution"
BEHAVIOR "Gets the pixels per inch for the display monitor"
CATEGORY Windows
{
to get displayRes

    linkDLL sysToolBookDirectory & "tb30win.dll"
        INT    displayLogPixelsX()
        INT displayLogPixelsY()
    end linkDLL

    displayPixX = displayLogPixelsX()
    displayPixY = displayLogPixelsY()

    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return displayPixX & "," & displayPixY
end displayRes
}

SCRIPT    "Get the colors in the display"
BEHAVIOR    "Returns the number of colors displayed"
CATEGORIES    Windows
{
to get numColors
    linkDLL "gdi"
        INT getDeviceCaps(WORD,INT)
    end linkDLL

    linkDLL "user"
        WORD getDC(WORD)
        INT  releaseDC(WORD,WORD)
    end linkDLL

    hDC = getDC(windowHandle of mainWindow)
    retVal = getDeviceCaps(hDC,24) -- 24 is the magic number for colors
    get ReleaseDC(windowHandle of mainWindow, hDC)
    unlinkDLL "gdi"
    unlinkDLL "user"
    return retVal
end    numColors
}

SCRIPT    "Get the color of a pixel"
BEHAVIOR    "Get the color of any pixel on the screen."
CATEGORIES    Windows
{
to handle buttonClick loc
    linkDLL "user"
        WORD getDC(WORD)
        INT releaseDC(WORD,WORD)
    end    linkDLL

    linkDLL "gdi"
        DWORD getPixel(WORD,INT,INT)
    end    linkDLL

    linkDLL sysToolBookDirectory & "tb30WIN.DLL"
        STRING RGBtoHLS(DOUBLE,DOUBLE,DOUBLE)
     end    linkDLL

    get pageUnitsToClient(loc)
    set xCoord to item 1 of it
    set yCoord to item 2 of it
    set hDC to getDC(sysClientHandle)
    get getPixel(hDC, xCoord, yCoord)
    if it <> -1     -- unlikely
        redValue = it mod 256 -- get the lobyte of the loword
        it = it bitShiftRight 8
        greenValue = it mod 256 -- get the lobyte of the loword
        blueValue = it bitShiftRight 8

        set HLSValue to RGBtoHLS(redValue, greenValue, blueValue)
        if HLSValue = -20     -- very unlikely
            request "RGB to HLS conversion failed "
            unlinkDLL "gdi"
            unlinkDLL "user"
            unlinkDLL sysToolBookDirectory & "tb30win.dll"
            break buttonUp
        end    if

--        set text of field "RGB" to redValue&","&greenValue&","&blueValue
--        set text of field "HLS" to HLSValue
--        set fillColor of rectangle "color" to HLSValue
        request "RGB is" && redValue&","&greenValue&","&blueValue
        request "HLS is" && HLSValue
    else
        request "Error getting pixel."
    end    if
    get ReleaseDC(sysWindowHandle, hDC)
    unlinkDLL "gdi"
    unlinkDLL "user"
    unlinkDLL sysToolBookDirectory & "tb30win.dll"
end buttonClick
}

SCRIPT    "Get the running version of Windows"
BEHAVIOR    "Returns the running version of Windows."
CATEGORIES    Windows
{
to get winVersion
    linkDLL "kernel"
        DWORD GetVersion()
    end
    set verNum to GetVersion()
    set WverNum to verNum mod 65536
    set majorNumber to WverNum mod 256
    set minorNumber to WverNum div 256
    unlinkDLL "kernel"
    return majorNumber &"." & minorNumber
 end winVersion
}

SCRIPT    "Get the current version of DOS"
BEHAVIOR    "Returns the running versions of DOS"
CATEGORIES    DOS
{
to get DOSVersion
    linkDLL "kernel"
        DWORD GetVersion()
    end
    set verNum to GetVersion()
    set DverNum to verNum div 65536
     set dmajorNumber to DverNum div 256
    set dminorNumber to DverNum mod 256
    unlinkDLL "kernel"
    return dmajorNumber & "." & dminorNumber
end DOSVersion
}

SCRIPT "Exit and restart Windows"
BEHAVIOR "This handler demonstrates a way to leave and restart Windows."
CATEGORY Windows
{
--When restart is true, Windows will exit and restart.
--If if restart is null or false, Windows will just exit.
to handle exitWindows restart
    linkDLL "user"
        INT ExitWindows (DWORD, INT)
    end linkDLL
    if restart is true
        get ExitWindows (66, 0)
    else
        get ExitWindows (0, 0)
    end if
    -- no need to unlink this one.
end    exitWindows
}

ACTION "Get custom sys info"
BEHAVIOR "Returns information on the system multimedia drivers"
CATEGORIES    Multimedia
ARG mediaType oneOf "all,animation,bitmap,cdAudio,digitalVideo,overlay,sequencer,vcr,videodisc,waveAudio" is "all" help "Choose a device type."
ARG info oneOf "installname, quantity, quantity open, name 1, name 1 open" is "installname" help "Get this information about the device."
{
      sMS = sysMediaSuspend
    sysMediaSuspend = FALSE
    clear sysError
    devType = "$$mediaType"
    info = "$$info"

    get callMCI("sysInfo" && devType && info)
    if sysError is NULL
        request it
    else
        if sMS = TRUE -- we'll trap the error if the user is expecting it
            request "Device" && QUOTE & devType & QUOTE && "does not understand" \
                && QUOTE & info & QUOTE & ":" & CRLF & CRLF & sysError
        end if
    end if
    sysMediaSuspend = sMS
}

ACTION "Get device capabilities"
BEHAVIOR "Returns information on the capabilities of the multimedia drivers"
CATEGORIES    Multimedia
ARG mediaType oneOf "all,animation,bitmap,cdAudio,digitalVideo,overlay,sequencer,vcr,videodisc,waveAudio" is "all" help "Choose a device type."
ARG info oneOf "can eject,can freeze,can play,can record,can reverse,can save,can stretch,compound device,device type,fast play rate,has audio,has video,inputs,normal play rate,outputs,slow play rate,uses files,uses palettes,windows" is "device type" help "Get this information about the device."
{
    -- If the behavior is not supported by the driver, but is supported
    -- in the spec, this function will return FALSE. If the behavior is
    -- not supported in the spec, this will return NULL and set up
    -- a report that is shown if sysMediaSuspend is TRUE
    sMS = sysMediaSuspend
    sysMediaSuspend = FALSE
    clear sysError
    devType = "$$mediaType"
    cap = "$$info"
    get callMCI("capability" && devType && cap)
    if sysError is NULL
        request it
    else
        if sMS = TRUE -- we'll trap the error if the user is expecting it
            request "Device" && QUOTE & devType & QUOTE && "does not understand" \
                && QUOTE & cap & QUOTE & ":" & CRLF & CRLF & sysError
        end if
    end if
    sysMediaSuspend = sMS
}


ACTION "Set mixer values"
BEHAVIOR "Sets the volume for the virtual audio mixer"
CATEGORIES Multimedia
ARG lineType oneOf "device_in,device_out" is "device_in" help "Choose input or output"
ARG lineSpec oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Choose the MCI device to query"
ARG channel oneOf "LEFT,RIGHT,BOTH" is "BOTH" help "Choose which channel"
ARG value oneOf "1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87,88,89,90,91,92,93,94,95,96,97,98,99,100" is "99" help "Choose the percent of full volume"
{
    -- The virtual mixer does the best it can with whatever
    -- soundcard is on the target machine. As there is no real
    -- standard, results will vary from card to card.
    clear sysError
    get mixerCommand("set tbkmixer $$lineType $$lineSpec control volume $$channel value")
    if it = 0
        if $$channel <> "both"
            request "Volume for the $$channel channel of the $$lineSpec device has been set to $$value"
        else
            request "Volume for both channels of the $$lineSpec device have been set to $$value"
        end if
    else
        request sysError
    end if
}

ACTION "Let user set mixer values for a device"
BEHAVIOR "Lets the user set the volume for the virtual audio mixer"
CATEGORIES Multimedia
ARG lineType oneOf "device_in,device_out" is "device_in" help "Choose input or output"
ARG lineSpec oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Choose the MCI device to query"
{
    -- The virtual mixer does the best it can with whatever
    -- soundcard is on the target machine. As there is no real
    -- standard, results will vary from card to card.
    -- This script lets the author decide which device,
    -- but lets the user decide what value
    local l_cancel,l_channel,l_value
    request "What channel would you like to set the volume of: the left, right, or both channels?" \
        with "Left" or "Right" or "Both"
    if it <> null -- null when canceled with the system button or alt-F4
        set l_channel to it
    else
        set l_cancel to TRUE,"the user canceled."
    end if

    if item 1 of l_cancel <> TRUE
        ask "What percent of full volume should the setting be?" with "50"
        if isType(INT,it) and it >= 0  and it <=100
            set l_value to it
        else
            set l_cancel to TRUE,"there was a bad value for volume."
        end if
    end if
    clear sysError
    if item 1 of l_cancel <> TRUE
        get mixerCommand("set tbkmixer $$lineType $$lineSpec control volume" && l_channel && l_value)
        if it = 0
            if l_channel <> "both"
                request "Volume for the" && l_channel && "channel of the $$lineSpec device has been set to" && l_value
            else
                request "Volume for both channels of the $$lineSpec device have been set to" && l_value
            end if
        else
            request sysError
        end if
    else
        request "The command was not executed because" && item 2 of l_cancel
    end if
}

ACTION "Get mixer values"
BEHAVIOR "Gets the volume for the virtual audio mixer"
CATEGORIES Multimedia
ARG lineType oneOf "device_in,device_out" is "device_in" help "Choose input or output"
ARG lineSpec oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Choose the MCI device to query"
ARG channel oneOf "LEFT,RIGHT,BOTH" is "BOTH" help "Choose which channel"
{
    -- The virtual mixer does the best it can with whatever
    -- soundcard is on the target machine. As there is no real
    -- standard, results will vary from card to card.
    clear sysError
    get mixerCommand("get tbkmixer $$lineType $$lineSpec control volume $$channel")
    if sysError is NULL
        if $$channel <> "both"
            request "Volume for the $$channel channel of the $$lineSpec device is set to" && it
        else
            request "Volume for both channels of the $$lineSpec device are set to" && it
        end if
    else
        request sysError
    end if
}

ACTION "Image Command - Capability"
BEHAVIOR "Requests information about the capability of the bitmap player"
CATEGORIES Images
ARG args oneOf "compound device,device type,has files,has video,static,uses palettes" is "device type" help "Choose what capability."
{
    get imageCommand("capability placeHolder $$args")
    request it
}

ACTION "Image Command - Close"
BEHAVIOR "Closes the window and file associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want to close, or 'all' to close all open bitmaps. Keep your aliases consistent!"
{
    get imageCommand("close $$alias")
}

ACTION "Image Command - Info"
BEHAVIOR "Get info on the window or file associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want information on. Keep your aliases consistent!"
ARG args oneOf "product,text,file" is "file" help "The type of information you want."
{
    get imageCommand("info $$alias $$args")
    request it
}

ACTION "Image Command - Open"
BEHAVIOR "Initializes the displayer and associates the file with the alias"
CATEGORIES Images
ARG myBitmap FILE "Bitmap Files(*.BMP),*.bmp,(*.DIB),*.dib" is "Cars.bmp" help "Find the bitmap file to display."
ARG alias is "myAlias" help "The alias you want associated with this file. Keep your aliases consistent!"
ARG style oneOf "overlapped,popup,child" is "overlapped" help "Choose the style of the window."
{
    get imageCommand("open $$myBitmap alias $$alias style $$style")
}

ACTION "Image Command - Play"
BEHAVIOR "Play the file in the window associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want to play. Keep your aliases consistent!"
{
    get imageCommand("play $$alias")
}


ACTION "Image Command - Put"
BEHAVIOR "Play the file in the window associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want to play. Keep your aliases consistent!"
ARG whereTo oneOf "source,destination" is "destination" help "Get the offset and extent of the source or destination."
ARG x1 is "0" help "Left to right offset."
ARG y1 is "0" help "Up to down offset."
ARG x2 is "100" help "Left to right extent."
ARG y2 is "100" help "Up to down extent."
{
    get imageCommand("put $$alias $$whereTo at $$x1 $$y1 $$x2 $$y2")
}


ACTION "Image Command - Status"
BEHAVIOR "Get the status of the window and file associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want the status of. Keep your aliases consistent!"
ARG args oneOf "window,position,extent,size,visible,style,palette" is "position" help "The element you need the status of."
{
    get imageCommand("status $$alias $$args")
    request it
}

ACTION "Image Command - Where"
BEHAVIOR "Obtains the rectangle specifying the source or destination area of the image."
CATEGORIES Images
ARG whereTo oneOf "source,destination" is "destination" help "Get the offset and extent of the source or destination."
ARG alias is "myAlias" help "The filename or the alias you want. Keep your aliases consistent!"
{
    get imageCommand("where $$alias $$whereto")
    request it
}

ACTION "Image Command - Window"
BEHAVIOR "Change parameters of the window associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want to close, or 'all' to close all open bitmaps. Keep your aliases consistent!"
ARG args oneOf "text,position,size" is "position" help "Choose what aspect of the window to change."
ARG value help "For 'text', the caption of the window, or use 'default' for the name of the bitmap. For 'position'and 'size', use two pixels, e.g. '100,100'."
{
    get imageCommand("window $$alias $$args $$value")
}

ACTION "Image Command - Window State"
BEHAVIOR "Change the state of the window associated with the alias"
CATEGORIES Images
ARG alias is "myAlias" help "The filename or the alias you want to close, or 'all' to close all open bitmaps. Keep your aliases consistent!"
ARG value oneOf "hide,minimize,minimized,show,maximize,iconic,asIs,asWas,normal" is "show" help "Use one of these constants to more precisely control the way the window is displayed."
{
    get imageCommand("window $$alias state $$value")
}

ACTION    "Play a Wave file as a new clip"
BEHAVIOR "Creates a clip from a wave file using 'WaveFile' ($$WaveFile,) then plays it."
CATEGORY    Clips,Audio
ARG     waveFile FILE "Wave Files(*.WAV),*.wav" is "Chord.Wav" help "Get the wave file."
ARG clipName is "myClip" help "Give the new clip a name."
ARG startTime is "0:00:00" help "Set to a time in 'Minutes:Seconds:Milliseconds' format; defaults to beginning of the file."
ARG endTime is "0:10:00" help "Set to a time in 'Minutes:Seconds:Milliseconds' format; defaults to 10 seconds into the file."

{
     -- The new clip is made when this script is activated,
     -- not when it is written, so make sure the media is
     -- still in the right place before activating this script
      new clip from "$$WaveFile"
      name of it = "$$clipName"
      mediaRef = clip "$$clipName"
      mmTimeFormat of mediaRef = "MSms"
      mmBeginPoint of mediaRef = "$$startTime"
      mmEndPoint of mediaRef = "$$endTime"
      mmPlay mediaRef autoclose
}



ACTION    "Play an AVI file as a clip"
BEHAVIOR "Creates a clip from an AVI file using 'AVIFile' ($$AVIFile,) then plays it."
CATEGORY    Clips,Video
ARG     AVIFile FILE "AVI Files(*.avi),*.avi" is "windmill.avi" help "Get the wave file."
ARG clipName is "myClip" help "Give the new clip a name."
ARG startTime is "0" help "Set to frame number; defaults to beginning of the file."
ARG endTime is "300" help "Set to a frame number; defaults to frame 300."
ARG StageObj OBJTYP "Stage" is "stage myStage" help "Choose the stage object for playback"
{
     -- The new clip is made when this script is activated,
     -- not when it is written, so make sure the media is
     -- still in the right place before activating this script
      new clip from "$$AVIFile"
      name of it = "$$clipName"
      mediaRef = clip "$$clipName"
      mmTimeFormat of mediaRef = "frames"
      mmBeginPoint of mediaRef = "$$startTime"
      mmEndPoint of mediaRef = "$$endTime"
      mmPlay mediaRef in $$StageObj autoclose
}


ACTION    "Build and play an AVI clip w/out the clip manager"
BEHAVIOR "Allows the user to create a clip from an AVI file, then plays it."
CATEGORY    Clips,Video
ARG ClipName is "Enter a name for the new clip" help "This is the default text the user will see, or modify for your needs."
ARG StageObj OBJTYP "Stage" is "stage myStage" help "Choose the stage object for playback"
ARG BeginPoint is "Enter a beginning point for the clip in frames" help "This is the default text the user will see, or modify for your needs."
ARG EndPoint is "Enter an ending point for the clip in frames" help "This is the default text the user will see, or modify for your needs."
ARG    caption    is    "Open an AVI File"    help "This is the default text the user will see, or modify for your needs."
ARG    prompt    is    "Choose the AVI file to open" help "This is the default text the user will see, or modify for your needs."
{
     -- The new clip is made by the user, so this is more
     -- flexible than the 'Play a Wave file as a clip' script.
     -- This is a good sample script, as defauults and errorrs
     -- are handled fairly gracefully.
    while not (sysSupportedMedia contains "digitalVideo")
        request  "Error: breaking execution of this script." & CRLF \
          & "Multimedia ToolBook is not being allowed to play digitalVideo." & CRLF \
          & "The appropriate drivers may not be available."
        break to system
    end while
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg(".","*.avi","$$prompt","$$caption")
    if it <> null
        newAVI = it

        do
            ask "$$ClipName" with "newClip"
            if it is null
                request "Are you sure you want to cancel creating this clip?" \
                  with "Yes, cancel" or "No, try again"
                if it contains "Yes"
                    break to system
                else
                    clear it
                  end if
            end if
        until it <> null
        clipName = it

        new clip from newAVI
        name of it = clipName
        mediaRef = clip clipName
        while not (mmPlayable of mediaRef)
            request "This clip is not playable"
            break to system
        end while
        mmTimeFormat of mediaRef = "frames"

         sS = sysSuspend
        sMS = sysMediaSuspend
        sysSuspend = FALSE
        sysMediaSuspend = FALSE

        ask  "$$BeginPoint" with "0"
        clear sysError
        mmBeginPoint of mediaRef = it
        if sysError <> null
            request "Error, the beginning point of the clip set to default: ""0"""
            mmBeginPoint of mediaRef = "0"
        end if

        ask "$$EndPoint" with "300"
        clear sysError
         mmEndPoint of mediaRef = it
        if sysError <> null
            request "Error, the ending point of the clip set to default: ""300"""
            mmEndPoint of mediaRef = "300"
        end if

        sysSuspend = sS
        sysMediaSuspend = sMS
        if mmPlayable of mediaRef
            mmPlay mediaRef in $$StageObj autoclose
        end if
    end if

    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

ACTION    "Build and play a Wave clip"
BEHAVIOR "Allows the user to create a clip from a wave file, then plays it."
CATEGORY    Clips,Audio
ARG ClipName is "Enter a name for the new clip" help "Default is good, or modify for your needs."
ARG BeginPoint is "Enter a beginning point for the clip in 'Minutes:Seconds:Milliseconds'" help "Default is good, or modify for your needs."
ARG EndPoint is "Enter an ending point for the clip in 'Minutes:Seconds:Milliseconds'" help "Default is good, or modify for your needs."
ARG    caption    is    "Open a Wave File"    help "Default is good, or modify for your needs."
ARG    prompt    is    "Choose the wave file to open" help "Default is good, or modify for your needs."
{
     -- The new clip is made by the user, so this is more
     -- flexible than the 'Play a Wave file as a clip' script.
     -- This is a good sample script, as defauults and errorrs
     -- are handled fairly gracefully.

    -- this funny structure gets around auto-script choking when it sees the break
    -- statement in an "if" structure
    while not (sysSupportedMedia contains "waveAudio")
        request  "Error: breaking execution of this script." & CRLF \
          & "The multimedia driver can not find the waveAudio device." & CRLF \
          & "The appropriate drivers may not be available."
        break to system
    end while
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg(".","*.wav","$$prompt","$$caption")
    if it <> null
        newWave = it

        do
            ask "$$ClipName" with "newClip"
            if it is null
                request "Are you sure you want to cancel creating this clip?" \
                  with "Yes, cancel" or "No, try again"
                if it contains "Yes"
                    break to system
                else
                    clear it
                  end if
            end if
        until it <> null
        clipName = it

        new clip from newWave
        name of it = clipName
        mediaRef = clip clipName
        mmTimeFormat of mediaRef = "MSms"

         sS = sysSuspend
        sMS = sysMediaSuspend
        sysSuspend = FALSE
        sysMediaSuspend = FALSE

        ask  "$$BeginPoint" with "0:00:00"
        clear sysError
        mmBeginPoint of mediaRef = it
        if sysError <> null
            request "Error, the beginning point of the clip set to default: ""0:00:00"""
            mmBeginPoint of mediaRef = "0:00:00"
        end if

        ask "$$EndPoint" with "0:05:00"
        clear sysError
         mmEndPoint of mediaRef = it
        if sysError <> null
            request "Error, the ending point of the clip set to default: ""0:05:00"""
            mmEndPoint of mediaRef = "0:05:00"
        end if

        sysSuspend = sS
        sysMediaSuspend = sMS
        if mmPlayable of mediaRef
            mmPlay mediaRef autoclose
        end if
    end if

    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

ACTION    "Set book to read automatically"
BEHAVIOR    "Example program for a continuously running book."
HANDLERS    enterApplication, enterBook, enterBackground, buttonClick, buttonUp, buttonDown
CATEGORIES Navigation
ARG    Effect    oneOf    "blinds,dissolve,drip,fade,iris,puzzle,tear"  is "fade"
ARG    Speed    oneOf    "Normal,Fast,Slow"    is    "Normal"
ARG pauseTime    oneof    "1,2,3,4,5,6,7,8,9,10" is "5" help "Time in seconds to pause on a page."
{
     send reader
    send sizeToPage
    set caption of mainWindow to name of this page
    forward

    -- defeat imaging behavior
    set sysLockScreen to TRUE
    set sysLockScreen to FALSE

    show statusBar
    set caption of statusBar to "Press and hold [space] to stop demo"

    while keyState(keySpace) <> down
        transition    "$$effect $$speed" to next page
        set caption of mainWindow to name of this page
        pause $$pauseTime
    end while
    set caption of statusBar to " "
}

ACTION "Step through a clip"
BEHAVIOR "Step through a video or animation"
CATEGORIES Clips,Stages,Videon
ARG ClipRef  Clip is "clip id 100" help "Select the clip to be played."
ARG StepSize is "1" help "Any integer value from 1 up to the frame count of the clip."
ARG StageObj OBJTYP "Stage" is "stage myStage" help "Choose the stage object for showing"
ARG StepDelay is "100" help "Delay in ticks, or one hundredths of a second, so '100' = 1 second, '50' = 1/2 of a second."
{
    if mmIsOpen of $$ClipRef
        mmClose $$ClipRef wait
    end if
    mmOpen $$ClipRef  wait

    oldMTF = mmTimeFormat of $$ClipRef
    mmTimeFormat of $$ClipRef  = "frames"
    frameVar= $$StepSize

    maxFrame = mmLength of $$ClipRef
    conditions
    when frameVar < 1
        frameVar = 1
    when frameVar > maxFrame
        frameVar = maxFrame
    end conditions

    mmCue $$ClipRef

    conditions
    when $$StepDelay < 1
        myDelay = 1
    when $$StepDelay > 231
        myDelay = 231
    else
        myDelay = $$StepDelay
    end conditions
    step i from 1 to (floor(maxframe/frameVar))-1
        mmShow $$ClipRef  in $$StageObj  wait
        pause myDelay
        mmStep $$ClipRef by frameVar
    end step
    mmShow clip "windmill"  in $$StageObj  wait
    mmSeek clip "windMill" to maxFrame
    mmShow clip "windmill"  in $$StageObj  wait
    mmTimeFormat of $$ClipRef  = oldMTF
}

SCRIPT "Continuously play a visual clip"
BEHAVIOR "Use the mmNotify message to play an animation or video clip continuously. This script would go in the page object."
CATEGORIES Clips,Video
ARG ClipRef CLIP is "clip id 100" help "Select the clip to be played."
ARG StageObj OBJTYP "Stage" is "stage myStage" help "Choose the stage object for playback"
{
to handle enterPage
    forward
    --cue and play the clip at enterPage
    mmOpen $$ClipRef
    send playScore
end enterPage

to handle playScore
    mmPlay $$ClipRef in $$StageObj notify self
end playScore

to handle mmNotify mediaRef, commandName, cResult
    if (mediaRef = $$ClipRef) and (cResult = "successful")
        send playScore
    end if
end mmNotify
}

SCRIPT "Continuously play any clip"
BEHAVIOR "Use the mmNotify message to play any clip continuously. This script would go in the page object."
CATEGORIES Clips
ARG ClipRef CLIP is "clip id 100" help "Select the clip to be played."
{
to handle enterPage
    forward
    --cue and play the clip at enterPage
    mmOpen $$ClipRef
    send playScore
end enterPage

to handle playScore
    mmPlay $$ClipRef notify self
end playScore

to handle mmNotify mediaRef, commandName, cResult
    if (mediaRef = $$ClipRef) and (cResult = "successful")
        send playScore
    end if
end mmNotify
}

SCRIPT "Set text of field to position of clip"
BEHAVIOR "Use a field to show the current position of a clip as it is being played"
CATEGORIES Utilities
ARG ClipRef CLIP is "clip id 100" help "Select the clip to be monitored."
{
-- this script goes in the field displaying the position
notifyBefore idle
    cName = $$ClipRef
    if (mmIsOpen of cName)
        oldPos = my text
        newPos = mmPosition of cName
        if oldPos <> newPos
            my text = newPos
        end if
    end if
end idle
}