home *** CD-ROM | disk | FTP | other *** search
/ Australian Personal Computer 2004 July / APC0407D2.iso / workshop / apache / files / ActivePerl-5.8.3.809-MSWin32-x86.msi / _662c49f9627f56e1b904931a860d4acf < prev    next >
Encoding:
Text File  |  2004-02-02  |  299.4 KB  |  8,533 lines

  1. =head1 NAME 
  2.  
  3. C<perl5db.pl> - the perl debugger
  4.  
  5. =head1 SYNOPSIS
  6.  
  7.     perl -d  your_Perl_script
  8.  
  9. =head1 DESCRIPTION
  10.  
  11. C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  12. you invoke a script with C<perl -d>. This documentation tries to outline the
  13. structure and services provided by C<perl5db.pl>, and to describe how you
  14. can use them.
  15.  
  16. =head1 GENERAL NOTES
  17.  
  18. The debugger can look pretty forbidding to many Perl programmers. There are
  19. a number of reasons for this, many stemming out of the debugger's history.
  20.  
  21. When the debugger was first written, Perl didn't have a lot of its nicer
  22. features - no references, no lexical variables, no closures, no object-oriented
  23. programming. So a lot of the things one would normally have done using such
  24. features was done using global variables, globs and the C<local()> operator 
  25. in creative ways.
  26.  
  27. Some of these have survived into the current debugger; a few of the more
  28. interesting and still-useful idioms are noted in this section, along with notes
  29. on the comments themselves.
  30.  
  31. =head2 Why not use more lexicals?
  32.  
  33. Experienced Perl programmers will note that the debugger code tends to use
  34. mostly package globals rather than lexically-scoped variables. This is done
  35. to allow a significant amount of control of the debugger from outside the
  36. debugger itself.       
  37.  
  38. Unfortunately, though the variables are accessible, they're not well
  39. documented, so it's generally been a decision that hasn't made a lot of
  40. difference to most users. Where appropriate, comments have been added to
  41. make variables more accessible and usable, with the understanding that these
  42. i<are> debugger internals, and are therefore subject to change. Future
  43. development should probably attempt to replace the globals with a well-defined
  44. API, but for now, the variables are what we've got.
  45.  
  46. =head2 Automated variable stacking via C<local()>
  47.  
  48. As you may recall from reading C<perlfunc>, the C<local()> operator makes a 
  49. temporary copy of a variable in the current scope. When the scope ends, the
  50. old copy is restored. This is often used in the debugger to handle the 
  51. automatic stacking of variables during recursive calls:
  52.  
  53.      sub foo {
  54.         local $some_global++;
  55.  
  56.         # Do some stuff, then ...
  57.         return;
  58.      }
  59.  
  60. What happens is that on entry to the subroutine, C<$some_global> is localized,
  61. then altered. When the subroutine returns, Perl automatically undoes the 
  62. localization, restoring the previous value. Voila, automatic stack management.
  63.  
  64. The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>, 
  65. which lets the debugger get control inside of C<eval>'ed code. The debugger
  66. localizes a saved copy of C<$@> inside the subroutine, which allows it to
  67. keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  68. value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep 
  69. track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  70.  
  71. In any case, watch for this pattern. It occurs fairly often.
  72.  
  73. =head2 The C<^> trick
  74.  
  75. This is used to cleverly reverse the sense of a logical test depending on 
  76. the value of an auxiliary variable. For instance, the debugger's C<S>
  77. (search for subroutines by pattern) allows you to negate the pattern 
  78. like this:
  79.  
  80.    # Find all non-'foo' subs:
  81.    S !/foo/      
  82.  
  83. Boolean algebra states that the truth table for XOR looks like this:
  84.  
  85. =over 4
  86.  
  87. =item * 0 ^ 0 = 0 
  88.  
  89. (! not present and no match) --> false, don't print
  90.  
  91. =item * 0 ^ 1 = 1 
  92.  
  93. (! not present and matches) --> true, print
  94.  
  95. =item * 1 ^ 0 = 1 
  96.  
  97. (! present and no match) --> true, print
  98.  
  99. =item * 1 ^ 1 = 0 
  100.  
  101. (! present and matches) --> false, don't print
  102.  
  103. =back
  104.  
  105. As you can see, the first pair applies when C<!> isn't supplied, and
  106. the second pair applies when it isn't. The XOR simply allows us to
  107. compact a more complicated if-then-elseif-else into a more elegant 
  108. (but perhaps overly clever) single test. After all, it needed this
  109. explanation...
  110.  
  111. =head2 FLAGS, FLAGS, FLAGS
  112.  
  113. There is a certain C programming legacy in the debugger. Some variables,
  114. such as C<$single>, C<$trace>, and C<$frame>, have "magical" values composed
  115. of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
  116. of state to be stored independently in a single scalar. 
  117.  
  118. A test like
  119.  
  120.     if ($scalar & 4) ...
  121.  
  122. is checking to see if the appropriate bit is on. Since each bit can be 
  123. "addressed" independently in this way, C<$scalar> is acting sort of like
  124. an array of bits. Obviously, since the contents of C<$scalar> are just a 
  125. bit-pattern, we can save and restore it easily (it will just look like
  126. a number).
  127.  
  128. The problem, is of course, that this tends to leave magic numbers scattered
  129. all over your program whenever a bit is set, cleared, or checked. So why do 
  130. it?
  131.  
  132. =over 4
  133.  
  134.  
  135. =item * First, doing an arithmetical or bitwise operation on a scalar is
  136. just about the fastest thing you can do in Perl: C<use constant> actually
  137. creates a subroutine call, and array hand hash lookups are much slower. Is
  138. this over-optimization at the expense of readability? Possibly, but the 
  139. debugger accesses these  variables a I<lot>. Any rewrite of the code will
  140. probably have to benchmark alternate implementations and see which is the
  141. best balance of readability and speed, and then document how it actually 
  142. works.
  143.  
  144. =item * Second, it's very easy to serialize a scalar number. This is done in 
  145. the restart code; the debugger state variables are saved in C<%ENV> and then
  146. restored when the debugger is restarted. Having them be just numbers makes
  147. this trivial. 
  148.  
  149. =item * Third, some of these variables are being shared with the Perl core 
  150. smack in the middle of the interpreter's execution loop. It's much faster for 
  151. a C program (like the interpreter) to check a bit in a scalar than to access 
  152. several different variables (or a Perl array).
  153.  
  154. =back
  155.  
  156. =head2 What are those C<XXX> comments for?
  157.  
  158. Any comment containing C<XXX> means that the comment is either somewhat
  159. speculative - it's not exactly clear what a given variable or chunk of 
  160. code is doing, or that it is incomplete - the basics may be clear, but the
  161. subtleties are not completely documented.
  162.  
  163. Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
  164.  
  165. =head1 DATA STRUCTURES MAINTAINED BY CORE         
  166.  
  167. There are a number of special data structures provided to the debugger by
  168. the Perl interpreter.
  169.  
  170. The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
  171. assignment) contains the text from C<$filename>, with each element
  172. corresponding to a single line of C<$filename>.
  173.  
  174. The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob 
  175. assignment) contains breakpoints and actions.  The keys are line numbers; 
  176. you can set individual values, but not the whole hash. The Perl interpreter 
  177. uses this hash to determine where breakpoints have been set. Any true value is
  178. considered to be a breakpoint; C<perl5db.pl> uses "$break_condition\0$action".
  179. Values are magical in numeric context: 1 if the line is breakable, 0 if not.
  180.  
  181. The scalar ${'_<'.$filename} contains $filename  XXX What?
  182.  
  183. =head1 DEBUGGER STARTUP
  184.  
  185. When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
  186. non-interactive sessions, C<.perldb> for interactive ones) that can set a number
  187. of options. In addition, this file may define a subroutine C<&afterinit>
  188. that will be executed (in the debugger's context) after the debugger has 
  189. initialized itself.
  190.  
  191. Next, it checks the C<PERLDB_OPTS> environment variable and treats its 
  192. contents as the argument of a debugger <C<O> command.
  193.  
  194. =head2 STARTUP-ONLY OPTIONS
  195.  
  196. The following options can only be specified at startup.
  197. To set them in your rcfile, add a call to
  198. C<&parse_options("optionName=new_value")>.
  199.  
  200. =over 4
  201.  
  202. =item * TTY 
  203.  
  204. the TTY to use for debugging i/o.
  205.  
  206. =item * noTTY 
  207.  
  208. if set, goes in NonStop mode.  On interrupt, if TTY is not set,
  209. uses the value of noTTY or "/tmp/perldbtty$$" to find TTY using
  210. Term::Rendezvous.  Current variant is to have the name of TTY in this
  211. file.
  212.  
  213. =item * ReadLine 
  214.  
  215. If false, a dummy  ReadLine is used, so you can debug
  216. ReadLine applications.
  217.  
  218. =item * NonStop 
  219.  
  220. if true, no i/o is performed until interrupt.
  221.  
  222. =item * LineInfo 
  223.  
  224. file or pipe to print line number info to.  If it is a
  225. pipe, a short "emacs like" message is used.
  226.  
  227. =item * RemotePort 
  228.  
  229. host:port to connect to on remote host for remote debugging.
  230.  
  231. =back
  232.  
  233. =head3 SAMPLE RCFILE
  234.  
  235.  &parse_options("NonStop=1 LineInfo=db.out");
  236.   sub afterinit { $trace = 1; }
  237.  
  238. The script will run without human intervention, putting trace
  239. information into C<db.out>.  (If you interrupt it, you had better
  240. reset C<LineInfo> to something "interactive"!)
  241.  
  242. =head1 INTERNALS DESCRIPTION
  243.  
  244. =head2 DEBUGGER INTERFACE VARIABLES
  245.  
  246. Perl supplies the values for C<%sub>.  It effectively inserts
  247. a C<&DB'DB();> in front of each place that can have a
  248. breakpoint. At each subroutine call, it calls C<&DB::sub> with
  249. C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
  250. {require 'perl5db.pl'}> before the first line.
  251.  
  252. After each C<require>d file is compiled, but before it is executed, a
  253. call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
  254. is the expanded name of the C<require>d file (as found via C<%INC>).
  255.  
  256. =head3 IMPORTANT INTERNAL VARIABLES
  257.  
  258. =head4 C<$CreateTTY>
  259.  
  260. Used to control when the debugger will attempt to acquire another TTY to be
  261. used for input. 
  262.  
  263. =over   
  264.  
  265. =item * 1 -  on C<fork()>
  266.  
  267. =item * 2 - debugger is started inside debugger
  268.  
  269. =item * 4 -  on startup
  270.  
  271. =back
  272.  
  273. =head4 C<$doret>
  274.  
  275. The value -2 indicates that no return value should be printed.
  276. Any other positive value causes C<DB::sub> to print return values.
  277.  
  278. =head4 C<$evalarg>
  279.  
  280. The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
  281. contents of C<@_> when C<DB::eval> is called.
  282.  
  283. =head4 C<$frame>
  284.  
  285. Determines what messages (if any) will get printed when a subroutine (or eval)
  286. is entered or exited. 
  287.  
  288. =over 4
  289.  
  290. =item * 0 -  No enter/exit messages
  291.  
  292. =item * 1 - Print "entering" messages on subroutine entry
  293.  
  294. =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
  295.  
  296. =item * 4 - Extended messages: C<in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line>>. If no other flag is on, acts like 1+4.
  297.  
  298. =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
  299.  
  300. =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
  301.  
  302. =back
  303.  
  304. To get everything, use C<$frame=30> (or C<o f-30> as a debugger command).
  305. The debugger internally juggles the value of C<$frame> during execution to
  306. protect external modules that the debugger uses from getting traced.
  307.  
  308. =head4 C<$level>
  309.  
  310. Tracks current debugger nesting level. Used to figure out how many 
  311. C<E<lt>E<gt>> pairs to surround the line number with when the debugger 
  312. outputs a prompt. Also used to help determine if the program has finished
  313. during command parsing.
  314.  
  315. =head4 C<$onetimeDump>
  316.  
  317. Controls what (if anything) C<DB::eval()> will print after evaluating an
  318. expression.
  319.  
  320. =over 4
  321.  
  322. =item * C<undef> - don't print anything
  323.  
  324. =item * C<dump> - use C<dumpvar.pl> to display the value returned
  325.  
  326. =item * C<methods> - print the methods callable on the first item returned
  327.  
  328. =back
  329.  
  330. =head4 C<$onetimeDumpDepth>
  331.  
  332. Controls how far down C<dumpvar.pl> will go before printing '...' while
  333. dumping a structure. Numeric. If C<undef>, print all levels.
  334.  
  335. =head4 C<$signal>
  336.  
  337. Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
  338. which is called before every statement, checks this and puts the user into
  339. command mode if it finds C<$signal> set to a true value.
  340.  
  341. =head4 C<$single>
  342.  
  343. Controls behavior during single-stepping. Stacked in C<@stack> on entry to
  344. each subroutine; popped again at the end of each subroutine.
  345.  
  346. =over 4 
  347.  
  348. =item * 0 - run continuously.
  349.  
  350. =item * 1 - single-step, go into subs. The 's' command.
  351.  
  352. =item * 2 - single-step, don't go into subs. The 'n' command.
  353.  
  354. =item * 4 - print current sub depth (turned on to force this when "too much
  355. recursion" occurs.
  356.  
  357. =back
  358.  
  359. =head4 C<$trace>
  360.  
  361. Controls the output of trace information. 
  362.  
  363. =over 4
  364.  
  365. =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
  366.  
  367. =item * 2 - watch expressions are active
  368.  
  369. =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
  370.  
  371. =back
  372.  
  373. =head4 C<$slave_editor>
  374.  
  375. 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
  376.  
  377. =head4 C<@cmdfhs>
  378.  
  379. Stack of filehandles that C<DB::readline()> will read commands from.
  380. Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
  381.  
  382. =head4 C<@dbline>
  383.  
  384. Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> , 
  385. supplied by the Perl interpreter to the debugger. Contains the source.
  386.  
  387. =head4 C<@old_watch>
  388.  
  389. Previous values of watch expressions. First set when the expression is
  390. entered; reset whenever the watch expression changes.
  391.  
  392. =head4 C<@saved>
  393.  
  394. Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
  395. so that the debugger can substitute safe values while it's running, and
  396. restore them when it returns control.
  397.  
  398. =head4 C<@stack>
  399.  
  400. Saves the current value of C<$single> on entry to a subroutine.
  401. Manipulated by the C<c> command to turn off tracing in all subs above the
  402. current one.
  403.  
  404. =head4 C<@to_watch>
  405.  
  406. The 'watch' expressions: to be evaluated before each line is executed.
  407.  
  408. =head4 C<@typeahead>
  409.  
  410. The typeahead buffer, used by C<DB::readline>.
  411.  
  412. =head4 C<%alias>
  413.  
  414. Command aliases. Stored as character strings to be substituted for a command
  415. entered.
  416.  
  417. =head4 C<%break_on_load>
  418.  
  419. Keys are file names, values are 1 (break when this file is loaded) or undef
  420. (don't break when it is loaded).
  421.  
  422. =head4 C<%dbline>
  423.  
  424. Keys are line numbers, values are "condition\0action". If used in numeric
  425. context, values are 0 if not breakable, 1 if breakable, no matter what is
  426. in the actual hash entry.
  427.  
  428. =head4 C<%had_breakpoints>
  429.  
  430. Keys are file names; values are bitfields:
  431.  
  432. =over 4 
  433.  
  434. =item * 1 - file has a breakpoint in it.
  435.  
  436. =item * 2 - file has an action in it.
  437.  
  438. =back
  439.  
  440. A zero or undefined value means this file has neither.
  441.  
  442. =head4 C<%option>
  443.  
  444. Stores the debugger options. These are character string values.
  445.  
  446. =head4 C<%postponed>
  447.  
  448. Saves breakpoints for code that hasn't been compiled yet.
  449. Keys are subroutine names, values are:
  450.  
  451. =over 4
  452.  
  453. =item * 'compile' - break when this sub is compiled
  454.  
  455. =item * 'break +0 if <condition>' - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
  456.  
  457. =back
  458.  
  459. =head4 C<%postponed_file>
  460.  
  461. This hash keeps track of breakpoints that need to be set for files that have
  462. not yet been compiled. Keys are filenames; values are references to hashes.
  463. Each of these hashes is keyed by line number, and its values are breakpoint
  464. definitions ("condition\0action").
  465.  
  466. =head1 DEBUGGER INITIALIZATION
  467.  
  468. The debugger's initialization actually jumps all over the place inside this
  469. package. This is because there are several BEGIN blocks (which of course 
  470. execute immediately) spread through the code. Why is that? 
  471.  
  472. The debugger needs to be able to change some things and set some things up 
  473. before the debugger code is compiled; most notably, the C<$deep> variable that
  474. C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
  475. debugger has to turn off warnings while the debugger code is compiled, but then
  476. restore them to their original setting before the program being debugged begins
  477. executing.
  478.  
  479. The first C<BEGIN> block simply turns off warnings by saving the current
  480. setting of C<$^W> and then setting it to zero. The second one initializes
  481. the debugger variables that are needed before the debugger begins executing.
  482. The third one puts C<$^X> back to its former value. 
  483.  
  484. We'll detail the second C<BEGIN> block later; just remember that if you need
  485. to initialize something before the debugger starts really executing, that's
  486. where it has to go.
  487.  
  488. =cut
  489.  
  490. package DB;
  491.  
  492. use IO::Handle;
  493.  
  494. # Debugger for Perl 5.00x; perl5db.pl patch level:
  495. $VERSION = 1.23;
  496.  
  497. $header  = "perl5db.pl version $VERSION";
  498.  
  499. =head1 DEBUGGER ROUTINES
  500.  
  501. =head2 C<DB::eval()>
  502.  
  503. This function replaces straight C<eval()> inside the debugger; it simplifies
  504. the process of evaluating code in the user's context.
  505.  
  506. The code to be evaluated is passed via the package global variable 
  507. C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
  508.  
  509. We preserve the current settings of X<C<$trace>>, X<C<$single>>, and X<C<$^D>>;
  510. add the X<C<$usercontext>> (that's the preserved values of C<$@>, C<$!>,
  511. C<$^E>, C<$,>, C<$/>, C<$\>, and C<$^W>, grabbed when C<DB::DB> got control,
  512. and the user's current package) and a add a newline before we do the C<eval()>.
  513. This causes the proper context to be used when the eval is actually done.
  514. Afterward, we restore C<$trace>, C<$single>, and C<$^D>.
  515.  
  516. Next we need to handle C<$@> without getting confused. We save C<$@> in a
  517. local lexical, localize C<$saved[0]> (which is where C<save()> will put 
  518. C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>, 
  519. C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
  520. considered sane by the debugger. If there was an C<eval()> error, we print 
  521. it on the debugger's output. If X<C<$onetimedump>> is defined, we call 
  522. X<C<dumpit>> if it's set to 'dump', or X<C<methods>> if it's set to 
  523. 'methods'. Setting it to something else causes the debugger to do the eval 
  524. but not print the result - handy if you want to do something else with it 
  525. (the "watch expressions" code does this to get the value of the watch
  526. expression but not show it unless it matters).
  527.  
  528. In any case, we then return the list of output from C<eval> to the caller, 
  529. and unwinding restores the former version of C<$@> in C<@saved> as well 
  530. (the localization of C<$saved[0]> goes away at the end of this scope).
  531.  
  532. =head3 Parameters and variables influencing execution of DB::eval()
  533.  
  534. C<DB::eval> isn't parameterized in the standard way; this is to keep the
  535. debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
  536. The variables listed below influence C<DB::eval()>'s execution directly. 
  537.  
  538. =over 4
  539.  
  540. =item C<$evalarg> - the thing to actually be eval'ed
  541.  
  542. =item C<$trace> - Current state of execution tracing (see X<$trace>)
  543.  
  544. =item C<$single> - Current state of single-stepping (see X<$single>)        
  545.  
  546. =item C<$onetimeDump> - what is to be displayed after the evaluation 
  547.  
  548. =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
  549.  
  550. =back
  551.  
  552. The following variables are altered by C<DB::eval()> during its execution. They
  553. are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>. 
  554.  
  555. =over 4
  556.  
  557. =item C<@res> - used to capture output from actual C<eval>.
  558.  
  559. =item C<$otrace> - saved value of C<$trace>.
  560.  
  561. =item C<$osingle> - saved value of C<$single>.      
  562.  
  563. =item C<$od> - saved value of C<$^D>.
  564.  
  565. =item C<$saved[0]> - saved value of C<$@>.
  566.  
  567. =item $\ - for output of C<$@> if there is an evaluation error.      
  568.  
  569. =back
  570.  
  571. =head3 The problem of lexicals
  572.  
  573. The context of C<DB::eval()> presents us with some problems. Obviously,
  574. we want to be 'sandboxed' away from the debugger's internals when we do
  575. the eval, but we need some way to control how punctuation variables and
  576. debugger globals are used. 
  577.  
  578. We can't use local, because the code inside C<DB::eval> can see localized
  579. variables; and we can't use C<my> either for the same reason. The code
  580. in this routine compromises and uses C<my>.
  581.  
  582. After this routine is over, we don't have user code executing in the debugger's
  583. context, so we can use C<my> freely.
  584.  
  585. =cut
  586.  
  587. ############################################## Begin lexical danger zone
  588.  
  589. # 'my' variables used here could leak into (that is, be visible in)
  590. # the context that the code being evaluated is executing in. This means that
  591. # the code could modify the debugger's variables.
  592. #
  593. # Fiddling with the debugger's context could be Bad. We insulate things as
  594. # much as we can.
  595.  
  596. sub eval {
  597.  
  598.     # 'my' would make it visible from user code
  599.     #    but so does local! --tchrist  
  600.     # Remember: this localizes @DB::res, not @main::res.
  601.     local @res;
  602.     {
  603.         # Try to keep the user code from messing  with us. Save these so that 
  604.         # even if the eval'ed code changes them, we can put them back again. 
  605.         # Needed because the user could refer directly to the debugger's 
  606.         # package globals (and any 'my' variables in this containing scope)
  607.         # inside the eval(), and we want to try to stay safe.
  608.         local $otrace  = $trace; 
  609.         local $osingle = $single;
  610.         local $od      = $^D;
  611.  
  612.         # Untaint the incoming eval() argument.
  613.         { ($evalarg) = $evalarg =~ /(.*)/s; }
  614.  
  615.         # $usercontext built in DB::DB near the comment 
  616.         # "set up the context for DB::eval ..."
  617.         # Evaluate and save any results.
  618.         @res =
  619.           eval "$usercontext $evalarg;\n";    # '\n' for nice recursive debug
  620.  
  621.         # Restore those old values.
  622.         $trace  = $otrace;
  623.         $single = $osingle;
  624.         $^D     = $od;
  625.     }
  626.  
  627.     # Save the current value of $@, and preserve it in the debugger's copy
  628.     # of the saved precious globals.
  629.     my $at = $@;
  630.  
  631.     # Since we're only saving $@, we only have to localize the array element
  632.     # that it will be stored in.
  633.     local $saved[0];                          # Preserve the old value of $@
  634.     eval { &DB::save };
  635.  
  636.     # Now see whether we need to report an error back to the user.
  637.     if ($at) {
  638.         local $\ = '';
  639.         print $OUT $at;
  640.     }
  641.  
  642.     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
  643.     # are package globals.
  644.     elsif ($onetimeDump) {
  645.         if ($onetimeDump eq 'dump') {
  646.             local $option{dumpDepth} = $onetimedumpDepth
  647.               if defined $onetimedumpDepth;
  648.             dumpit($OUT, \@res);
  649.         }
  650.         elsif ($onetimeDump eq 'methods') {
  651.             methods($res[0]);
  652.         }
  653.     } ## end elsif ($onetimeDump)
  654.     @res;
  655. } ## end sub eval
  656.  
  657. ############################################## End lexical danger zone
  658.  
  659. # After this point it is safe to introduce lexicals.
  660. # The code being debugged will be executing in its own context, and 
  661. # can't see the inside of the debugger.
  662. #
  663. # However, one should not overdo it: leave as much control from outside as    
  664. # possible. If you make something a lexical, it's not going to be addressable
  665. # from outside the debugger even if you know its name.
  666.  
  667. # This file is automatically included if you do perl -d.
  668. # It's probably not useful to include this yourself.
  669. #
  670. # Before venturing further into these twisty passages, it is 
  671. # wise to read the perldebguts man page or risk the ire of dragons.
  672. #
  673. # (It should be noted that perldebguts will tell you a lot about
  674. # the uderlying mechanics of how the debugger interfaces into the
  675. # Perl interpreter, but not a lot about the debugger itself. The new
  676. # comments in this code try to address this problem.)
  677.  
  678. # Note that no subroutine call is possible until &DB::sub is defined
  679. # (for subroutines defined outside of the package DB). In fact the same is
  680. # true if $deep is not defined.
  681. #
  682. # $Log:    perldb.pl,v $
  683.  
  684. # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
  685.  
  686. # modified Perl debugger, to be run from Emacs in perldb-mode
  687. # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
  688. # Johan Vromans -- upgrade to 4.0 pl 10
  689. # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
  690.  
  691. # (We have made efforts to  clarify the comments in the change log
  692. # in other places; some of them may seem somewhat obscure as they
  693. # were originally written, and explaining them away from the code
  694. # in question seems conterproductive.. -JM)
  695.  
  696. ########################################################################
  697. # Changes: 0.94
  698. #   + A lot of things changed after 0.94. First of all, core now informs
  699. #     debugger about entry into XSUBs, overloaded operators, tied operations,
  700. #     BEGIN and END. Handy with `O f=2'.
  701. #   + This can make debugger a little bit too verbose, please be patient
  702. #     and report your problems promptly.
  703. #   + Now the option frame has 3 values: 0,1,2. XXX Document!
  704. #   + Note that if DESTROY returns a reference to the object (or object),
  705. #     the deletion of data may be postponed until the next function call,
  706. #     due to the need to examine the return value.
  707. #
  708. # Changes: 0.95
  709. #   + `v' command shows versions.
  710. #
  711. # Changes: 0.96 
  712. #   + `v' command shows version of readline.
  713. #     primitive completion works (dynamic variables, subs for `b' and `l',
  714. #     options). Can `p %var'
  715. #   + Better help (`h <' now works). New commands <<, >>, {, {{.
  716. #     {dump|print}_trace() coded (to be able to do it from <<cmd).
  717. #   + `c sub' documented.
  718. #   + At last enough magic combined to stop after the end of debuggee.
  719. #   + !! should work now (thanks to Emacs bracket matching an extra
  720. #     `]' in a regexp is caught).
  721. #   + `L', `D' and `A' span files now (as documented).
  722. #   + Breakpoints in `require'd code are possible (used in `R').
  723. #   +  Some additional words on internal work of debugger.
  724. #   + `b load filename' implemented.
  725. #   + `b postpone subr' implemented.
  726. #   + now only `q' exits debugger (overwritable on $inhibit_exit).
  727. #   + When restarting debugger breakpoints/actions persist.
  728. #   + Buglet: When restarting debugger only one breakpoint/action per 
  729. #             autoloaded function persists.
  730. #
  731. # Changes: 0.97: NonStop will not stop in at_exit().
  732. #   + Option AutoTrace implemented.
  733. #   + Trace printed differently if frames are printed too.
  734. #   + new `inhibitExit' option.
  735. #   + printing of a very long statement interruptible.
  736. # Changes: 0.98: New command `m' for printing possible methods
  737. #   + 'l -' is a synonym for `-'.
  738. #   + Cosmetic bugs in printing stack trace.
  739. #   +  `frame' & 8 to print "expanded args" in stack trace.
  740. #   + Can list/break in imported subs.
  741. #   + new `maxTraceLen' option.
  742. #   + frame & 4 and frame & 8 granted.
  743. #   + new command `m'
  744. #   + nonstoppable lines do not have `:' near the line number.
  745. #   + `b compile subname' implemented.
  746. #   + Will not use $` any more.
  747. #   + `-' behaves sane now.
  748. # Changes: 0.99: Completion for `f', `m'.
  749. #   +  `m' will remove duplicate names instead of duplicate functions.
  750. #   + `b load' strips trailing whitespace.
  751. #     completion ignores leading `|'; takes into account current package
  752. #     when completing a subroutine name (same for `l').
  753. # Changes: 1.07: Many fixed by tchrist 13-March-2000
  754. #   BUG FIXES:
  755. #   + Added bare minimal security checks on perldb rc files, plus
  756. #     comments on what else is needed.
  757. #   + Fixed the ornaments that made "|h" completely unusable.
  758. #     They are not used in print_help if they will hurt.  Strip pod
  759. #     if we're paging to less.
  760. #   + Fixed mis-formatting of help messages caused by ornaments
  761. #     to restore Larry's original formatting.  
  762. #   + Fixed many other formatting errors.  The code is still suboptimal, 
  763. #     and needs a lot of work at restructuring.  It's also misindented
  764. #     in many places.
  765. #   + Fixed bug where trying to look at an option like your pager
  766. #     shows "1".  
  767. #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
  768. #     lose.  You should consider shell escapes not using their shell,
  769. #     or else not caring about detailed status.  This should really be
  770. #     unified into one place, too.
  771. #   + Fixed bug where invisible trailing whitespace on commands hoses you,
  772. #     tricking Perl into thinking you weren't calling a debugger command!
  773. #   + Fixed bug where leading whitespace on commands hoses you.  (One
  774. #     suggests a leading semicolon or any other irrelevant non-whitespace
  775. #     to indicate literal Perl code.)
  776. #   + Fixed bugs that ate warnings due to wrong selected handle.
  777. #   + Fixed a precedence bug on signal stuff.
  778. #   + Fixed some unseemly wording.
  779. #   + Fixed bug in help command trying to call perl method code.
  780. #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
  781. #   ENHANCEMENTS:
  782. #   + Added some comments.  This code is still nasty spaghetti.
  783. #   + Added message if you clear your pre/post command stacks which was
  784. #     very easy to do if you just typed a bare >, <, or {.  (A command
  785. #     without an argument should *never* be a destructive action; this
  786. #     API is fundamentally screwed up; likewise option setting, which
  787. #     is equally buggered.)
  788. #   + Added command stack dump on argument of "?" for >, <, or {.
  789. #   + Added a semi-built-in doc viewer command that calls man with the
  790. #     proper %Config::Config path (and thus gets caching, man -k, etc),
  791. #     or else perldoc on obstreperous platforms.
  792. #   + Added to and rearranged the help information.
  793. #   + Detected apparent misuse of { ... } to declare a block; this used
  794. #     to work but now is a command, and mysteriously gave no complaint.
  795. #
  796. # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
  797. #   BUG FIX:
  798. #   + This patch to perl5db.pl cleans up formatting issues on the help
  799. #     summary (h h) screen in the debugger.  Mostly columnar alignment
  800. #     issues, plus converted the printed text to use all spaces, since
  801. #     tabs don't seem to help much here.
  802. #
  803. # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
  804. #   Minor bugs corrected;
  805. #   + Support for auto-creation of new TTY window on startup, either
  806. #     unconditionally, or if started as a kid of another debugger session;
  807. #   + New `O'ption CreateTTY
  808. #       I<CreateTTY>      bits control attempts to create a new TTY on events:
  809. #                         1: on fork()   
  810. #                         2: debugger is started inside debugger
  811. #                         4: on startup
  812. #   + Code to auto-create a new TTY window on OS/2 (currently one
  813. #     extra window per session - need named pipes to have more...);
  814. #   + Simplified interface for custom createTTY functions (with a backward
  815. #     compatibility hack); now returns the TTY name to use; return of ''
  816. #     means that the function reset the I/O handles itself;
  817. #   + Better message on the semantic of custom createTTY function;
  818. #   + Convert the existing code to create a TTY into a custom createTTY
  819. #     function;
  820. #   + Consistent support for TTY names of the form "TTYin,TTYout";
  821. #   + Switch line-tracing output too to the created TTY window;
  822. #   + make `b fork' DWIM with CORE::GLOBAL::fork;
  823. #   + High-level debugger API cmd_*():
  824. #      cmd_b_load($filenamepart)            # b load filenamepart
  825. #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
  826. #      cmd_b_sub($sub [, $cond])            # b sub [cond]
  827. #      cmd_stop()                           # Control-C
  828. #      cmd_d($lineno)                       # d lineno (B)
  829. #      The cmd_*() API returns FALSE on failure; in this case it outputs
  830. #      the error message to the debugging output.
  831. #   + Low-level debugger API
  832. #      break_on_load($filename)             # b load filename
  833. #      @files = report_break_on_load()      # List files with load-breakpoints
  834. #      breakable_line_in_filename($name, $from [, $to])
  835. #                                           # First breakable line in the
  836. #                                           # range $from .. $to.  $to defaults
  837. #                                           # to $from, and may be less than 
  838. #                                           # $to
  839. #      breakable_line($from [, $to])        # Same for the current file
  840. #      break_on_filename_line($name, $lineno [, $cond])
  841. #                                           # Set breakpoint,$cond defaults to 
  842. #                                           # 1
  843. #      break_on_filename_line_range($name, $from, $to [, $cond])
  844. #                                           # As above, on the first
  845. #                                           # breakable line in range
  846. #      break_on_line($lineno [, $cond])     # As above, in the current file
  847. #      break_subroutine($sub [, $cond])     # break on the first breakable line
  848. #      ($name, $from, $to) = subroutine_filename_lines($sub)
  849. #                                           # The range of lines of the text
  850. #      The low-level API returns TRUE on success, and die()s on failure.
  851. #
  852. # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
  853. #   BUG FIXES:
  854. #   + Fixed warnings generated by "perl -dWe 42"
  855. #   + Corrected spelling errors
  856. #   + Squeezed Help (h) output into 80 columns
  857. #
  858. # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
  859. #   + Made "x @INC" work like it used to
  860. #
  861. # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
  862. #   + Fixed warnings generated by "O" (Show debugger options)
  863. #   + Fixed warnings generated by "p 42" (Print expression)
  864. # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
  865. #   + Added windowSize option 
  866. # Changes: 1.14: Oct  9, 2001 multiple
  867. #   + Clean up after itself on VMS (Charles Lane in 12385)
  868. #   + Adding "@ file" syntax (Peter Scott in 12014)
  869. #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
  870. #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
  871. #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
  872. # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
  873. #   + Updated 1.14 change log
  874. #   + Added *dbline explainatory comments
  875. #   + Mentioning perldebguts man page
  876. # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
  877. #   + $onetimeDump improvements
  878. # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
  879. #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
  880. #   rationalised the following commands and added cmd_wrapper() to 
  881. #   enable switching between old and frighteningly consistent new 
  882. #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
  883. #     a(add),       A(del)            # action expr   (added del by line)
  884. #   + b(add),       B(del)            # break  [line] (was b,D)
  885. #   + w(add),       W(del)            # watch  expr   (was W,W) 
  886. #                                     # added del by expr
  887. #   + h(summary), h h(long)           # help (hh)     (was h h,h)
  888. #   + m(methods),   M(modules)        # ...           (was m,v)
  889. #   + o(option)                       # lc            (was O)
  890. #   + v(view code), V(view Variables) # ...           (was w,V)
  891. # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
  892. #   + fixed missing cmd_O bug
  893. # Changes: 1.19: Mar 29, 2002 Spider Boardman
  894. #   + Added missing local()s -- DB::DB is called recursively.
  895. # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
  896. #   + pre'n'post commands no longer trashed with no args
  897. #   + watch val joined out of eval()
  898. # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
  899. #   + Added comments and reformatted source. No bug fixes/enhancements.
  900. #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
  901. # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
  902. #   + Flush stdout/stderr before the debugger prompt is printed.
  903. # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
  904. #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
  905.  
  906. ####################################################################
  907.  
  908. =head1 DEBUGGER INITIALIZATION
  909.  
  910. The debugger starts up in phases.
  911.  
  912. =head2 BASIC SETUP
  913.  
  914. First, it initializes the environment it wants to run in: turning off
  915. warnings during its own compilation, defining variables which it will need
  916. to avoid warnings later, setting itself up to not exit when the program
  917. terminates, and defaulting to printing return values for the C<r> command.
  918.  
  919. =cut
  920.  
  921. # Needed for the statement after exec():
  922. #
  923. # This BEGIN block is simply used to switch off warnings during debugger
  924. # compiliation. Probably it would be better practice to fix the warnings,
  925. # but this is how it's done at the moment.
  926.  
  927. BEGIN {
  928.     $ini_warn = $^W;
  929.     $^W       = 0;
  930. }    # Switch compilation warnings off until another BEGIN.
  931.  
  932. local ($^W) = 0;    # Switch run-time warnings off during init.
  933.  
  934. # This would probably be better done with "use vars", but that wasn't around
  935. # when this code was originally written. (Neither was "use strict".) And on
  936. # the principle of not fiddling with something that was working, this was
  937. # left alone.
  938. warn(               # Do not ;-)
  939.     # These variables control the execution of 'dumpvar.pl'.
  940.     $dumpvar::hashDepth,
  941.     $dumpvar::arrayDepth,
  942.     $dumpvar::dumpDBFiles,
  943.     $dumpvar::dumpPackages,
  944.     $dumpvar::quoteHighBit,
  945.     $dumpvar::printUndef,
  946.     $dumpvar::globPrint,
  947.     $dumpvar::usageOnly,
  948.  
  949.     # used to save @ARGV and extract any debugger-related flags.
  950.     @ARGS,
  951.  
  952.     # used to control die() reporting in diesignal()
  953.     $Carp::CarpLevel,
  954.  
  955.     # used to prevent multiple entries to diesignal()
  956.     # (if for instance diesignal() itself dies)
  957.     $panic,
  958.  
  959.     # used to prevent the debugger from running nonstop
  960.     # after a restart
  961.     $second_time,
  962.   )
  963.   if 0;
  964.  
  965. # Command-line + PERLLIB:
  966. # Save the contents of @INC before they are modified elsewhere.
  967. @ini_INC = @INC;
  968.  
  969. # This was an attempt to clear out the previous values of various
  970. # trapped errors. Apparently it didn't help. XXX More info needed!
  971. # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
  972.  
  973. # We set these variables to safe values. We don't want to blindly turn
  974. # off warnings, because other packages may still want them.
  975. $trace = $signal = $single = 0;   # Uninitialized warning suppression
  976.                                   # (local $^W cannot help - other packages!).
  977.  
  978. # Default to not exiting when program finishes; print the return
  979. # value when the 'r' command is used to return from a subroutine.
  980. $inhibit_exit = $option{PrintRet} = 1;
  981.  
  982. =head1 OPTION PROCESSING
  983.  
  984. The debugger's options are actually spread out over the debugger itself and 
  985. C<dumpvar.pl>; some of these are variables to be set, while others are 
  986. subs to be called with a value. To try to make this a little easier to
  987. manage, the debugger uses a few data structures to define what options
  988. are legal and how they are to be processed.
  989.  
  990. First, the C<@options> array defines the I<names> of all the options that
  991. are to be accepted.
  992.  
  993. =cut
  994.  
  995. @options = qw(
  996.              CommandSet
  997.              hashDepth    arrayDepth    dumpDepth
  998.              DumpDBFiles  DumpPackages  DumpReused
  999.              compactDump  veryCompact   quote
  1000.              HighBit      undefPrint    globPrint 
  1001.              PrintRet     UsageOnly     frame
  1002.              AutoTrace    TTY           noTTY 
  1003.              ReadLine     NonStop       LineInfo 
  1004.              maxTraceLen  recallCommand ShellBang
  1005.              pager        tkRunning     ornaments
  1006.              signalLevel  warnLevel     dieLevel 
  1007.              inhibit_exit ImmediateStop bareStringify 
  1008.              CreateTTY    RemotePort    windowSize
  1009.            );
  1010.  
  1011. =pod
  1012.  
  1013. Second, C<optionVars> lists the variables that each option uses to save its
  1014. state.
  1015.  
  1016. =cut
  1017.  
  1018. %optionVars = (
  1019.     hashDepth     => \$dumpvar::hashDepth,
  1020.     arrayDepth    => \$dumpvar::arrayDepth,
  1021.     CommandSet    => \$CommandSet,
  1022.     DumpDBFiles   => \$dumpvar::dumpDBFiles,
  1023.     DumpPackages  => \$dumpvar::dumpPackages,
  1024.     DumpReused    => \$dumpvar::dumpReused,
  1025.     HighBit       => \$dumpvar::quoteHighBit,
  1026.     undefPrint    => \$dumpvar::printUndef,
  1027.     globPrint     => \$dumpvar::globPrint,
  1028.     UsageOnly     => \$dumpvar::usageOnly,
  1029.     CreateTTY     => \$CreateTTY,
  1030.     bareStringify => \$dumpvar::bareStringify,
  1031.     frame         => \$frame,
  1032.     AutoTrace     => \$trace,
  1033.     inhibit_exit  => \$inhibit_exit,
  1034.     maxTraceLen   => \$maxtrace,
  1035.     ImmediateStop => \$ImmediateStop,
  1036.     RemotePort    => \$remoteport,
  1037.     windowSize    => \$window,
  1038.     );
  1039.  
  1040. =pod
  1041.  
  1042. Third, C<%optionAction> defines the subroutine to be called to process each
  1043. option.
  1044.  
  1045. =cut 
  1046.  
  1047. %optionAction = (
  1048.     compactDump   => \&dumpvar::compactDump,
  1049.     veryCompact   => \&dumpvar::veryCompact,
  1050.     quote         => \&dumpvar::quote,
  1051.     TTY           => \&TTY,
  1052.     noTTY         => \&noTTY,
  1053.     ReadLine      => \&ReadLine,
  1054.     NonStop       => \&NonStop,
  1055.     LineInfo      => \&LineInfo,
  1056.     recallCommand => \&recallCommand,
  1057.     ShellBang     => \&shellBang,
  1058.     pager         => \&pager,
  1059.     signalLevel   => \&signalLevel,
  1060.     warnLevel     => \&warnLevel,
  1061.     dieLevel      => \&dieLevel,
  1062.     tkRunning     => \&tkRunning,
  1063.     ornaments     => \&ornaments,
  1064.     RemotePort    => \&RemotePort,
  1065.     );
  1066.  
  1067. =pod
  1068.  
  1069. Last, the C<%optionRequire> notes modules that must be C<require>d if an
  1070. option is used.
  1071.  
  1072. =cut
  1073.  
  1074. # Note that this list is not complete: several options not listed here
  1075. # actually require that dumpvar.pl be loaded for them to work, but are
  1076. # not in the table. A subsequent patch will correct this problem; for
  1077. # the moment, we're just recommenting, and we are NOT going to change
  1078. # function.
  1079. %optionRequire = (
  1080.     compactDump => 'dumpvar.pl',
  1081.     veryCompact => 'dumpvar.pl',
  1082.     quote       => 'dumpvar.pl',
  1083.     );
  1084.  
  1085. =pod
  1086.  
  1087. There are a number of initialization-related variables which can be set
  1088. by putting code to set them in a BEGIN block in the C<PERL5DB> environment
  1089. variable. These are:
  1090.  
  1091. =over 4
  1092.  
  1093. =item C<$rl> - readline control XXX needs more explanation
  1094.  
  1095. =item C<$warnLevel> - whether or not debugger takes over warning handling
  1096.  
  1097. =item C<$dieLevel> - whether or not debugger takes over die handling
  1098.  
  1099. =item C<$signalLevel> - whether or not debugger takes over signal handling
  1100.  
  1101. =item C<$pre> - preprompt actions (array reference)
  1102.  
  1103. =item C<$post> - postprompt actions (array reference)
  1104.  
  1105. =item C<$pretype>
  1106.  
  1107. =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
  1108.  
  1109. =item C<$CommandSet> - which command set to use (defaults to new, documented set)
  1110.  
  1111. =back
  1112.  
  1113. =cut
  1114.  
  1115. # These guys may be defined in $ENV{PERL5DB} :
  1116. $rl          = 1     unless defined $rl;
  1117. $warnLevel   = 1     unless defined $warnLevel;
  1118. $dieLevel    = 1     unless defined $dieLevel;
  1119. $signalLevel = 1     unless defined $signalLevel;
  1120. $pre         = []    unless defined $pre;
  1121. $post        = []    unless defined $post;
  1122. $pretype     = []    unless defined $pretype;
  1123. $CreateTTY   = 3     unless defined $CreateTTY;
  1124. $CommandSet  = '580' unless defined $CommandSet;
  1125.  
  1126. =pod
  1127.  
  1128. The default C<die>, C<warn>, and C<signal> handlers are set up.
  1129.  
  1130. =cut
  1131.  
  1132. warnLevel($warnLevel);
  1133. dieLevel($dieLevel);
  1134. signalLevel($signalLevel);
  1135.  
  1136. =pod
  1137.  
  1138. The pager to be used is needed next. We try to get it from the
  1139. environment first.  if it's not defined there, we try to find it in
  1140. the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
  1141. then call the C<pager()> function to save the pager name.
  1142.  
  1143. =cut
  1144.  
  1145. # This routine makes sure $pager is set up so that '|' can use it.
  1146. pager(
  1147.     # If PAGER is defined in the environment, use it.
  1148.     defined $ENV{PAGER} 
  1149.       ? $ENV{PAGER}
  1150.  
  1151.       # If not, see if Config.pm defines it.
  1152.       : eval { require Config } && defined $Config::Config{pager} 
  1153.         ? $Config::Config{pager}
  1154.  
  1155.       # If not, fall back to 'more'.
  1156.         : 'more'
  1157.   )
  1158.   unless defined $pager;
  1159.  
  1160. =pod
  1161.  
  1162. We set up the command to be used to access the man pages, the command
  1163. recall character ("!" unless otherwise defined) and the shell escape
  1164. character ("!" unless otherwise defined). Yes, these do conflict, and
  1165. neither works in the debugger at the moment.
  1166.  
  1167. =cut
  1168.  
  1169. setman();
  1170.  
  1171. # Set up defaults for command recall and shell escape (note:
  1172. # these currently don't work in linemode debugging).
  1173. &recallCommand("!") unless defined $prc;
  1174. &shellBang("!")     unless defined $psh;
  1175.  
  1176. =pod
  1177.  
  1178. We then set up the gigantic string containing the debugger help.
  1179. We also set the limit on the number of arguments we'll display during a
  1180. trace.
  1181.  
  1182. =cut
  1183.  
  1184. sethelp();
  1185.  
  1186. # If we didn't get a default for the length of eval/stack trace args,
  1187. # set it here.
  1188. $maxtrace = 400 unless defined $maxtrace;
  1189.  
  1190. =head2 SETTING UP THE DEBUGGER GREETING
  1191.  
  1192. The debugger 'greeting'  helps to inform the user how many debuggers are
  1193. running, and whether the current debugger is the primary or a child.
  1194.  
  1195. If we are the primary, we just hang onto our pid so we'll have it when
  1196. or if we start a child debugger. If we are a child, we'll set things up
  1197. so we'll have a unique greeting and so the parent will give us our own
  1198. TTY later.
  1199.  
  1200. We save the current contents of the C<PERLDB_PIDS> environment variable
  1201. because we mess around with it. We'll also need to hang onto it because
  1202. we'll need it if we restart.
  1203.  
  1204. Child debuggers make a label out of the current PID structure recorded in
  1205. PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
  1206. yet so the parent will give them one later via C<resetterm()>.
  1207.  
  1208. =cut
  1209.  
  1210. # Save the current contents of the environment; we're about to 
  1211. # much with it. We'll need this if we have to restart.
  1212. $ini_pids = $ENV{PERLDB_PIDS};
  1213.  
  1214. if (defined $ENV{PERLDB_PIDS}) { 
  1215.     # We're a child. Make us a label out of the current PID structure
  1216.     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having 
  1217.     # a term yet so the parent will give us one later via resetterm().
  1218.     $pids = "[$ENV{PERLDB_PIDS}]";
  1219.     $ENV{PERLDB_PIDS} .= "->$$";
  1220.     $term_pid = -1;
  1221. } ## end if (defined $ENV{PERLDB_PIDS...
  1222. else {
  1223.     # We're the parent PID. Initialize PERLDB_PID in case we end up with a 
  1224.     # child debugger, and mark us as the parent, so we'll know to set up
  1225.     # more TTY's is we have to.
  1226.     $ENV{PERLDB_PIDS} = "$$";
  1227.     $pids     = "{pid=$$}";
  1228.     $term_pid = $$;
  1229. }
  1230.  
  1231. $pidprompt = '';
  1232.  
  1233. # Sets up $emacs as a synonym for $slave_editor.
  1234. *emacs     = $slave_editor if $slave_editor;   # May be used in afterinit()...
  1235.  
  1236. =head2 READING THE RC FILE
  1237.  
  1238. The debugger will read a file of initialization options if supplied. If    
  1239. running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
  1240.  
  1241. =cut      
  1242.  
  1243. # As noted, this test really doesn't check accurately that the debugger
  1244. # is running at a terminal or not.
  1245. if (-e "/dev/tty") {                           # this is the wrong metric!
  1246.     $rcfile = ".perldb";
  1247. }
  1248. else {
  1249.     $rcfile = "perldb.ini";
  1250. }
  1251.  
  1252. =pod
  1253.  
  1254. The debugger does a safety test of the file to be read. It must be owned
  1255. either by the current user or root, and must only be writable by the owner.
  1256.  
  1257. =cut
  1258.  
  1259. # This wraps a safety test around "do" to read and evaluate the init file.
  1260. #
  1261. # This isn't really safe, because there's a race
  1262. # between checking and opening.  The solution is to
  1263. # open and fstat the handle, but then you have to read and
  1264. # eval the contents.  But then the silly thing gets
  1265. # your lexical scope, which is unfortunate at best.
  1266. sub safe_do {
  1267.     my $file = shift;
  1268.  
  1269.     # Just exactly what part of the word "CORE::" don't you understand?
  1270.     local $SIG{__WARN__};
  1271.     local $SIG{__DIE__};
  1272.  
  1273.     unless (is_safe_file($file)) {
  1274.         CORE::warn <<EO_GRIPE;
  1275. perldb: Must not source insecure rcfile $file.
  1276.         You or the superuser must be the owner, and it must not 
  1277.         be writable by anyone but its owner.
  1278. EO_GRIPE
  1279.         return;
  1280.     } ## end unless (is_safe_file($file...
  1281.  
  1282.     do $file;
  1283.     CORE::warn("perldb: couldn't parse $file: $@") if $@;
  1284. } ## end sub safe_do
  1285.  
  1286. # This is the safety test itself.
  1287. #
  1288. # Verifies that owner is either real user or superuser and that no
  1289. # one but owner may write to it.  This function is of limited use
  1290. # when called on a path instead of upon a handle, because there are
  1291. # no guarantees that filename (by dirent) whose file (by ino) is
  1292. # eventually accessed is the same as the one tested. 
  1293. # Assumes that the file's existence is not in doubt.
  1294. sub is_safe_file {
  1295.     my $path = shift;
  1296.     stat($path) || return;    # mysteriously vaporized
  1297.     my ($dev, $ino, $mode, $nlink, $uid, $gid) = stat(_);
  1298.  
  1299.     return 0 if $uid != 0 && $uid != $<;
  1300.     return 0 if $mode & 022;
  1301.     return 1;
  1302. } ## end sub is_safe_file
  1303.  
  1304. # If the rcfile (whichever one we decided was the right one to read)
  1305. # exists, we safely do it. 
  1306. if (-f $rcfile) {
  1307.     safe_do("./$rcfile");
  1308. }
  1309. # If there isn't one here, try the user's home directory.
  1310. elsif (defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile") {
  1311.     safe_do("$ENV{HOME}/$rcfile");
  1312. }
  1313. # Else try the login directory.
  1314. elsif (defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile") {
  1315.     safe_do("$ENV{LOGDIR}/$rcfile");
  1316. }
  1317.  
  1318. # If the PERLDB_OPTS variable has options in it, parse those out next.
  1319. if (defined $ENV{PERLDB_OPTS}) {
  1320.     parse_options($ENV{PERLDB_OPTS});
  1321. }
  1322.  
  1323. =pod
  1324.  
  1325. The last thing we do during initialization is determine which subroutine is
  1326. to be used to obtain a new terminal when a new debugger is started. Right now,
  1327. the debugger only handles X Windows and OS/2.
  1328.  
  1329. =cut
  1330.  
  1331. # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
  1332. # Works if you're running an xterm or xterm-like window, or you're on
  1333. # OS/2. This may need some expansion: for instance, this doesn't handle
  1334. # OS X Terminal windows.       
  1335.  
  1336. if (not defined &get_fork_TTY                        # no routine exists,
  1337.     and defined $ENV{TERM}                           # and we know what kind
  1338.                                                      # of terminal this is,
  1339.     and $ENV{TERM} eq 'xterm'                        # and it's an xterm,
  1340.     and defined $ENV{WINDOWID}                       # and we know what
  1341.                                                      # window this is,
  1342.     and defined $ENV{DISPLAY})                       # and what display it's
  1343.                                                      # on,
  1344. {
  1345.     *get_fork_TTY = \&xterm_get_fork_TTY;            # use the xterm version
  1346. } ## end if (not defined &get_fork_TTY...
  1347. elsif ($^O eq 'os2') {                               # If this is OS/2,
  1348.     *get_fork_TTY = \&os2_get_fork_TTY;              # use the OS/2 version
  1349. }
  1350. # untaint $^O, which may have been tainted by the last statement.
  1351. # see bug [perl #24674]
  1352. $^O =~ m/^(.*)\z/; $^O = $1;
  1353.  
  1354. # "Here begin the unreadable code.  It needs fixing." 
  1355.  
  1356. =head2 RESTART PROCESSING
  1357.  
  1358. This section handles the restart command. When the C<R> command is invoked, it
  1359. tries to capture all of the state it can into environment variables, and
  1360. then sets C<PERLDB_RESTART>. When we start executing again, we check to see
  1361. if C<PERLDB_RESTART> is there; if so, we reload all the information that
  1362. the R command stuffed into the environment variables.
  1363.  
  1364.   PERLDB_RESTART   - flag only, contains no restart data itself.       
  1365.   PERLDB_HIST      - command history, if it's available
  1366.   PERLDB_ON_LOAD   - breakpoints set by the rc file
  1367.   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
  1368.   PERLDB_VISITED   - files that had breakpoints
  1369.   PERLDB_FILE_...  - breakpoints for a file
  1370.   PERLDB_OPT       - active options
  1371.   PERLDB_INC       - the original @INC
  1372.   PERLDB_PRETYPE   - preprompt debugger actions
  1373.   PERLDB_PRE       - preprompt Perl code
  1374.   PERLDB_POST      - post-prompt Perl code
  1375.   PERLDB_TYPEAHEAD - typeahead captured by readline()
  1376.  
  1377. We chug through all these variables and plug the values saved in them
  1378. back into the appropriate spots in the debugger.
  1379.  
  1380. =cut
  1381.  
  1382. if (exists $ENV{PERLDB_RESTART}) {
  1383.     # We're restarting, so we don't need the flag that says to restart anymore.
  1384.     delete $ENV{PERLDB_RESTART};
  1385.     # $restart = 1;
  1386.     @hist          = get_list('PERLDB_HIST');
  1387.     %break_on_load = get_list("PERLDB_ON_LOAD");
  1388.     %postponed     = get_list("PERLDB_POSTPONE");
  1389.  
  1390.     # restore breakpoints/actions
  1391.     my @had_breakpoints = get_list("PERLDB_VISITED");
  1392.     for (0 .. $#had_breakpoints) {
  1393.         my %pf = get_list("PERLDB_FILE_$_");
  1394.         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
  1395.     }
  1396.  
  1397.     # restore options
  1398.     my %opt = get_list("PERLDB_OPT");
  1399.     my ($opt, $val);
  1400.     while (($opt, $val) = each %opt) {
  1401.         $val =~ s/[\\\']/\\$1/g;
  1402.         parse_options("$opt'$val'");
  1403.     }
  1404.  
  1405.     # restore original @INC
  1406.     @INC       = get_list("PERLDB_INC");
  1407.     @ini_INC   = @INC;
  1408.  
  1409.     # return pre/postprompt actions and typeahead buffer
  1410.     $pretype   = [get_list("PERLDB_PRETYPE")];
  1411.     $pre       = [get_list("PERLDB_PRE")];
  1412.     $post      = [get_list("PERLDB_POST")];
  1413.     @typeahead = get_list("PERLDB_TYPEAHEAD", @typeahead);
  1414. } ## end if (exists $ENV{PERLDB_RESTART...
  1415.  
  1416. =head2 SETTING UP THE TERMINAL
  1417.  
  1418. Now, we'll decide how the debugger is going to interact with the user.
  1419. If there's no TTY, we set the debugger to run non-stop; there's not going
  1420. to be anyone there to enter commands.
  1421.  
  1422. =cut
  1423.  
  1424. if ($notty) {
  1425.     $runnonstop = 1;
  1426. }
  1427.  
  1428. =pod
  1429.  
  1430. If there is a TTY, we have to determine who it belongs to before we can
  1431. proceed. If this is a slave editor or graphical debugger (denoted by
  1432. the first command-line switch being '-emacs'), we shift this off and
  1433. set C<$rl> to 0 (XXX ostensibly to do straight reads).
  1434.  
  1435. =cut
  1436.  
  1437. else {
  1438.     # Is Perl being run from a slave editor or graphical debugger?
  1439.     # If so, don't use readline, and set $slave_editor = 1.
  1440.     $slave_editor =
  1441.       ((defined $main::ARGV[0]) and ($main::ARGV[0] eq '-emacs'));
  1442.     $rl = 0, shift (@main::ARGV) if $slave_editor;
  1443.     #require Term::ReadLine;
  1444.  
  1445. =pod
  1446.  
  1447. We then determine what the console should be on various systems:
  1448.  
  1449. =over 4
  1450.  
  1451. =item * Cygwin - We use C<stdin> instead of a separate device.
  1452.  
  1453. =cut
  1454.  
  1455.  
  1456.     if ($^O eq 'cygwin') {
  1457.         # /dev/tty is binary. use stdin for textmode
  1458.         undef $console;
  1459.     }
  1460.  
  1461. =item * Unix - use C</dev/tty>.
  1462.  
  1463. =cut
  1464.  
  1465.     elsif (-e "/dev/tty") {
  1466.         $console = "/dev/tty";
  1467.     }
  1468.  
  1469. =item * Windows or MSDOS - use C<con>.
  1470.  
  1471. =cut
  1472.  
  1473.     elsif ($^O eq 'dos' or -e "con" or $^O eq 'MSWin32') {
  1474.         $console = "con";
  1475.     }
  1476.  
  1477. =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
  1478. Console> if not. (Note that Mac OS X returns 'darwin', not 'MacOS'. Also note that the debugger doesn't do anything special for 'darwin'. Maybe it should.)
  1479.  
  1480. =cut
  1481.  
  1482.     elsif ($^O eq 'MacOS') {
  1483.         if ($MacPerl::Version !~ /MPW/) {
  1484.             $console =
  1485.               "Dev:Console:Perl Debug";    # Separate window for application
  1486.         }
  1487.         else {
  1488.             $console = "Dev:Console";
  1489.         }
  1490.     } ## end elsif ($^O eq 'MacOS')
  1491.  
  1492. =item * VMS - use C<sys$command>.
  1493.  
  1494. =cut
  1495.  
  1496.     else {
  1497.         # everything else is ...
  1498.         $console = "sys\$command";
  1499.     }
  1500.  
  1501. =pod
  1502.  
  1503. =back
  1504.  
  1505. Several other systems don't use a specific console. We C<undef $console>
  1506. for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
  1507. with a slave editor, Epoc).
  1508.  
  1509. =cut
  1510.  
  1511.     if (($^O eq 'MSWin32') and ($slave_editor or defined $ENV{EMACS})) {
  1512.         # /dev/tty is binary. use stdin for textmode
  1513.         $console = undef;
  1514.     }
  1515.  
  1516.     if ($^O eq 'NetWare') {
  1517.         # /dev/tty is binary. use stdin for textmode
  1518.         $console = undef;
  1519.     }
  1520.  
  1521.     # In OS/2, we need to use STDIN to get textmode too, even though
  1522.     # it pretty much looks like Unix otherwise.
  1523.     if (defined $ENV{OS2_SHELL} and ($slave_editor or $ENV{WINDOWID}))
  1524.     {    # In OS/2
  1525.         $console = undef;
  1526.     }
  1527.     # EPOC also falls into the 'got to use STDIN' camp.
  1528.     if ($^O eq 'epoc') {
  1529.         $console = undef;
  1530.     }
  1531.  
  1532. =pod
  1533.  
  1534. If there is a TTY hanging around from a parent, we use that as the console.
  1535.  
  1536. =cut
  1537.  
  1538.     $console = $tty if defined $tty;
  1539.  
  1540. =head2 SOCKET HANDLING   
  1541.  
  1542. The debugger is capable of opening a socket and carrying out a debugging
  1543. session over the socket.
  1544.  
  1545. If C<RemotePort> was defined in the options, the debugger assumes that it
  1546. should try to start a debugging session on that port. It builds the socket
  1547. and then tries to connect the input and output filehandles to it.
  1548.  
  1549. =cut
  1550.  
  1551.     # Handle socket stuff.
  1552.     if (defined $remoteport) {
  1553.         # If RemotePort was defined in the options, connect input and output
  1554.         # to the socket.
  1555.         require IO::Socket;
  1556.         $OUT = new IO::Socket::INET(
  1557.             Timeout  => '10',
  1558.             PeerAddr => $remoteport,
  1559.             Proto    => 'tcp',
  1560.             );
  1561.         if (!$OUT) { die "Unable to connect to remote host: $remoteport\n"; }
  1562.         $IN = $OUT;
  1563.     } ## end if (defined $remoteport)
  1564.  
  1565. =pod
  1566.  
  1567. If no C<RemotePort> was defined, and we want to create a TTY on startup,
  1568. this is probably a situation where multiple debuggers are running (for example,
  1569. a backticked command that starts up another debugger). We create a new IN and
  1570. OUT filehandle, and do the necessary mojo to create a new TTY if we know how
  1571. and if we can.
  1572.  
  1573. =cut
  1574.  
  1575.     # Non-socket.
  1576.     else {
  1577.         # Two debuggers running (probably a system or a backtick that invokes
  1578.         # the debugger itself under the running one). create a new IN and OUT
  1579.         # filehandle, and do the necessary mojo to create a new tty if we 
  1580.         # know how, and we can.
  1581.         create_IN_OUT(4) if $CreateTTY & 4;
  1582.         if ($console) {
  1583.             # If we have a console, check to see if there are separate ins and
  1584.             # outs to open. (They are assumed identiical if not.)
  1585.             my ($i, $o) = split /,/, $console;
  1586.             $o = $i unless defined $o;
  1587.  
  1588.             # read/write on in, or just read, or read on STDIN.
  1589.             open(IN, "+<$i") || 
  1590.              open(IN, "<$i") || 
  1591.               open(IN, "<&STDIN");
  1592.  
  1593.             # read/write/create/clobber out, or write/create/clobber out,
  1594.             # or merge with STDERR, or merge with STDOUT.
  1595.             open(OUT,   "+>$o")     ||
  1596.               open(OUT, ">$o")      ||
  1597.               open(OUT, ">&STDERR") ||
  1598.               open(OUT, ">&STDOUT");    # so we don't dongle stdout
  1599.  
  1600.         } ## end if ($console)
  1601.         elsif (not defined $console) {
  1602.            # No console. Open STDIN.
  1603.             open(IN,    "<&STDIN");
  1604.  
  1605.            # merge with STDERR, or with STDOUT.
  1606.             open(OUT,   ">&STDERR") ||
  1607.               open(OUT, ">&STDOUT");     # so we don't dongle stdout
  1608.  
  1609.             $console = 'STDIN/OUT';
  1610.         } ## end elsif (not defined $console)
  1611.  
  1612.         # Keep copies of the filehandles so that when the pager runs, it
  1613.         # can close standard input without clobbering ours.
  1614.         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
  1615.     } ## end elsif (from if(defined $remoteport))
  1616.  
  1617.     # Unbuffer DB::OUT. We need to see responses right away. 
  1618.     my $previous = select($OUT);
  1619.     $| = 1;                              # for DB::OUT
  1620.     select($previous);
  1621.  
  1622.     # Line info goes to debugger output unless pointed elsewhere.
  1623.     # Pointing elsewhere makes it possible for slave editors to
  1624.     # keep track of file and position. We have both a filehandle 
  1625.     # and a I/O description to keep track of.
  1626.     $LINEINFO = $OUT     unless defined $LINEINFO;
  1627.     $lineinfo = $console unless defined $lineinfo;
  1628.  
  1629. =pod
  1630.  
  1631. To finish initialization, we show the debugger greeting,
  1632. and then call the C<afterinit()> subroutine if there is one.
  1633.  
  1634. =cut
  1635.  
  1636.     # Show the debugger greeting.
  1637.     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
  1638.     unless ($runnonstop) {
  1639.         local $\ = '';
  1640.         local $, = '';
  1641.         if ($term_pid eq '-1') {
  1642.             print $OUT "\nDaughter DB session started...\n";
  1643.         }
  1644.         else {
  1645.             print $OUT "\nLoading DB routines from $header\n";
  1646.             print $OUT (
  1647.                 "Editor support ",
  1648.                 $slave_editor ? "enabled" : "available", ".\n"
  1649.                 );
  1650.             print $OUT
  1651. "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
  1652.         } ## end else [ if ($term_pid eq '-1')
  1653.     } ## end unless ($runnonstop)
  1654. } ## end else [ if ($notty)
  1655.  
  1656. # XXX This looks like a bug to me.
  1657. # Why copy to @ARGS and then futz with @args?
  1658. @ARGS = @ARGV;
  1659. for (@args) {
  1660.     # Make sure backslashes before single quotes are stripped out, and
  1661.     # keep args unless they are numeric (XXX why?)
  1662.     s/\'/\\\'/g;
  1663.     s/(.*)/'$1'/ unless /^-?[\d.]+$/;
  1664. }
  1665.  
  1666. # If there was an afterinit() sub defined, call it. It will get 
  1667. # executed in our scope, so it can fiddle with debugger globals.
  1668. if (defined &afterinit) {    # May be defined in $rcfile
  1669.     &afterinit();
  1670. }
  1671. # Inform us about "Stack dump during die enabled ..." in dieLevel().
  1672. $I_m_init = 1;
  1673.  
  1674. ############################################################ Subroutines
  1675.  
  1676. =head1 SUBROUTINES
  1677.  
  1678. =head2 DB
  1679.  
  1680. This gigantic subroutine is the heart of the debugger. Called before every
  1681. statement, its job is to determine if a breakpoint has been reached, and
  1682. stop if so; read commands from the user, parse them, and execute
  1683. them, and hen send execution off to the next statement.
  1684.  
  1685. Note that the order in which the commands are processed is very important;
  1686. some commands earlier in the loop will actually alter the C<$cmd> variable
  1687. to create other commands to be executed later. This is all highly "optimized"
  1688. but can be confusing. Check the comments for each C<$cmd ... && do {}> to
  1689. see what's happening in any given command.
  1690.  
  1691. =cut
  1692.  
  1693. sub DB {
  1694.  
  1695.     # Check for whether we should be running continuously or not.
  1696.     # _After_ the perl program is compiled, $single is set to 1:
  1697.     if ($single and not $second_time++) {
  1698.         # Options say run non-stop. Run until we get an interrupt.
  1699.         if ($runnonstop) {    # Disable until signal
  1700.             # If there's any call stack in place, turn off single
  1701.             # stepping into subs throughout the stack.
  1702.             for ($i = 0 ; $i <= $stack_depth ;) {
  1703.                 $stack[$i++] &= ~1;
  1704.             }
  1705.             # And we are now no longer in single-step mode.
  1706.             $single = 0;
  1707.  
  1708.             # If we simply returned at this point, we wouldn't get
  1709.             # the trace info. Fall on through.
  1710.             # return; 
  1711.         } ## end if ($runnonstop)
  1712.  
  1713.         elsif ($ImmediateStop) {
  1714.             # We are supposed to stop here; XXX probably a break. 
  1715.             $ImmediateStop = 0;               # We've processed it; turn it off
  1716.             $signal        = 1;               # Simulate an interrupt to force
  1717.                                               # us into the command loop
  1718.         }
  1719.     } ## end if ($single and not $second_time...
  1720.  
  1721.     # If we're in single-step mode, or an interrupt (real or fake)
  1722.     # has occurred, turn off non-stop mode.
  1723.     $runnonstop = 0 if $single or $signal;
  1724.  
  1725.     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
  1726.     # The code being debugged may have altered them.
  1727.     &save;
  1728.  
  1729.     # Since DB::DB gets called after every line, we can use caller() to
  1730.     # figure out where we last were executing. Sneaky, eh? This works because
  1731.     # caller is returning all the extra information when called from the 
  1732.     # debugger.
  1733.     local ($package, $filename, $line) = caller;
  1734.     local $filename_ini = $filename;
  1735.  
  1736.     # set up the context for DB::eval, so it can properly execute
  1737.     # code on behalf of the user. We add the package in so that the
  1738.     # code is eval'ed in the proper package (not in the debugger!).
  1739.     local $usercontext  =
  1740.       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' .
  1741.       "package $package;"; 
  1742.  
  1743.     # Create an alias to the active file magical array to simplify
  1744.     # the code here.
  1745.     local (*dbline) = $main::{ '_<' . $filename };
  1746.  
  1747.     # we need to check for pseudofiles on Mac OS (these are files
  1748.     # not attached to a filename, but instead stored in Dev:Pseudo)
  1749.     if ($^O eq 'MacOS' && $#dbline < 0) {
  1750.         $filename_ini = $filename = 'Dev:Pseudo';
  1751.         *dbline = $main::{ '_<' . $filename };
  1752.     }
  1753.  
  1754.     # Last line in the program.
  1755.     local $max = $#dbline;
  1756.  
  1757.     # if we have something here, see if we should break.
  1758.     if ($dbline{$line} && (($stop, $action) = split (/\0/, $dbline{$line}))) {
  1759.         # Stop if the stop criterion says to just stop.
  1760.         if ($stop eq '1') {
  1761.             $signal |= 1;
  1762.         }
  1763.         # It's a conditional stop; eval it in the user's context and
  1764.         # see if we should stop. If so, remove the one-time sigil.
  1765.         elsif ($stop) {
  1766.             $evalarg = "\$DB::signal |= 1 if do {$stop}";
  1767.             &eval;
  1768.             $dbline{$line} =~ s/;9($|\0)/$1/;
  1769.         }
  1770.     } ## end if ($dbline{$line} && ...
  1771.  
  1772.     # Preserve the current stop-or-not, and see if any of the W
  1773.     # (watch expressions) has changed.
  1774.     my $was_signal = $signal;
  1775.  
  1776.     # If we have any watch expressions ...
  1777.     if ($trace & 2) {
  1778.         for (my $n = 0 ; $n <= $#to_watch ; $n++) {
  1779.             $evalarg = $to_watch[$n];
  1780.             local $onetimeDump;    # Tell DB::eval() to not output results
  1781.  
  1782.             # Fix context DB::eval() wants to return an array, but
  1783.             # we need a scalar here.
  1784.             my ($val) =
  1785.               join ( "', '", &eval );
  1786.             $val = ((defined $val) ? "'$val'" : 'undef');
  1787.  
  1788.             # Did it change?
  1789.             if ($val ne $old_watch[$n]) {
  1790.                 # Yep! Show the difference, and fake an interrupt.
  1791.                 $signal = 1;
  1792.                 print $OUT <<EOP;
  1793. Watchpoint $n:\t$to_watch[$n] changed:
  1794.     old value:\t$old_watch[$n]
  1795.     new value:\t$val
  1796. EOP
  1797.                 $old_watch[$n] = $val;
  1798.             } ## end if ($val ne $old_watch...
  1799.         } ## end for (my $n = 0 ; $n <= ...
  1800.     } ## end if ($trace & 2)
  1801.  
  1802. =head2 C<watchfunction()>
  1803.  
  1804. C<watchfunction()> is a function that can be defined by the user; it is a
  1805. function which will be run on each entry to C<DB::DB>; it gets the 
  1806. current package, filename, and line as its parameters.
  1807.  
  1808. The watchfunction can do anything it likes; it is executing in the 
  1809. debugger's context, so it has access to all of the debugger's internal
  1810. data structures and functions.
  1811.  
  1812. C<watchfunction()> can control the debugger's actions. Any of the following
  1813. will cause the debugger to return control to the user's program after
  1814. C<watchfunction()> executes:
  1815.  
  1816. =over 4 
  1817.  
  1818. =item * Returning a false value from the C<watchfunction()> itself.
  1819.  
  1820. =item * Altering C<$single> to a false value.
  1821.  
  1822. =item * Altering C<$signal> to a false value.
  1823.  
  1824. =item *  Turning off the '4' bit in C<$trace> (this also disables the
  1825. check for C<watchfunction()>. This can be done with
  1826.  
  1827.     $trace &= ~4;
  1828.  
  1829. =back
  1830.  
  1831. =cut
  1832.  
  1833.     # If there's a user-defined DB::watchfunction, call it with the 
  1834.     # current package, filename, and line. The function executes in
  1835.     # the DB:: package.
  1836.     if ($trace & 4) {    # User-installed watch
  1837.         return
  1838.           if watchfunction($package, $filename, $line)
  1839.           and not $single
  1840.           and not $was_signal
  1841.           and not($trace & ~4);
  1842.     } ## end if ($trace & 4)
  1843.  
  1844.  
  1845.     # Pick up any alteration to $signal in the watchfunction, and 
  1846.     # turn off the signal now.
  1847.     $was_signal = $signal;
  1848.     $signal     = 0;
  1849.  
  1850. =head2 GETTING READY TO EXECUTE COMMANDS
  1851.  
  1852. The debugger decides to take control if single-step mode is on, the
  1853. C<t> command was entered, or the user generated a signal. If the program
  1854. has fallen off the end, we set things up so that entering further commands
  1855. won't cause trouble, and we say that the program is over.
  1856.  
  1857. =cut
  1858.  
  1859.     # Check to see if we should grab control ($single true,
  1860.     # trace set appropriately, or we got a signal).
  1861.     if ($single || ($trace & 1) || $was_signal) {
  1862.         # Yes, grab control.
  1863.         if ($slave_editor) {
  1864.             # Tell the editor to update its position.
  1865.             $position = "\032\032$filename:$line:0\n";
  1866.             print_lineinfo($position);
  1867.         }
  1868.  
  1869. =pod
  1870.  
  1871. Special check: if we're in package C<DB::fake>, we've gone through the 
  1872. C<END> block at least once. We set up everything so that we can continue
  1873. to enter commands and have a valid context to be in.
  1874.  
  1875. =cut
  1876.  
  1877.         elsif ($package eq 'DB::fake') {
  1878.             # Fallen off the end already.
  1879.             $term || &setterm;
  1880.             print_help(<<EOP);
  1881. Debugged program terminated.  Use B<q> to quit or B<R> to restart,
  1882.   use B<O> I<inhibit_exit> to avoid stopping after program termination,
  1883.   B<h q>, B<h R> or B<h O> to get additional info.  
  1884. EOP
  1885.  
  1886.             # Set the DB::eval context appropriately.
  1887.             $package     = 'main';
  1888.             $usercontext =
  1889.               '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' .
  1890.               "package $package;";    # this won't let them modify, alas
  1891.         } ## end elsif ($package eq 'DB::fake')
  1892.  
  1893. =pod
  1894.  
  1895. If the program hasn't finished executing, we scan forward to the
  1896. next executable line, print that out, build the prompt from the file and line
  1897. number information, and print that.   
  1898.  
  1899. =cut
  1900.  
  1901.         else {
  1902.             # Still somewhere in the midst of execution. Set up the
  1903.             #  debugger prompt.
  1904.             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
  1905.                                  # Perl 5 ones (sorry, we don't print Klingon 
  1906.                                  #module names)
  1907.  
  1908.             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
  1909.             $prefix .= "$sub($filename:";
  1910.             $after = ($dbline[$line] =~ /\n$/ ? '' : "\n");
  1911.  
  1912.             # Break up the prompt if it's really long.
  1913.             if (length($prefix) > 30) {
  1914.                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
  1915.                 $prefix   = "";
  1916.                 $infix    = ":\t";
  1917.             }
  1918.             else {
  1919.                 $infix    = "):\t";
  1920.                 $position = "$prefix$line$infix$dbline[$line]$after";
  1921.             }
  1922.  
  1923.             # Print current line info, indenting if necessary.
  1924.             if ($frame) {
  1925.                 print_lineinfo(' ' x $stack_depth,
  1926.                     "$line:\t$dbline[$line]$after");
  1927.             }
  1928.             else {
  1929.                 print_lineinfo($position);
  1930.             }
  1931.  
  1932.             # Scan forward, stopping at either the end or the next
  1933.             # unbreakable line.
  1934.             for ($i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i)
  1935.             {    #{ vi
  1936.  
  1937.                 # Drop out on null statements, block closers, and comments.
  1938.                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
  1939.  
  1940.                 # Drop out if the user interrupted us.
  1941.                 last if $signal;
  1942.                
  1943.                 # Append a newline if the line doesn't have one. Can happen
  1944.                 # in eval'ed text, for instance.
  1945.                 $after = ($dbline[$i] =~ /\n$/ ? '' : "\n");
  1946.  
  1947.                 # Next executable line.
  1948.                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
  1949.                 $position .= $incr_pos;
  1950.                 if ($frame) {
  1951.                     # Print it indented if tracing is on.
  1952.                     print_lineinfo(' ' x $stack_depth,
  1953.                         "$i:\t$dbline[$i]$after");
  1954.                 }
  1955.                 else {
  1956.                     print_lineinfo($incr_pos);
  1957.                 }
  1958.             } ## end for ($i = $line + 1 ; $i...
  1959.         } ## end else [ if ($slave_editor)
  1960.     } ## end if ($single || ($trace...
  1961.  
  1962. =pod
  1963.  
  1964. If there's an action to be executed for the line we stopped at, execute it.
  1965. If there are any preprompt actions, execute those as well.      
  1966.  
  1967. =cut
  1968.  
  1969.     # If there's an action, do it now.
  1970.     $evalarg = $action, &eval if $action;
  1971.  
  1972.     # Are we nested another level (e.g., did we evaluate a function
  1973.     # that had a breakpoint in it at the debugger prompt)?
  1974.     if ($single || $was_signal) {
  1975.         # Yes, go down a level.
  1976.         local $level = $level + 1;
  1977.  
  1978.         # Do any pre-prompt actions.
  1979.         foreach $evalarg (@$pre) {
  1980.             &eval;
  1981.         }
  1982.  
  1983.         # Complain about too much recursion if we passed the limit.
  1984.         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
  1985.           if $single & 4;
  1986.  
  1987.         # The line we're currently on. Set $incr to -1 to stay here
  1988.         # until we get a command that tells us to advance.
  1989.         $start     = $line;
  1990.         $incr      = -1;                        # for backward motion.
  1991.  
  1992.         # Tack preprompt debugger actions ahead of any actual input.
  1993.         @typeahead = (@$pretype, @typeahead);
  1994.  
  1995. =head2 WHERE ARE WE?
  1996.  
  1997. XXX Relocate this section?
  1998.  
  1999. The debugger normally shows the line corresponding to the current line of
  2000. execution. Sometimes, though, we want to see the next line, or to move elsewhere
  2001. in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
  2002.  
  2003. C<$incr> controls by how many lines the "current" line should move forward
  2004. after a command is executed. If set to -1, this indicates that the "current"
  2005. line shouldn't change.
  2006.  
  2007. C<$start> is the "current" line. It is used for things like knowing where to
  2008. move forwards or backwards from when doing an C<L> or C<-> command.
  2009.  
  2010. C<$max> tells the debugger where the last line of the current file is. It's
  2011. used to terminate loops most often.
  2012.  
  2013. =head2 THE COMMAND LOOP
  2014.  
  2015. Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
  2016. in two parts:
  2017.  
  2018. =over 4
  2019.  
  2020. =item * The outer part of the loop, starting at the C<CMD> label. This loop
  2021. reads a command and then executes it.
  2022.  
  2023. =item * The inner part of the loop, starting at the C<PIPE> label. This part
  2024. is wholly contained inside the C<CMD> block and only executes a command.
  2025. Used to handle commands running inside a pager.
  2026.  
  2027. =back
  2028.  
  2029. So why have two labels to restart the loop? Because sometimes, it's easier to
  2030. have a command I<generate> another command and then re-execute the loop to do
  2031. the new command. This is faster, but perhaps a bit more convoluted.
  2032.  
  2033. =cut
  2034.  
  2035.         # The big command dispatch loop. It keeps running until the
  2036.         # user yields up control again.
  2037.         #
  2038.         # If we have a terminal for input, and we get something back
  2039.         # from readline(), keep on processing.
  2040.       CMD:
  2041.         while (
  2042.             # We have a terminal, or can get one ...
  2043.             ($term || &setterm),
  2044.             # ... and it belogs to this PID or we get one for this PID ...
  2045.             ($term_pid == $$ or resetterm(1)),
  2046.             # ... and we got a line of command input ...
  2047.             defined(
  2048.                 $cmd = &readline(
  2049.                     "$pidprompt  DB" . ('<' x $level) . ($#hist + 1) .
  2050.                       ('>' x $level) . " "
  2051.                 )
  2052.             )
  2053.           )
  2054.         {
  2055.             # ... try to execute the input as debugger commands.
  2056.  
  2057.             # Don't stop running.
  2058.             $single = 0;
  2059.  
  2060.             # No signal is active.
  2061.             $signal = 0;
  2062.  
  2063.             # Handle continued commands (ending with \):
  2064.             $cmd =~ s/\\$/\n/ && do {
  2065.                 $cmd .= &readline("  cont: ");
  2066.                 redo CMD;
  2067.             };
  2068.  
  2069. =head4 The null command
  2070.  
  2071. A newline entered by itself means "re-execute the last command". We grab the
  2072. command out of C<$laststep> (where it was recorded previously), and copy it
  2073. back into C<$cmd> to be executed below. If there wasn't any previous command,
  2074. we'll do nothing below (no command will match). If there was, we also save it
  2075. in the command history and fall through to allow the command parsing to pick
  2076. it up.
  2077.  
  2078. =cut
  2079.  
  2080.             # Empty input means repeat the last command.
  2081.             $cmd =~ /^$/ && ($cmd = $laststep);
  2082.             push (@hist, $cmd) if length($cmd) > 1;
  2083.  
  2084.  
  2085.           # This is a restart point for commands that didn't arrive
  2086.           # via direct user input. It allows us to 'redo PIPE' to
  2087.           # re-execute command processing without reading a new command.
  2088.           PIPE: {
  2089.                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
  2090.                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
  2091.                 ($i) = split (/\s+/, $cmd);
  2092.  
  2093. =head3 COMMAND ALIASES
  2094.  
  2095. The debugger can create aliases for commands (these are stored in the
  2096. C<%alias> hash). Before a command is executed, the command loop looks it up
  2097. in the alias hash and substitutes the contents of the alias for the command,
  2098. completely replacing it.
  2099.  
  2100. =cut
  2101.  
  2102.                 # See if there's an alias for the command, and set it up if so.
  2103.                 if ($alias{$i}) {
  2104.                     # Squelch signal handling; we want to keep control here
  2105.                     # if something goes loco during the alias eval.
  2106.                     local $SIG{__DIE__};
  2107.                     local $SIG{__WARN__};
  2108.  
  2109.                     # This is a command, so we eval it in the DEBUGGER's
  2110.                     # scope! Otherwise, we can't see the special debugger
  2111.                     # variables, or get to the debugger's subs. (Well, we
  2112.                     # _could_, but why make it even more complicated?)
  2113.                     eval "\$cmd =~ $alias{$i}";
  2114.                     if ($@) {
  2115.                         local $\ = '';
  2116.                         print $OUT "Couldn't evaluate `$i' alias: $@";
  2117.                         next CMD;
  2118.                     }
  2119.                 } ## end if ($alias{$i})
  2120.  
  2121. =head3 MAIN-LINE COMMANDS
  2122.  
  2123. All of these commands work up to and after the program being debugged has
  2124. terminated. 
  2125.  
  2126. =head4 C<q> - quit
  2127.  
  2128. Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't 
  2129. try to execute further, cleaning any restart-related stuff out of the
  2130. environment, and executing with the last value of C<$?>.
  2131.  
  2132. =cut
  2133.  
  2134.                 $cmd =~ /^q$/ && do {
  2135.                     $fall_off_end = 1;
  2136.                     clean_ENV();
  2137.                     exit $?;
  2138.                 };
  2139.  
  2140. =head4 C<t> - trace
  2141.  
  2142. Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
  2143.  
  2144. =cut
  2145.  
  2146.                 $cmd =~ /^t$/ && do {
  2147.                     $trace ^= 1;
  2148.                     local $\ = '';
  2149.                     print $OUT "Trace = " . (($trace & 1) ? "on" : "off") .
  2150.                       "\n";
  2151.                     next CMD;
  2152.                 };
  2153.  
  2154. =head4 C<S> - list subroutines matching/not matching a pattern
  2155.  
  2156. Walks through C<%sub>, checking to see whether or not to print the name.
  2157.  
  2158. =cut
  2159.  
  2160.                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
  2161.  
  2162.                     $Srev     = defined $2;     # Reverse scan? 
  2163.                     $Spatt    = $3;             # The pattern (if any) to use.
  2164.                     $Snocheck = !defined $1;    # No args - print all subs.
  2165.  
  2166.                     # Need to make these sane here.
  2167.                     local $\ = '';
  2168.                     local $, = '';
  2169.  
  2170.                     # Search through the debugger's magical hash of subs.
  2171.                     # If $nocheck is true, just print the sub name.
  2172.                     # Otherwise, check it against the pattern. We then use
  2173.                     # the XOR trick to reverse the condition as required.
  2174.                     foreach $subname (sort(keys %sub)) {
  2175.                         if ($Snocheck or $Srev ^ ($subname =~ /$Spatt/)) {
  2176.                             print $OUT $subname, "\n";
  2177.                         }
  2178.                     }
  2179.                     next CMD;
  2180.                 };
  2181.  
  2182. =head4 C<X> - list variables in current package
  2183.  
  2184. Since the C<V> command actually processes this, just change this to the 
  2185. appropriate C<V> command and fall through.
  2186.  
  2187. =cut
  2188.  
  2189.                 $cmd =~ s/^X\b/V $package/;
  2190.  
  2191. =head4 C<V> - list variables
  2192.  
  2193. Uses C<dumpvar.pl> to dump out the current values for selected variables. 
  2194.  
  2195. =cut
  2196.  
  2197.                 # Bare V commands get the currently-being-debugged package
  2198.                 # added.
  2199.                 $cmd =~ /^V$/ && do {
  2200.                     $cmd = "V $package";
  2201.                 };
  2202.  
  2203.  
  2204.                 # V - show variables in package.
  2205.                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
  2206.                     # Save the currently selected filehandle and
  2207.                     # force output to debugger's filehandle (dumpvar
  2208.                     # just does "print" for output).
  2209.                     local ($savout) = select($OUT);
  2210.  
  2211.                     # Grab package name and variables to dump.
  2212.                     $packname = $1;
  2213.                     @vars = split (' ', $2);
  2214.  
  2215.                     # If main::dumpvar isn't here, get it.
  2216.                     do 'dumpvar.pl' unless defined &main::dumpvar;
  2217.                     if (defined &main::dumpvar) {
  2218.                         # We got it. Turn off subroutine entry/exit messages
  2219.                         # for the moment, along with return values.
  2220.                         local $frame = 0;
  2221.                         local $doret = -2;
  2222.  
  2223.                         # must detect sigpipe failures  - not catching
  2224.                         # then will cause the debugger to die.
  2225.                         eval {
  2226.                             &main::dumpvar(
  2227.                                 $packname,
  2228.                                 defined $option{dumpDepth}
  2229.                                 ? $option{dumpDepth}
  2230.                                 : -1,          # assume -1 unless specified
  2231.                                 @vars
  2232.                                 );
  2233.                         };
  2234.  
  2235.                         # The die doesn't need to include the $@, because 
  2236.                         # it will automatically get propagated for us.
  2237.                         if ($@) {
  2238.                             die unless $@ =~ /dumpvar print failed/;
  2239.                         }
  2240.                     } ## end if (defined &main::dumpvar)
  2241.                     else {
  2242.                         # Couldn't load dumpvar.
  2243.                         print $OUT "dumpvar.pl not available.\n";
  2244.                     }
  2245.                     # Restore the output filehandle, and go round again.
  2246.                     select($savout);
  2247.                     next CMD;
  2248.                 };
  2249.  
  2250. =head4 C<x> - evaluate and print an expression
  2251.  
  2252. Hands the expression off to C<DB::eval>, setting it up to print the value
  2253. via C<dumpvar.pl> instead of just printing it directly.
  2254.  
  2255. =cut
  2256.  
  2257.                 $cmd =~ s/^x\b/ / && do {   # Remainder gets done by DB::eval()
  2258.                     $onetimeDump = 'dump';  # main::dumpvar shows the output
  2259.  
  2260.                     # handle special  "x 3 blah" syntax XXX propagate
  2261.                     # doc back to special variables.
  2262.                     if ($cmd =~ s/^\s*(\d+)(?=\s)/ /) {
  2263.                         $onetimedumpDepth = $1;
  2264.                     }
  2265.                 };
  2266.  
  2267. =head4 C<m> - print methods
  2268.  
  2269. Just uses C<DB::methods> to determine what methods are available.
  2270.  
  2271. =cut
  2272.  
  2273.                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
  2274.                     methods($1);
  2275.                     next CMD;
  2276.                 };
  2277.  
  2278.                 # m expr - set up DB::eval to do the work
  2279.                 $cmd =~ s/^m\b/ / && do {     # Rest gets done by DB::eval()
  2280.                     $onetimeDump = 'methods'; #  method output gets used there
  2281.                 };
  2282.  
  2283. =head4 C<f> - switch files
  2284.  
  2285. =cut
  2286.  
  2287.                 $cmd =~ /^f\b\s*(.*)/ && do {
  2288.                     $file = $1;
  2289.                     $file =~ s/\s+$//;
  2290.  
  2291.                     # help for no arguments (old-style was return from sub).
  2292.                     if (!$file) {
  2293.                         print $OUT
  2294.                           "The old f command is now the r command.\n";  # hint
  2295.                         print $OUT "The new f command switches filenames.\n";
  2296.                         next CMD;
  2297.                     } ## end if (!$file)
  2298.  
  2299.                     # if not in magic file list, try a close match.
  2300.                     if (!defined $main::{ '_<' . $file }) {
  2301.                         if (($try) = grep(m#^_<.*$file#, keys %main::)) {
  2302.                             {
  2303.                                 $try = substr($try, 2);
  2304.                                 print $OUT
  2305.                                   "Choosing $try matching `$file':\n";
  2306.                                 $file = $try;
  2307.                             }
  2308.                         } ## end if (($try) = grep(m#^_<.*$file#...
  2309.                     } ## end if (!defined $main::{ ...
  2310.  
  2311.                     # If not successfully switched now, we failed.
  2312.                     if (!defined $main::{ '_<' . $file }) {
  2313.                         print $OUT "No file matching `$file' is loaded.\n";
  2314.                         next CMD;
  2315.                     }
  2316.  
  2317.                     # We switched, so switch the debugger internals around.
  2318.                     elsif ($file ne $filename) {
  2319.                         *dbline   = $main::{ '_<' . $file };
  2320.                         $max      = $#dbline;
  2321.                         $filename = $file;
  2322.                         $start    = 1;
  2323.                         $cmd      = "l";
  2324.                     } ## end elsif ($file ne $filename)
  2325.  
  2326.                     # We didn't switch; say we didn't.
  2327.                     else {
  2328.                         print $OUT "Already in $file.\n";
  2329.                         next CMD;
  2330.                     }
  2331.                 };
  2332.  
  2333. =head4 C<.> - return to last-executed line.
  2334.  
  2335. We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
  2336. and then we look up the line in the magical C<%dbline> hash.
  2337.  
  2338. =cut
  2339.  
  2340.                 # . command.
  2341.                 $cmd =~ /^\.$/ && do {
  2342.                     $incr     = -1;              # stay at current line
  2343.  
  2344.                     # Reset everything to the old location.
  2345.                     $start    = $line;
  2346.                     $filename = $filename_ini;
  2347.                     *dbline = $main::{ '_<' . $filename };
  2348.                     $max    = $#dbline;
  2349.  
  2350.                     # Now where are we?
  2351.                     print_lineinfo($position);
  2352.                     next CMD;
  2353.                 };
  2354.  
  2355. =head4 C<-> - back one window
  2356.  
  2357. We change C<$start> to be one window back; if we go back past the first line,
  2358. we set it to be the first line. We ser C<$incr> to put us back at the
  2359. currently-executing line, and then put a C<l $start +> (list one window from
  2360. C<$start>) in C<$cmd> to be executed later.
  2361.  
  2362. =cut
  2363.  
  2364.                 # - - back a window.
  2365.                 $cmd =~ /^-$/ && do {
  2366.                     # back up by a window; go to 1 if back too far.
  2367.                     $start -= $incr + $window + 1;
  2368.                     $start = 1 if $start <= 0;
  2369.                     $incr = $window - 1;
  2370.  
  2371.                     # Generate and execute a "l +" command (handled below).
  2372.                     $cmd = 'l ' . ($start) . '+';
  2373.                 };
  2374.  
  2375. =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
  2376.  
  2377. In Perl 5.8.0, a realignment of the commands was done to fix up a number of
  2378. problems, most notably that the default case of several commands destroying
  2379. the user's work in setting watchpoints, actions, etc. We wanted, however, to
  2380. retain the old commands for those who were used to using them or who preferred
  2381. them. At this point, we check for the new commands and call C<cmd_wrapper> to
  2382. deal with them instead of processing them in-line.
  2383.  
  2384. =cut
  2385.  
  2386.                 # All of these commands were remapped in perl 5.8.0;
  2387.                 # we send them off to the secondary dispatcher (see below). 
  2388.                 $cmd =~ /^([aAbBhlLMoOvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
  2389.                     &cmd_wrapper($1, $2, $line);
  2390.                     next CMD;
  2391.                 };
  2392.  
  2393. =head4 C<y> - List lexicals in higher scope
  2394.  
  2395. Uses C<PadWalker> to find the lexicals supplied as arguments in a scope    
  2396. above the current one and then displays then using C<dumpvar.pl>.
  2397.  
  2398. =cut
  2399.  
  2400.                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
  2401.  
  2402.                     # See if we've got the necessary support.
  2403.                     eval { require PadWalker; PadWalker->VERSION(0.08) }
  2404.                       or &warn(
  2405.                         $@ =~ /locate/
  2406.                         ? "PadWalker module not found - please install\n"
  2407.                         : $@
  2408.                       )
  2409.                       and next CMD;
  2410.  
  2411.                     # Load up dumpvar if we don't have it. If we can, that is.
  2412.                     do 'dumpvar.pl' unless defined &main::dumpvar;
  2413.                     defined &main::dumpvar
  2414.                       or print $OUT "dumpvar.pl not available.\n"
  2415.                       and next CMD;
  2416.  
  2417.                     # Got all the modules we need. Find them and print them.
  2418.                     my @vars = split (' ', $2 || '');
  2419.  
  2420.                     # Find the pad.
  2421.                     my $h = eval { PadWalker::peek_my(($1 || 0) + 1) };
  2422.  
  2423.                     # Oops. Can't find it.
  2424.                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
  2425.  
  2426.                     # Show the desired vars with dumplex().
  2427.                     my $savout = select($OUT);
  2428.  
  2429.                     # Have dumplex dump the lexicals.
  2430.                     dumpvar::dumplex(
  2431.                         $_,
  2432.                         $h->{$_},
  2433.                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
  2434.                         @vars
  2435.                     ) for sort keys %$h;
  2436.                     select($savout);
  2437.                     next CMD;
  2438.                 };
  2439.  
  2440. =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
  2441.  
  2442. All of the commands below this point don't work after the program being
  2443. debugged has ended. All of them check to see if the program has ended; this
  2444. allows the commands to be relocated without worrying about a 'line of
  2445. demarcation' above which commands can be entered anytime, and below which
  2446. they can't.
  2447.  
  2448. =head4 C<n> - single step, but don't trace down into subs
  2449.  
  2450. Done by setting C<$single> to 2, which forces subs to execute straight through
  2451. when entered (see X<DB::sub>). We also save the C<n> command in C<$laststep>,
  2452. so a null command knows what to re-execute. 
  2453.  
  2454. =cut
  2455.  
  2456.                 # n - next 
  2457.                 $cmd =~ /^n$/ && do {
  2458.                     end_report(), next CMD if $finished and $level <= 1;
  2459.                     # Single step, but don't enter subs.
  2460.                     $single   = 2;
  2461.                     # Save for empty command (repeat last).
  2462.                     $laststep = $cmd;
  2463.                     last CMD;
  2464.                 };
  2465.  
  2466. =head4 C<s> - single-step, entering subs
  2467.  
  2468. Sets C<$single> to 1, which causes X<DB::sub> to continue tracing inside     
  2469. subs. Also saves C<s> as C<$lastcmd>.
  2470.  
  2471. =cut
  2472.  
  2473.                 # s - single step.
  2474.                 $cmd =~ /^s$/ && do {
  2475.                     # Get out and restart the command loop if program
  2476.                     # has finished.
  2477.                     end_report(), next CMD if $finished and $level <= 1;
  2478.                     # Single step should enter subs.
  2479.                     $single   = 1;
  2480.                     # Save for empty command (repeat last).
  2481.                     $laststep = $cmd;
  2482.                     last CMD;
  2483.                 };
  2484.  
  2485. =head4 C<c> - run continuously, setting an optional breakpoint
  2486.  
  2487. Most of the code for this command is taken up with locating the optional
  2488. breakpoint, which is either a subroutine name or a line number. We set
  2489. the appropriate one-time-break in C<@dbline> and then turn off single-stepping
  2490. in this and all call levels above this one.
  2491.  
  2492. =cut
  2493.  
  2494.                 # c - start continuous execution.
  2495.                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
  2496.                     # Hey, show's over. The debugged program finished
  2497.                     # executing already.
  2498.                     end_report(), next CMD if $finished and $level <= 1;
  2499.  
  2500.                     # Capture the place to put a one-time break.
  2501.                     $subname = $i = $1;
  2502.  
  2503.                     #  Probably not needed, since we finish an interactive
  2504.                     #  sub-session anyway...
  2505.                     # local $filename = $filename;
  2506.                     # local *dbline = *dbline; # XXX Would this work?!
  2507.                     #
  2508.                     # The above question wonders if localizing the alias
  2509.                     # to the magic array works or not. Since it's commented
  2510.                     # out, we'll just leave that to speculation for now.
  2511.  
  2512.                     # If the "subname" isn't all digits, we'll assume it
  2513.                     # is a subroutine name, and try to find it.
  2514.                     if ($subname =~ /\D/) {    # subroutine name
  2515.                         # Qualify it to the current package unless it's
  2516.                         # already qualified.
  2517.                         $subname = $package . "::" . $subname
  2518.                           unless $subname =~ /::/;
  2519.                         # find_sub will return "file:line_number" corresponding
  2520.                         # to where the subroutine is defined; we call find_sub,
  2521.                         # break up the return value, and assign it in one 
  2522.                         # operation.
  2523.                         ($file, $i) = (find_sub($subname) =~ /^(.*):(.*)$/);
  2524.  
  2525.                         # Force the line number to be numeric.
  2526.                         $i += 0;
  2527.  
  2528.                         # If we got a line number, we found the sub.
  2529.                         if ($i) {
  2530.                             # Switch all the debugger's internals around so
  2531.                             # we're actually working with that file.
  2532.                             $filename = $file;
  2533.                             *dbline   = $main::{ '_<' . $filename };
  2534.                             # Mark that there's a breakpoint in this file.
  2535.                             $had_breakpoints{$filename} |= 1;
  2536.                             # Scan forward to the first executable line
  2537.                             # after the 'sub whatever' line.
  2538.                             $max = $#dbline;
  2539.                             ++$i while $dbline[$i] == 0 && $i < $max;
  2540.                         } ## end if ($i)
  2541.  
  2542.                         # We didn't find a sub by that name.
  2543.                         else {
  2544.                             print $OUT "Subroutine $subname not found.\n";
  2545.                             next CMD;
  2546.                         }
  2547.                     } ## end if ($subname =~ /\D/)
  2548.  
  2549.                     # At this point, either the subname was all digits (an
  2550.                     # absolute line-break request) or we've scanned through
  2551.                     # the code following the definition of the sub, looking
  2552.                     # for an executable, which we may or may not have found.
  2553.                     #
  2554.                     # If $i (which we set $subname from) is non-zero, we
  2555.                     # got a request to break at some line somewhere. On 
  2556.                     # one hand, if there wasn't any real subroutine name 
  2557.                     # involved, this will be a request to break in the current 
  2558.                     # file at the specified line, so we have to check to make 
  2559.                     # sure that the line specified really is breakable.
  2560.                     #
  2561.                     # On the other hand, if there was a subname supplied, the
  2562.                     # preceeding block has moved us to the proper file and
  2563.                     # location within that file, and then scanned forward
  2564.                     # looking for the next executable line. We have to make
  2565.                     # sure that one was found.
  2566.                     #
  2567.                     # On the gripping hand, we can't do anything unless the
  2568.                     # current value of $i points to a valid breakable line.
  2569.                     # Check that.
  2570.                     if ($i) {
  2571.                         # Breakable?
  2572.                         if ($dbline[$i] == 0) {
  2573.                             print $OUT "Line $i not breakable.\n";
  2574.                             next CMD;
  2575.                         }
  2576.                         # Yes. Set up the one-time-break sigil.
  2577.                         $dbline{$i} =~
  2578.                           s/($|\0)/;9$1/;    # add one-time-only b.p.
  2579.                     } ## end if ($i)
  2580.  
  2581.                     # Turn off stack tracing from here up.
  2582.                     for ($i = 0 ; $i <= $stack_depth ;) {
  2583.                         $stack[$i++] &= ~1;
  2584.                     }
  2585.                     last CMD;
  2586.                 };
  2587.  
  2588. =head4 C<r> - return from a subroutine
  2589.  
  2590. For C<r> to work properly, the debugger has to stop execution again
  2591. immediately after the return is executed. This is done by forcing
  2592. single-stepping to be on in the call level above the current one. If
  2593. we are printing return values when a C<r> is executed, set C<$doret>
  2594. appropriately, and force us out of the command loop.
  2595.  
  2596. =cut
  2597.  
  2598.                 # r - return from the current subroutine.
  2599.                 $cmd =~ /^r$/ && do {
  2600.                     # Can't do anythign if the program's over.
  2601.                     end_report(), next CMD if $finished and $level <= 1;
  2602.                     # Turn on stack trace.
  2603.                     $stack[$stack_depth] |= 1;
  2604.                     # Print return value unless the stack is empty.
  2605.                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
  2606.                     last CMD;
  2607.                 };
  2608.  
  2609. =head4 C<R> - restart
  2610.  
  2611. Restarting the debugger is a complex operation that occurs in several phases.
  2612. First, we try to reconstruct the command line that was used to invoke Perl
  2613. and the debugger.
  2614.  
  2615. =cut
  2616.  
  2617.                 # R - restart execution.
  2618.                 $cmd =~ /^R$/ && do {
  2619.                     # I may not be able to resurrect you, but here goes ...
  2620.                     print $OUT
  2621. "Warning: some settings and command-line options may be lost!\n";
  2622.                     my (@script, @flags, $cl);
  2623.  
  2624.                     # If warn was on before, turn it on again.
  2625.                     push @flags, '-w' if $ini_warn;
  2626.  
  2627.                     # Rebuild the -I flags that were on the initial
  2628.                     # command line.
  2629.                     for (@ini_INC) {
  2630.                         push @flags, '-I', $_;
  2631.                     }
  2632.  
  2633.                     # Turn on taint if it was on before.
  2634.                     push @flags, '-T' if ${^TAINT};
  2635.  
  2636.                     # Arrange for setting the old INC:
  2637.                     # Save the current @init_INC in the environment.
  2638.                     set_list("PERLDB_INC", @ini_INC);
  2639.  
  2640.                     # If this was a perl one-liner, go to the "file"
  2641.                     # corresponding to the one-liner read all the lines
  2642.                     # out of it (except for the first one, which is going
  2643.                     # to be added back on again when 'perl -d' runs: that's
  2644.                     # the 'require perl5db.pl;' line), and add them back on
  2645.                     # to the command line to be executed.
  2646.                     if ($0 eq '-e') {
  2647.                         for (1 .. $#{'::_<-e'}) {  # The first line is PERL5DB
  2648.                             chomp($cl = ${'::_<-e'}[$_]);
  2649.                             push @script, '-e', $cl;
  2650.                         }
  2651.                     } ## end if ($0 eq '-e')
  2652.  
  2653.                     # Otherwise we just reuse the original name we had 
  2654.                     # before.
  2655.                     else {
  2656.                         @script = $0;
  2657.                     }
  2658.  
  2659. =pod
  2660.  
  2661. After the command line  has been reconstructed, the next step is to save
  2662. the debugger's status in environment variables. The C<DB::set_list> routine
  2663. is used to save aggregate variables (both hashes and arrays); scalars are
  2664. just popped into environment variables directly.
  2665.  
  2666. =cut
  2667.  
  2668.                     # If the terminal supported history, grab it and
  2669.                     # save that in the environment.
  2670.                     set_list("PERLDB_HIST",
  2671.                         $term->Features->{getHistory}
  2672.                         ? $term->GetHistory
  2673.                         : @hist);
  2674.                     # Find all the files that were visited during this
  2675.                     # session (i.e., the debugger had magic hashes
  2676.                     # corresponding to them) and stick them in the environment.
  2677.                     my @had_breakpoints = keys %had_breakpoints;
  2678.                     set_list("PERLDB_VISITED", @had_breakpoints);
  2679.  
  2680.                     # Save the debugger options we chose.
  2681.                     set_list("PERLDB_OPT",     %option);
  2682.  
  2683.                     # Save the break-on-loads.
  2684.                     set_list("PERLDB_ON_LOAD", %break_on_load);
  2685.  
  2686. =pod 
  2687.  
  2688. The most complex part of this is the saving of all of the breakpoints. They
  2689. can live in an awful lot of places, and we have to go through all of them,
  2690. find the breakpoints, and then save them in the appropriate environment
  2691. variable via C<DB::set_list>.
  2692.  
  2693. =cut
  2694.  
  2695.                     # Go through all the breakpoints and make sure they're
  2696.                     # still valid.
  2697.                     my @hard;
  2698.                     for (0 .. $#had_breakpoints) {
  2699.                         # We were in this file.
  2700.                         my $file = $had_breakpoints[$_];
  2701.  
  2702.                         # Grab that file's magic line hash.
  2703.                         *dbline = $main::{ '_<' . $file };
  2704.  
  2705.                         # Skip out if it doesn't exist, or if the breakpoint
  2706.                         # is in a postponed file (we'll do postponed ones 
  2707.                         # later).
  2708.                         next unless %dbline or $postponed_file{$file};
  2709.  
  2710.                         # In an eval. This is a little harder, so we'll
  2711.                         # do more processing on that below.
  2712.                         (push @hard, $file), next
  2713.                           if $file =~ /^\(\w*eval/;
  2714.                         # XXX I have no idea what this is doing. Yet. 
  2715.                         my @add;
  2716.                         @add = %{ $postponed_file{$file} }
  2717.                           if $postponed_file{$file};
  2718.  
  2719.                         # Save the list of all the breakpoints for this file.
  2720.                         set_list("PERLDB_FILE_$_", %dbline, @add);
  2721.                     } ## end for (0 .. $#had_breakpoints)
  2722.  
  2723.                     # The breakpoint was inside an eval. This is a little
  2724.                     # more difficult. XXX and I don't understand it.
  2725.                     for (@hard) {    
  2726.                         # Get over to the eval in question.
  2727.                         *dbline = $main::{ '_<' . $_ };
  2728.                         my ($quoted, $sub, %subs, $line) = quotemeta $_;
  2729.                         for $sub (keys %sub) {
  2730.                             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
  2731.                             $subs{$sub} = [$1, $2];
  2732.                         }
  2733.                         unless (%subs) {
  2734.                             print $OUT
  2735.                               "No subroutines in $_, ignoring breakpoints.\n";
  2736.                             next;
  2737.                         }
  2738.                       LINES: for $line (keys %dbline) {
  2739.  
  2740.                             # One breakpoint per sub only:
  2741.                             my ($offset, $sub, $found);
  2742.                           SUBS: for $sub (keys %subs) {
  2743.                                 if (
  2744.                                     $subs{$sub}->[1] >=
  2745.                                     $line    # Not after the subroutine
  2746.                                     and (
  2747.                                         not defined $offset    # Not caught
  2748.                                         or $offset < 0
  2749.                                     )
  2750.                                   )
  2751.                                 {    # or badly caught
  2752.                                     $found  = $sub;
  2753.                                     $offset = $line - $subs{$sub}->[0];
  2754.                                     $offset = "+$offset", last SUBS
  2755.                                       if $offset >= 0;
  2756.                                 } ## end if ($subs{$sub}->[1] >=...
  2757.                             } ## end for $sub (keys %subs)
  2758.                             if (defined $offset) {
  2759.                                 $postponed{$found} =
  2760.                                   "break $offset if $dbline{$line}";
  2761.                             }
  2762.                             else {
  2763.                                 print $OUT
  2764. "Breakpoint in $_:$line ignored: after all the subroutines.\n";
  2765.                             }
  2766.                         } ## end for $line (keys %dbline)
  2767.                     } ## end for (@hard)
  2768.  
  2769.                     # Save the other things that don't need to be 
  2770.                     # processed.
  2771.                     set_list("PERLDB_POSTPONE",  %postponed);
  2772.                     set_list("PERLDB_PRETYPE",   @$pretype);
  2773.                     set_list("PERLDB_PRE",       @$pre);
  2774.                     set_list("PERLDB_POST",      @$post);
  2775.                     set_list("PERLDB_TYPEAHEAD", @typeahead);
  2776.  
  2777.                     # We are oficially restarting.
  2778.                     $ENV{PERLDB_RESTART} = 1;
  2779.  
  2780.                     # We are junking all child debuggers.
  2781.                     delete $ENV{PERLDB_PIDS};    # Restore ini state
  2782.  
  2783.                     # Set this back to the initial pid.
  2784.                     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
  2785.  
  2786. =pod 
  2787.  
  2788. After all the debugger status has been saved, we take the command we built
  2789. up and then C<exec()> it. The debugger will spot the C<PERLDB_RESTART>
  2790. environment variable and realize it needs to reload its state from the
  2791. environment.
  2792.  
  2793. =cut
  2794.  
  2795.                     # And run Perl again. Add the "-d" flag, all the 
  2796.                     # flags we built up, the script (whether a one-liner
  2797.                     # or a file), add on the -emacs flag for a slave editor,
  2798.                     # and then the old arguments. We use exec() to keep the
  2799.                     # PID stable (and that way $ini_pids is still valid).
  2800.                     exec($^X, '-d', @flags, @script,
  2801.                         ($slave_editor ? '-emacs' : ()), @ARGS) ||
  2802.                       print $OUT "exec failed: $!\n";
  2803.                     last CMD;
  2804.                 };
  2805.  
  2806. =head4 C<T> - stack trace
  2807.  
  2808. Just calls C<DB::print_trace>.
  2809.  
  2810. =cut
  2811.  
  2812.                 $cmd =~ /^T$/ && do {
  2813.                     print_trace($OUT, 1);        # skip DB
  2814.                     next CMD;
  2815.                 };
  2816.  
  2817. =head4 C<w> - List window around current line.
  2818.  
  2819. Just calls C<DB::cmd_w>.
  2820.  
  2821. =cut
  2822.  
  2823.                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w('w', $1); next CMD; };
  2824.  
  2825. =head4 C<W> - watch-expression processing.
  2826.  
  2827. Just calls C<DB::cmd_W>. 
  2828.  
  2829. =cut
  2830.  
  2831.                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W('W', $1); next CMD; };
  2832.  
  2833. =head4 C</> - search forward for a string in the source
  2834.  
  2835. We take the argument and treat it as a pattern. If it turns out to be a 
  2836. bad one, we return the error we got from trying to C<eval> it and exit.
  2837. If not, we create some code to do the search and C<eval> it so it can't 
  2838. mess us up.
  2839.  
  2840. =cut
  2841.  
  2842.                 $cmd =~ /^\/(.*)$/     && do {
  2843.  
  2844.                     # The pattern as a string.
  2845.                     $inpat = $1;
  2846.  
  2847.                     # Remove the final slash.
  2848.                     $inpat =~ s:([^\\])/$:$1:;
  2849.  
  2850.                     # If the pattern isn't null ...
  2851.                     if ($inpat ne "") {
  2852.  
  2853.                         # Turn of warn and die procesing for a bit.
  2854.                         local $SIG{__DIE__};
  2855.                         local $SIG{__WARN__};
  2856.  
  2857.                         # Create the pattern.
  2858.                         eval '$inpat =~ m' . "\a$inpat\a";
  2859.                         if ($@ ne "") {
  2860.                             # Oops. Bad pattern. No biscuit.
  2861.                             # Print the eval error and go back for more 
  2862.                             # commands.
  2863.                             print $OUT "$@";
  2864.                             next CMD;
  2865.                         }
  2866.                         $pat = $inpat;
  2867.                     } ## end if ($inpat ne "")
  2868.  
  2869.                     # Set up to stop on wrap-around.
  2870.                     $end  = $start;
  2871.  
  2872.                     # Don't move off the current line.
  2873.                     $incr = -1;
  2874.  
  2875.                     # Done in eval so nothing breaks if the pattern
  2876.                     # does something weird.
  2877.                     eval '
  2878.                         for (;;) {
  2879.                             # Move ahead one line.
  2880.                             ++$start;
  2881.  
  2882.                             # Wrap if we pass the last line.
  2883.                             $start = 1 if ($start > $max);
  2884.  
  2885.                             # Stop if we have gotten back to this line again,
  2886.                             last if ($start == $end);
  2887.  
  2888.                             # A hit! (Note, though, that we are doing
  2889.                             # case-insensitive matching. Maybe a qr//
  2890.                             # expression would be better, so the user could
  2891.                             # do case-sensitive matching if desired.
  2892.                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
  2893.                                 if ($slave_editor) {
  2894.                                     # Handle proper escaping in the slave.
  2895.                                     print $OUT "\032\032$filename:$start:0\n";
  2896.                                 } 
  2897.                                 else {
  2898.                                     # Just print the line normally.
  2899.                                     print $OUT "$start:\t",$dbline[$start],"\n";
  2900.                                 }
  2901.                                 # And quit since we found something.
  2902.                                 last;
  2903.                             }
  2904.                          } ';
  2905.                     # If we wrapped, there never was a match.
  2906.                     print $OUT "/$pat/: not found\n" if ($start == $end);
  2907.                     next CMD;
  2908.                 };
  2909.  
  2910. =head4 C<?> - search backward for a string in the source
  2911.  
  2912. Same as for C</>, except the loop runs backwards.
  2913.  
  2914. =cut
  2915.  
  2916.                 # ? - backward pattern search.
  2917.                 $cmd =~ /^\?(.*)$/ && do {
  2918.  
  2919.                     # Get the pattern, remove trailing question mark.
  2920.                     $inpat = $1;
  2921.                     $inpat =~ s:([^\\])\?$:$1:;
  2922.  
  2923.                     # If we've got one ...
  2924.                     if ($inpat ne "") {
  2925.  
  2926.                         # Turn off die & warn handlers.
  2927.                         local $SIG{__DIE__};
  2928.                         local $SIG{__WARN__};
  2929.                         eval '$inpat =~ m' . "\a$inpat\a";
  2930.  
  2931.                         if ($@ ne "") {
  2932.                             # Ouch. Not good. Print the error.
  2933.                             print $OUT $@;
  2934.                             next CMD;
  2935.                         }
  2936.                         $pat = $inpat;
  2937.                     } ## end if ($inpat ne "")
  2938.  
  2939.                     # Where we are now is where to stop after wraparound.
  2940.                     $end  = $start;
  2941.  
  2942.                     # Don't move away from this line.
  2943.                     $incr = -1;
  2944.  
  2945.                     # Search inside the eval to prevent pattern badness
  2946.                     # from killing us.
  2947.                     eval '
  2948.                         for (;;) {
  2949.                             # Back up a line.
  2950.                             --$start;
  2951.  
  2952.                             # Wrap if we pass the first line.
  2953.                             $start = $max if ($start <= 0);
  2954.  
  2955.                             # Quit if we get back where we started,
  2956.                             last if ($start == $end);
  2957.  
  2958.                             # Match?
  2959.                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
  2960.                                 if ($slave_editor) {
  2961.                                     # Yep, follow slave editor requirements.
  2962.                                     print $OUT "\032\032$filename:$start:0\n";
  2963.                                 } 
  2964.                                 else {
  2965.                                     # Yep, just print normally.
  2966.                                     print $OUT "$start:\t",$dbline[$start],"\n";
  2967.                                 }
  2968.  
  2969.                                 # Found, so done.
  2970.                                 last;
  2971.                             }
  2972.                         } ';
  2973.  
  2974.                     # Say we failed if the loop never found anything,
  2975.                     print $OUT "?$pat?: not found\n" if ($start == $end);
  2976.                     next CMD;
  2977.                 };
  2978.  
  2979. =head4 C<$rc> - Recall command
  2980.  
  2981. Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
  2982. that the terminal supports history). It find the the command required, puts it
  2983. into C<$cmd>, and redoes the loop to execute it.
  2984.  
  2985. =cut
  2986.  
  2987.                 # $rc - recall command. 
  2988.                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
  2989.  
  2990.                     # No arguments, take one thing off history.
  2991.                     pop (@hist) if length($cmd) > 1;
  2992.  
  2993.                     # Relative (- found)? 
  2994.                     #  Y - index back from most recent (by 1 if bare minus)
  2995.                     #  N - go to that particular command slot or the last 
  2996.                     #      thing if nothing following.
  2997.                     $i = $1 ? ($#hist - ($2 || 1)) : ($2 || $#hist);
  2998.  
  2999.                     # Pick out the command desired.
  3000.                     $cmd = $hist[$i];
  3001.  
  3002.                     # Print the command to be executed and restart the loop
  3003.                     # with that command in the buffer.
  3004.                     print $OUT $cmd, "\n";
  3005.                     redo CMD;
  3006.                 };
  3007.  
  3008. =head4 C<$sh$sh> - C<system()> command
  3009.  
  3010. Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
  3011. C<STDOUT> from getting messed up.
  3012.  
  3013. =cut
  3014.  
  3015.                 # $sh$sh - run a shell command (if it's all ASCII).
  3016.                 # Can't run shell commands with Unicode in the debugger, hmm.
  3017.                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
  3018.                     # System it.
  3019.                     &system($1);
  3020.                     next CMD;
  3021.                 };
  3022.  
  3023. =head4 C<$rc I<pattern> $rc> - Search command history
  3024.  
  3025. Another command to manipulate C<@hist>: this one searches it with a pattern.
  3026. If a command is found, it is placed in C<$cmd> and executed via <redo>.
  3027.  
  3028. =cut
  3029.  
  3030.                 # $rc pattern $rc - find a command in the history. 
  3031.                 $cmd =~ /^$rc([^$rc].*)$/ && do {
  3032.                     # Create the pattern to use.
  3033.                     $pat = "^$1";
  3034.  
  3035.                     # Toss off last entry if length is >1 (and it always is).
  3036.                     pop (@hist) if length($cmd) > 1;
  3037.  
  3038.                     # Look backward through the history.
  3039.                     for ($i = $#hist ; $i ; --$i) {
  3040.                         # Stop if we find it.
  3041.                         last if $hist[$i] =~ /$pat/;
  3042.                     }
  3043.  
  3044.                     if (!$i) {
  3045.                         # Never found it.
  3046.                         print $OUT "No such command!\n\n";
  3047.                         next CMD;
  3048.                     }
  3049.  
  3050.                     # Found it. Put it in the buffer, print it, and process it.
  3051.                     $cmd = $hist[$i];
  3052.                     print $OUT $cmd, "\n";
  3053.                     redo CMD;
  3054.                 };
  3055.  
  3056. =head4 C<$sh> - Invoke a shell     
  3057.  
  3058. Uses C<DB::system> to invoke a shell.
  3059.  
  3060. =cut
  3061.  
  3062.                 # $sh - start a shell.
  3063.                 $cmd =~ /^$sh$/ && do {
  3064.                     # Run the user's shell. If none defined, run Bourne.
  3065.                     # We resume execution when the shell terminates.
  3066.                     &system($ENV{SHELL} || "/bin/sh");
  3067.                     next CMD;
  3068.                 };
  3069.  
  3070. =head4 C<$sh I<command>> - Force execution of a command in a shell
  3071.  
  3072. Like the above, but the command is passed to the shell. Again, we use
  3073. C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
  3074.  
  3075. =cut
  3076.  
  3077.                 # $sh command - start a shell and run a command in it.
  3078.                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
  3079.                     # XXX: using csh or tcsh destroys sigint retvals!
  3080.                     #&system($1);  # use this instead
  3081.  
  3082.                     # use the user's shell, or Bourne if none defined.
  3083.                     &system($ENV{SHELL} || "/bin/sh", "-c", $1);
  3084.                     next CMD;
  3085.                 };
  3086.  
  3087. =head4 C<H> - display commands in history
  3088.  
  3089. Prints the contents of C<@hist> (if any).
  3090.  
  3091. =cut
  3092.  
  3093.                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
  3094.                     # Anything other than negative numbers is ignored by 
  3095.                     # the (incorrect) pattern, so this test does nothing.
  3096.                     $end = $2 ? ($#hist - $2) : 0;
  3097.  
  3098.                     # Set to the minimum if less than zero.
  3099.                     $hist = 0 if $hist < 0;
  3100.  
  3101.                     # Start at the end of the array. 
  3102.                     # Stay in while we're still above the ending value.
  3103.                     # Tick back by one each time around the loop.
  3104.                     for ($i = $#hist ; $i > $end ; $i--) {
  3105.  
  3106.                         # Print the command  unless it has no arguments.
  3107.                         print $OUT "$i: ", $hist[$i], "\n"
  3108.                           unless $hist[$i] =~ /^.?$/;
  3109.                     }
  3110.                     next CMD;
  3111.                 };
  3112.  
  3113. =head4 C<man, doc, perldoc> - look up documentation
  3114.  
  3115. Just calls C<runman()> to print the appropriate document.
  3116.  
  3117. =cut
  3118.  
  3119.                 # man, perldoc, doc - show manual pages.               
  3120.                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
  3121.                     runman($1);
  3122.                     next CMD;
  3123.                 };
  3124.  
  3125. =head4 C<p> - print
  3126.  
  3127. Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
  3128. the bottom of the loop.
  3129.  
  3130. =cut
  3131.  
  3132.                 # p - print (no args): print $_.
  3133.                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
  3134.  
  3135.                 # p - print the given expression.
  3136.                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
  3137.  
  3138. =head4 C<=> - define command alias
  3139.  
  3140. Manipulates C<%alias> to add or list command aliases.
  3141.  
  3142. =cut
  3143.  
  3144.                  # = - set up a command alias.
  3145.                 $cmd =~ s/^=\s*// && do {
  3146.                     my @keys;
  3147.                     if (length $cmd == 0) {
  3148.                         # No args, get current aliases.
  3149.                         @keys = sort keys %alias;
  3150.                     }
  3151.                     elsif (my ($k, $v) = ($cmd =~ /^(\S+)\s+(\S.*)/)) {
  3152.                         # Creating a new alias. $k is alias name, $v is
  3153.                         # alias value.
  3154.  
  3155.                         # can't use $_ or kill //g state
  3156.                         for my $x ($k, $v) { 
  3157.                           # Escape "alarm" characters.
  3158.                           $x =~ s/\a/\\a/g 
  3159.                         }
  3160.  
  3161.                         # Substitute key for value, using alarm chars
  3162.                         # as separators (which is why we escaped them in 
  3163.                         # the command).
  3164.                         $alias{$k} = "s\a$k\a$v\a";
  3165.  
  3166.                         # Turn off standard warn and die behavior.
  3167.                         local $SIG{__DIE__};
  3168.                         local $SIG{__WARN__};
  3169.  
  3170.                         # Is it valid Perl?
  3171.                         unless (eval "sub { s\a$k\a$v\a }; 1") {
  3172.                             # Nope. Bad alias. Say so and get out.
  3173.                             print $OUT "Can't alias $k to $v: $@\n";
  3174.                             delete $alias{$k};
  3175.                             next CMD;
  3176.                         }
  3177.                         # We'll only list the new one.
  3178.                         @keys = ($k);
  3179.                     } ## end elsif (my ($k, $v) = ($cmd...
  3180.  
  3181.                     # The argument is the alias to list.
  3182.                     else {
  3183.                         @keys = ($cmd);
  3184.                     }
  3185.  
  3186.                     # List aliases.
  3187.                     for my $k (@keys) {
  3188.                         # Messy metaquoting: Trim the substiution code off.
  3189.                         # We use control-G as the delimiter because it's not
  3190.                         # likely to appear in the alias.
  3191.                         if ((my $v = $alias{$k}) =~ ss\a$k\a(.*)\a$1) {
  3192.                             # Print the alias.
  3193.                             print $OUT "$k\t= $1\n";
  3194.                         }
  3195.                         elsif (defined $alias{$k}) {
  3196.                             # Couldn't trim it off; just print the alias code.
  3197.                             print $OUT "$k\t$alias{$k}\n";
  3198.                         }
  3199.                         else {
  3200.                             # No such, dude.
  3201.                             print "No alias for $k\n";
  3202.                         }
  3203.                     } ## end for my $k (@keys)
  3204.                     next CMD;
  3205.                 };
  3206.  
  3207. =head4 C<source> - read commands from a file.
  3208.  
  3209. Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
  3210. pick it up.
  3211.  
  3212. =cut
  3213.  
  3214.                 # source - read commands from a file (or pipe!) and execute. 
  3215.                 $cmd =~ /^source\s+(.*\S)/ && do {
  3216.                     if (open my $fh, $1) {
  3217.                         # Opened OK; stick it in the list of file handles.
  3218.                         push @cmdfhs, $fh;
  3219.                     }
  3220.                     else {
  3221.                         # Couldn't open it. 
  3222.                         &warn("Can't execute `$1': $!\n");
  3223.                     }
  3224.                     next CMD;
  3225.                 };
  3226.  
  3227. =head4 C<|, ||> - pipe output through the pager.
  3228.  
  3229. FOR C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
  3230. (the program's standard output). For C<||>, we only save C<OUT>. We open a
  3231. pipe to the pager (restoring the output filehandles if this fails). If this
  3232. is the C<|> command, we also set up a C<SIGPIPE> handler which will simply 
  3233. set C<$signal>, sending us back into the debugger.
  3234.  
  3235. We then trim off the pipe symbols and C<redo> the command loop at the
  3236. C<PIPE> label, causing us to evaluate the command in C<$cmd> without
  3237. reading another.
  3238.  
  3239. =cut
  3240.  
  3241.                 # || - run command in the pager, with output to DB::OUT.
  3242.                 $cmd =~ /^\|\|?\s*[^|]/ && do {
  3243.                     if ($pager =~ /^\|/) {
  3244.                         # Default pager is into a pipe. Redirect I/O.
  3245.                         open(SAVEOUT, ">&STDOUT") ||
  3246.                           &warn("Can't save STDOUT");
  3247.                         open(STDOUT, ">&OUT") ||
  3248.                           &warn("Can't redirect STDOUT");
  3249.                     } ## end if ($pager =~ /^\|/)
  3250.                     else {
  3251.                         # Not into a pipe. STDOUT is safe.
  3252.                         open(SAVEOUT, ">&OUT") || &warn("Can't save DB::OUT");
  3253.                     }
  3254.  
  3255.                     # Fix up environment to record we have less if so.
  3256.                     fix_less();
  3257.  
  3258.                     unless ($piped = open(OUT, $pager)) {
  3259.                         # Couldn't open pipe to pager.
  3260.                         &warn("Can't pipe output to `$pager'");
  3261.                         if ($pager =~ /^\|/) {
  3262.                             # Redirect I/O back again.
  3263.                             open(OUT, ">&STDOUT")    # XXX: lost message
  3264.                               || &warn("Can't restore DB::OUT");
  3265.                             open(STDOUT, ">&SAVEOUT") ||
  3266.                               &warn("Can't restore STDOUT");
  3267.                             close(SAVEOUT);
  3268.                         } ## end if ($pager =~ /^\|/)
  3269.                         else {
  3270.                             # Redirect I/O. STDOUT already safe.
  3271.                             open(OUT, ">&STDOUT")    # XXX: lost message
  3272.                               || &warn("Can't restore DB::OUT");
  3273.                         }
  3274.                         next CMD;
  3275.                     } ## end unless ($piped = open(OUT,...
  3276.  
  3277.                     # Set up broken-pipe handler if necessary.
  3278.                     $SIG{PIPE} = \&DB::catch
  3279.                       if $pager =~ /^\|/ &&
  3280.                       ("" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE});
  3281.  
  3282.                     # Save current filehandle, unbuffer out, and put it back.
  3283.                     $selected = select(OUT);
  3284.                     $|        = 1;
  3285.  
  3286.                     # Don't put it back if pager was a pipe.
  3287.                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
  3288.  
  3289.                     # Trim off the pipe symbols and run the command now.
  3290.                     $cmd =~ s/^\|+\s*//;
  3291.                     redo PIPE;
  3292.                 };
  3293.  
  3294.  
  3295. =head3 END OF COMMAND PARSING
  3296.  
  3297. Anything left in C<$cmd> at this point is a Perl expression that we want to 
  3298. evaluate. We'll always evaluate in the user's context, and fully qualify 
  3299. any variables we might want to address in the C<DB> package.
  3300.  
  3301. =cut
  3302.  
  3303.                 # t - turn trace on.
  3304.                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
  3305.  
  3306.                 # s - single-step. Remember the last command was 's'.
  3307.                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
  3308.  
  3309.                 # n - single-step, but not into subs. Remember last command
  3310.                 # was 'n'.
  3311.                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
  3312.  
  3313.             }    # PIPE:
  3314.  
  3315.             # Make sure the flag that says "the debugger's running" is 
  3316.             # still on, to make sure we get control again.
  3317.             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
  3318.  
  3319.             # Run *our* eval that executes in the caller's context.
  3320.             &eval;
  3321.  
  3322.             # Turn off the one-time-dump stuff now.
  3323.             if ($onetimeDump) {
  3324.                 $onetimeDump      = undef;
  3325.                 $onetimedumpDepth = undef;
  3326.             }
  3327.             elsif ($term_pid == $$) {
  3328.                 STDOUT->flush();
  3329.                 STDERR->flush();
  3330.                 # XXX If this is the master pid, print a newline.
  3331.                 print $OUT "\n";
  3332.             }
  3333.         } ## end while (($term || &setterm...
  3334.  
  3335. =head3 POST-COMMAND PROCESSING
  3336.  
  3337. After each command, we check to see if the command output was piped anywhere.
  3338. If so, we go through the necessary code to unhook the pipe and go back to
  3339. our standard filehandles for input and output.
  3340.  
  3341. =cut
  3342.  
  3343.         continue {    # CMD:
  3344.  
  3345.             # At the end of every command:
  3346.             if ($piped) {
  3347.                 # Unhook the pipe mechanism now.
  3348.                 if ($pager =~ /^\|/) {
  3349.                     # No error from the child.
  3350.                     $? = 0;
  3351.  
  3352.                     # we cannot warn here: the handle is missing --tchrist
  3353.                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
  3354.  
  3355.                     # most of the $? crud was coping with broken cshisms
  3356.                     # $? is explicitly set to 0, so this never runs.
  3357.                     if ($?) {
  3358.                         print SAVEOUT "Pager `$pager' failed: ";
  3359.                         if ($? == -1) {
  3360.                             print SAVEOUT "shell returned -1\n";
  3361.                         }
  3362.                         elsif ($? >> 8) {
  3363.                             print SAVEOUT ($? & 127)
  3364.                               ? " (SIG#" . ($? & 127) . ")"
  3365.                               : "", ($? & 128) ? " -- core dumped" : "", "\n";
  3366.                         }
  3367.                         else {
  3368.                             print SAVEOUT "status ", ($? >> 8), "\n";
  3369.                         }
  3370.                     } ## end if ($?)
  3371.  
  3372.                     # Reopen filehandle for our output (if we can) and 
  3373.                     # restore STDOUT (if we can).
  3374.                     open(OUT, ">&STDOUT") || &warn("Can't restore DB::OUT");
  3375.                     open(STDOUT, ">&SAVEOUT") ||
  3376.                       &warn("Can't restore STDOUT");
  3377.  
  3378.                     # Turn off pipe exception handler if necessary.
  3379.                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
  3380.  
  3381.                     # Will stop ignoring SIGPIPE if done like nohup(1)
  3382.                     # does SIGINT but Perl doesn't give us a choice.
  3383.                 } ## end if ($pager =~ /^\|/)
  3384.                 else {
  3385.                     # Non-piped "pager". Just restore STDOUT.
  3386.                     open(OUT, ">&SAVEOUT") || &warn("Can't restore DB::OUT");
  3387.                 }
  3388.  
  3389.                 # Close filehandle pager was using, restore the normal one
  3390.                 # if necessary,
  3391.                 close(SAVEOUT);
  3392.                 select($selected), $selected = "" unless $selected eq "";
  3393.  
  3394.                 # No pipes now.
  3395.                 $piped = "";
  3396.             } ## end if ($piped)
  3397.         }    # CMD:
  3398.  
  3399. =head3 COMMAND LOOP TERMINATION
  3400.  
  3401. When commands have finished executing, we come here. If the user closed the
  3402. input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
  3403. evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
  3404. C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
  3405. The interpreter will then execute the next line and then return control to us
  3406. again.
  3407.  
  3408. =cut
  3409.  
  3410.         # No more commands? Quit.
  3411.         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
  3412.  
  3413.         # Evaluate post-prompt commands.
  3414.         foreach $evalarg (@$post) {
  3415.             &eval;
  3416.         }
  3417.     }    # if ($single || $signal)
  3418.  
  3419.     # Put the user's globals back where you found them.
  3420.     ($@, $!, $^E, $,, $/, $\, $^W) = @saved;
  3421.     ();
  3422. } ## end sub DB
  3423.  
  3424. # The following code may be executed now:
  3425. # BEGIN {warn 4}
  3426.  
  3427. =head2 sub
  3428.  
  3429. C<sub> is called whenever a subroutine call happens in the program being 
  3430. debugged. The variable C<$DB::sub> contains the name of the subroutine
  3431. being called.
  3432.  
  3433. The core function of this subroutine is to actually call the sub in the proper
  3434. context, capturing its output. This of course causes C<DB::DB> to get called
  3435. again, repeating until the subroutine ends and returns control to C<DB::sub>
  3436. again. Once control returns, C<DB::sub> figures out whether or not to dump the
  3437. return value, and returns its captured copy of the return value as its own
  3438. return value. The value then feeds back into the program being debugged as if
  3439. C<DB::sub> hadn't been there at all.
  3440.  
  3441. C<sub> does all the work of printing the subroutine entry and exit messages
  3442. enabled by setting C<$frame>. It notes what sub the autoloader got called for,
  3443. and also prints the return value if needed (for the C<r> command and if 
  3444. the 16 bit is set in C<$frame>).
  3445.  
  3446. It also tracks the subroutine call depth by saving the current setting of
  3447. C<$single> in the C<@stack> package global; if this exceeds the value in
  3448. C<$deep>, C<sub> automatically turns on printing of the current depth by
  3449. setting the 4 bit in C<$single>. In any case, it keeps the current setting
  3450. of stop/don't stop on entry to subs set as it currently is set.
  3451.  
  3452. =head3 C<caller()> support
  3453.  
  3454. If C<caller()> is called from the package C<DB>, it provides some
  3455. additional data, in the following order:
  3456.  
  3457. =over 4
  3458.  
  3459. =item * C<$package>
  3460.  
  3461. The package name the sub was in
  3462.  
  3463. =item * C<$filename>
  3464.  
  3465. The filename it was defined in
  3466.  
  3467. =item * C<$line>
  3468.  
  3469. The line number it was defined on
  3470.  
  3471. =item * C<$subroutine>
  3472.  
  3473. The subroutine name; C<'(eval)'> if an C<eval>().
  3474.  
  3475. =item * C<$hasargs>
  3476.  
  3477. 1 if it has arguments, 0 if not
  3478.  
  3479. =item * C<$wantarray>
  3480.  
  3481. 1 if array context, 0 if scalar context
  3482.  
  3483. =item * C<$evaltext>
  3484.  
  3485. The C<eval>() text, if any (undefined for C<eval BLOCK>)
  3486.  
  3487. =item * C<$is_require>
  3488.  
  3489. frame was created by a C<use> or C<require> statement
  3490.  
  3491. =item * C<$hints>
  3492.  
  3493. pragma information; subject to change between versions
  3494.  
  3495. =item * C<$bitmask>
  3496.  
  3497. pragma information: subject to change between versions
  3498.  
  3499. =item * C<@DB::args>
  3500.  
  3501. arguments with which the subroutine was invoked
  3502.  
  3503. =back
  3504.  
  3505. =cut
  3506.  
  3507. sub sub {
  3508.  
  3509.     # Whether or not the autoloader was running, a scalar to put the
  3510.     # sub's return value in (if needed), and an array to put the sub's
  3511.     # return value in (if needed).
  3512.     my ($al, $ret, @ret) = "";
  3513.  
  3514.     # If the last ten characters are C'::AUTOLOAD', note we've traced
  3515.     # into AUTOLOAD for $sub.
  3516.     if (length($sub) > 10 && substr($sub, -10, 10) eq '::AUTOLOAD') {
  3517.         $al = " for $$sub";
  3518.     }
  3519.  
  3520.     # We stack the stack pointer and then increment it to protect us
  3521.     # from a situation that might unwind a whole bunch of call frames
  3522.     # at once. Localizing the stack pointer means that it will automatically
  3523.     # unwind the same amount when multiple stack frames are unwound.
  3524.     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
  3525.  
  3526.     # Expand @stack.
  3527.     $#stack = $stack_depth;
  3528.  
  3529.     # Save current single-step setting.
  3530.     $stack[-1] = $single;
  3531.  
  3532.     # Turn off all flags except single-stepping. 
  3533.     $single &= 1;
  3534.  
  3535.     # If we've gotten really deeply recursed, turn on the flag that will
  3536.     # make us stop with the 'deep recursion' message.
  3537.     $single |= 4 if $stack_depth == $deep;
  3538.  
  3539.     # If frame messages are on ...
  3540.     (
  3541.         $frame & 4    # Extended frame entry message
  3542.         ? (
  3543.             print_lineinfo(' ' x ($stack_depth - 1), "in  "),
  3544.  
  3545.             # Why -1? But it works! :-(
  3546.             # Because print_trace will call add 1 to it and then call
  3547.             # dump_trace; this results in our skipping -1+1 = 0 stack frames
  3548.             # in dump_trace.
  3549.             print_trace($LINEINFO, -1, 1, 1, "$sub$al")
  3550.           )
  3551.         : print_lineinfo(' ' x ($stack_depth - 1), "entering $sub$al\n")
  3552.           # standard frame entry message
  3553.       )
  3554.       if $frame;
  3555.  
  3556.     # Determine the sub's return type,and capture approppriately.
  3557.     if (wantarray) {
  3558.         # Called in array context. call sub and capture output.
  3559.         # DB::DB will recursively get control again if appropriate; we'll come
  3560.         # back here when the sub is finished.
  3561.         @ret = &$sub;
  3562.  
  3563.         # Pop the single-step value back off the stack.
  3564.         $single |= $stack[$stack_depth--];
  3565.  
  3566.         # Check for exit trace messages...
  3567.         (
  3568.             $frame & 4         # Extended exit message
  3569.             ? (
  3570.                 print_lineinfo(' ' x $stack_depth, "out "),
  3571.                 print_trace($LINEINFO, -1, 1, 1, "$sub$al")
  3572.               )
  3573.             : print_lineinfo(' ' x $stack_depth, "exited $sub$al\n")
  3574.               # Standard exit message
  3575.           )
  3576.           if $frame & 2;
  3577.  
  3578.         # Print the return info if we need to.
  3579.         if ($doret eq $stack_depth or $frame & 16) {
  3580.             # Turn off output record separator.
  3581.             local $\ = '';
  3582.             my $fh = ($doret eq $stack_depth ? $OUT : $LINEINFO);
  3583.  
  3584.             # Indent if we're printing because of $frame tracing.
  3585.             print $fh ' ' x $stack_depth if $frame & 16;
  3586.  
  3587.             # Print the return value.
  3588.             print $fh "list context return from $sub:\n";
  3589.             dumpit($fh, \@ret);
  3590.  
  3591.             # And don't print it again.
  3592.             $doret = -2;
  3593.         } ## end if ($doret eq $stack_depth...
  3594.         # And we have to return the return value now.
  3595.         @ret;
  3596.  
  3597.     } ## end if (wantarray)
  3598.  
  3599.     # Scalar context.
  3600.     else {
  3601.         if (defined wantarray) {
  3602.             # Save the value if it's wanted at all. 
  3603.             $ret = &$sub;
  3604.         }
  3605.         else {
  3606.             # Void return, explicitly.
  3607.             &$sub;
  3608.             undef $ret;
  3609.         }
  3610.  
  3611.         # Pop the single-step value off the stack.
  3612.         $single |= $stack[$stack_depth--];
  3613.  
  3614.         # If we're doing exit messages...
  3615.         (
  3616.             $frame & 4                        # Extended messsages
  3617.             ? (
  3618.                 print_lineinfo(' ' x $stack_depth, "out "),
  3619.                 print_trace($LINEINFO, -1, 1, 1, "$sub$al")
  3620.               )
  3621.             : print_lineinfo(' ' x $stack_depth, "exited $sub$al\n")
  3622.                                               # Standard messages
  3623.           )
  3624.           if $frame & 2;
  3625.  
  3626.         # If we are supposed to show the return value... same as before.
  3627.         if ($doret eq $stack_depth or $frame & 16 and defined wantarray) {
  3628.             local $\ = '';
  3629.             my $fh = ($doret eq $stack_depth ? $OUT : $LINEINFO);
  3630.             print $fh (' ' x $stack_depth) if $frame & 16;
  3631.             print $fh (
  3632.                 defined wantarray
  3633.                 ? "scalar context return from $sub: "
  3634.                 : "void context return from $sub\n"
  3635.                 );
  3636.             dumpit($fh, $ret) if defined wantarray;
  3637.             $doret = -2;
  3638.         } ## end if ($doret eq $stack_depth...
  3639.  
  3640.         # Return the appropriate scalar value.
  3641.         $ret;
  3642.     } ## end else [ if (wantarray)
  3643. } ## end sub sub
  3644.  
  3645. =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
  3646.  
  3647. In Perl 5.8.0, there was a major realignment of the commands and what they did,
  3648. Most of the changes were to systematize the command structure and to eliminate
  3649. commands that threw away user input without checking.
  3650.  
  3651. The following sections describe the code added to make it easy to support 
  3652. multiple command sets with conflicting command names. This section is a start 
  3653. at unifying all command processing to make it simpler to develop commands.
  3654.  
  3655. Note that all the cmd_[a-zA-Z] subroutines require the command name, a line 
  3656. number, and C<$dbline> (the current line) as arguments.
  3657.  
  3658. Support functions in this section which have multiple modes of failure C<die> 
  3659. on error; the rest simply return a false value.
  3660.  
  3661. The user-interface functions (all of the C<cmd_*> functions) just output
  3662. error messages.
  3663.  
  3664. =head2 C<%set>
  3665.  
  3666. The C<%set> hash defines the mapping from command letter to subroutine
  3667. name suffix. 
  3668.  
  3669. C<%set> is a two-level hash, indexed by set name and then by command name.
  3670. Note that trying to set the CommandSet to 'foobar' simply results in the
  3671. 5.8.0 command set being used, since there's no top-level entry for 'foobar'.
  3672.  
  3673. =cut 
  3674.  
  3675. ### The API section
  3676.  
  3677. my %set = (    #
  3678.     'pre580' => {
  3679.         'a' => 'pre580_a',
  3680.         'A' => 'pre580_null',
  3681.         'b' => 'pre580_b',
  3682.         'B' => 'pre580_null',
  3683.         'd' => 'pre580_null',
  3684.         'D' => 'pre580_D',
  3685.         'h' => 'pre580_h',
  3686.         'M' => 'pre580_null',
  3687.         'O' => 'o',
  3688.         'o' => 'pre580_null',
  3689.         'v' => 'M',
  3690.         'w' => 'v',
  3691.         'W' => 'pre580_W',
  3692.     },
  3693.     'pre590' => {
  3694.         '<'  => 'pre590_prepost',
  3695.         '<<' => 'pre590_prepost',
  3696.         '>'  => 'pre590_prepost',
  3697.         '>>' => 'pre590_prepost',
  3698.         '{'  => 'pre590_prepost',
  3699.         '{{' => 'pre590_prepost',
  3700.     },
  3701.   );
  3702.  
  3703. =head2 C<cmd_wrapper()> (API)
  3704.  
  3705. C<cmd_wrapper()> allows the debugger to switch command sets 
  3706. depending on the value of the C<CommandSet> option. 
  3707.  
  3708. It tries to look up the command in the X<C<%set>> package-level I<lexical>
  3709. (which means external entities can't fiddle with it) and create the name of 
  3710. the sub to call based on the value found in the hash (if it's there). I<All> 
  3711. of the commands to be handled in a set have to be added to C<%set>; if they 
  3712. aren't found, the 5.8.0 equivalent is called (if there is one).
  3713.  
  3714. This code uses symbolic references. 
  3715.  
  3716. =cut
  3717.  
  3718. sub cmd_wrapper {
  3719.     my $cmd      = shift;
  3720.     my $line     = shift;
  3721.     my $dblineno = shift;
  3722.  
  3723.     # Assemble the command subroutine's name by looking up the 
  3724.     # command set and command name in %set. If we can't find it,
  3725.     # default to the older version of the command.
  3726.     my $call = 'cmd_'
  3727.       . ( $set{$CommandSet}{$cmd}
  3728.           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
  3729.  
  3730.     # Call the command subroutine, call it by name.
  3731.     return &$call($cmd, $line, $dblineno);
  3732. } ## end sub cmd_wrapper
  3733.  
  3734. =head3 C<cmd_a> (command)
  3735.  
  3736. The C<a> command handles pre-execution actions. These are associated with a
  3737. particular line, so they're stored in C<%dbline>. We default to the current 
  3738. line if none is specified. 
  3739.  
  3740. =cut
  3741.  
  3742. sub cmd_a {
  3743.     my $cmd  = shift;
  3744.     my $line = shift || '';    # [.|line] expr
  3745.     my $dbline = shift;
  3746.  
  3747.     # If it's dot (here), or not all digits,  use the current line.
  3748.     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
  3749.  
  3750.     # Should be a line number followed by an expression. 
  3751.     if ($line =~ /^\s*(\d*)\s*(\S.+)/) {
  3752.         my ($lineno, $expr) = ($1, $2);
  3753.  
  3754.         # If we have an expression ...
  3755.         if (length $expr) {
  3756.             # ... but the line isn't breakable, complain.
  3757.             if ($dbline[$lineno] == 0) {
  3758.                 print $OUT
  3759.                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
  3760.             }
  3761.             else {
  3762.                 # It's executable. Record that the line has an action.
  3763.                 $had_breakpoints{$filename} |= 2;
  3764.  
  3765.                 # Remove any action, temp breakpoint, etc.
  3766.                 $dbline{$lineno} =~ s/\0[^\0]*//;
  3767.  
  3768.                 # Add the action to the line.
  3769.                 $dbline{$lineno} .= "\0" . action($expr);
  3770.             }
  3771.         } ## end if (length $expr)
  3772.     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
  3773.     else {
  3774.         # Syntax wrong.
  3775.         print $OUT
  3776.           "Adding an action requires an optional lineno and an expression\n"
  3777.           ;    # hint
  3778.     }
  3779. } ## end sub cmd_a
  3780.  
  3781. =head3 C<cmd_A> (command)
  3782.  
  3783. Delete actions. Similar to above, except the delete code is in a separate
  3784. subroutine, C<delete_action>.
  3785.  
  3786. =cut
  3787.  
  3788. sub cmd_A {
  3789.     my $cmd  = shift;
  3790.     my $line = shift || '';
  3791.     my $dbline = shift;
  3792.  
  3793.     # Dot is this line.
  3794.     $line =~ s/^\./$dbline/;
  3795.  
  3796.     # Call delete_action with a null param to delete them all.
  3797.     # The '1' forces the eval to be true. It'll be false only
  3798.     # if delete_action blows up for some reason, in which case
  3799.     # we print $@ and get out.
  3800.     if ($line eq '*') {
  3801.         eval { &delete_action(); 1 } or print $OUT $@ and return;
  3802.     }
  3803.  
  3804.     # There's a real line  number. Pass it to delete_action.
  3805.     # Error trapping is as above.
  3806.     elsif ($line =~ /^(\S.*)/) {
  3807.         eval { &delete_action($1); 1 } or print $OUT $@ and return;
  3808.     }
  3809.  
  3810.     # Swing and a miss. Bad syntax.
  3811.     else {
  3812.         print $OUT
  3813.           "Deleting an action requires a line number, or '*' for all\n"
  3814.           ;    # hint
  3815.     }
  3816. } ## end sub cmd_A
  3817.  
  3818. =head3 C<delete_action> (API)
  3819.  
  3820. C<delete_action> accepts either a line number or C<undef>. If a line number
  3821. is specified, we check for the line being executable (if it's not, it 
  3822. couldn't have had an  action). If it is, we just take the action off (this
  3823. will get any kind of an action, including breakpoints).
  3824.  
  3825. =cut
  3826.  
  3827. sub delete_action {
  3828.     my $i = shift;
  3829.     if (defined($i)) {
  3830.         # Can there be one?
  3831.         die "Line $i has no action .\n" if $dbline[$i] == 0;
  3832.  
  3833.         # Nuke whatever's there.
  3834.         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
  3835.         delete $dbline{$i} if $dbline{$i} eq '';
  3836.     }
  3837.     else {
  3838.         print $OUT "Deleting all actions...\n";
  3839.         for my $file (keys %had_breakpoints) {
  3840.             local *dbline = $main::{ '_<' . $file };
  3841.             my $max = $#dbline;
  3842.             my $was;
  3843.             for ($i = 1 ; $i <= $max ; $i++) {
  3844.                 if (defined $dbline{$i}) {
  3845.                     $dbline{$i} =~ s/\0[^\0]*//;
  3846.                     delete $dbline{$i} if $dbline{$i} eq '';
  3847.                 }
  3848.                 unless ($had_breakpoints{$file} &= ~2) {
  3849.                     delete $had_breakpoints{$file};
  3850.                 }
  3851.             } ## end for ($i = 1 ; $i <= $max...
  3852.         } ## end for my $file (keys %had_breakpoints)
  3853.     } ## end else [ if (defined($i))
  3854. } ## end sub delete_action
  3855.  
  3856. =head3 C<cmd_b> (command)
  3857.  
  3858. Set breakpoints. Since breakpoints can be set in so many places, in so many
  3859. ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
  3860. we try to parse the command type, and then shuttle it off to an appropriate
  3861. subroutine to actually do the work of setting the breakpoint in the right
  3862. place.
  3863.  
  3864. =cut
  3865.  
  3866. sub cmd_b {
  3867.     my $cmd    = shift;
  3868.     my $line   = shift;    # [.|line] [cond]
  3869.     my $dbline = shift;
  3870.  
  3871.     # Make . the current line number if it's there..
  3872.     $line =~ s/^\./$dbline/;
  3873.  
  3874.     # No line number, no condition. Simple break on current line. 
  3875.     if ($line =~ /^\s*$/) {
  3876.         &cmd_b_line($dbline, 1);
  3877.     }
  3878.  
  3879.     # Break on load for a file.
  3880.     elsif ($line =~ /^load\b\s*(.*)/) {
  3881.         my $file = $1;
  3882.         $file =~ s/\s+$//;
  3883.         &cmd_b_load($file);
  3884.     }
  3885.  
  3886.     # b compile|postpone <some sub> [<condition>]
  3887.     # The interpreter actually traps this one for us; we just put the 
  3888.     # necessary condition in the %postponed hash.
  3889.     elsif ($line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/) {
  3890.         # Capture the condition if there is one. Make it true if none.
  3891.         my $cond = length $3 ? $3 : '1';
  3892.  
  3893.         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
  3894.         # if it was 'compile'.
  3895.         my ($subname, $break) = ($2, $1 eq 'postpone');
  3896.  
  3897.         # De-Perl4-ify the name - ' separators to ::.
  3898.         $subname =~ s/\'/::/g;
  3899.  
  3900.         # Qualify it into the current package unless it's already qualified.
  3901.         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
  3902.  
  3903.         # Add main if it starts with ::.
  3904.         $subname = "main" . $subname if substr($subname, 0, 2) eq "::";
  3905.  
  3906.         # Save the break type for this sub.
  3907.         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
  3908.     } ## end elsif ($line =~ ...
  3909.  
  3910.     # b <sub name> [<condition>]
  3911.     elsif ($line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/) {
  3912.         # 
  3913.         $subname = $1;
  3914.         $cond = length $2 ? $2 : '1';
  3915.         &cmd_b_sub($subname, $cond);
  3916.     }
  3917.  
  3918.     # b <line> [<condition>].
  3919.     elsif ($line =~ /^(\d*)\s*(.*)/) {
  3920.         # Capture the line. If none, it's the current line.
  3921.         $line = $1 || $dbline;
  3922.  
  3923.         # If there's no condition, make it '1'.
  3924.         $cond = length $2 ? $2 : '1';
  3925.  
  3926.         # Break on line.
  3927.         &cmd_b_line($line, $cond);
  3928.     }
  3929.  
  3930.     # Line didn't make sense.
  3931.     else {
  3932.         print "confused by line($line)?\n";
  3933.     }
  3934. } ## end sub cmd_b
  3935.  
  3936. =head3 C<break_on_load> (API)
  3937.  
  3938. We want to break when this file is loaded. Mark this file in the
  3939. C<%break_on_load> hash, and note that it has a breakpoint in 
  3940. C<%had_breakpoints>.
  3941.  
  3942. =cut
  3943.  
  3944. sub break_on_load {
  3945.     my $file = shift;
  3946.     $break_on_load{$file} = 1;
  3947.     $had_breakpoints{$file} |= 1;
  3948. }
  3949.  
  3950. =head3 C<report_break_on_load> (API)
  3951.  
  3952. Gives us an array of filenames that are set to break on load. Note that 
  3953. only files with break-on-load are in here, so simply showing the keys
  3954. suffices.
  3955.  
  3956. =cut
  3957.  
  3958. sub report_break_on_load {
  3959.     sort keys %break_on_load;
  3960. }
  3961.  
  3962. =head3 C<cmd_b_load> (command)
  3963.  
  3964. We take the file passed in and try to find it in C<%INC> (which maps modules
  3965. to files they came from). We mark those files for break-on-load via 
  3966. C<break_on_load> and then report that it was done.
  3967.  
  3968. =cut
  3969.  
  3970. sub cmd_b_load {
  3971.     my $file = shift;
  3972.     my @files;
  3973.  
  3974.     # This is a block because that way we can use a redo inside it
  3975.     # even without there being any looping structure at all outside it.
  3976.     {
  3977.         # Save short name and full path if found.
  3978.         push @files, $file;
  3979.         push @files, $::INC{$file} if $::INC{$file};
  3980.  
  3981.         # Tack on .pm and do it again unless there was a '.' in the name 
  3982.         # already.
  3983.         $file .= '.pm', redo unless $file =~ /\./;
  3984.     }
  3985.  
  3986.     # Do the real work here.
  3987.     break_on_load($_) for @files;
  3988.  
  3989.     # All the files that have break-on-load breakpoints.
  3990.     @files = report_break_on_load;
  3991.  
  3992.     # Normalize for the purposes of our printing this.
  3993.     local $\ = '';
  3994.     local $" = ' ';
  3995.     print $OUT "Will stop on load of `@files'.\n";
  3996. } ## end sub cmd_b_load
  3997.  
  3998. =head3 C<$filename_error> (API package global)
  3999.  
  4000. Several of the functions we need to implement in the API need to work both
  4001. on the current file and on other files. We don't want to duplicate code, so
  4002. C<$filename_error> is used to contain the name of the file that's being 
  4003. worked on (if it's not the current one).
  4004.  
  4005. We can now build functions in pairs: the basic function works on the current
  4006. file, and uses C<$filename_error> as part of its error message. Since this is
  4007. initialized to C<''>, no filename will appear when we are working on the
  4008. current file.
  4009.  
  4010. The second function is a wrapper which does the following:
  4011.  
  4012. =over 4 
  4013.  
  4014. =item * Localizes C<$filename_error> and sets it to the name of the file to be processed.
  4015.  
  4016. =item * Localizes the C<*dbline> glob and reassigns it to point to the file we want to process. 
  4017.  
  4018. =item * Calls the first function. 
  4019.  
  4020. The first function works on the "current" (i.e., the one we changed to) file,
  4021. and prints C<$filename_error> in the error message (the name of the other file)
  4022. if it needs to. When the functions return, C<*dbline> is restored to point to the actual current file (the one we're executing in) and C<$filename_error> is 
  4023. restored to C<''>. This restores everything to the way it was before the 
  4024. second function was called at all.
  4025.  
  4026. See the comments in C<breakable_line> and C<breakable_line_in_file> for more
  4027. details.
  4028.  
  4029. =back
  4030.  
  4031. =cut
  4032.  
  4033. $filename_error = '';
  4034.  
  4035. =head3 breakable_line($from, $to) (API)
  4036.  
  4037. The subroutine decides whether or not a line in the current file is breakable.
  4038. It walks through C<@dbline> within the range of lines specified, looking for
  4039. the first line that is breakable.
  4040.  
  4041. If C<$to> is greater than C<$from>, the search moves forwards, finding the 
  4042. first line I<after> C<$to> that's breakable, if there is one.
  4043.  
  4044. If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
  4045. first line I<before> C<$to> that's breakable, if there is one.
  4046.  
  4047. =cut
  4048.  
  4049. sub breakable_line {
  4050.     
  4051.     my ($from, $to) = @_;
  4052.  
  4053.     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
  4054.     my $i = $from;
  4055.  
  4056.     # If there are at least 2 arguments, we're trying to search a range.
  4057.     if (@_ >= 2) {
  4058.  
  4059.         # $delta is positive for a forward search, negative for a backward one.
  4060.         my $delta = $from < $to ? +1 : -1;
  4061.  
  4062.         # Keep us from running off the ends of the file.
  4063.         my $limit = $delta > 0 ? $#dbline : 1;
  4064.  
  4065.         # Clever test. If you're a mathematician, it's obvious why this
  4066.         # test works. If not:
  4067.         # If $delta is positive (going forward), $limit will be $#dbline.
  4068.         #    If $to is less than $limit, ($limit - $to) will be positive, times
  4069.         #    $delta of 1 (positive), so the result is > 0 and we should use $to
  4070.         #    as the stopping point. 
  4071.         #
  4072.         #    If $to is greater than $limit, ($limit - $to) is negative,
  4073.         #    times $delta of 1 (positive), so the result is < 0 and we should 
  4074.         #    use $limit ($#dbline) as the stopping point.
  4075.         #
  4076.         # If $delta is negative (going backward), $limit will be 1. 
  4077.         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
  4078.         #    (negative) so the result is > 0, and we use $to as the stopping
  4079.         #    point.
  4080.         #
  4081.         #    If $to is less than zero, ($limit - $to) will be positive,
  4082.         #    times $delta of -1 (negative), so the result is not > 0, and 
  4083.         #    we use $limit (1) as the stopping point. 
  4084.         #
  4085.         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
  4086.         #    (negative), still giving zero; the result is not > 0, and 
  4087.         #    we use $limit (1) as the stopping point.
  4088.         #
  4089.         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
  4090.         #    (negative), giving a positive (>0) value, so we'll set $limit to
  4091.         #    $to.
  4092.         
  4093.         $limit = $to if ($limit - $to) * $delta > 0;
  4094.  
  4095.         # The real search loop.
  4096.         # $i starts at $from (the point we want to start searching from).
  4097.         # We move through @dbline in the appropriate direction (determined
  4098.         # by $delta: either -1 (back) or +1 (ahead). 
  4099.         # We stay in as long as we haven't hit an executable line 
  4100.         # ($dbline[$i] == 0 means not executable) and we haven't reached
  4101.         # the limit yet (test similar to the above).
  4102.         $i += $delta while $dbline[$i] == 0 and ($limit - $i) * $delta > 0;
  4103.  
  4104.     } ## end if (@_ >= 2)
  4105.  
  4106.     # If $i points to a line that is executable, return that.
  4107.     return $i unless $dbline[$i] == 0;
  4108.  
  4109.     # Format the message and print it: no breakable lines in range.
  4110.     my ($pl, $upto) = ('', '');
  4111.     ($pl, $upto) = ('s', "..$to") if @_ >= 2 and $from != $to;
  4112.  
  4113.     # If there's a filename in filename_error, we'll see it.
  4114.     # If not, not.
  4115.     die "Line$pl $from$upto$filename_error not breakable\n";
  4116. } ## end sub breakable_line
  4117.  
  4118. =head3 breakable_line_in_filename($file, $from, $to) (API)
  4119.  
  4120. Like C<breakable_line>, but look in another file.
  4121.  
  4122. =cut
  4123.  
  4124. sub breakable_line_in_filename {
  4125.     # Capture the file name.
  4126.     my ($f) = shift;
  4127.  
  4128.     # Swap the magic line array over there temporarily.
  4129.     local *dbline         = $main::{ '_<' . $f };
  4130.  
  4131.     # If there's an error, it's in this other file.
  4132.     local $filename_error = " of `$f'";
  4133.  
  4134.     # Find the breakable line.
  4135.     breakable_line(@_);
  4136.  
  4137.     # *dbline and $filename_error get restored when this block ends.
  4138.  
  4139. } ## end sub breakable_line_in_filename
  4140.  
  4141. =head3 break_on_line(lineno, [condition]) (API)
  4142.  
  4143. Adds a breakpoint with the specified condition (or 1 if no condition was 
  4144. specified) to the specified line. Dies if it can't.
  4145.  
  4146. =cut
  4147.  
  4148. sub break_on_line {
  4149.     my ($i, $cond) = @_;
  4150.  
  4151.     # Always true if no condition supplied.
  4152.     $cond = 1 unless @_ >= 2;
  4153.  
  4154.     my $inii  = $i;
  4155.     my $after = '';
  4156.     my $pl    = '';
  4157.  
  4158.     # Woops, not a breakable line. $filename_error allows us to say
  4159.     # if it was in a different file.
  4160.     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
  4161.  
  4162.     # Mark this file as having breakpoints in it.
  4163.     $had_breakpoints{$filename} |= 1;
  4164.  
  4165.     # If there is an action or condition here already ... 
  4166.     if ($dbline{$i}) { 
  4167.         # ... swap this condition for the existing one.
  4168.         $dbline{$i} =~ s/^[^\0]*/$cond/; 
  4169.     }
  4170.     else { 
  4171.         # Nothing here - just add the condition.
  4172.         $dbline{$i} = $cond; 
  4173.     }
  4174. } ## end sub break_on_line
  4175.  
  4176. =head3 cmd_b_line(line, [condition]) (command)
  4177.  
  4178. Wrapper for C<break_on_line>. Prints the failure message if it 
  4179. doesn't work.
  4180.  
  4181. =cut 
  4182.  
  4183. sub cmd_b_line {
  4184.     eval { break_on_line(@_); 1 } or do {
  4185.         local $\ = '';
  4186.         print $OUT $@ and return;
  4187.     };
  4188. } ## end sub cmd_b_line
  4189.  
  4190. =head3 break_on_filename_line(file, line, [condition]) (API)
  4191.  
  4192. Switches to the file specified and then calls C<break_on_line> to set 
  4193. the breakpoint.
  4194.  
  4195. =cut
  4196.  
  4197. sub break_on_filename_line {
  4198.     my ($f, $i, $cond) = @_;
  4199.  
  4200.     # Always true if condition left off.
  4201.     $cond = 1 unless @_ >= 3;
  4202.  
  4203.     # Switch the magical hash temporarily.
  4204.     local *dbline         = $main::{ '_<' . $f };
  4205.  
  4206.     # Localize the variables that break_on_line uses to make its message.
  4207.     local $filename_error = " of `$f'";
  4208.     local $filename       = $f;
  4209.  
  4210.     # Add the breakpoint.
  4211.     break_on_line($i, $cond);
  4212. } ## end sub break_on_filename_line
  4213.  
  4214. =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
  4215.  
  4216. Switch to another file, search the range of lines specified for an 
  4217. executable one, and put a breakpoint on the first one you find.
  4218.  
  4219. =cut
  4220.  
  4221. sub break_on_filename_line_range {
  4222.     my ($f, $from, $to, $cond) = @_;
  4223.  
  4224.     # Find a breakable line if there is one.
  4225.     my $i = breakable_line_in_filename($f, $from, $to);
  4226.  
  4227.     # Always true if missing.
  4228.     $cond = 1 unless @_ >= 3;
  4229.  
  4230.     # Add the breakpoint.
  4231.     break_on_filename_line($f, $i, $cond);
  4232. } ## end sub break_on_filename_line_range
  4233.  
  4234. =head3 subroutine_filename_lines(subname, [condition]) (API)
  4235.  
  4236. Search for a subroutine within a given file. The condition is ignored.
  4237. Uses C<find_sub> to locate the desired subroutine.
  4238.  
  4239. =cut
  4240.  
  4241. sub subroutine_filename_lines {
  4242.     my ($subname, $cond) = @_;
  4243.  
  4244.     # Returned value from find_sub() is fullpathname:startline-endline.
  4245.     # The match creates the list (fullpathname, start, end). Falling off
  4246.     # the end of the subroutine returns this implicitly.
  4247.     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
  4248. } ## end sub subroutine_filename_lines
  4249.  
  4250. =head3 break_subroutine(subname) (API)
  4251.  
  4252. Places a break on the first line possible in the specified subroutine. Uses
  4253. C<subroutine_filename_lines> to find the subroutine, and 
  4254. C<break_on_filename_line_range> to place the break.
  4255.  
  4256. =cut
  4257.  
  4258. sub break_subroutine {
  4259.     my $subname = shift;
  4260.  
  4261.     # Get filename, start, and end.
  4262.     my ($file, $s, $e) = subroutine_filename_lines($subname)
  4263.       or die "Subroutine $subname not found.\n";
  4264.  
  4265.     # Null condition changes to '1' (always true).
  4266.     $cond = 1 unless @_ >= 2;
  4267.  
  4268.     # Put a break the first place possible in the range of lines
  4269.     # that make up this subroutine.
  4270.     break_on_filename_line_range($file, $s, $e, @_);
  4271. } ## end sub break_subroutine
  4272.  
  4273. =head3 cmd_b_sub(subname, [condition]) (command)
  4274.  
  4275. We take the incoming subroutine name and fully-qualify it as best we can.
  4276.  
  4277. =over 4
  4278.  
  4279. =item 1. If it's already fully-qualified, leave it alone. 
  4280.  
  4281. =item 2. Try putting it in the current package.
  4282.  
  4283. =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
  4284.  
  4285. =item 4. If it starts with '::', put it in 'main::'.
  4286.  
  4287. =back
  4288.  
  4289. After all this cleanup, we call C<break_subroutine> to try to set the 
  4290. breakpoint.
  4291.  
  4292. =cut
  4293.  
  4294. sub cmd_b_sub {
  4295.     my ($subname, $cond) = @_;
  4296.  
  4297.     # Add always-true condition if we have none.
  4298.     $cond = 1 unless @_ >= 2;
  4299.  
  4300.     # If the subname isn't a code reference, qualify it so that 
  4301.     # break_subroutine() will work right.
  4302.     unless (ref $subname eq 'CODE') {
  4303.         # Not Perl4.
  4304.         $subname =~ s/\'/::/g;
  4305.         my $s = $subname;
  4306.  
  4307.         # Put it in this package unless it's already qualified.
  4308.         $subname = "${'package'}::" . $subname
  4309.           unless $subname =~ /::/;
  4310.  
  4311.         # Requalify it into CORE::GLOBAL if qualifying it into this
  4312.         # package resulted in its not being defined, but only do so
  4313.         # if it really is in CORE::GLOBAL.
  4314.         $subname = "CORE::GLOBAL::$s"
  4315.           if not defined &$subname
  4316.           and $s !~ /::/
  4317.           and defined &{"CORE::GLOBAL::$s"};
  4318.  
  4319.         # Put it in package 'main' if it has a leading ::.
  4320.         $subname = "main" . $subname if substr($subname, 0, 2) eq "::";
  4321.  
  4322.     } ## end unless (ref $subname eq 'CODE')
  4323.  
  4324.     # Try to set the breakpoint.
  4325.     eval { break_subroutine($subname, $cond); 1 } or do {
  4326.         local $\ = '';
  4327.         print $OUT $@ and return;
  4328.       }
  4329. } ## end sub cmd_b_sub
  4330.  
  4331. =head3 C<cmd_B> - delete breakpoint(s) (command)
  4332.  
  4333. The command mostly parses the command line and tries to turn the argument
  4334. into a line spec. If it can't, it uses the current line. It then calls
  4335. C<delete_breakpoint> to actually do the work.
  4336.  
  4337. If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
  4338. thereby deleting all the breakpoints.
  4339.  
  4340. =cut
  4341.  
  4342. sub cmd_B {
  4343.     my $cmd  = shift;
  4344.  
  4345.     # No line spec? Use dbline. 
  4346.     # If there is one, use it if it's non-zero, or wipe it out if it is.
  4347.     my $line = ($_[0] =~ /^\./) ? $dbline : shift || '';
  4348.     my $dbline = shift;
  4349.  
  4350.     # If the line was dot, make the line the current one.
  4351.     $line =~ s/^\./$dbline/;
  4352.  
  4353.     # If it's * we're deleting all the breakpoints.
  4354.     if ($line eq '*') {
  4355.         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
  4356.     }
  4357.  
  4358.     # If there is a line spec, delete the breakpoint on that line.
  4359.     elsif ($line =~ /^(\S.*)/) {
  4360.         eval { &delete_breakpoint($line || $dbline); 1 } or do {
  4361.             local $\ = '';
  4362.             print $OUT $@ and return;
  4363.         };
  4364.     } ## end elsif ($line =~ /^(\S.*)/)
  4365.  
  4366.     # No line spec. 
  4367.     else {
  4368.         print $OUT
  4369.           "Deleting a breakpoint requires a line number, or '*' for all\n"
  4370.           ;    # hint
  4371.     }
  4372. } ## end sub cmd_B
  4373.  
  4374. =head3 delete_breakpoint([line]) (API)
  4375.  
  4376. This actually does the work of deleting either a single breakpoint, or all
  4377. of them.
  4378.  
  4379. For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
  4380. just drop out with a message saying so. If it is, we remove the condition
  4381. part of the 'condition\0action' that says there's a breakpoint here. If,
  4382. after we've done that, there's nothing left, we delete the corresponding
  4383. line in C<%dbline> to signal that no action needs to be taken for this line.
  4384.  
  4385. For all breakpoints, we iterate through the keys of C<%had_breakpoints>, 
  4386. which lists all currently-loaded files which have breakpoints. We then look
  4387. at each line in each of these files, temporarily switching the C<%dbline>
  4388. and C<@dbline> structures to point to the files in question, and do what
  4389. we did in the single line case: delete the condition in C<@dbline>, and
  4390. delete the key in C<%dbline> if nothing's left.
  4391.  
  4392. We then wholesale delete C<%postponed>, C<%postponed_file>, and 
  4393. C<%break_on_load>, because these structures contain breakpoints for files
  4394. and code that haven't been loaded yet. We can just kill these off because there
  4395. are no magical debugger structures associated with them.
  4396.  
  4397. =cut
  4398.  
  4399. sub delete_breakpoint {
  4400.     my $i = shift;
  4401.  
  4402.     # If we got a line, delete just that one.
  4403.     if (defined($i)) {
  4404.  
  4405.         # Woops. This line wasn't breakable at all.
  4406.         die "Line $i not breakable.\n" if $dbline[$i] == 0;
  4407.  
  4408.         # Kill the condition, but leave any action.
  4409.         $dbline{$i} =~ s/^[^\0]*//;
  4410.  
  4411.         # Remove the entry entirely if there's no action left.
  4412.         delete $dbline{$i} if $dbline{$i} eq '';
  4413.     }
  4414.  
  4415.     # No line; delete them all.
  4416.     else {
  4417.         print $OUT "Deleting all breakpoints...\n";
  4418.  
  4419.         # %had_breakpoints lists every file that had at least one
  4420.         # breakpoint in it.
  4421.         for my $file (keys %had_breakpoints) {
  4422.             # Switch to the desired file temporarily.
  4423.             local *dbline = $main::{ '_<' . $file };
  4424.  
  4425.             my $max = $#dbline;
  4426.             my $was;
  4427.  
  4428.             # For all lines in this file ...
  4429.             for ($i = 1 ; $i <= $max ; $i++) {
  4430.                 # If there's a breakpoint or action on this line ...
  4431.                 if (defined $dbline{$i}) {
  4432.                     # ... remove the breakpoint.
  4433.                     $dbline{$i} =~ s/^[^\0]+//;
  4434.                     if ($dbline{$i} =~ s/^\0?$//) {
  4435.                         # Remove the entry altogether if no action is there.
  4436.                         delete $dbline{$i};
  4437.                     }
  4438.                 } ## end if (defined $dbline{$i...
  4439.             } ## end for ($i = 1 ; $i <= $max...
  4440.  
  4441.             # If, after we turn off the "there were breakpoints in this file"
  4442.             # bit, the entry in %had_breakpoints for this file is zero, 
  4443.             # we should remove this file from the hash.
  4444.             if (not $had_breakpoints{$file} &= ~1) {
  4445.                 delete $had_breakpoints{$file};
  4446.             }
  4447.         } ## end for my $file (keys %had_breakpoints)
  4448.  
  4449.         # Kill off all the other breakpoints that are waiting for files that
  4450.         # haven't been loaded yet.
  4451.         undef %postponed;
  4452.         undef %postponed_file;
  4453.         undef %break_on_load;
  4454.     } ## end else [ if (defined($i))
  4455. } ## end sub delete_breakpoint
  4456.  
  4457. =head3 cmd_stop (command)
  4458.  
  4459. This is meant to be part of the new command API, but it isn't called or used
  4460. anywhere else in the debugger. XXX It is probably meant for use in development
  4461. of new commands.
  4462.  
  4463. =cut
  4464.  
  4465. sub cmd_stop {    # As on ^C, but not signal-safy.
  4466.     $signal = 1;
  4467. }
  4468.  
  4469. =head3 C<cmd_h> - help command (command)
  4470.  
  4471. Does the work of either
  4472.  
  4473. =over 4
  4474.  
  4475. =item * Showing all the debugger help
  4476.  
  4477. =item * Showing help for a specific command
  4478.  
  4479. =back
  4480.  
  4481. =cut
  4482.  
  4483. sub cmd_h {
  4484.     my $cmd  = shift;
  4485.  
  4486.     # If we have no operand, assume null.
  4487.     my $line = shift || '';
  4488.  
  4489.     # 'h h'. Print the long-format help.
  4490.     if ($line =~ /^h\s*/) {
  4491.         print_help($help);
  4492.     }
  4493.  
  4494.     # 'h <something>'. Search for the command and print only its help.
  4495.     elsif ($line =~ /^(\S.*)$/) {
  4496.  
  4497.         # support long commands; otherwise bogus errors
  4498.         # happen when you ask for h on <CR> for example
  4499.         my $asked  = $1;                   # the command requested
  4500.                                            # (for proper error message)
  4501.  
  4502.         my $qasked = quotemeta($asked);    # for searching; we don't
  4503.                                            # want to use it as a pattern.
  4504.                                            # XXX: finds CR but not <CR>
  4505.  
  4506.         # Search the help string for the command.
  4507.         if ($help =~ /^                    # Start of a line
  4508.                       <?                   # Optional '<'
  4509.                       (?:[IB]<)            # Optional markup
  4510.                       $qasked              # The requested command
  4511.                      /mx) {
  4512.             # It's there; pull it out and print it.
  4513.             while ($help =~ /^
  4514.                               (<?            # Optional '<'
  4515.                                  (?:[IB]<)   # Optional markup
  4516.                                  $qasked     # The command
  4517.                                  ([\s\S]*?)  # Description line(s)
  4518.                               \n)            # End of last description line
  4519.                               (?!\s)         # Next line not starting with 
  4520.                                              # whitespace
  4521.                              /mgx) {
  4522.                 print_help($1);
  4523.             }
  4524.         }
  4525.  
  4526.         # Not found; not a debugger command.
  4527.         else {
  4528.             print_help("B<$asked> is not a debugger command.\n");
  4529.         }
  4530.     } ## end elsif ($line =~ /^(\S.*)$/)
  4531.  
  4532.     # 'h' - print the summary help.
  4533.     else {
  4534.         print_help($summary);
  4535.     }
  4536. } ## end sub cmd_h
  4537.  
  4538. =head3 C<cmd_l> - list lines (command)
  4539.  
  4540. Most of the command is taken up with transforming all the different line
  4541. specification syntaxes into 'start-stop'. After that is done, the command
  4542. runs a loop over C<@dbline> for the specified range of lines. It handles 
  4543. the printing of each line and any markers (C<==E<gt>> for current line,
  4544. C<b> for break on this line, C<a> for action on this line, C<:> for this
  4545. line breakable). 
  4546.  
  4547. We save the last line listed in the C<$start> global for further listing
  4548. later.
  4549.  
  4550. =cut
  4551.  
  4552. sub cmd_l {
  4553.     my $current_line  = $line;
  4554.  
  4555.     my $cmd           = shift;
  4556.     my $line          = shift;
  4557.  
  4558.     # If this is '-something', delete any spaces after the dash.
  4559.     $line =~ s/^-\s*$/-/;
  4560.  
  4561.     # If the line is '$something', assume this is a scalar containing a 
  4562.     # line number.
  4563.     if ($line =~ /^(\$.*)/s) {
  4564.  
  4565.         # Set up for DB::eval() - evaluate in *user* context.
  4566.         $evalarg = $1;
  4567.         my ($s) = &eval;
  4568.  
  4569.         # Ooops. Bad scalar.
  4570.         print($OUT "Error: $@\n"), next CMD if $@;
  4571.  
  4572.         # Good scalar. If it's a reference, find what it points to.
  4573.         $s = CvGV_name($s);
  4574.         print($OUT "Interpreted as: $1 $s\n");
  4575.         $line = "$1 $s";
  4576.  
  4577.         # Call self recursively to really do the command.
  4578.         &cmd_l('l', $s);
  4579.     } ## end if ($line =~ /^(\$.*)/s)
  4580.  
  4581.     # l name. Try to find a sub by that name. 
  4582.     elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s) {
  4583.         my $s = $subname = $1;
  4584.  
  4585.         # De-Perl4.
  4586.         $subname =~ s/\'/::/;
  4587.  
  4588.         # Put it in this package unless it starts with ::.
  4589.         $subname = $package . "::" . $subname unless $subname =~ /::/;
  4590.  
  4591.         # Put it in CORE::GLOBAL if t doesn't start with :: and
  4592.         # it doesn't live in this package and it lives in CORE::GLOBAL.
  4593.         $subname = "CORE::GLOBAL::$s"
  4594.           if not defined &$subname
  4595.           and $s !~ /::/
  4596.           and defined &{"CORE::GLOBAL::$s"};
  4597.  
  4598.         # Put leading '::' names into 'main::'.
  4599.         $subname = "main" . $subname if substr($subname, 0, 2) eq "::";
  4600.  
  4601.         # Get name:start-stop from find_sub, and break this up at 
  4602.         # colons.
  4603.         @pieces = split (/:/, find_sub($subname) || $sub{$subname});
  4604.  
  4605.         # Pull off start-stop.
  4606.         $subrange = pop @pieces;
  4607.  
  4608.         # If the name contained colons, the split broke it up.
  4609.         # Put it back together.
  4610.         $file     = join (':', @pieces);
  4611.  
  4612.         # If we're not in that file, switch over to it.
  4613.         if ($file ne $filename) {
  4614.             print $OUT "Switching to file '$file'.\n"
  4615.               unless $slave_editor;
  4616.  
  4617.             # Switch debugger's magic structures.
  4618.             *dbline   = $main::{ '_<' . $file };
  4619.             $max      = $#dbline;
  4620.             $filename = $file;
  4621.         } ## end if ($file ne $filename)
  4622.  
  4623.         # Subrange is 'start-stop'. If this is less than a window full,
  4624.         # swap it to 'start+', which will list a window from the start point.
  4625.         if ($subrange) {
  4626.             if (eval($subrange) < -$window) {
  4627.                 $subrange =~ s/-.*/+/;
  4628.             }
  4629.             # Call self recursively to list the range.
  4630.             $line = $subrange;
  4631.             &cmd_l('l', $subrange);
  4632.         } ## end if ($subrange)
  4633.  
  4634.         # Couldn't find it.
  4635.         else {
  4636.             print $OUT "Subroutine $subname not found.\n";
  4637.         }
  4638.     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
  4639.  
  4640.     # Bare 'l' command.
  4641.     elsif ($line =~ /^\s*$/) {
  4642.         # Compute new range to list.
  4643.         $incr = $window - 1;
  4644.         $line = $start . '-' . ($start + $incr);
  4645.         # Recurse to do it.
  4646.         &cmd_l('l', $line);
  4647.     }
  4648.  
  4649.     # l [start]+number_of_lines
  4650.     elsif ($line =~ /^(\d*)\+(\d*)$/) {
  4651.         # Don't reset start for 'l +nnn'.
  4652.         $start = $1 if $1;
  4653.  
  4654.         # Increment for list. Use window size if not specified.
  4655.         # (Allows 'l +' to work.)
  4656.         $incr = $2;
  4657.         $incr = $window - 1 unless $incr;
  4658.  
  4659.         # Create a line range we'll understand, and recurse to do it.
  4660.         $line = $start . '-' . ($start + $incr);
  4661.         &cmd_l('l', $line);
  4662.     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
  4663.  
  4664.     # l start-stop or l start,stop
  4665.     elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/) {
  4666.  
  4667.         # Determine end point; use end of file if not specified.
  4668.         $end = (!defined $2) ? $max : ($4 ? $4 : $2);
  4669.  
  4670.         # Go on to the end, and then stop.
  4671.         $end = $max if $end > $max;
  4672.  
  4673.         # Determine start line.  
  4674.         $i = $2;
  4675.         $i = $line if $i eq '.';
  4676.         $i = 1 if $i < 1;
  4677.         $incr = $end - $i;
  4678.  
  4679.         # If we're running under a slave editor, force it to show the lines.
  4680.         if ($slave_editor) {
  4681.             print $OUT "\032\032$filename:$i:0\n";
  4682.             $i = $end;
  4683.         }
  4684.  
  4685.         # We're doing it ourselves. We want to show the line and special
  4686.         # markers for:
  4687.         # - the current line in execution 
  4688.         # - whether a line is breakable or not
  4689.         # - whether a line has a break or not
  4690.         # - whether a line has an action or not
  4691.         else {
  4692.             for (; $i <= $end ; $i++) {
  4693.                 # Check for breakpoints and actions.
  4694.                 my ($stop, $action);
  4695.                 ($stop, $action) = split (/\0/, $dbline{$i})
  4696.                   if $dbline{$i};
  4697.  
  4698.                 # ==> if this is the current line in execution,
  4699.                 # : if it's breakable.
  4700.                 $arrow =
  4701.                   ($i == $current_line and $filename eq $filename_ini)
  4702.                   ? '==>'
  4703.                   : ($dbline[$i] + 0 ? ':' : ' ');
  4704.  
  4705.                 # Add break and action indicators.
  4706.                 $arrow .= 'b' if $stop;
  4707.                 $arrow .= 'a' if $action;
  4708.  
  4709.                 # Print the line.
  4710.                 print $OUT "$i$arrow\t", $dbline[$i];
  4711.  
  4712.                 # Move on to the next line. Drop out on an interrupt.
  4713.                 $i++, last if $signal;
  4714.             } ## end for (; $i <= $end ; $i++)
  4715.  
  4716.             # Line the prompt up; print a newline if the last line listed
  4717.             # didn't have a newline.
  4718.             print $OUT "\n" unless $dbline[$i - 1] =~ /\n$/;
  4719.         } ## end else [ if ($slave_editor)
  4720.  
  4721.         # Save the point we last listed to in case another relative 'l'
  4722.         # command is desired. Don't let it run off the end.
  4723.         $start = $i;
  4724.         $start = $max if $start > $max;
  4725.     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
  4726. } ## end sub cmd_l
  4727.  
  4728. =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
  4729.  
  4730. To list breakpoints, the command has to look determine where all of them are
  4731. first. It starts a C<%had_breakpoints>, which tells us what all files have
  4732. breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the 
  4733. magic source and breakpoint data structures) to the file, and then look 
  4734. through C<%dbline> for lines with breakpoints and/or actions, listing them 
  4735. out. We look through C<%postponed> not-yet-compiled subroutines that have 
  4736. breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files 
  4737. that have breakpoints.
  4738.  
  4739. Watchpoints are simpler: we just list the entries in C<@to_watch>.
  4740.  
  4741. =cut
  4742.  
  4743. sub cmd_L {
  4744.     my $cmd = shift;
  4745.  
  4746.     # If no argument, list everything. Pre-5.8.0 version always lists 
  4747.     # everything
  4748.     my $arg = shift || 'abw';
  4749.     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
  4750.  
  4751.     # See what is wanted.
  4752.     my $action_wanted = ($arg =~ /a/) ? 1 : 0;
  4753.     my $break_wanted  = ($arg =~ /b/) ? 1 : 0;
  4754.     my $watch_wanted  = ($arg =~ /w/) ? 1 : 0;
  4755.  
  4756.     # Breaks and actions are found together, so we look in the same place
  4757.     # for both.
  4758.     if ($break_wanted or $action_wanted) {
  4759.         # Look in all the files with breakpoints...
  4760.         for my $file (keys %had_breakpoints) {
  4761.             # Temporary switch to this file.
  4762.             local *dbline = $main::{ '_<' . $file };
  4763.  
  4764.             # Set up to look through the whole file.
  4765.             my $max = $#dbline;
  4766.             my $was;                         # Flag: did we print something
  4767.                                              # in this file?
  4768.  
  4769.             # For each line in the file ...
  4770.             for ($i = 1 ; $i <= $max ; $i++) {
  4771.                 # We've got something on this line.
  4772.                 if (defined $dbline{$i}) {
  4773.                     # Print the header if we haven't.
  4774.                     print $OUT "$file:\n" unless $was++;
  4775.  
  4776.                     # Print the line.
  4777.                     print $OUT " $i:\t", $dbline[$i];
  4778.  
  4779.                     # Pull out the condition and the action.
  4780.                     ($stop, $action) = split (/\0/, $dbline{$i});
  4781.  
  4782.                     # Print the break if there is one and it's wanted.
  4783.                     print $OUT "   break if (", $stop, ")\n"
  4784.                       if $stop
  4785.                       and $break_wanted;
  4786.  
  4787.                     # Print the action if there is one and it's wanted.
  4788.                     print $OUT "   action:  ", $action, "\n"
  4789.                       if $action
  4790.                       and $action_wanted;
  4791.  
  4792.                     # Quit if the user hit interrupt.
  4793.                     last if $signal;
  4794.                 } ## end if (defined $dbline{$i...
  4795.             } ## end for ($i = 1 ; $i <= $max...
  4796.         } ## end for my $file (keys %had_breakpoints)
  4797.     } ## end if ($break_wanted or $action_wanted)
  4798.  
  4799.     # Look for breaks in not-yet-compiled subs:
  4800.     if (%postponed and $break_wanted) {
  4801.         print $OUT "Postponed breakpoints in subroutines:\n";
  4802.         my $subname;
  4803.         for $subname (keys %postponed) {
  4804.             print $OUT " $subname\t$postponed{$subname}\n";
  4805.             last if $signal;
  4806.         }
  4807.     } ## end if (%postponed and $break_wanted)
  4808.  
  4809.     # Find files that have not-yet-loaded breaks:
  4810.     my @have = map {    # Combined keys
  4811.         keys %{ $postponed_file{$_} }
  4812.     } keys %postponed_file;
  4813.  
  4814.     # If there are any, list them.
  4815.     if (@have and ($break_wanted or $action_wanted)) {
  4816.         print $OUT "Postponed breakpoints in files:\n";
  4817.         my ($file, $line);
  4818.  
  4819.         for $file (keys %postponed_file) {
  4820.             my $db = $postponed_file{$file};
  4821.             print $OUT " $file:\n";
  4822.             for $line (sort { $a <=> $b } keys %$db) {
  4823.                 print $OUT "  $line:\n";
  4824.                 my ($stop, $action) = split (/\0/, $$db{$line});
  4825.                 print $OUT "    break if (", $stop, ")\n"
  4826.                   if $stop
  4827.                   and $break_wanted;
  4828.                 print $OUT "    action:  ", $action, "\n"
  4829.                   if $action
  4830.                   and $action_wanted;
  4831.                 last if $signal;
  4832.             } ## end for $line (sort { $a <=>...
  4833.             last if $signal;
  4834.         } ## end for $file (keys %postponed_file)
  4835.     } ## end if (@have and ($break_wanted...
  4836.     if (%break_on_load and $break_wanted) {
  4837.         print $OUT "Breakpoints on load:\n";
  4838.         my $file;
  4839.         for $file (keys %break_on_load) {
  4840.             print $OUT " $file\n";
  4841.             last if $signal;
  4842.         }
  4843.     } ## end if (%break_on_load and...
  4844.     if ($watch_wanted) {
  4845.         if ($trace & 2) {
  4846.             print $OUT "Watch-expressions:\n" if @to_watch;
  4847.             for my $expr (@to_watch) {
  4848.                 print $OUT " $expr\n";
  4849.                 last if $signal;
  4850.             }
  4851.         } ## end if ($trace & 2)
  4852.     } ## end if ($watch_wanted)
  4853. } ## end sub cmd_L
  4854.  
  4855. =head3 C<cmd_M> - list modules (command)
  4856.  
  4857. Just call C<list_modules>.
  4858.  
  4859. =cut
  4860.  
  4861. sub cmd_M {
  4862.     &list_modules();
  4863. }
  4864.  
  4865. =head3 C<cmd_o> - options (command)
  4866.  
  4867. If this is just C<o> by itself, we list the current settings via 
  4868. C<dump_option>. If there's a nonblank value following it, we pass that on to
  4869. C<parse_options> for processing.
  4870.  
  4871. =cut
  4872.  
  4873. sub cmd_o {
  4874.     my $cmd = shift;
  4875.     my $opt = shift || '';    # opt[=val]
  4876.  
  4877.     # Nonblank. Try to parse and process.
  4878.     if ($opt =~ /^(\S.*)/) {
  4879.         &parse_options($1);
  4880.     }
  4881.  
  4882.     # Blank. List the current option settings.
  4883.     else {
  4884.         for (@options) {
  4885.             &dump_option($_);
  4886.         }
  4887.     }
  4888. } ## end sub cmd_o
  4889.  
  4890. =head3 C<cmd_O> - nonexistent in 5.8.x (command)
  4891.  
  4892. Advises the user that the O command has been renamed.
  4893.  
  4894. =cut
  4895.  
  4896. sub cmd_O {
  4897.     print $OUT "The old O command is now the o command.\n";             # hint
  4898.     print $OUT "Use 'h' to get current command help synopsis or\n";     #
  4899.     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
  4900. }
  4901.  
  4902. =head3 C<cmd_v> - view window (command)
  4903.  
  4904. Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
  4905. move back a few lines to list the selected line in context. Uses C<cmd_l>
  4906. to do the actual listing after figuring out the range of line to request.
  4907.  
  4908. =cut 
  4909.  
  4910. sub cmd_v {
  4911.     my $cmd  = shift;
  4912.     my $line = shift;
  4913.  
  4914.     # Extract the line to list around. (Astute readers will have noted that
  4915.     # this pattern will match whether or not a numeric line is specified,
  4916.     # which means that we'll always enter this loop (though a non-numeric
  4917.     # argument results in no action at all)).
  4918.     if ($line =~ /^(\d*)$/) {
  4919.         # Total number of lines to list (a windowful).
  4920.         $incr = $window - 1;
  4921.  
  4922.         # Set the start to the argument given (if there was one).
  4923.        $start = $1 if $1;
  4924.  
  4925.         # Back up by the context amount.
  4926.         $start -= $preview;
  4927.  
  4928.         # Put together a linespec that cmd_l will like.
  4929.         $line = $start . '-' . ($start + $incr);
  4930.  
  4931.         # List the lines.
  4932.         &cmd_l('l', $line);
  4933.     } ## end if ($line =~ /^(\d*)$/)
  4934. } ## end sub cmd_v
  4935.  
  4936. =head3 C<cmd_w> - add a watch expression (command)
  4937.  
  4938. The 5.8 version of this command adds a watch expression if one is specified;
  4939. it does nothing if entered with no operands.
  4940.  
  4941. We extract the expression, save it, evaluate it in the user's context, and
  4942. save the value. We'll re-evaluate it each time the debugger passes a line,
  4943. and will stop (see the code at the top of the command loop) if the value
  4944. of any of the expressions changes.
  4945.  
  4946. =cut
  4947.  
  4948. sub cmd_w {
  4949.     my $cmd  = shift;
  4950.  
  4951.     # Null expression if no arguments.
  4952.     my $expr = shift || '';
  4953.  
  4954.     # If expression is not null ...
  4955.     if ($expr =~ /^(\S.*)/) {
  4956.         # ... save it.
  4957.         push @to_watch, $expr;
  4958.  
  4959.         # Parameterize DB::eval and call it to get the expression's value
  4960.         # in the user's context. This version can handle expressions which
  4961.         # return a list value.
  4962.         $evalarg = $expr;
  4963.         my ($val) = join(' ', &eval);
  4964.         $val = (defined $val) ? "'$val'" : 'undef';
  4965.  
  4966.         # Save the current value of the expression.
  4967.         push @old_watch, $val;
  4968.  
  4969.         # We are now watching expressions.
  4970.         $trace |= 2;
  4971.     } ## end if ($expr =~ /^(\S.*)/)
  4972.  
  4973.     # You have to give one to get one.
  4974.     else {
  4975.         print $OUT
  4976.           "Adding a watch-expression requires an expression\n";    # hint
  4977.     }
  4978. } ## end sub cmd_w
  4979.  
  4980. =head3 C<cmd_W> - delete watch expressions (command)
  4981.  
  4982. This command accepts either a watch expression to be removed from the list
  4983. of watch expressions, or C<*> to delete them all.
  4984.  
  4985. If C<*> is specified, we simply empty the watch expression list and the 
  4986. watch expression value list. We also turn off the bit that says we've got 
  4987. watch expressions.
  4988.  
  4989. If an expression (or partial expression) is specified, we pattern-match
  4990. through the expressions and remove the ones that match. We also discard
  4991. the corresponding values. If no watch expressions are left, we turn off 
  4992. the 'watching expressions' bit.
  4993.  
  4994. =cut
  4995.  
  4996. sub cmd_W {
  4997.     my $cmd  = shift;
  4998.     my $expr = shift || '';
  4999.  
  5000.     # Delete them all.
  5001.     if ($expr eq '*') {
  5002.         # Not watching now.
  5003.         $trace &= ~2;
  5004.  
  5005.         print $OUT "Deleting all watch expressions ...\n";
  5006.  
  5007.         # And all gone.
  5008.         @to_watch = @old_watch = ();
  5009.     }
  5010.  
  5011.     # Delete one of them.
  5012.     elsif ($expr =~ /^(\S.*)/) {
  5013.         # Where we are in the list.
  5014.         my $i_cnt = 0;
  5015.  
  5016.         # For each expression ...
  5017.         foreach (@to_watch) {
  5018.             my $val = $to_watch[$i_cnt];
  5019.  
  5020.             # Does this one match the command argument?
  5021.             if ($val eq $expr) {    # =~ m/^\Q$i$/) {
  5022.                 # Yes. Turn it off, and its value too.
  5023.                 splice(@to_watch, $i_cnt, 1);
  5024.                 splice(@old_watch, $i_cnt, 1);
  5025.             }
  5026.             $i_cnt++;
  5027.         } ## end foreach (@to_watch)
  5028.  
  5029.         # We don't bother to turn watching off because
  5030.         #  a) we don't want to stop calling watchfunction() it it exists
  5031.         #  b) foreach over a null list doesn't do anything anyway
  5032.  
  5033.     } ## end elsif ($expr =~ /^(\S.*)/)
  5034.  
  5035.     # No command arguments entered.
  5036.     else {
  5037.         print $OUT
  5038. "Deleting a watch-expression requires an expression, or '*' for all\n"
  5039.           ;                         # hint
  5040.     }
  5041. } ## end sub cmd_W
  5042.  
  5043. ### END of the API section
  5044.  
  5045. =head1 SUPPORT ROUTINES
  5046.  
  5047. These are general support routines that are used in a number of places
  5048. throughout the debugger.
  5049.  
  5050. =head2 save
  5051.  
  5052. save() saves the user's versions of globals that would mess us up in C<@saved>,
  5053. and installs the versions we like better. 
  5054.  
  5055. =cut
  5056.  
  5057. sub save {
  5058.     # Save eval failure, command failure, extended OS error, output field 
  5059.     # separator, input record separator, output record separator and 
  5060.     # the warning setting.
  5061.     @saved = ($@, $!, $^E, $,, $/, $\, $^W);
  5062.  
  5063.     $,     = "";             # output field separator is null string
  5064.     $/     = "\n";           # input record separator is newline
  5065.     $\     = "";             # output record separator is null string
  5066.     $^W    = 0;              # warnings are off
  5067. } ## end sub save
  5068.  
  5069. =head2 C<print_lineinfo> - show where we are now
  5070.  
  5071. print_lineinfo prints whatever it is that it is handed; it prints it to the
  5072. C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
  5073. us to feed line information to a slave editor without messing up the 
  5074. debugger output.
  5075.  
  5076. =cut
  5077.  
  5078. sub print_lineinfo {
  5079.     # Make the terminal sensible if we're not the primary debugger.
  5080.     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
  5081.     local $\ = '';
  5082.     local $, = '';
  5083.     print $LINEINFO @_;
  5084. } ## end sub print_lineinfo
  5085.  
  5086. =head2 C<postponed_sub>
  5087.  
  5088. Handles setting postponed breakpoints in subroutines once they're compiled.
  5089. For breakpoints, we use C<DB::find_sub> to locate the source file and line
  5090. range for the subroutine, then mark the file as having a breakpoint,
  5091. temporarily switch the C<*dbline> glob over to the source file, and then 
  5092. search the given range of lines to find a breakable line. If we find one,
  5093. we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
  5094.  
  5095. =cut 
  5096.  
  5097. # The following takes its argument via $evalarg to preserve current @_
  5098.  
  5099. sub postponed_sub {
  5100.     # Get the subroutine name.
  5101.     my $subname = shift;
  5102.  
  5103.     # If this is a 'break +<n> if <condition>' ...
  5104.     if ($postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s//) {
  5105.         # If there's no offset, use '+0'.
  5106.         my $offset = $1 || 0;
  5107.  
  5108.         # find_sub's value is 'fullpath-filename:start-stop'. It's
  5109.         # possible that the filename might have colons in it too.
  5110.         my ($file, $i) = (find_sub($subname) =~ /^(.*):(\d+)-.*$/);
  5111.         if ($i) {
  5112.             # We got the start line. Add the offset '+<n>' from 
  5113.             # $postponed{subname}.
  5114.             $i += $offset;
  5115.  
  5116.             # Switch to the file this sub is in, temporarily.
  5117.             local *dbline = $main::{ '_<' . $file };
  5118.  
  5119.             # No warnings, please.
  5120.             local $^W     = 0;                         # != 0 is magical below
  5121.  
  5122.             # This file's got a breakpoint in it.
  5123.             $had_breakpoints{$file} |= 1;
  5124.  
  5125.             # Last line in file.
  5126.             my $max = $#dbline;
  5127.  
  5128.             # Search forward until we hit a breakable line or get to
  5129.             # the end of the file.
  5130.             ++$i until $dbline[$i] != 0 or $i >= $max;
  5131.  
  5132.             # Copy the breakpoint in and delete it from %postponed.
  5133.             $dbline{$i} = delete $postponed{$subname};
  5134.         } ## end if ($i)
  5135.  
  5136.         # find_sub didn't find the sub.
  5137.         else {
  5138.             local $\ = '';
  5139.             print $OUT "Subroutine $subname not found.\n";
  5140.         }
  5141.         return;
  5142.     } ## end if ($postponed{$subname...
  5143.     elsif ($postponed{$subname} eq 'compile') { $signal = 1 }
  5144.  
  5145.     #print $OUT "In postponed_sub for `$subname'.\n";
  5146. } ## end sub postponed_sub
  5147.  
  5148. =head2 C<postponed>
  5149.  
  5150. Called after each required file is compiled, but before it is executed;
  5151. also called if the name of a just-compiled subroutine is a key of 
  5152. C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
  5153. etc.) into the just-compiled code.
  5154.  
  5155. If this is a C<require>'d file, the incoming parameter is the glob 
  5156. C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
  5157.  
  5158. If it's a subroutine, the incoming parameter is the subroutine name.
  5159.  
  5160. =cut
  5161.  
  5162. sub postponed {
  5163.     # If there's a break, process it.
  5164.     if ($ImmediateStop) {
  5165.         # Right, we've stopped. Turn it off.
  5166.         $ImmediateStop = 0;
  5167.  
  5168.         # Enter the command loop when DB::DB gets called.
  5169.         $signal        = 1;
  5170.     }
  5171.  
  5172.     # If this is a subroutine, let postponed_sub() deal with it.
  5173.     return &postponed_sub unless ref \$_[0] eq 'GLOB';
  5174.  
  5175.     # Not a subroutine. Deal with the file.
  5176.     local *dbline = shift;
  5177.     my $filename = $dbline;
  5178.     $filename =~ s/^_<//;
  5179.     local $\ = '';
  5180.     $signal = 1, print $OUT "'$filename' loaded...\n"
  5181.       if $break_on_load{$filename};
  5182.     print_lineinfo(' ' x $stack_depth, "Package $filename.\n") if $frame;
  5183.  
  5184.     # Do we have any breakpoints to put in this file?
  5185.     return unless $postponed_file{$filename};
  5186.  
  5187.     # Yes. Mark this file as having breakpoints.
  5188.     $had_breakpoints{$filename} |= 1;
  5189.  
  5190.     # "Cannot be done: unsufficient magic" - we can't just put the
  5191.     # breakpoints saved in %postponed_file into %dbline by assigning
  5192.     # the whole hash; we have to do it one item at a time for the
  5193.     # breakpoints to be set properly.
  5194.     #%dbline = %{$postponed_file{$filename}}; 
  5195.  
  5196.     # Set the breakpoints, one at a time.
  5197.     my $key;
  5198.  
  5199.     for $key (keys %{ $postponed_file{$filename} }) {
  5200.         # Stash the saved breakpoint into the current file's magic line array.
  5201.         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
  5202.     }
  5203.  
  5204.     # This file's been compiled; discard the stored breakpoints.
  5205.     delete $postponed_file{$filename};
  5206.  
  5207. } ## end sub postponed
  5208.  
  5209. =head2 C<dumpit>
  5210.  
  5211. C<dumpit> is the debugger's wrapper around dumpvar.pl. 
  5212.  
  5213. It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
  5214. a reference to a variable (the thing to be dumped) as its input. 
  5215.  
  5216. The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
  5217. the currently-selected filehandle, thank you very much). The current
  5218. values of the package globals C<$single> and C<$trace> are backed up in 
  5219. lexicals, and they are turned off (this keeps the debugger from trying
  5220. to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
  5221. preserve its current value and it is set to zero to prevent entry/exit
  5222. messages from printing, and C<$doret> is localized as well and set to -2 to 
  5223. prevent return values from being shown.
  5224.  
  5225. C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and 
  5226. tries to load it (note: if you have a C<dumpvar.pl>  ahead of the 
  5227. installed version in @INC, yours will be used instead. Possible security 
  5228. problem?).
  5229.  
  5230. It then checks to see if the subroutine C<main::dumpValue> is now defined
  5231. (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()> 
  5232. localizes the globals necessary for things to be sane when C<main::dumpValue()>
  5233. is called, and picks up the variable to be dumped from the parameter list. 
  5234.  
  5235. It checks the package global C<%options> to see if there's a C<dumpDepth> 
  5236. specified. If not, -1 is assumed; if so, the supplied value gets passed on to 
  5237. C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a 
  5238. structure: -1 means dump everything.
  5239.  
  5240. C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a 
  5241. warning.
  5242.  
  5243. In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
  5244. and we then return to the caller.
  5245.  
  5246. =cut
  5247.  
  5248. sub dumpit {
  5249.     # Save the current output filehandle and switch to the one
  5250.     # passed in as the first parameter.
  5251.     local ($savout) = select(shift);
  5252.  
  5253.     # Save current settings of $single and $trace, and then turn them off.
  5254.     my $osingle = $single;
  5255.     my $otrace  = $trace;
  5256.     $single = $trace = 0;
  5257.  
  5258.     # XXX Okay, what do $frame and $doret do, again?
  5259.     local $frame = 0;
  5260.     local $doret = -2;
  5261.  
  5262.     # Load dumpvar.pl unless we've already got the sub we need from it.
  5263.     unless (defined &main::dumpValue) {
  5264.         do 'dumpvar.pl';
  5265.     }
  5266.  
  5267.     # If the load succeeded (or we already had dumpvalue()), go ahead
  5268.     # and dump things.
  5269.     if (defined &main::dumpValue) {
  5270.         local $\ = '';
  5271.         local $, = '';
  5272.         local $" = ' ';
  5273.         my $v = shift;
  5274.         my $maxdepth = shift || $option{dumpDepth};
  5275.         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
  5276.         &main::dumpValue($v, $maxdepth);
  5277.     } ## end if (defined &main::dumpValue)
  5278.  
  5279.     # Oops, couldn't load dumpvar.pl.
  5280.     else {
  5281.         local $\ = '';
  5282.         print $OUT "dumpvar.pl not available.\n";
  5283.     }
  5284.  
  5285.     # Reset $single and $trace to their old values.
  5286.     $single = $osingle;
  5287.     $trace  = $otrace;
  5288.  
  5289.     # Restore the old filehandle.
  5290.     select($savout);
  5291. } ## end sub dumpit
  5292.  
  5293. =head2 C<print_trace>
  5294.  
  5295. C<print_trace>'s job is to print a stack trace. It does this via the 
  5296. C<dump_trace> routine, which actually does all the ferreting-out of the
  5297. stack trace data. C<print_trace> takes care of formatting it nicely and
  5298. printing it to the proper filehandle.
  5299.  
  5300. Parameters:
  5301.  
  5302. =over 4
  5303.  
  5304. =item * The filehandle to print to.
  5305.  
  5306. =item * How many frames to skip before starting trace.
  5307.  
  5308. =item * How many frames to print.
  5309.  
  5310. =item * A flag: if true, print a "short" trace without filenames, line numbers, or arguments
  5311.  
  5312. =back
  5313.  
  5314. The original comment below seems to be noting that the traceback may not be
  5315. correct if this routine is called in a tied method.
  5316.  
  5317. =cut
  5318.  
  5319. # Tied method do not create a context, so may get wrong message:
  5320.  
  5321. sub print_trace {
  5322.     local $\ = '';
  5323.     my $fh = shift;
  5324.     # If this is going to a slave editor, but we're not the primary
  5325.     # debugger, reset it first.
  5326.     resetterm(1)
  5327.       if $fh eq $LINEINFO          # slave editor
  5328.       and $LINEINFO eq $OUT        # normal output
  5329.       and $term_pid != $$;         # not the primary
  5330.  
  5331.     # Collect the actual trace information to be formatted.
  5332.     # This is an array of hashes of subroutine call info.
  5333.     my @sub = dump_trace($_[0] + 1, $_[1]);
  5334.  
  5335.     # Grab the "short report" flag from @_.
  5336.     my $short = $_[2];    # Print short report, next one for sub name
  5337.  
  5338.     # Run through the traceback info, format it, and print it.
  5339.     my $s;
  5340.     for ($i = 0 ; $i <= $#sub ; $i++) {
  5341.         # Drop out if the user has lost interest and hit control-C.
  5342.         last if $signal;
  5343.  
  5344.         # Set the separator so arrys print nice. 
  5345.         local $" = ', ';
  5346.  
  5347.         # Grab and stringify the arguments if they are there.
  5348.         my $args =
  5349.           defined $sub[$i]{args}
  5350.           ? "(@{ $sub[$i]{args} })"
  5351.           : '';
  5352.         # Shorten them up if $maxtrace says they're too long.
  5353.         $args = (substr $args, 0, $maxtrace - 3) . '...'
  5354.           if length $args > $maxtrace;
  5355.  
  5356.         # Get the file name.
  5357.         my $file = $sub[$i]{file};
  5358.  
  5359.         # Put in a filename header if short is off.
  5360.         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
  5361.  
  5362.         # Get the actual sub's name, and shorten to $maxtrace's requirement.
  5363.         $s = $sub[$i]{sub};
  5364.         $s = (substr $s, 0, $maxtrace - 3) . '...' if length $s > $maxtrace;
  5365.  
  5366.         # Short report uses trimmed file and sub names.
  5367.         if ($short) {
  5368.             my $sub = @_ >= 4 ? $_[3] : $s;
  5369.             print $fh
  5370.               "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
  5371.         } ## end if ($short)
  5372.  
  5373.         # Non-short report includes full names.
  5374.         else {
  5375.             print $fh "$sub[$i]{context} = $s$args" . " called from $file" .
  5376.               " line $sub[$i]{line}\n";
  5377.         }
  5378.     } ## end for ($i = 0 ; $i <= $#sub...
  5379. } ## end sub print_trace
  5380.  
  5381. =head2 dump_trace(skip[,count])
  5382.  
  5383. Actually collect the traceback information available via C<caller()>. It does
  5384. some filtering and cleanup of the data, but mostly it just collects it to
  5385. make C<print_trace()>'s job easier.
  5386.  
  5387. C<skip> defines the number of stack frames to be skipped, working backwards
  5388. from the most current. C<count> determines the total number of frames to 
  5389. be returned; all of them (well, the first 10^9) are returned if C<count>
  5390. is omitted.
  5391.  
  5392. This routine returns a list of hashes, from most-recent to least-recent
  5393. stack frame. Each has the following keys and values:
  5394.  
  5395. =over 4
  5396.  
  5397. =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
  5398.  
  5399. =item * C<sub> - subroutine name, or C<eval> information
  5400.  
  5401. =item * C<args> - undef, or a reference to an array of arguments
  5402.  
  5403. =item * C<file> - the file in which this item was defined (if any)
  5404.  
  5405. =item * C<line> - the line on which it was defined
  5406.  
  5407. =back
  5408.  
  5409. =cut
  5410.  
  5411. sub dump_trace {
  5412.  
  5413.     # How many levels to skip.
  5414.     my $skip = shift;
  5415.  
  5416.     # How many levels to show. (1e9 is a cheap way of saying "all of them";
  5417.     # it's unlikely that we'll have more than a billion stack frames. If you
  5418.     # do, you've got an awfully big machine...)
  5419.     my $count = shift || 1e9;
  5420.  
  5421.     # We increment skip because caller(1) is the first level *back* from
  5422.     # the current one.  Add $skip to the count of frames so we have a 
  5423.     # simple stop criterion, counting from $skip to $count+$skip.
  5424.     $skip++;
  5425.     $count += $skip;
  5426.  
  5427.     # These variables are used to capture output from caller();
  5428.     my ($p, $file, $line, $sub, $h, $context);
  5429.  
  5430.     my ($e, $r, @a, @sub, $args);
  5431.  
  5432.     # XXX Okay... why'd we do that?
  5433.     my $nothard = not $frame & 8;
  5434.     local $frame = 0;    
  5435.  
  5436.     # Do not want to trace this.
  5437.     my $otrace = $trace;
  5438.     $trace = 0;
  5439.  
  5440.     # Start out at the skip count.
  5441.     # If we haven't reached the number of frames requested, and caller() is
  5442.     # still returning something, stay in the loop. (If we pass the requested
  5443.     # number of stack frames, or we run out - caller() returns nothing - we
  5444.     # quit.
  5445.     # Up the stack frame index to go back one more level each time.
  5446.     for (
  5447.         $i = $skip ;
  5448.         $i < $count
  5449.         and ($p, $file, $line, $sub, $h, $context, $e, $r) = caller($i) ;
  5450.         $i++
  5451.       )
  5452.     {
  5453.  
  5454.         # Go through the arguments and save them for later.
  5455.         @a = ();
  5456.         for $arg (@args) {
  5457.             my $type;
  5458.             if (not defined $arg) {                    # undefined parameter
  5459.                 push @a, "undef";
  5460.             }
  5461.  
  5462.             elsif ($nothard and tied $arg) {           # tied parameter
  5463.                 push @a, "tied";
  5464.             }
  5465.             elsif ($nothard and $type = ref $arg) {    # reference
  5466.                 push @a, "ref($type)";
  5467.             }
  5468.             else {                                     # can be stringified
  5469.                 local $_ =
  5470.                   "$arg";    # Safe to stringify now - should not call f().
  5471.  
  5472.                 # Backslash any single-quotes or backslashes.
  5473.                 s/([\'\\])/\\$1/g;
  5474.  
  5475.                 # Single-quote it unless it's a number or a colon-separated
  5476.                 # name.
  5477.                 s/(.*)/'$1'/s
  5478.                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
  5479.  
  5480.                 # Turn high-bit characters into meta-whatever.
  5481.                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
  5482.  
  5483.                 # Turn control characters into ^-whatever.
  5484.                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
  5485.  
  5486.                 push (@a, $_);
  5487.             } ## end else [ if (not defined $arg)
  5488.         } ## end for $arg (@args)
  5489.  
  5490.         # If context is true, this is array (@)context.
  5491.         # If context is false, this is scalar ($) context.
  5492.         # If neither, context isn't defined. (This is apparently a 'can't 
  5493.         # happen' trap.)
  5494.         $context = $context ? '@' : (defined $context ? "\$" : '.');
  5495.  
  5496.         # if the sub has args ($h true), make an anonymous array of the
  5497.         # dumped args.
  5498.         $args = $h ? [@a] : undef;
  5499.  
  5500.         # remove trailing newline-whitespace-semicolon-end of line sequence
  5501.         # from the eval text, if any.
  5502.         $e =~ s/\n\s*\;\s*\Z//  if $e;
  5503.  
  5504.         # Escape backslashed single-quotes again if necessary.
  5505.         $e =~ s/([\\\'])/\\$1/g if $e;
  5506.  
  5507.         # if the require flag is true, the eval text is from a require.
  5508.         if ($r) {
  5509.             $sub = "require '$e'";
  5510.         }
  5511.         # if it's false, the eval text is really from an eval.
  5512.         elsif (defined $r) {
  5513.             $sub = "eval '$e'";
  5514.         }
  5515.  
  5516.         # If the sub is '(eval)', this is a block eval, meaning we don't
  5517.         # know what the eval'ed text actually was.
  5518.         elsif ($sub eq '(eval)') {
  5519.             $sub = "eval {...}";
  5520.         }
  5521.  
  5522.         # Stick the collected information into @sub as an anonymous hash.
  5523.         push (
  5524.             @sub,
  5525.             {
  5526.                 context => $context,
  5527.                 sub     => $sub,
  5528.                 args    => $args,
  5529.                 file    => $file,
  5530.                 line    => $line
  5531.             }
  5532.             );
  5533.  
  5534.         # Stop processing frames if the user hit control-C.
  5535.         last if $signal;
  5536.     } ## end for ($i = $skip ; $i < ...
  5537.  
  5538.     # Restore the trace value again.
  5539.     $trace = $otrace;
  5540.     @sub;
  5541. } ## end sub dump_trace
  5542.  
  5543. =head2 C<action()>
  5544.  
  5545. C<action()> takes input provided as the argument to an add-action command,
  5546. either pre- or post-, and makes sure it's a complete command. It doesn't do
  5547. any fancy parsing; it just keeps reading input until it gets a string
  5548. without a trailing backslash.
  5549.  
  5550. =cut
  5551.  
  5552. sub action {
  5553.     my $action = shift;
  5554.  
  5555.     while ($action =~ s/\\$//) {
  5556.         # We have a backslash on the end. Read more.
  5557.         $action .= &gets;
  5558.     } ## end while ($action =~ s/\\$//)
  5559.  
  5560.     # Return the assembled action.
  5561.     $action;
  5562. } ## end sub action
  5563.  
  5564. =head2 unbalanced
  5565.  
  5566. This routine mostly just packages up a regular expression to be used
  5567. to check that the thing it's being matched against has properly-matched
  5568. curly braces.
  5569.  
  5570. Of note is the definition of the $balanced_brace_re global via ||=, which
  5571. speeds things up by only creating the qr//'ed expression once; if it's 
  5572. already defined, we don't try to define it again. A speed hack.
  5573.  
  5574. =cut
  5575.  
  5576. sub unbalanced {
  5577.  
  5578.     # I hate using globals!
  5579.     $balanced_brace_re ||= qr{ 
  5580.         ^ \{
  5581.              (?:
  5582.                  (?> [^{}] + )              # Non-parens without backtracking
  5583.                 |
  5584.                  (??{ $balanced_brace_re }) # Group with matching parens
  5585.               ) *
  5586.           \} $
  5587.    }x;
  5588.     return $_[0] !~ m/$balanced_brace_re/;
  5589. } ## end sub unbalanced
  5590.  
  5591. =head2 C<gets()>
  5592.  
  5593. C<gets()> is a primitive (very primitive) routine to read continuations.
  5594. It was devised for reading continuations for actions.
  5595. it just reads more input with X<C<readline()>> and returns it.
  5596.  
  5597. =cut
  5598.  
  5599. sub gets {
  5600.     &readline("cont: ");
  5601. }
  5602.  
  5603. =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
  5604.  
  5605. The C<system()> function assumes that it can just go ahead and use STDIN and
  5606. STDOUT, but under the debugger, we want it to use the debugger's input and 
  5607. outout filehandles. 
  5608.  
  5609. C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
  5610. the debugger's IN and OUT filehandles for them. It does the C<system()> call,
  5611. and then puts everything back again.
  5612.  
  5613. =cut
  5614.  
  5615. sub system {
  5616.  
  5617.     # We save, change, then restore STDIN and STDOUT to avoid fork() since
  5618.     # some non-Unix systems can do system() but have problems with fork().
  5619.     open(SAVEIN,  "<&STDIN")  || &warn("Can't save STDIN");
  5620.     open(SAVEOUT, ">&STDOUT") || &warn("Can't save STDOUT");
  5621.     open(STDIN,   "<&IN")     || &warn("Can't redirect STDIN");
  5622.     open(STDOUT,  ">&OUT")    || &warn("Can't redirect STDOUT");
  5623.  
  5624.     # XXX: using csh or tcsh destroys sigint retvals!
  5625.     system(@_);
  5626.     open(STDIN,  "<&SAVEIN")  || &warn("Can't restore STDIN");
  5627.     open(STDOUT, ">&SAVEOUT") || &warn("Can't restore STDOUT");
  5628.     close(SAVEIN);
  5629.     close(SAVEOUT);
  5630.  
  5631.     # most of the $? crud was coping with broken cshisms
  5632.     if ($? >> 8) {
  5633.         &warn("(Command exited ", ($? >> 8), ")\n");
  5634.     }
  5635.     elsif ($?) {
  5636.         &warn(
  5637.             "(Command died of SIG#",
  5638.             ($? & 127),
  5639.             (($? & 128) ? " -- core dumped" : ""),
  5640.             ")", "\n"
  5641.             );
  5642.     } ## end elsif ($?)
  5643.  
  5644.     return $?;
  5645.  
  5646. } ## end sub system
  5647.  
  5648. =head1 TTY MANAGEMENT
  5649.  
  5650. The subs here do some of the terminal management for multiple debuggers.
  5651.  
  5652. =head2 setterm
  5653.  
  5654. Top-level function called when we want to set up a new terminal for use
  5655. by the debugger.
  5656.  
  5657. If the C<noTTY> debugger option was set, we'll either use the terminal
  5658. supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
  5659. to find one. If we're a forked debugger, we call C<resetterm> to try to 
  5660. get a whole new terminal if we can. 
  5661.  
  5662. In either case, we set up the terminal next. If the C<ReadLine> option was
  5663. true, we'll get a C<Term::ReadLine> object for the current terminal and save
  5664. the appropriate attributes. We then 
  5665.  
  5666. =cut
  5667.  
  5668. sub setterm {
  5669.     # Load Term::Readline, but quietly; don't debug it and don't trace it.
  5670.     local $frame = 0;
  5671.     local $doret = -2;
  5672.     eval { require Term::ReadLine } or die $@;
  5673.  
  5674.     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
  5675.     if ($notty) {
  5676.         if ($tty) {
  5677.             my ($i, $o) = split $tty, /,/;
  5678.             $o = $i unless defined $o;
  5679.             open(IN,  "<$i") or die "Cannot open TTY `$i' for read: $!";
  5680.             open(OUT, ">$o") or die "Cannot open TTY `$o' for write: $!";
  5681.             $IN  = \*IN;
  5682.             $OUT = \*OUT;
  5683.             my $sel = select($OUT);
  5684.             $| = 1;
  5685.             select($sel);
  5686.         } ## end if ($tty)
  5687.  
  5688.         # We don't have a TTY - try to find one via Term::Rendezvous.
  5689.         else {
  5690.             eval "require Term::Rendezvous;" or die;
  5691.             # See if we have anything to pass to Term::Rendezvous.
  5692.             # Use /tmp/perldbtty$$ if not.
  5693.             my $rv = $ENV{PERLDB_NOTTY} || "/tmp/perldbtty$$";
  5694.  
  5695.             # Rendezvous and get the filehandles.
  5696.             my $term_rv = new Term::Rendezvous $rv;
  5697.             $IN  = $term_rv->IN;
  5698.             $OUT = $term_rv->OUT;
  5699.         } ## end else [ if ($tty)
  5700.     } ## end if ($notty)
  5701.  
  5702.  
  5703.     # We're a daughter debugger. Try to fork off another TTY.
  5704.     if ($term_pid eq '-1') {    # In a TTY with another debugger
  5705.         resetterm(2);
  5706.     }
  5707.  
  5708.     # If we shouldn't use Term::ReadLine, don't.
  5709.     if (!$rl) {
  5710.         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
  5711.     }
  5712.  
  5713.     # We're using Term::ReadLine. Get all the attributes for this terminal.
  5714.     else {
  5715.         $term = new Term::ReadLine 'perldb', $IN, $OUT;
  5716.  
  5717.         $rl_attribs = $term->Attribs;
  5718.         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
  5719.           if defined $rl_attribs->{basic_word_break_characters}
  5720.           and index($rl_attribs->{basic_word_break_characters}, ":") == -1;
  5721.         $rl_attribs->{special_prefixes} = '$@&%';
  5722.         $rl_attribs->{completer_word_break_characters} .= '$@&%';
  5723.         $rl_attribs->{completion_function} = \&db_complete;
  5724.     } ## end else [ if (!$rl)
  5725.  
  5726.     # Set up the LINEINFO filehandle.
  5727.     $LINEINFO = $OUT     unless defined $LINEINFO;
  5728.     $lineinfo = $console unless defined $lineinfo;
  5729.  
  5730.     $term->MinLine(2);
  5731.  
  5732.     if ($term->Features->{setHistory} and "@hist" ne "?") {
  5733.         $term->SetHistory(@hist);
  5734.     }
  5735.  
  5736.     # XXX Ornaments are turned on unconditionally, which is not
  5737.     # always a good thing.
  5738.     ornaments($ornaments) if defined $ornaments;
  5739.     $term_pid = $$;
  5740. } ## end sub setterm
  5741.  
  5742. =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
  5743.  
  5744. When the process being debugged forks, or the process invokes a command
  5745. via C<system()> which starts a new debugger, we need to be able to get a new
  5746. C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
  5747. fight over the terminal, and you can never quite be sure who's going to get the
  5748. input you're typing.
  5749.  
  5750. C<get_fork_TTY> is a glob-aliased function which calls the real function that 
  5751. is tasked with doing all the necessary operating system mojo to get a new 
  5752. TTY (and probably another window) and to direct the new debugger to read and
  5753. write there.
  5754.  
  5755. The debugger provides C<get_fork_TTY> functions which work for X Windows and
  5756. OS/2. Other systems are not supported. You are encouraged to write 
  5757. C<get_fork_TTY> functions which work for I<your> platform and contribute them.
  5758.  
  5759. =head3 C<xterm_get_fork_TTY>
  5760.  
  5761. This function provides the C<get_fork_TTY> function for X windows. If a 
  5762. program running under the debugger forks, a new <xterm> window is opened and
  5763. the subsidiary debugger is directed there.
  5764.  
  5765. The C<open()> call is of particular note here. We have the new C<xterm>
  5766. we're spawning route file number 3 to STDOUT, and then execute the C<tty> 
  5767. command (which prints the device name of the TTY we'll want to use for input 
  5768. and output to STDOUT, then C<sleep> for a very long time, routing this output
  5769. to file number 3. This way we can simply read from the <XT> filehandle (which
  5770. is STDOUT from the I<commands> we ran) to get the TTY we want to use. 
  5771.  
  5772. Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are 
  5773. properly set up.
  5774.  
  5775. =cut
  5776.  
  5777. sub xterm_get_fork_TTY {
  5778.     (my $name = $0) =~ s,^.*[/\\],,s;
  5779.     open XT,
  5780. qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
  5781.  sleep 10000000' |];
  5782.  
  5783.     # Get the output from 'tty' and clean it up a little.
  5784.     my $tty = <XT>;
  5785.     chomp $tty;
  5786.  
  5787.     $pidprompt = '';    # Shown anyway in titlebar
  5788.  
  5789.     # There's our new TTY.
  5790.     return $tty;
  5791. } ## end sub xterm_get_fork_TTY
  5792.  
  5793. =head3 C<os2_get_fork_TTY>
  5794.  
  5795. XXX It behooves an OS/2 expert to write the necessary documentation for this!
  5796.  
  5797. =cut
  5798.  
  5799. # This example function resets $IN, $OUT itself
  5800. sub os2_get_fork_TTY {
  5801.     local $^F = 40;     # XXXX Fixme!
  5802.     local $\  = '';
  5803.     my ($in1, $out1, $in2, $out2);
  5804.  
  5805.     # Having -d in PERL5OPT would lead to a disaster...
  5806.     local $ENV{PERL5OPT} = $ENV{PERL5OPT} if $ENV{PERL5OPT};
  5807.     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\b//  if $ENV{PERL5OPT};
  5808.     $ENV{PERL5OPT} =~ s/(?:^|(?<=\s))-d\B/-/ if $ENV{PERL5OPT};
  5809.     print $OUT "Making kid PERL5OPT->`$ENV{PERL5OPT}'.\n" if $ENV{PERL5OPT};
  5810.     local $ENV{PERL5LIB} = $ENV{PERL5LIB} ? $ENV{PERL5LIB} : $ENV{PERLLIB};
  5811.     $ENV{PERL5LIB} = '' unless defined $ENV{PERL5LIB};
  5812.     $ENV{PERL5LIB} = join ';', @ini_INC, split /;/, $ENV{PERL5LIB};
  5813.     (my $name = $0) =~ s,^.*[/\\],,s;
  5814.     my @args;
  5815.  
  5816.     if (
  5817.             pipe $in1, $out1
  5818.         and pipe $in2, $out2
  5819.  
  5820.         # system P_SESSION will fail if there is another process
  5821.         # in the same session with a "dependent" asynchronous child session.
  5822.         and @args = (
  5823.             $rl, fileno $in1, fileno $out2,
  5824.             "Daughter Perl debugger $pids $name"
  5825.         )
  5826.         and (
  5827.             ($kpid = CORE::system 4, $^X, '-we',
  5828.                 <<'ES', @args) >= 0    # P_SESSION
  5829. END {sleep 5 unless $loaded}
  5830. BEGIN {open STDIN,  '</dev/con' or warn "reopen stdin: $!"}
  5831. use OS2::Process;
  5832.  
  5833. my ($rl, $in) = (shift, shift);        # Read from $in and pass through
  5834. set_title pop;
  5835. system P_NOWAIT, $^X, '-we', <<EOS or die "Cannot start a grandkid";
  5836.   open IN, '<&=$in' or die "open <&=$in: \$!";
  5837.   \$| = 1; print while sysread IN, \$_, 1<<16;
  5838. EOS
  5839.  
  5840. my $out = shift;
  5841. open OUT, ">&=$out" or die "Cannot open &=$out for writing: $!";
  5842. select OUT;    $| = 1;
  5843. require Term::ReadKey if $rl;
  5844. Term::ReadKey::ReadMode(4) if $rl; # Nodelay on kbd.  Pipe is automatically nodelay...
  5845. print while sysread STDIN, $_, 1<<($rl ? 16 : 0);
  5846. ES
  5847.             or warn "system P_SESSION: $!, $^E" and 0
  5848.         )
  5849.         and close $in1
  5850.         and close $out2
  5851.       )
  5852.     {
  5853.         $pidprompt = '';    # Shown anyway in titlebar
  5854.         reset_IN_OUT($in2, $out1);
  5855.         $tty = '*reset*';
  5856.         return '';          # Indicate that reset_IN_OUT is called
  5857.     } ## end if (pipe $in1, $out1 and...
  5858.     return;
  5859. } ## end sub os2_get_fork_TTY
  5860.  
  5861. =head2 C<create_IN_OUT($flags)>
  5862.  
  5863. Create a new pair of filehandles, pointing to a new TTY. If impossible,
  5864. try to diagnose why.
  5865.  
  5866. Flags are:
  5867.  
  5868. =over 4
  5869.  
  5870. =item * 1 - Don't know how to create a new TTY.
  5871.  
  5872. =item * 2 - Debugger has forked, but we can't get a new TTY.
  5873.  
  5874. =item * 4 - standard debugger startup is happening.
  5875.  
  5876. =back
  5877.  
  5878. =cut
  5879.  
  5880. sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
  5881.  
  5882.     # If we know how to get a new TTY, do it! $in will have
  5883.     # the TTY name if get_fork_TTY works.
  5884.     my $in = &get_fork_TTY if defined &get_fork_TTY;
  5885.  
  5886.     # It used to be that 
  5887.     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
  5888.  
  5889.     if (not defined $in) {
  5890.         my $why = shift;
  5891.  
  5892.         # We don't know how.
  5893.         print_help(<<EOP) if $why == 1;
  5894. I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
  5895. EOP
  5896.  
  5897.         # Forked debugger.
  5898.         print_help(<<EOP) if $why == 2;
  5899. I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
  5900.   This may be an asynchronous session, so the parent debugger may be active.
  5901. EOP
  5902.  
  5903.         # Note that both debuggers are fighting over the same input.
  5904.         print_help(<<EOP) if $why != 4;
  5905.   Since two debuggers fight for the same TTY, input is severely entangled.
  5906.  
  5907. EOP
  5908.         print_help(<<EOP);
  5909.   I know how to switch the output to a different window in xterms
  5910.   and OS/2 consoles only.  For a manual switch, put the name of the created I<TTY>
  5911.   in B<\$DB::fork_TTY>, or define a function B<DB::get_fork_TTY()> returning this.
  5912.  
  5913.   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
  5914.   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
  5915.  
  5916. EOP
  5917.     } ## end if (not defined $in)
  5918.     elsif ($in ne '') {
  5919.         TTY($in);
  5920.     }
  5921.     else {
  5922.         $console = '';    # Indicate no need to open-from-the-console
  5923.     }
  5924.     undef $fork_TTY;
  5925. } ## end sub create_IN_OUT
  5926.  
  5927. =head2 C<resetterm>
  5928.  
  5929. Handles rejiggering the prompt when we've forked off a new debugger.
  5930.  
  5931. If the new debugger happened because of a C<system()> that invoked a 
  5932. program under the debugger, the arrow between the old pid and the new
  5933. in the prompt has I<two> dashes instead of one.
  5934.  
  5935. We take the current list of pids and add this one to the end. If there
  5936. isn't any list yet, we make one up out of the initial pid associated with 
  5937. the terminal and our new pid, sticking an arrow (either one-dashed or 
  5938. two dashed) in between them.
  5939.  
  5940. If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
  5941. we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
  5942. and try to do that.
  5943.  
  5944. =cut
  5945.  
  5946. sub resetterm {           # We forked, so we need a different TTY
  5947.  
  5948.     # Needs to be passed to create_IN_OUT() as well.
  5949.     my $in = shift;
  5950.  
  5951.     # resetterm(2): got in here because of a system() starting a debugger.
  5952.     # resetterm(1): just forked.
  5953.     my $systemed = $in > 1 ? '-' : '';
  5954.  
  5955.     # If there's already a list of pids, add this to the end.
  5956.     if ($pids) {
  5957.         $pids =~ s/\]/$systemed->$$]/;
  5958.     }
  5959.  
  5960.     # No pid list. Time to make one.
  5961.     else {
  5962.         $pids = "[$term_pid->$$]";
  5963.     }
  5964.  
  5965.     # The prompt we're going to be using for this debugger.
  5966.     $pidprompt = $pids;
  5967.  
  5968.     # We now 0wnz this terminal.
  5969.     $term_pid  = $$;
  5970.  
  5971.     # Just return if we're not supposed to try to create a new TTY.
  5972.     return unless $CreateTTY & $in;
  5973.  
  5974.     # Try to create a new IN/OUT pair.
  5975.     create_IN_OUT($in);
  5976. } ## end sub resetterm
  5977.  
  5978. =head2 C<readline>
  5979.  
  5980. First, we handle stuff in the typeahead buffer. If there is any, we shift off
  5981. the next line, print a message saying we got it, add it to the terminal
  5982. history (if possible), and return it.
  5983.  
  5984. If there's nothing in the typeahead buffer, check the command filehandle stack.
  5985. If there are any filehandles there, read from the last one, and return the line
  5986. if we got one. If not, we pop the filehandle off and close it, and try the
  5987. next one up the stack.
  5988.  
  5989. If we've emptied the filehandle stack, we check to see if we've got a socket 
  5990. open, and we read that and return it if we do. If we don't, we just call the 
  5991. core C<readline()> and return its value.
  5992.  
  5993. =cut
  5994.  
  5995. sub readline {
  5996.  
  5997.     # Localize to prevent it from being smashed in the program being debugged.
  5998.     local $.;
  5999.  
  6000.     # Pull a line out of the typeahead if there's stuff there.
  6001.     if (@typeahead) {
  6002.         # How many lines left.
  6003.         my $left = @typeahead;
  6004.  
  6005.         # Get the next line.
  6006.         my $got  = shift @typeahead;
  6007.  
  6008.         # Print a message saying we got input from the typeahead.
  6009.         local $\ = '';
  6010.         print $OUT "auto(-$left)", shift, $got, "\n";
  6011.  
  6012.         # Add it to the terminal history (if possible).
  6013.         $term->AddHistory($got)
  6014.           if length($got) > 1
  6015.           and defined $term->Features->{addHistory};
  6016.         return $got;
  6017.     } ## end if (@typeahead)
  6018.  
  6019.     # We really need to read some input. Turn off entry/exit trace and 
  6020.     # return value printing.
  6021.     local $frame = 0;
  6022.     local $doret = -2;
  6023.  
  6024.     # If there are stacked filehandles to read from ...
  6025.     while (@cmdfhs) {
  6026.         # Read from the last one in the stack.
  6027.         my $line = CORE::readline($cmdfhs[-1]);
  6028.         # If we got a line ...
  6029.         defined $line
  6030.           ? (print $OUT ">> $line" and return $line)  # Echo and return
  6031.           : close pop @cmdfhs;                        # Pop and close
  6032.     } ## end while (@cmdfhs)
  6033.  
  6034.     # Nothing on the filehandle stack. Socket?
  6035.     if (ref $OUT and UNIVERSAL::isa($OUT, 'IO::Socket::INET')) {
  6036.         # Send anyting we have to send.
  6037.         $OUT->write(join ('', @_));
  6038.  
  6039.         # Receive anything there is to receive.
  6040.         my $stuff;
  6041.         $IN->recv($stuff, 2048);    # XXX "what's wrong with sysread?"
  6042.                                     # XXX Don't know. You tell me.
  6043.  
  6044.         # What we got.
  6045.         $stuff;
  6046.     } ## end if (ref $OUT and UNIVERSAL::isa...
  6047.  
  6048.     # No socket. Just read from the terminal.
  6049.     else {
  6050.         $term->readline(@_);
  6051.     }
  6052. } ## end sub readline
  6053.  
  6054. =head1 OPTIONS SUPPORT ROUTINES
  6055.  
  6056. These routines handle listing and setting option values.
  6057.  
  6058. =head2 C<dump_option> - list the current value of an option setting
  6059.  
  6060. This routine uses C<option_val> to look up the value for an option.
  6061. It cleans up escaped single-quotes and then displays the option and
  6062. its value.
  6063.  
  6064. =cut
  6065.  
  6066. sub dump_option {
  6067.     my ($opt, $val) = @_;
  6068.     $val = option_val($opt, 'N/A');
  6069.     $val =~ s/([\\\'])/\\$1/g;
  6070.     printf $OUT "%20s = '%s'\n", $opt, $val;
  6071. } ## end sub dump_option
  6072.  
  6073. =head2 C<option_val> - find the current value of an option
  6074.  
  6075. This can't just be a simple hash lookup because of the indirect way that
  6076. the option values are stored. Some are retrieved by calling a subroutine,
  6077. some are just variables.
  6078.  
  6079. You must supply a default value to be used in case the option isn't set.
  6080.  
  6081. =cut
  6082.  
  6083. sub option_val {
  6084.     my ($opt, $default) = @_;
  6085.     my $val;
  6086.  
  6087.     # Does this option exist, and is it a variable?
  6088.     # If so, retrieve the value via the value in %optionVars.
  6089.     if (    defined $optionVars{$opt}
  6090.         and defined ${ $optionVars{$opt} }) {
  6091.         $val = ${ $optionVars{$opt} };
  6092.     }
  6093.  
  6094.     # Does this option exist, and it's a subroutine?
  6095.     # If so, call the subroutine via the ref in %optionAction
  6096.     # and capture the value.
  6097.     elsif ( defined $optionAction{$opt}
  6098.         and defined &{ $optionAction{$opt} }) {
  6099.         $val = &{ $optionAction{$opt} }();
  6100.     }
  6101.  
  6102.     # If there's an action or variable for the supplied option,
  6103.     # but no value was set, use the default.
  6104.     elsif (defined $optionAction{$opt} and not defined $option{$opt}
  6105.         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} })
  6106.     {
  6107.         $val = $default;
  6108.     }
  6109.  
  6110.     # Otherwise, do the simple hash lookup.
  6111.     else {
  6112.         $val = $option{$opt};
  6113.     }
  6114.  
  6115.     # If the value isn't defined, use the default.
  6116.     # Then return whatever the value is.
  6117.     $val = $default unless defined $val;
  6118.     $val;
  6119. } ## end sub option_val
  6120.  
  6121. =head2 C<parse_options>
  6122.  
  6123. Handles the parsing and execution of option setting/displaying commands.
  6124.  
  6125. An option entered by itself is assumed to be 'set me to 1' (the default value)
  6126. if the option is a boolean one. If not, the user is prompted to enter a valid
  6127. value or to query the current value (via 'option? ').
  6128.  
  6129. If 'option=value' is entered, we try to extract a quoted string from the
  6130. value (if it is quoted). If it's not, we just use the whole value as-is.
  6131.  
  6132. We load any modules required to service this option, and then we set it: if
  6133. it just gets stuck in a variable, we do that; if there's a subroutine to 
  6134. handle setting the option, we call that.
  6135.  
  6136. Finally, if we're running in interactive mode, we display the effect of the
  6137. user's command back to the terminal, skipping this if we're setting things
  6138. during initialization.
  6139.  
  6140. =cut
  6141.  
  6142. sub parse_options {
  6143.     local ($_) = @_;
  6144.     local $\ = '';
  6145.  
  6146.     # These options need a value. Don't allow them to be clobbered by accident.
  6147.     my %opt_needs_val = map { ($_ => 1) } qw{
  6148.       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
  6149.       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
  6150.       };
  6151.  
  6152.     while (length) {
  6153.         my $val_defaulted;
  6154.  
  6155.         # Clean off excess leading whitespace.
  6156.         s/^\s+// && next;
  6157.  
  6158.         # Options are always all word characters, followed by a non-word
  6159.         # separator.
  6160.         s/^(\w+)(\W?)// or print($OUT "Invalid option `$_'\n"), last;
  6161.         my ($opt, $sep) = ($1, $2);
  6162.  
  6163.         # Make sure that such an option exists.
  6164.         my $matches = grep(/^\Q$opt/ && ($option = $_), @options) ||
  6165.           grep(/^\Q$opt/i && ($option = $_), @options);
  6166.  
  6167.         print($OUT "Unknown option `$opt'\n"), next unless $matches;
  6168.         print($OUT "Ambiguous option `$opt'\n"), next if $matches > 1;
  6169.  
  6170.         my $val;
  6171.  
  6172.         # '?' as separator means query, but must have whitespace after it.
  6173.         if ("?" eq $sep) {
  6174.             print($OUT "Option query `$opt?' followed by non-space `$_'\n"),
  6175.               last
  6176.               if /^\S/;
  6177.  
  6178.             #&dump_option($opt);
  6179.         } ## end if ("?" eq $sep)
  6180.  
  6181.         # Separator is whitespace (or just a carriage return).
  6182.         # They're going for a default, which we assume is 1.
  6183.         elsif ($sep !~ /\S/) {
  6184.             $val_defaulted = 1;
  6185.             $val           = "1"; #  this is an evil default; make 'em set it!
  6186.         }
  6187.  
  6188.         # Separator is =. Trying to set a value.
  6189.         elsif ($sep eq "=") {
  6190.             # If quoted, extract a quoted string.
  6191.             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
  6192.                 my $quote = $1;
  6193.                 ($val = $2) =~ s/\\([$quote\\])/$1/g;
  6194.             }
  6195.  
  6196.             # Not quoted. Use the whole thing. Warn about 'option='.
  6197.             else {
  6198.                 s/^(\S*)//;
  6199.                 $val = $1;
  6200.                 print OUT qq(Option better cleared using $opt=""\n)
  6201.                   unless length $val;
  6202.             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
  6203.  
  6204.         } ## end elsif ($sep eq "=")
  6205.  
  6206.         # "Quoted" with [], <>, or {}.  
  6207.         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
  6208.             my ($end) = "\\" . substr(")]>}$sep", index("([<{", $sep), 1);  #}
  6209.             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
  6210.               or print($OUT "Unclosed option value `$opt$sep$_'\n"), last;
  6211.             ($val = $1) =~ s/\\([\\$end])/$1/g;
  6212.         } ## end else [ if ("?" eq $sep)
  6213.  
  6214.         # Impedance-match the code above to the code below.
  6215.         my $option = $opt;
  6216.  
  6217.         # Exclude non-booleans from getting set to 1 by default.
  6218.         if ($opt_needs_val{$option} && $val_defaulted) {
  6219.             my $cmd = ($CommandSet eq '580') ? 'o' : 'O';
  6220.             print $OUT
  6221. "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
  6222.             next;
  6223.         } ## end if ($opt_needs_val{$option...
  6224.  
  6225.         # Save the option value.
  6226.         $option{$option} = $val if defined $val;
  6227.  
  6228.         # Load any module that this option requires.
  6229.         eval qq{
  6230.                 local \$frame = 0; 
  6231.                 local \$doret = -2; 
  6232.                 require '$optionRequire{$option}';
  6233.                 1;
  6234.                } || die    # XXX: shouldn't happen
  6235.           if defined $optionRequire{$option} &&
  6236.              defined $val;
  6237.  
  6238.         # Set it. 
  6239.         # Stick it in the proper variable if it goes in a variable.
  6240.         ${ $optionVars{$option} } = $val
  6241.           if defined $optionVars{$option} &&
  6242.           defined $val;
  6243.  
  6244.         # Call the appropriate sub if it gets set via sub.
  6245.         &{ $optionAction{$option} }($val)
  6246.           if defined $optionAction{$option} &&
  6247.           defined &{ $optionAction{$option} } &&
  6248.           defined $val;
  6249.  
  6250.         # Not initialization - echo the value we set it to.
  6251.         dump_option($option) unless $OUT eq \*STDERR;
  6252.     } ## end while (length)
  6253. } ## end sub parse_options
  6254.  
  6255. =head1 RESTART SUPPORT
  6256.  
  6257. These routines are used to store (and restore) lists of items in environment 
  6258. variables during a restart.
  6259.  
  6260. =head2 set_list
  6261.  
  6262. Set_list packages up items to be stored in a set of environment variables
  6263. (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
  6264. the values). Values outside the standard ASCII charset are stored by encoding
  6265. then as hexadecimal values.
  6266.  
  6267. =cut
  6268.  
  6269. sub set_list {
  6270.     my ($stem, @list) = @_;
  6271.     my $val;
  6272.  
  6273.     # VAR_n: how many we have. Scalar assignment gets the number of items.
  6274.     $ENV{"${stem}_n"} = @list;
  6275.  
  6276.     # Grab each item in the list, escape the backslashes, encode the non-ASCII
  6277.     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
  6278.     for $i (0 .. $#list) {
  6279.         $val = $list[$i];
  6280.         $val =~ s/\\/\\\\/g;
  6281.         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
  6282.         $ENV{"${stem}_$i"} = $val;
  6283.     } ## end for $i (0 .. $#list)
  6284. } ## end sub set_list
  6285.  
  6286. =head2 get_list
  6287.  
  6288. Reverse the set_list operation: grab VAR_n to see how many we should be getting
  6289. back, and then pull VAR_0, VAR_1. etc. back out.
  6290.  
  6291. =cut 
  6292.  
  6293. sub get_list {
  6294.     my $stem = shift;
  6295.     my @list;
  6296.     my $n = delete $ENV{"${stem}_n"};
  6297.     my $val;
  6298.     for $i (0 .. $n - 1) {
  6299.         $val = delete $ENV{"${stem}_$i"};
  6300.         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
  6301.         push @list, $val;
  6302.     }
  6303.     @list;
  6304. } ## end sub get_list
  6305.  
  6306. =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
  6307.  
  6308. =head2 catch()
  6309.  
  6310. The C<catch()> subroutine is the essence of fast and low-impact. We simply
  6311. set an already-existing global scalar variable to a constant value. This 
  6312. avoids allocating any memory possibly in the middle of something that will
  6313. get all confused if we do.
  6314.  
  6315. =cut
  6316.  
  6317. sub catch {
  6318.     $signal = 1;
  6319.     return;    # Put nothing on the stack - malloc/free land!
  6320. }
  6321.  
  6322. =head2 C<warn()>
  6323.  
  6324. C<warn> emits a warning, by joining together its arguments and printing
  6325. them, with couple of fillips.
  6326.  
  6327. If the composited message I<doesn't> end with a newline, we automatically 
  6328. add C<$!> and a newline to the end of the message. The subroutine expects $OUT 
  6329. to be set to the filehandle to be used to output warnings; it makes no 
  6330. assumptions about what filehandles are available.
  6331.  
  6332. =cut
  6333.  
  6334. sub warn {
  6335.     my ($msg) = join ("", @_);
  6336.     $msg .= ": $!\n" unless $msg =~ /\n$/;
  6337.     local $\ = '';
  6338.     print $OUT $msg;
  6339. } ## end sub warn
  6340.  
  6341. =head1 INITIALIZATION TTY SUPPORT
  6342.  
  6343. =head2 C<reset_IN_OUT>
  6344.  
  6345. This routine handles restoring the debugger's input and output filehandles
  6346. after we've tried and failed to move them elsewhere.  In addition, it assigns 
  6347. the debugger's output filehandle to $LINEINFO if it was already open there.
  6348.  
  6349. =cut
  6350.  
  6351. sub reset_IN_OUT {
  6352.     my $switch_li = $LINEINFO eq $OUT;
  6353.  
  6354.     # If there's a term and it's able to get a new tty, try to get one.
  6355.     if ($term and $term->Features->{newTTY}) {
  6356.         ($IN, $OUT) = (shift, shift);
  6357.         $term->newTTY($IN, $OUT);
  6358.     }
  6359.  
  6360.     # This term can't get a new tty now. Better luck later.
  6361.     elsif ($term) {
  6362.         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
  6363.     }
  6364.  
  6365.     # Set the filehndles up as they were.
  6366.     else {
  6367.         ($IN, $OUT) = (shift, shift);
  6368.     }
  6369.  
  6370.     # Unbuffer the output filehandle.
  6371.     my $o = select $OUT;
  6372.     $| = 1;
  6373.     select $o;
  6374.  
  6375.     # Point LINEINFO to the same output filehandle if it was there before.
  6376.     $LINEINFO = $OUT if $switch_li;
  6377. } ## end sub reset_IN_OUT
  6378.  
  6379. =head1 OPTION SUPPORT ROUTINES
  6380.  
  6381. The following routines are used to process some of the more complicated 
  6382. debugger options.
  6383.  
  6384. =head2 C<TTY>
  6385.  
  6386. Sets the input and output filehandles to the specified files or pipes.
  6387. If the terminal supports switching, we go ahead and do it. If not, and
  6388. there's already a terminal in place, we save the information to take effect
  6389. on restart.
  6390.  
  6391. If there's no terminal yet (for instance, during debugger initialization),
  6392. we go ahead and set C<$console> and C<$tty> to the file indicated.
  6393.  
  6394. =cut
  6395.  
  6396. sub TTY {
  6397.     if (@_ and $term and $term->Features->{newTTY}) {
  6398.         # This terminal supports switching to a new TTY.
  6399.         # Can be a list of two files, or on string containing both names,
  6400.         # comma-separated.
  6401.         # XXX Should this perhaps be an assignment from @_?
  6402.         my ($in, $out) = shift; 
  6403.         if ($in =~ /,/) {
  6404.             # Split list apart if supplied.
  6405.             ($in, $out) = split /,/, $in, 2;
  6406.         }
  6407.         else {
  6408.             # Use the same file for both input and output.
  6409.             $out = $in;
  6410.         }
  6411.  
  6412.         # Open file onto the debugger's filehandles, if you can.
  6413.         open IN, $in or die "cannot open `$in' for read: $!";
  6414.         open OUT, ">$out" or die "cannot open `$out' for write: $!";
  6415.  
  6416.         # Swap to the new filehandles.
  6417.         reset_IN_OUT(\*IN, \*OUT);
  6418.  
  6419.         # Save the setting for later.
  6420.         return $tty = $in;
  6421.     } ## end if (@_ and $term and $term...
  6422.  
  6423.     # Terminal doesn't support new TTY, or doesn't support readline.
  6424.     # Can't do it now, try restarting.
  6425.     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
  6426.     
  6427.     # Useful if done through PERLDB_OPTS:
  6428.     $console = $tty = shift if @_;
  6429.  
  6430.     # Return whatever the TTY is.
  6431.     $tty or $console;
  6432. } ## end sub TTY
  6433.  
  6434. =head2 C<noTTY>
  6435.  
  6436. Sets the C<$notty> global, controlling whether or not the debugger tries to
  6437. get a terminal to read from. If called after a terminal is already in place,
  6438. we save the value to use it if we're restarted.
  6439.  
  6440. =cut
  6441.  
  6442. sub noTTY {
  6443.     if ($term) {
  6444.         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
  6445.     }
  6446.     $notty = shift if @_;
  6447.     $notty;
  6448. } ## end sub noTTY
  6449.  
  6450. =head2 C<ReadLine>
  6451.  
  6452. Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub> 
  6453. (essentially, no C<readline> processing on this "terminal"). Otherwise, we
  6454. use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
  6455. the value in case a restart is done so we can change it then.
  6456.  
  6457. =cut
  6458.  
  6459. sub ReadLine {
  6460.     if ($term) {
  6461.         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
  6462.     }
  6463.     $rl = shift if @_;
  6464.     $rl;
  6465. } ## end sub ReadLine
  6466.  
  6467. =head2 C<RemotePort>
  6468.  
  6469. Sets the port that the debugger will try to connect to when starting up.
  6470. If the terminal's already been set up, we can't do it, but we remember the
  6471. setting in case the user does a restart.
  6472.  
  6473. =cut
  6474.  
  6475. sub RemotePort {
  6476.     if ($term) {
  6477.         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
  6478.     }
  6479.     $remoteport = shift if @_;
  6480.     $remoteport;
  6481. } ## end sub RemotePort
  6482.  
  6483. =head2 C<tkRunning>
  6484.  
  6485. Checks with the terminal to see if C<Tk> is running, and returns true or
  6486. false. Returns false if the current terminal doesn't support C<readline>.
  6487.  
  6488. =cut
  6489.  
  6490. sub tkRunning {
  6491.     if (${ $term->Features }{tkRunning}) {
  6492.         return $term->tkRunning(@_);
  6493.     }
  6494.     else {
  6495.         local $\ = '';
  6496.         print $OUT "tkRunning not supported by current ReadLine package.\n";
  6497.         0;
  6498.     }
  6499. } ## end sub tkRunning
  6500.  
  6501. =head2 C<NonStop>
  6502.  
  6503. Sets nonstop mode. If a terminal's already been set up, it's too late; the
  6504. debugger remembers the setting in case you restart, though.
  6505.  
  6506. =cut
  6507.  
  6508. sub NonStop {
  6509.     if ($term) {
  6510.         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
  6511.           if @_;
  6512.     }
  6513.     $runnonstop = shift if @_;
  6514.     $runnonstop;
  6515. } ## end sub NonStop
  6516.  
  6517. =head2 C<pager>
  6518.  
  6519. Set up the C<$pager> variable. Adds a pipe to the front unless there's one
  6520. there already.
  6521.  
  6522. =cut
  6523.  
  6524. sub pager {
  6525.     if (@_) {
  6526.         $pager = shift;
  6527.         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
  6528.     }
  6529.     $pager;
  6530. } ## end sub pager
  6531.  
  6532. =head2 C<shellBang>
  6533.  
  6534. Sets the shell escape command, and generates a printable copy to be used 
  6535. in the help.
  6536.  
  6537. =cut
  6538.  
  6539. sub shellBang {
  6540.  
  6541.     # If we got an argument, meta-quote it, and add '\b' if it
  6542.     # ends in a word character.
  6543.     if (@_) {
  6544.         $sh = quotemeta shift;
  6545.         $sh .= "\\b" if $sh =~ /\w$/;
  6546.     }
  6547.  
  6548.     # Generate the printable version for the help:
  6549.     $psh = $sh;                       # copy it
  6550.     $psh =~ s/\\b$//;                 # Take off trailing \b if any
  6551.     $psh =~ s/\\(.)/$1/g;             # De-escape
  6552.     $psh;                             # return the printable version
  6553. } ## end sub shellBang
  6554.  
  6555. =head2 C<ornaments>
  6556.  
  6557. If the terminal has its own ornaments, fetch them. Otherwise accept whatever
  6558. was passed as the argument. (This means you can't override the terminal's
  6559. ornaments.)
  6560.  
  6561. =cut 
  6562.  
  6563. sub ornaments {
  6564.     if (defined $term) {
  6565.         # We don't want to show warning backtraces, but we do want die() ones.
  6566.         local ($warnLevel, $dieLevel) = (0, 1);
  6567.  
  6568.         # No ornaments if the terminal doesn't support them.
  6569.         return '' unless $term->Features->{ornaments};
  6570.         eval { $term->ornaments(@_) } || '';
  6571.     }
  6572.  
  6573.     # Use what was passed in if we can't determine it ourselves.
  6574.     else {
  6575.         $ornaments = shift;
  6576.     }
  6577. } ## end sub ornaments
  6578.  
  6579. =head2 C<recallCommand>
  6580.  
  6581. Sets the recall command, and builds a printable version which will appear in
  6582. the help text.
  6583.  
  6584. =cut
  6585.  
  6586. sub recallCommand {
  6587.  
  6588.     # If there is input, metaquote it. Add '\b' if it ends with a word
  6589.     # character.
  6590.     if (@_) {
  6591.         $rc = quotemeta shift;
  6592.         $rc .= "\\b" if $rc =~ /\w$/;
  6593.     }
  6594.  
  6595.     # Build it into a printable version.
  6596.     $prc = $rc;                             # Copy it
  6597.     $prc =~ s/\\b$//;                       # Remove trailing \b
  6598.     $prc =~ s/\\(.)/$1/g;                   # Remove escapes
  6599.     $prc;                                   # Return the printable version
  6600. } ## end sub recallCommand
  6601.  
  6602. =head2 C<LineInfo> - where the line number information goes
  6603.  
  6604. Called with no arguments, returns the file or pipe that line info should go to.
  6605.  
  6606. Called with an argument (a file or a pipe), it opens that onto the 
  6607. C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the 
  6608. file or pipe again to the caller.
  6609.  
  6610. =cut
  6611.  
  6612. sub LineInfo {
  6613.     return $lineinfo unless @_;
  6614.     $lineinfo = shift;
  6615.  
  6616.     #  If this is a valid "thing to be opened for output", tack a 
  6617.     # '>' onto the front.
  6618.     my $stream = ($lineinfo =~ /^(\+?\>|\|)/) ? $lineinfo : ">$lineinfo";
  6619.  
  6620.     # If this is a pipe, the stream points to a slave editor.
  6621.     $slave_editor = ($stream =~ /^\|/);
  6622.  
  6623.     # Open it up and unbuffer it.
  6624.     open(LINEINFO, "$stream") || &warn("Cannot open `$stream' for write");
  6625.     $LINEINFO = \*LINEINFO;
  6626.     my $save = select($LINEINFO);
  6627.     $| = 1;
  6628.     select($save);
  6629.  
  6630.     # Hand the file or pipe back again.
  6631.     $lineinfo;
  6632. } ## end sub LineInfo
  6633.  
  6634. =head1 COMMAND SUPPORT ROUTINES
  6635.  
  6636. These subroutines provide functionality for various commands.
  6637.  
  6638. =head2 C<list_modules>
  6639.  
  6640. For the C<M> command: list modules loaded and their versions.
  6641. Essentially just runs through the keys in %INC, picks up the 
  6642. $VERSION package globals from each package, gets the file name, and formats the
  6643. information for output.
  6644.  
  6645. =cut
  6646.  
  6647. sub list_modules {    # versions
  6648.     my %version;
  6649.     my $file;
  6650.     # keys are the "as-loaded" name, values are the fully-qualified path
  6651.     # to the file itself.
  6652.     for (keys %INC) {
  6653.         $file = $_;                                # get the module name
  6654.         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
  6655.         s,/,::,g;                                  # change '/' to '::'
  6656.         s/^perl5db$/DB/;                           # Special case: debugger
  6657.                                                    # moves to package DB
  6658.         s/^Term::ReadLine::readline$/readline/;    # simplify readline
  6659.  
  6660.         # If the package has a $VERSION package global (as all good packages
  6661.         # should!) decode it and save as partial message.
  6662.         if (defined ${ $_ . '::VERSION' }) {
  6663.             $version{$file} = "${ $_ . '::VERSION' } from ";
  6664.         }
  6665.  
  6666.         # Finish up the message with the file the package came from.
  6667.         $version{$file} .= $INC{$file};
  6668.     } ## end for (keys %INC)
  6669.  
  6670.     # Hey, dumpit() formats a hash nicely, so why not use it?
  6671.     dumpit($OUT, \%version);
  6672. } ## end sub list_modules
  6673.  
  6674. =head2 C<sethelp()>
  6675.  
  6676. Sets up the monster string used to format and print the help.
  6677.  
  6678. =head3 HELP MESSAGE FORMAT
  6679.  
  6680. The help message is a peculiar format unto itself; it mixes C<pod> 'ornaments'
  6681. (BE<lt>E<gt>, IE<gt>E<lt>) with tabs to come up with a format that's fairly
  6682. easy to parse and portable, but which still allows the help to be a little
  6683. nicer than just plain text.
  6684.  
  6685. Essentially, you define the command name (usually marked up with BE<gt>E<lt>
  6686. and IE<gt>E<lt>), followed by a tab, and then the descriptive text, ending in a newline. The descriptive text can also be marked up in the same way. If you 
  6687. need to continue the descriptive text to another line, start that line with 
  6688. just tabs and then enter the marked-up text.
  6689.  
  6690. If you are modifying the help text, I<be careful>. The help-string parser is 
  6691. not very sophisticated, and if you don't follow these rules it will mangle the 
  6692. help beyond hope until you fix the string.
  6693.  
  6694. =cut
  6695.  
  6696. sub sethelp {
  6697.  
  6698.     # XXX: make sure there are tabs between the command and explanation,
  6699.     #      or print_help will screw up your formatting if you have
  6700.     #      eeevil ornaments enabled.  This is an insane mess.
  6701.  
  6702.     $help = "
  6703. Help is currently only available for the new 5.8 command set. 
  6704. No help is available for the old command set. 
  6705. We assume you know what you're doing if you switch to it.
  6706.  
  6707. B<T>        Stack trace.
  6708. B<s> [I<expr>]    Single step [in I<expr>].
  6709. B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
  6710. <B<CR>>        Repeat last B<n> or B<s> command.
  6711. B<r>        Return from current subroutine.
  6712. B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
  6713.         at the specified position.
  6714. B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
  6715. B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
  6716. B<l> I<line>        List single I<line>.
  6717. B<l> I<subname>    List first window of lines from subroutine.
  6718. B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
  6719. B<l>        List next window of lines.
  6720. B<->        List previous window of lines.
  6721. B<v> [I<line>]    View window around I<line>.
  6722. B<.>        Return to the executed line.
  6723. B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
  6724.         I<filename> may be either the full name of the file, or a regular
  6725.         expression matching the full file name:
  6726.         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
  6727.         Evals (with saved bodies) are considered to be filenames:
  6728.         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
  6729.         (in the order of execution).
  6730. B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
  6731. B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
  6732. B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
  6733. B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
  6734. B<t>        Toggle trace mode.
  6735. B<t> I<expr>        Trace through execution of I<expr>.
  6736. B<b>        Sets breakpoint on current line)
  6737. B<b> [I<line>] [I<condition>]
  6738.         Set breakpoint; I<line> defaults to the current execution line;
  6739.         I<condition> breaks if it evaluates to true, defaults to '1'.
  6740. B<b> I<subname> [I<condition>]
  6741.         Set breakpoint at first line of subroutine.
  6742. B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
  6743. B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
  6744. B<b> B<postpone> I<subname> [I<condition>]
  6745.         Set breakpoint at first line of subroutine after 
  6746.         it is compiled.
  6747. B<b> B<compile> I<subname>
  6748.         Stop after the subroutine is compiled.
  6749. B<B> [I<line>]    Delete the breakpoint for I<line>.
  6750. B<B> I<*>             Delete all breakpoints.
  6751. B<a> [I<line>] I<command>
  6752.         Set an action to be done before the I<line> is executed;
  6753.         I<line> defaults to the current execution line.
  6754.         Sequence is: check for breakpoint/watchpoint, print line
  6755.         if necessary, do action, prompt user if necessary,
  6756.         execute line.
  6757. B<a>        Does nothing
  6758. B<A> [I<line>]    Delete the action for I<line>.
  6759. B<A> I<*>             Delete all actions.
  6760. B<w> I<expr>        Add a global watch-expression.
  6761. B<w>             Does nothing
  6762. B<W> I<expr>        Delete a global watch-expression.
  6763. B<W> I<*>             Delete all watch-expressions.
  6764. B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
  6765.         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
  6766. B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
  6767. B<x> I<expr>        Evals expression in list context, dumps the result.
  6768. B<m> I<expr>        Evals expression in list context, prints methods callable
  6769.         on the first element of the result.
  6770. B<m> I<class>        Prints methods callable via the given class.
  6771. B<M>        Show versions of loaded modules.
  6772. B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
  6773.  
  6774. B<<> ?            List Perl commands to run before each prompt.
  6775. B<<> I<expr>        Define Perl command to run before each prompt.
  6776. B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
  6777. B<< *>                Delete the list of perl commands to run before each prompt.
  6778. B<>> ?            List Perl commands to run after each prompt.
  6779. B<>> I<expr>        Define Perl command to run after each prompt.
  6780. B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
  6781. B<>>B< *>        Delete the list of Perl commands to run after each prompt.
  6782. B<{> I<db_command>    Define debugger command to run before each prompt.
  6783. B<{> ?            List debugger commands to run before each prompt.
  6784. B<{ *>                Delete the list of debugger commands to run before each prompt.
  6785. B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
  6786. B<$prc> I<number>    Redo a previous command (default previous command).
  6787. B<$prc> I<-number>    Redo number'th-to-last command.
  6788. B<$prc> I<pattern>    Redo last command that started with I<pattern>.
  6789.         See 'B<O> I<recallCommand>' too.
  6790. B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
  6791.       . (
  6792.         $rc eq $sh
  6793.         ? ""
  6794.         : "
  6795. B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
  6796.       ) 
  6797.       . "
  6798.         See 'B<O> I<shellBang>' too.
  6799. B<source> I<file>        Execute I<file> containing debugger commands (may nest).
  6800. B<H> I<-number>    Display last number commands (default all).
  6801. B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
  6802. B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
  6803. B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
  6804. B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
  6805. I<command>        Execute as a perl statement in current package.
  6806. B<R>        Pure-man-restart of debugger, some of debugger state
  6807.         and command-line options may be lost.
  6808.         Currently the following settings are preserved:
  6809.         history, breakpoints and actions, debugger B<O>ptions 
  6810.         and the following command-line options: I<-w>, I<-I>, I<-e>.
  6811.  
  6812. B<o> [I<opt>] ...    Set boolean option to true
  6813. B<o> [I<opt>B<?>]    Query options
  6814. B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ... 
  6815.         Set options.  Use quotes in spaces in value.
  6816.     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
  6817.     I<pager>            program for output of \"|cmd\";
  6818.     I<tkRunning>            run Tk while prompting (with ReadLine);
  6819.     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
  6820.     I<inhibit_exit>        Allows stepping off the end of the script.
  6821.     I<ImmediateStop>        Debugger should stop as early as possible.
  6822.     I<RemotePort>            Remote hostname:port for remote debugging
  6823.   The following options affect what happens with B<V>, B<X>, and B<x> commands:
  6824.     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
  6825.     I<compactDump>, I<veryCompact>     change style of array and hash dump;
  6826.     I<globPrint>             whether to print contents of globs;
  6827.     I<DumpDBFiles>         dump arrays holding debugged files;
  6828.     I<DumpPackages>         dump symbol tables of packages;
  6829.     I<DumpReused>             dump contents of \"reused\" addresses;
  6830.     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
  6831.     I<bareStringify>         Do not print the overload-stringified value;
  6832.   Other options include:
  6833.     I<PrintRet>        affects printing of return value after B<r> command,
  6834.     I<frame>        affects printing messages on subroutine entry/exit.
  6835.     I<AutoTrace>    affects printing messages on possible breaking points.
  6836.     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
  6837.     I<ornaments>     affects screen appearance of the command line.
  6838.     I<CreateTTY>     bits control attempts to create a new TTY on events:
  6839.             1: on fork()    2: debugger is started inside debugger
  6840.             4: on startup
  6841.     During startup options are initialized from \$ENV{PERLDB_OPTS}.
  6842.     You can put additional initialization options I<TTY>, I<noTTY>,
  6843.     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
  6844.     `B<R>' after you set them).
  6845.  
  6846. B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
  6847. B<h>        Summary of debugger commands.
  6848. B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
  6849. B<h h>        Long help for debugger commands
  6850. B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the 
  6851.         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
  6852.         Set B<\$DB::doccmd> to change viewer.
  6853.  
  6854. Type `|h h' for a paged display if this was too hard to read.
  6855.  
  6856. ";    # Fix balance of vi % matching: }}}}
  6857.  
  6858.     #  note: tabs in the following section are not-so-helpful
  6859.     $summary = <<"END_SUM";
  6860. I<List/search source lines:>               I<Control script execution:>
  6861.   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
  6862.   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
  6863.   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
  6864.   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
  6865.   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
  6866.   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
  6867. I<Debugger controls:>                        B<L>           List break/watch/actions
  6868.   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
  6869.   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
  6870.   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
  6871.   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
  6872.   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
  6873.   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
  6874.   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
  6875.   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
  6876.   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
  6877. I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
  6878.   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
  6879.   B<p> I<expr>         Print expression (uses script's current package).
  6880.   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
  6881.   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
  6882.   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
  6883.   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
  6884. For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
  6885. END_SUM
  6886.  
  6887.     # ')}}; # Fix balance of vi % matching
  6888.  
  6889.     # and this is really numb...
  6890.     $pre580_help = "
  6891. B<T>        Stack trace.
  6892. B<s> [I<expr>]    Single step [in I<expr>].
  6893. B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
  6894. B<CR>>            Repeat last B<n> or B<s> command.
  6895. B<r>        Return from current subroutine.
  6896. B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
  6897.         at the specified position.
  6898. B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
  6899. B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
  6900. B<l> I<line>        List single I<line>.
  6901. B<l> I<subname>    List first window of lines from subroutine.
  6902. B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
  6903. B<l>        List next window of lines.
  6904. B<->        List previous window of lines.
  6905. B<w> [I<line>]    List window around I<line>.
  6906. B<.>        Return to the executed line.
  6907. B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
  6908.         I<filename> may be either the full name of the file, or a regular
  6909.         expression matching the full file name:
  6910.         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
  6911.         Evals (with saved bodies) are considered to be filenames:
  6912.         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
  6913.         (in the order of execution).
  6914. B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
  6915. B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
  6916. B<L>        List all breakpoints and actions.
  6917. B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
  6918. B<t>        Toggle trace mode.
  6919. B<t> I<expr>        Trace through execution of I<expr>.
  6920. B<b> [I<line>] [I<condition>]
  6921.         Set breakpoint; I<line> defaults to the current execution line;
  6922.         I<condition> breaks if it evaluates to true, defaults to '1'.
  6923. B<b> I<subname> [I<condition>]
  6924.         Set breakpoint at first line of subroutine.
  6925. B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
  6926. B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
  6927. B<b> B<postpone> I<subname> [I<condition>]
  6928.         Set breakpoint at first line of subroutine after 
  6929.         it is compiled.
  6930. B<b> B<compile> I<subname>
  6931.         Stop after the subroutine is compiled.
  6932. B<d> [I<line>]    Delete the breakpoint for I<line>.
  6933. B<D>        Delete all breakpoints.
  6934. B<a> [I<line>] I<command>
  6935.         Set an action to be done before the I<line> is executed;
  6936.         I<line> defaults to the current execution line.
  6937.         Sequence is: check for breakpoint/watchpoint, print line
  6938.         if necessary, do action, prompt user if necessary,
  6939.         execute line.
  6940. B<a> [I<line>]    Delete the action for I<line>.
  6941. B<A>        Delete all actions.
  6942. B<W> I<expr>        Add a global watch-expression.
  6943. B<W>        Delete all watch-expressions.
  6944. B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
  6945.         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
  6946. B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
  6947. B<x> I<expr>        Evals expression in list context, dumps the result.
  6948. B<m> I<expr>        Evals expression in list context, prints methods callable
  6949.         on the first element of the result.
  6950. B<m> I<class>        Prints methods callable via the given class.
  6951.  
  6952. B<<> ?            List Perl commands to run before each prompt.
  6953. B<<> I<expr>        Define Perl command to run before each prompt.
  6954. B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
  6955. B<>> ?            List Perl commands to run after each prompt.
  6956. B<>> I<expr>        Define Perl command to run after each prompt.
  6957. B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
  6958. B<{> I<db_command>    Define debugger command to run before each prompt.
  6959. B<{> ?            List debugger commands to run before each prompt.
  6960. B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
  6961. B<$prc> I<number>    Redo a previous command (default previous command).
  6962. B<$prc> I<-number>    Redo number'th-to-last command.
  6963. B<$prc> I<pattern>    Redo last command that started with I<pattern>.
  6964.         See 'B<O> I<recallCommand>' too.
  6965. B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
  6966.       . (
  6967.         $rc eq $sh
  6968.         ? ""
  6969.         : "
  6970. B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
  6971.       ) .
  6972.       "
  6973.         See 'B<O> I<shellBang>' too.
  6974. B<source> I<file>        Execute I<file> containing debugger commands (may nest).
  6975. B<H> I<-number>    Display last number commands (default all).
  6976. B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
  6977. B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
  6978. B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
  6979. B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
  6980. I<command>        Execute as a perl statement in current package.
  6981. B<v>        Show versions of loaded modules.
  6982. B<R>        Pure-man-restart of debugger, some of debugger state
  6983.         and command-line options may be lost.
  6984.         Currently the following settings are preserved:
  6985.         history, breakpoints and actions, debugger B<O>ptions 
  6986.         and the following command-line options: I<-w>, I<-I>, I<-e>.
  6987.  
  6988. B<O> [I<opt>] ...    Set boolean option to true
  6989. B<O> [I<opt>B<?>]    Query options
  6990. B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ... 
  6991.         Set options.  Use quotes in spaces in value.
  6992.     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
  6993.     I<pager>            program for output of \"|cmd\";
  6994.     I<tkRunning>            run Tk while prompting (with ReadLine);
  6995.     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
  6996.     I<inhibit_exit>        Allows stepping off the end of the script.
  6997.     I<ImmediateStop>        Debugger should stop as early as possible.
  6998.     I<RemotePort>            Remote hostname:port for remote debugging
  6999.   The following options affect what happens with B<V>, B<X>, and B<x> commands:
  7000.     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
  7001.     I<compactDump>, I<veryCompact>     change style of array and hash dump;
  7002.     I<globPrint>             whether to print contents of globs;
  7003.     I<DumpDBFiles>         dump arrays holding debugged files;
  7004.     I<DumpPackages>         dump symbol tables of packages;
  7005.     I<DumpReused>             dump contents of \"reused\" addresses;
  7006.     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
  7007.     I<bareStringify>         Do not print the overload-stringified value;
  7008.   Other options include:
  7009.     I<PrintRet>        affects printing of return value after B<r> command,
  7010.     I<frame>        affects printing messages on subroutine entry/exit.
  7011.     I<AutoTrace>    affects printing messages on possible breaking points.
  7012.     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
  7013.     I<ornaments>     affects screen appearance of the command line.
  7014.     I<CreateTTY>     bits control attempts to create a new TTY on events:
  7015.             1: on fork()    2: debugger is started inside debugger
  7016.             4: on startup
  7017.     During startup options are initialized from \$ENV{PERLDB_OPTS}.
  7018.     You can put additional initialization options I<TTY>, I<noTTY>,
  7019.     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
  7020.     `B<R>' after you set them).
  7021.  
  7022. B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
  7023. B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
  7024. B<h h>        Summary of debugger commands.
  7025. B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the 
  7026.         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
  7027.         Set B<\$DB::doccmd> to change viewer.
  7028.  
  7029. Type `|h' for a paged display if this was too hard to read.
  7030.  
  7031. ";    # Fix balance of vi % matching: }}}}
  7032.  
  7033.     #  note: tabs in the following section are not-so-helpful
  7034.     $pre580_summary = <<"END_SUM";
  7035. I<List/search source lines:>               I<Control script execution:>
  7036.   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
  7037.   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
  7038.   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
  7039.   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
  7040.   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
  7041.   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
  7042. I<Debugger controls:>                        B<L>           List break/watch/actions
  7043.   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
  7044.   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
  7045.   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
  7046.   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
  7047.   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
  7048.   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
  7049.   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
  7050.   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
  7051. I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
  7052.   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
  7053.   B<p> I<expr>         Print expression (uses script's current package).
  7054.   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
  7055.   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
  7056.   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
  7057.   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
  7058. For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
  7059. END_SUM
  7060.  
  7061.     # ')}}; # Fix balance of vi % matching
  7062.  
  7063. } ## end sub sethelp
  7064.  
  7065. =head2 C<print_help()>
  7066.  
  7067. Most of what C<print_help> does is just text formatting. It finds the
  7068. C<B> and C<I> ornaments, cleans them off, and substitutes the proper
  7069. terminal control characters to simulate them (courtesy of 
  7070. <Term::ReadLine::TermCap>).
  7071.  
  7072. =cut
  7073.  
  7074. sub print_help {
  7075.     local $_ = shift;
  7076.  
  7077.     # Restore proper alignment destroyed by eeevil I<> and B<>
  7078.     # ornaments: A pox on both their houses!
  7079.     #
  7080.     # A help command will have everything up to and including
  7081.     # the first tab sequence padded into a field 16 (or if indented 20)
  7082.     # wide.  If it's wider than that, an extra space will be added.
  7083.     s{
  7084.         ^                       # only matters at start of line
  7085.           ( \040{4} | \t )*     # some subcommands are indented
  7086.           ( < ?                 # so <CR> works
  7087.             [BI] < [^\t\n] + )  # find an eeevil ornament
  7088.           ( \t+ )               # original separation, discarded
  7089.           ( .* )                # this will now start (no earlier) than 
  7090.                                 # column 16
  7091.     } {
  7092.         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
  7093.         my $clean = $command;
  7094.         $clean =~ s/[BI]<([^>]*)>/$1/g;  
  7095.  
  7096.         # replace with this whole string:
  7097.         ($leadwhite ? " " x 4 : "")
  7098.       . $command
  7099.       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
  7100.       . $text;
  7101.  
  7102.     }mgex;
  7103.  
  7104.     s{                          # handle bold ornaments
  7105.        B < ( [^>] + | > ) >
  7106.     } {
  7107.           $Term::ReadLine::TermCap::rl_term_set[2] 
  7108.         . $1
  7109.         . $Term::ReadLine::TermCap::rl_term_set[3]
  7110.     }gex;
  7111.  
  7112.     s{                         # handle italic ornaments
  7113.        I < ( [^>] + | > ) >
  7114.     } {
  7115.           $Term::ReadLine::TermCap::rl_term_set[0] 
  7116.         . $1
  7117.         . $Term::ReadLine::TermCap::rl_term_set[1]
  7118.     }gex;
  7119.  
  7120.     local $\ = '';
  7121.     print $OUT $_;
  7122. } ## end sub print_help
  7123.  
  7124. =head2 C<fix_less> 
  7125.  
  7126. This routine does a lot of gyrations to be sure that the pager is C<less>.
  7127. It checks for C<less> masquerading as C<more> and records the result in
  7128. C<$ENV{LESS}> so we don't have to go through doing the stats again.
  7129.  
  7130. =cut
  7131.  
  7132. sub fix_less {
  7133.  
  7134.     # We already know if this is set.
  7135.     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
  7136.  
  7137.     # Pager is less for sure.
  7138.     my $is_less = $pager =~ /\bless\b/;
  7139.     if ($pager =~ /\bmore\b/) {
  7140.         # Nope, set to more. See what's out there.
  7141.         my @st_more = stat('/usr/bin/more');
  7142.         my @st_less = stat('/usr/bin/less');
  7143.  
  7144.         # is it really less, pretending to be more?
  7145.         $is_less = @st_more &&
  7146.           @st_less &&
  7147.           $st_more[0] == $st_less[0] &&
  7148.           $st_more[1] == $st_less[1];
  7149.     } ## end if ($pager =~ /\bmore\b/)
  7150.  
  7151.     # changes environment!
  7152.     # 'r' added so we don't do (slow) stats again.
  7153.     $ENV{LESS} .= 'r' if $is_less;
  7154. } ## end sub fix_less
  7155.  
  7156. =head1 DIE AND WARN MANAGEMENT
  7157.  
  7158. =head2 C<diesignal>
  7159.  
  7160. C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
  7161. to debug a debugger problem.
  7162.  
  7163. It does its best to report the error that occurred, and then forces the
  7164. program, debugger, and everything to die.
  7165.  
  7166. =cut
  7167.  
  7168. sub diesignal {
  7169.     # No entry/exit messages.
  7170.     local $frame = 0;
  7171.  
  7172.     # No return value prints.
  7173.     local $doret = -2;
  7174.  
  7175.     # set the abort signal handling to the default (just terminate).
  7176.     $SIG{'ABRT'} = 'DEFAULT';
  7177.  
  7178.     # If we enter the signal handler recursively, kill myself with an
  7179.     # abort signal (so we just terminate).
  7180.     kill 'ABRT', $$ if $panic++;
  7181.  
  7182.     # If we can show detailed info, do so.
  7183.     if (defined &Carp::longmess) {
  7184.         # Don't recursively enter the warn handler, since we're carping.
  7185.         local $SIG{__WARN__} = '';
  7186.  
  7187.         # Skip two levels before reporting traceback: we're skipping 
  7188.         # mydie and confess. 
  7189.         local $Carp::CarpLevel = 2;    # mydie + confess
  7190.  
  7191.         # Tell us all about it.
  7192.         &warn(Carp::longmess("Signal @_"));
  7193.     }
  7194.  
  7195.     # No Carp. Tell us about the signal as best we can.
  7196.     else {
  7197.         local $\ = '';
  7198.         print $DB::OUT "Got signal @_\n";
  7199.     }
  7200.  
  7201.     # Drop dead.
  7202.     kill 'ABRT', $$;
  7203. } ## end sub diesignal
  7204.  
  7205. =head2 C<dbwarn>
  7206.  
  7207. The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
  7208. be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
  7209.  
  7210. =cut
  7211.  
  7212. sub dbwarn {
  7213.     # No entry/exit trace. 
  7214.     local $frame = 0;
  7215.  
  7216.     # No return value printing.
  7217.     local $doret = -2;
  7218.  
  7219.     # Turn off warn and die handling to prevent recursive entries to this
  7220.     # routine.
  7221.     local $SIG{__WARN__} = '';
  7222.     local $SIG{__DIE__}  = '';
  7223.  
  7224.     # Load Carp if we can. If $^S is false (current thing being compiled isn't
  7225.     # done yet), we may not be able to do a require.
  7226.     eval { require Carp }
  7227.       if defined $^S;    # If error/warning during compilation,
  7228.                          # require may be broken.
  7229.  
  7230.     # Use the core warn() unless Carp loaded OK.
  7231.     CORE::warn(@_,
  7232.         "\nCannot print stack trace, load with -MCarp option to see stack"),
  7233.       return
  7234.       unless defined &Carp::longmess;
  7235.  
  7236.     # Save the current values of $single and $trace, and then turn them off.
  7237.     my ($mysingle, $mytrace) = ($single, $trace);
  7238.     $single = 0;
  7239.     $trace  = 0;
  7240.  
  7241.     # We can call Carp::longmess without its being "debugged" (which we 
  7242.     # don't want - we just want to use it!). Capture this for later.
  7243.     my $mess = Carp::longmess(@_);
  7244.  
  7245.     # Restore $single and $trace to their original values.
  7246.     ($single, $trace) = ($mysingle, $mytrace);
  7247.  
  7248.     # Use the debugger's own special way of printing warnings to print
  7249.     # the stack trace message.
  7250.     &warn($mess);
  7251. } ## end sub dbwarn
  7252.  
  7253. =head2 C<dbdie>
  7254.  
  7255. The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
  7256. by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off 
  7257. single stepping and tracing during the call to C<Carp::longmess> to avoid 
  7258. debugging it - we just want to use it.
  7259.  
  7260. If C<dieLevel> is zero, we let the program being debugged handle the
  7261. exceptions. If it's 1, you get backtraces for any exception. If it's 2,
  7262. the debugger takes over all exception handling, printing a backtrace and
  7263. displaying the exception via its C<dbwarn()> routine. 
  7264.  
  7265. =cut
  7266.  
  7267. sub dbdie {
  7268.     local $frame = 0;
  7269.     local $doret = -2;
  7270.     local $SIG{__DIE__}  = '';
  7271.     local $SIG{__WARN__} = '';
  7272.     my $i      = 0;
  7273.     my $ineval = 0;
  7274.     my $sub;
  7275.     if ($dieLevel > 2) {
  7276.         local $SIG{__WARN__} = \&dbwarn;
  7277.         &warn(@_);    # Yell no matter what
  7278.         return;
  7279.     }
  7280.     if ($dieLevel < 2) {
  7281.         die @_ if $^S;    # in eval propagate
  7282.     }
  7283.  
  7284.     # The code used to check $^S to see if compiliation of the current thing
  7285.     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
  7286.     eval { require Carp }; 
  7287.  
  7288.     die (@_,
  7289.         "\nCannot print stack trace, load with -MCarp option to see stack")
  7290.       unless defined &Carp::longmess;
  7291.  
  7292.     # We do not want to debug this chunk (automatic disabling works
  7293.     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
  7294.     # get the stack trace from Carp::longmess (if possible), restore $signal
  7295.     # and $trace, and then die with the stack trace.
  7296.     my ($mysingle, $mytrace) = ($single, $trace);
  7297.     $single = 0;
  7298.     $trace  = 0;
  7299.     my $mess = "@_";
  7300.     {
  7301.  
  7302.         package Carp;    # Do not include us in the list
  7303.         eval { $mess = Carp::longmess(@_); };
  7304.     }
  7305.     ($single, $trace) = ($mysingle, $mytrace);
  7306.     die $mess;
  7307. } ## end sub dbdie
  7308.  
  7309. =head2 C<warnlevel()>
  7310.  
  7311. Set the C<$DB::warnLevel> variable that stores the value of the
  7312. C<warnLevel> option. Calling C<warnLevel()> with a positive value
  7313. results in the debugger taking over all warning handlers. Setting
  7314. C<warnLevel> to zero leaves any warning handlers set up by the program
  7315. being debugged in place.
  7316.  
  7317. =cut
  7318.  
  7319. sub warnLevel {
  7320.     if (@_) {
  7321.         $prevwarn = $SIG{__WARN__} unless $warnLevel;
  7322.         $warnLevel = shift;
  7323.         if ($warnLevel) {
  7324.             $SIG{__WARN__} = \&DB::dbwarn;
  7325.         }
  7326.         elsif ($prevwarn) {
  7327.             $SIG{__WARN__} = $prevwarn;
  7328.         }
  7329.     } ## end if (@_)
  7330.     $warnLevel;
  7331. } ## end sub warnLevel
  7332.  
  7333. =head2 C<dielevel>
  7334.  
  7335. Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the 
  7336. C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
  7337. zero lets you use your own C<die()> handler.
  7338.  
  7339. =cut
  7340.  
  7341. sub dieLevel {
  7342.     local $\ = '';
  7343.     if (@_) {
  7344.         $prevdie = $SIG{__DIE__} unless $dieLevel;
  7345.         $dieLevel = shift;
  7346.         if ($dieLevel) {
  7347.             # Always set it to dbdie() for non-zero values.
  7348.             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
  7349.  
  7350.            # No longer exists, so don't try  to use it.
  7351.            #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
  7352.  
  7353.             # If we've finished initialization, mention that stack dumps
  7354.             # are enabled, If dieLevel is 1, we won't stack dump if we die
  7355.             # in an eval().
  7356.             print $OUT "Stack dump during die enabled",
  7357.               ($dieLevel == 1 ? " outside of evals" : ""), ".\n"
  7358.               if $I_m_init;
  7359.  
  7360.             # XXX This is probably obsolete, given that diehard() is gone.
  7361.             print $OUT "Dump printed too.\n" if $dieLevel > 2;
  7362.         } ## end if ($dieLevel)
  7363.  
  7364.         # Put the old one back if there was one.
  7365.         elsif ($prevdie) {
  7366.             $SIG{__DIE__} = $prevdie;
  7367.             print $OUT "Default die handler restored.\n";
  7368.         }
  7369.     } ## end if (@_)
  7370.     $dieLevel;
  7371. } ## end sub dieLevel
  7372.  
  7373. =head2 C<signalLevel>
  7374.  
  7375. Number three in a series: set C<signalLevel> to zero to keep your own
  7376. signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger 
  7377. takes over and handles them with C<DB::diesignal()>.
  7378.  
  7379. =cut
  7380.  
  7381. sub signalLevel {
  7382.     if (@_) {
  7383.         $prevsegv = $SIG{SEGV} unless $signalLevel;
  7384.         $prevbus  = $SIG{BUS}  unless $signalLevel;
  7385.         $signalLevel = shift;
  7386.         if ($signalLevel) {
  7387.             $SIG{SEGV} = \&DB::diesignal;
  7388.             $SIG{BUS}  = \&DB::diesignal;
  7389.         }
  7390.         else {
  7391.             $SIG{SEGV} = $prevsegv;
  7392.             $SIG{BUS}  = $prevbus;
  7393.         }
  7394.     } ## end if (@_)
  7395.     $signalLevel;
  7396. } ## end sub signalLevel
  7397.  
  7398. =head1 SUBROUTINE DECODING SUPPORT
  7399.  
  7400. These subroutines are used during the C<x> and C<X> commands to try to
  7401. produce as much information as possible about a code reference. They use
  7402. L<Devel::Peek> to try to find the glob in which this code reference lives
  7403. (if it does) - this allows us to actually code references which correspond
  7404. to named subroutines (including those aliased via glob assignment).
  7405.  
  7406. =head2 C<CvGV_name()>
  7407.  
  7408. Wrapper for X<CvGV_name_or_bust>; tries to get the name of a reference
  7409. via that routine. If this fails, return the reference again (when the
  7410. reference is stringified, it'll come out as "SOMETHING(0X...)").
  7411.  
  7412. =cut
  7413.  
  7414. sub CvGV_name {
  7415.     my $in   = shift;
  7416.     my $name = CvGV_name_or_bust($in);
  7417.     defined $name ? $name : $in;
  7418. }
  7419.  
  7420. =head2 C<CvGV_name_or_bust> I<coderef>
  7421.  
  7422. Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
  7423. C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
  7424. find a glob for this ref.
  7425.  
  7426. Returns "I<package>::I<glob name>" if the code ref is found in a glob.
  7427.  
  7428. =cut
  7429.  
  7430. sub CvGV_name_or_bust {
  7431.     my $in = shift;
  7432.     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
  7433.     return unless ref $in;
  7434.     $in = \&$in;            # Hard reference...
  7435.     eval { require Devel::Peek; 1 } or return;
  7436.     my $gv = Devel::Peek::CvGV($in) or return;
  7437.     *$gv{PACKAGE} . '::' . *$gv{NAME};
  7438. } ## end sub CvGV_name_or_bust
  7439.  
  7440. =head2 C<find_sub>
  7441.  
  7442. A utility routine used in various places; finds the file where a subroutine 
  7443. was defined, and returns that filename and a line-number range.
  7444.  
  7445. Tries to use X<@sub> first; if it can't find it there, it tries building a
  7446. reference to the subroutine and uses X<CvGV_name_or_bust> to locate it,
  7447. loading it into X<@sub> as a side effect (XXX I think). If it can't find it
  7448. this way, it brute-force searches X<%sub>, checking for identical references.
  7449.  
  7450. =cut
  7451.  
  7452. sub find_sub {
  7453.     my $subr = shift;
  7454.     $sub{$subr} or do {
  7455.         return unless defined &$subr;
  7456.         my $name = CvGV_name_or_bust($subr);
  7457.         my $data;
  7458.         $data = $sub{$name} if defined $name;
  7459.         return $data if defined $data;
  7460.  
  7461.         # Old stupid way...
  7462.         $subr = \&$subr;    # Hard reference
  7463.         my $s;
  7464.         for (keys %sub) {
  7465.             $s = $_, last if $subr eq \&$_;
  7466.         }
  7467.         $sub{$s} if $s;
  7468.       } ## end do
  7469. } ## end sub find_sub
  7470.  
  7471. =head2 C<methods>
  7472.  
  7473. A subroutine that uses the utility function X<methods_via> to find all the
  7474. methods in the class corresponding to the current reference and in 
  7475. C<UNIVERSAL>.
  7476.  
  7477. =cut
  7478.  
  7479. sub methods {
  7480.  
  7481.     # Figure out the class - either this is the class or it's a reference
  7482.     # to something blessed into that class.
  7483.     my $class = shift;
  7484.     $class = ref $class if ref $class;
  7485.  
  7486.     local %seen;
  7487.     local %packs;
  7488.  
  7489.     # Show the methods that this class has.
  7490.     methods_via($class, '', 1);
  7491.  
  7492.     # Show the methods that UNIVERSAL has.
  7493.     methods_via('UNIVERSAL', 'UNIVERSAL', 0);
  7494. } ## end sub methods
  7495.  
  7496. =head2 C<methods_via($class, $prefix, $crawl_upward)>
  7497.  
  7498. C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
  7499. all the parent class methods. C<$class> is the name of the next class to
  7500. try; C<$prefix> is the message prefix, which gets built up as we go up the
  7501. C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
  7502. higher in the C<@ISA> tree, 0 if we should stop.
  7503.  
  7504. =cut
  7505.  
  7506. sub methods_via {
  7507.     # If we've processed this class already, just quit.
  7508.     my $class = shift;
  7509.     return if $seen{$class}++;
  7510.  
  7511.     # This is a package that is contributing the methods we're about to print. 
  7512.     my $prefix = shift;
  7513.     my $prepend = $prefix ? "via $prefix: " : '';
  7514.  
  7515.     my $name;
  7516.     for $name (
  7517.         # Keep if this is a defined subroutine in this class.
  7518.         grep { defined &{ ${"${class}::"}{$_} } }
  7519.              # Extract from all the symbols in this class.
  7520.              sort keys %{"${class}::"}
  7521.       ) {
  7522.         # If we printed this already, skip it.
  7523.         next if $seen{$name}++;
  7524.  
  7525.         # Print the new method name.
  7526.         local $\ = '';
  7527.         local $, = '';
  7528.         print $DB::OUT "$prepend$name\n";
  7529.     } ## end for $name (grep { defined...
  7530.  
  7531.     # If the $crawl_upward argument is false, just quit here.
  7532.     return unless shift; 
  7533.  
  7534.     # $crawl_upward true: keep going up the tree.
  7535.     # Find all the classes this one is a subclass of.
  7536.     for $name (@{"${class}::ISA"}) {
  7537.         # Set up the new prefix.
  7538.         $prepend = $prefix ? $prefix . " -> $name" : $name;
  7539.         # Crawl up the tree and keep trying to crawl up. 
  7540.         methods_via($name, $prepend, 1);
  7541.     }
  7542. } ## end sub methods_via
  7543.  
  7544. =head2 C<setman> - figure out which command to use to show documentation
  7545.  
  7546. Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
  7547.  
  7548. =cut
  7549.  
  7550. sub setman {
  7551.     $doccmd =
  7552.       $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
  7553.       ? "man"               # O Happy Day!
  7554.       : "perldoc";          # Alas, poor unfortunates
  7555. } ## end sub setman
  7556.  
  7557. =head2 C<runman> - run the appropriate command to show documentation
  7558.  
  7559. Accepts a man page name; runs the appropriate command to display it (set up
  7560. during debugger initialization). Uses C<DB::system> to avoid mucking up the
  7561. program's STDIN and STDOUT.
  7562.  
  7563. =cut
  7564.  
  7565. sub runman {
  7566.     my $page = shift;
  7567.     unless ($page) {
  7568.         &system("$doccmd $doccmd");
  7569.         return;
  7570.     }
  7571.  
  7572.     # this way user can override, like with $doccmd="man -Mwhatever"
  7573.     # or even just "man " to disable the path check.
  7574.     unless ($doccmd eq 'man') {
  7575.         &system("$doccmd $page");
  7576.         return;
  7577.     }
  7578.  
  7579.     $page = 'perl' if lc($page) eq 'help';
  7580.  
  7581.     require Config;
  7582.     my $man1dir = $Config::Config{'man1dir'};
  7583.     my $man3dir = $Config::Config{'man3dir'};
  7584.     for ($man1dir, $man3dir) { s#/[^/]*\z## if /\S/ }
  7585.     my $manpath = '';
  7586.     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
  7587.     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
  7588.     chop $manpath if $manpath;
  7589.  
  7590.     # harmless if missing, I figure
  7591.     my $oldpath = $ENV{MANPATH};
  7592.     $ENV{MANPATH} = $manpath if $manpath;
  7593.     my $nopathopt = $^O =~ /dunno what goes here/;
  7594.     if (
  7595.         CORE::system(
  7596.             $doccmd,
  7597.  
  7598.             # I just *know* there are men without -M
  7599.             (($manpath && !$nopathopt) ? ("-M", $manpath) : ()),
  7600.             split ' ', $page
  7601.         )
  7602.       )
  7603.     {
  7604.         unless ($page =~ /^perl\w/) {
  7605.             if (
  7606.                 grep { $page eq $_ }
  7607.                 qw{
  7608.                 5004delta 5005delta amiga api apio book boot bot call compile
  7609.                 cygwin data dbmfilter debug debguts delta diag doc dos dsc embed
  7610.                 faq faq1 faq2 faq3 faq4 faq5 faq6 faq7 faq8 faq9 filter fork
  7611.                 form func guts hack hist hpux intern ipc lexwarn locale lol mod
  7612.                 modinstall modlib number obj op opentut os2 os390 pod port
  7613.                 ref reftut run sec style sub syn thrtut tie toc todo toot tootc
  7614.                 trap unicode var vms win32 xs xstut
  7615.                 }
  7616.               )
  7617.             {
  7618.                 $page =~ s/^/perl/;
  7619.                 CORE::system($doccmd,
  7620.                     (($manpath && !$nopathopt) ? ("-M", $manpath) : ()),
  7621.                     $page);
  7622.             } ## end if (grep { $page eq $_...
  7623.         } ## end unless ($page =~ /^perl\w/)
  7624.     } ## end if (CORE::system($doccmd...
  7625.     if (defined $oldpath) {
  7626.         $ENV{MANPATH} = $manpath;
  7627.     }
  7628.     else {
  7629.         delete $ENV{MANPATH};
  7630.     }
  7631. } ## end sub runman
  7632.  
  7633. #use Carp;                          # This did break, left for debugging
  7634.  
  7635. =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
  7636.  
  7637. Because of the way the debugger interface to the Perl core is designed, any
  7638. debugger package globals that C<DB::sub()> requires have to be defined before
  7639. any subroutines can be called. These are defined in the second C<BEGIN> block.
  7640.  
  7641. This block sets things up so that (basically) the world is sane
  7642. before the debugger starts executing. We set up various variables that the
  7643. debugger has to have set up before the Perl core starts running:
  7644.  
  7645. =over 4 
  7646.  
  7647. =item * The debugger's own filehandles (copies of STD and STDOUT for now).
  7648.  
  7649. =item * Characters for shell escapes, the recall command, and the history command.
  7650.  
  7651. =item * The maximum recursion depth.
  7652.  
  7653. =item * The size of a C<w> command's window.
  7654.  
  7655. =item * The before-this-line context to be printed in a C<v> (view a window around this line) command.
  7656.  
  7657. =item * The fact that we're not in a sub at all right now.
  7658.  
  7659. =item * The default SIGINT handler for the debugger.
  7660.  
  7661. =item * The appropriate value of the flag in C<$^D> that says the debugger is running
  7662.  
  7663. =item * The current debugger recursion level
  7664.  
  7665. =item * The list of postponed (XXX define) items and the C<$single> stack
  7666.  
  7667. =item * That we want no return values and no subroutine entry/exit trace.
  7668.  
  7669. =back
  7670.  
  7671. =cut
  7672.  
  7673. # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
  7674.  
  7675. BEGIN {    # This does not compile, alas. (XXX eh?)
  7676.     $IN      = \*STDIN;     # For bugs before DB::OUT has been opened
  7677.     $OUT     = \*STDERR;    # For errors before DB::OUT has been opened
  7678.  
  7679.     # Define characters used by command parsing. 
  7680.     $sh      = '!';         # Shell escape (does not work)
  7681.     $rc      = ',';         # Recall command (does not work)
  7682.     @hist    = ('?');       # Show history (does not work)
  7683.  
  7684.     # This defines the point at which you get the 'deep recursion' 
  7685.     # warning. It MUST be defined or the debugger will not load.
  7686.     $deep    = 100;
  7687.  
  7688.     # Number of lines around the current one that are shown in the 
  7689.     # 'w' command.
  7690.     $window  = 10;
  7691.  
  7692.     # How much before-the-current-line context the 'v' command should
  7693.     # use in calculating the start of the window it will display.
  7694.     $preview = 3;
  7695.  
  7696.     # We're not in any sub yet, but we need this to be a defined value.
  7697.     $sub     = '';
  7698.  
  7699.     # Set up the debugger's interrupt handler. It simply sets a flag 
  7700.     # ($signal) that DB::DB() will check before each command is executed.
  7701.     $SIG{INT} = \&DB::catch;
  7702.  
  7703.     # The following lines supposedly, if uncommented, allow the debugger to
  7704.     # debug itself. Perhaps we can try that someday. 
  7705.     # This may be enabled to debug debugger:
  7706.     #$warnLevel = 1 unless defined $warnLevel;
  7707.     #$dieLevel = 1 unless defined $dieLevel;
  7708.     #$signalLevel = 1 unless defined $signalLevel;
  7709.  
  7710.     # This is the flag that says "a debugger is running, please call
  7711.     # DB::DB and DB::sub". We will turn it on forcibly before we try to
  7712.     # execute anything in the user's context, because we always want to
  7713.     # get control back.
  7714.     $db_stop = 0;           # Compiler warning ...
  7715.     $db_stop = 1 << 30;     # ... because this is only used in an eval() later.
  7716.  
  7717.     # This variable records how many levels we're nested in debugging. Used
  7718.     # Used in the debugger prompt, and in determining whether it's all over or 
  7719.     # not.
  7720.     $level   = 0;           # Level of recursive debugging
  7721.  
  7722.     # "Triggers bug (?) in perl if we postpone this until runtime."
  7723.     # XXX No details on this yet, or whether we should fix the bug instead
  7724.     # of work around it. Stay tuned. 
  7725.     @postponed = @stack = (0);
  7726.  
  7727.     # Used to track the current stack depth using the auto-stacked-variable
  7728.     # trick.
  7729.     $stack_depth = 0;    # Localized repeatedly; simple way to track $#stack
  7730.  
  7731.     # Don't print return values on exiting a subroutine.
  7732.     $doret       = -2;
  7733.  
  7734.     # No extry/exit tracing.
  7735.     $frame       = 0;
  7736.  
  7737. } ## end BEGIN
  7738.  
  7739. BEGIN { $^W = $ini_warn; }    # Switch warnings back
  7740.  
  7741. =head1 READLINE SUPPORT - COMPLETION FUNCTION
  7742.  
  7743. =head2 db_complete
  7744.  
  7745. C<readline> support - adds command completion to basic C<readline>. 
  7746.  
  7747. Returns a list of possible completions to C<readline> when invoked. C<readline>
  7748. will print the longest common substring following the text already entered. 
  7749.  
  7750. If there is only a single possible completion, C<readline> will use it in full.
  7751.  
  7752. This code uses C<map> and C<grep> heavily to create lists of possible 
  7753. completion. Think LISP in this section.
  7754.  
  7755. =cut
  7756.  
  7757. sub db_complete {
  7758.  
  7759.     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
  7760.     # $text is the text to be completed.
  7761.     # $line is the incoming line typed by the user.
  7762.     # $start is the start of the text to be completed in the incoming line.
  7763.     my ($text, $line, $start) = @_;
  7764.  
  7765.     # Save the initial text.
  7766.     # The search pattern is current package, ::, extract the next qualifier
  7767.     # Prefix and pack are set to undef.
  7768.     my ($itext, $search, $prefix, $pack) =
  7769.       ($text, "^\Q${'package'}::\E([^:]+)\$");
  7770.  
  7771. =head3 C<b postpone|compile> 
  7772.  
  7773. =over 4
  7774.  
  7775. =item * Find all the subroutines that might match in this package
  7776.  
  7777. =item * Add "postpone", "load", and "compile" as possibles (we may be completing the keyword itself
  7778.  
  7779. =item * Include all the rest of the subs that are known
  7780.  
  7781. =item * C<grep> out the ones that match the text we have so far
  7782.  
  7783. =item * Return this as the list of possible completions
  7784.  
  7785. =back
  7786.  
  7787. =cut 
  7788.  
  7789.     return sort grep /^\Q$text/, (keys %sub),
  7790.       qw(postpone load compile),    # subroutines
  7791.       (map { /$search/ ? ($1) : () } keys %sub)
  7792.       if (substr $line, 0, $start) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
  7793.  
  7794. =head3 C<b load>
  7795.  
  7796. Get all the possible files from @INC as it currently stands and
  7797. select the ones that match the text so far.
  7798.  
  7799. =cut
  7800.  
  7801.     return sort grep /^\Q$text/, values %INC    # files
  7802.       if (substr $line, 0, $start) =~ /^\|*b\s+load\s+$/;
  7803.  
  7804. =head3  C<V> (list variable) and C<m> (list modules)
  7805.  
  7806. There are two entry points for these commands:
  7807.  
  7808. =head4 Unqualified package names
  7809.  
  7810. Get the top-level packages and grab everything that matches the text
  7811. so far. For each match, recursively complete the partial packages to
  7812. get all possible matching packages. Return this sorted list.
  7813.  
  7814. =cut
  7815.  
  7816.     return sort map { ($_, db_complete($_ . "::", "V ", 2)) }
  7817.       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::  # top-packages
  7818.       if (substr $line, 0, $start) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
  7819.  
  7820. =head4 Qualified package names
  7821.  
  7822. Take a partially-qualified package and find all subpackages for it
  7823. by getting all the subpackages for the package so far, matching all
  7824. the subpackages against the text, and discarding all of them which 
  7825. start with 'main::'. Return this list.
  7826.  
  7827. =cut
  7828.  
  7829.     return sort map { ($_, db_complete($_ . "::", "V ", 2)) }
  7830.       grep !/^main::/, grep /^\Q$text/,
  7831.         map { /^(.*)::$/ ? ($prefix . "::$1") : () } keys %{ $prefix . '::' }
  7832.           if (substr $line, 0, $start) =~ /^\|*[Vm]\s+$/
  7833.               and $text =~ /^(.*[^:])::?(\w*)$/
  7834.               and $prefix = $1;
  7835.  
  7836. =head3 C<f> - switch files
  7837.  
  7838. Here, we want to get a fully-qualified filename for the C<f> command.
  7839. Possibilities are:
  7840.  
  7841. =over 4
  7842.  
  7843. =item 1. The original source file itself
  7844.  
  7845. =item 2. A file from C<@INC>
  7846.  
  7847. =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
  7848.  
  7849. =back
  7850.  
  7851. =cut
  7852.  
  7853.     if ($line =~ /^\|*f\s+(.*)/) {                              # Loaded files
  7854.         # We might possibly want to switch to an eval (which has a "filename"
  7855.         # like '(eval 9)'), so we may need to clean up the completion text 
  7856.         # before proceeding. 
  7857.         $prefix = length($1) - length($text);
  7858.         $text   = $1;
  7859.  
  7860. =pod
  7861.  
  7862. Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file> 
  7863. (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these 
  7864. out of C<%main::>, add the initial source file, and extract the ones that 
  7865. match the completion text so far.
  7866.  
  7867. =cut
  7868.  
  7869.         return sort
  7870.           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, (keys %main::),
  7871.           $0;
  7872.     } ## end if ($line =~ /^\|*f\s+(.*)/)
  7873.  
  7874. =head3 Subroutine name completion
  7875.  
  7876. We look through all of the defined subs (the keys of C<%sub>) and
  7877. return both all the possible matches to the subroutine name plus
  7878. all the matches qualified to the current package.
  7879.  
  7880. =cut
  7881.  
  7882.     if ((substr $text, 0, 1) eq '&') {    # subroutines
  7883.         $text = substr $text, 1;
  7884.         $prefix = "&";
  7885.         return sort map "$prefix$_", grep /^\Q$text/, (keys %sub),
  7886.           (
  7887.             map { /$search/ ? ($1) : () }
  7888.               keys %sub
  7889.               );
  7890.     } ## end if ((substr $text, 0, ...
  7891.  
  7892. =head3  Scalar, array, and hash completion: partially qualified package
  7893.  
  7894. Much like the above, except we have to do a little more cleanup:
  7895.  
  7896. =cut
  7897.  
  7898.     if ($text =~ /^[\$@%](.*)::(.*)/) {    # symbols in a package
  7899.  
  7900. =pod
  7901.  
  7902. =over 4 
  7903.  
  7904. =item * Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
  7905.  
  7906. =cut
  7907.  
  7908.         $pack = ($1 eq 'main' ? '' : $1) . '::';
  7909.  
  7910. =pod
  7911.  
  7912. =item * Figure out the prefix vs. what needs completing.
  7913.  
  7914. =cut
  7915.  
  7916.         $prefix = (substr $text, 0, 1) . $1 . '::';
  7917.         $text = $2;
  7918.  
  7919. =pod
  7920.  
  7921. =item * Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
  7922.  
  7923. =cut
  7924.  
  7925.         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
  7926.           keys %$pack;
  7927.  
  7928. =pod
  7929.  
  7930. =item * If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
  7931.  
  7932. =cut
  7933.  
  7934.         if (@out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext) {
  7935.             return db_complete($out[0], $line, $start);
  7936.         }
  7937.  
  7938.         # Return the list of possibles.
  7939.         return sort @out;
  7940.  
  7941.     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
  7942.  
  7943. =pod
  7944.  
  7945. =back
  7946.  
  7947. =head3 Symbol completion: current package or package C<main>.
  7948.  
  7949. =cut
  7950.  
  7951.  
  7952.     if ($text =~ /^[\$@%]/) {    # symbols (in $package + packages in main)
  7953.  
  7954. =pod
  7955.  
  7956. =over 4
  7957.  
  7958. =item * If it's C<main>, delete main to just get C<::> leading.
  7959.  
  7960. =cut
  7961.  
  7962.         $pack = ($package eq 'main' ? '' : $package) . '::';
  7963.  
  7964. =pod
  7965.  
  7966. =item * We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
  7967.  
  7968. =cut
  7969.  
  7970.         $prefix = substr $text, 0, 1;
  7971.         $text = substr $text, 1;
  7972.  
  7973. =pod
  7974.  
  7975. =item * If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
  7976.  
  7977. =cut
  7978.  
  7979.         my @out = map "$prefix$_", grep /^\Q$text/,
  7980.           (grep /^_?[a-zA-Z]/, keys %$pack),
  7981.           ($pack eq '::' ? () : (grep /::$/, keys %::));
  7982.  
  7983. =item * If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
  7984.  
  7985. =back
  7986.  
  7987. =cut
  7988.  
  7989.         if (@out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext) {
  7990.             return db_complete($out[0], $line, $start);
  7991.         }
  7992.  
  7993.         # Return the list of possibles.
  7994.         return sort @out;
  7995.     } ## end if ($text =~ /^[\$@%]/)
  7996.  
  7997. =head3 Options 
  7998.  
  7999. We use C<option_val()> to look up the current value of the option. If there's
  8000. only a single value, we complete the command in such a way that it is a 
  8001. complete command for setting the option in question. If there are multiple
  8002. possible values, we generate a command consisting of the option plus a trailing
  8003. question mark, which, if executed, will list the current value of the option.
  8004.  
  8005. =cut
  8006.  
  8007.     my $cmd = ($CommandSet eq '580') ? 'o' : 'O';
  8008.     if ((substr $line, 0, $start) =~ /^\|*$cmd\b.*\s$/) { # Options after space
  8009.         # We look for the text to be matched in the list of possible options, 
  8010.         # and fetch the current value. 
  8011.         my @out = grep /^\Q$text/, @options;
  8012.         my $val = option_val($out[0], undef);
  8013.  
  8014.         # Set up a 'query option's value' command.
  8015.         my $out = '? ';
  8016.         if (not defined $val or $val =~ /[\n\r]/) {
  8017.            # There's really nothing else we can do.
  8018.         }
  8019.  
  8020.         # We have a value. Create a proper option-setting command.
  8021.         elsif ($val =~ /\s/) {
  8022.             # XXX This may be an extraneous variable.
  8023.             my $found;
  8024.  
  8025.             # We'll want to quote the string (because of the embedded
  8026.             # whtespace), but we want to make sure we don't end up with
  8027.             # mismatched quote characters. We try several possibilities.
  8028.             foreach $l (split //, qq/\"\'\#\|/) {
  8029.                 # If we didn't find this quote character in the value,
  8030.                 # quote it using this quote character.
  8031.                 $out = "$l$val$l ", last if (index $val, $l) == -1;
  8032.             }
  8033.         } ## end elsif ($val =~ /\s/)
  8034.  
  8035.         # Don't need any quotes.
  8036.         else {
  8037.             $out = "=$val ";
  8038.         }
  8039.  
  8040.         # If there were multiple possible values, return '? ', which
  8041.         # makes the command into a query command. If there was just one,
  8042.         # have readline append that.
  8043.         $rl_attribs->{completer_terminator_character} =
  8044.           (@out == 1 ? $out : '? ');
  8045.  
  8046.         # Return list of possibilities.
  8047.         return sort @out;
  8048.     } ## end if ((substr $line, 0, ...
  8049.  
  8050. =head3 Filename completion
  8051.  
  8052. For entering filenames. We simply call C<readline>'s C<filename_list()>
  8053. method with the completion text to get the possible completions.
  8054.  
  8055. =cut
  8056.  
  8057.     return $term->filename_list($text);    # filenames
  8058.  
  8059. } ## end sub db_complete
  8060.  
  8061. =head1 MISCELLANEOUS SUPPORT FUNCTIONS
  8062.  
  8063. Functions that possibly ought to be somewhere else.
  8064.  
  8065. =head2 end_report
  8066.  
  8067. Say we're done.
  8068.  
  8069. =cut
  8070.  
  8071. sub end_report {
  8072.     local $\ = '';
  8073.     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
  8074. }
  8075.  
  8076. =head2 clean_ENV
  8077.  
  8078. If we have $ini_pids, save it in the environment; else remove it from the
  8079. environment. Used by the C<R> (restart) command.
  8080.  
  8081. =cut
  8082.  
  8083. sub clean_ENV {
  8084.     if (defined($ini_pids)) {
  8085.         $ENV{PERLDB_PIDS} = $ini_pids;
  8086.     }
  8087.     else {
  8088.         delete($ENV{PERLDB_PIDS});
  8089.     }
  8090. } ## end sub clean_ENV
  8091.  
  8092. =head1 END PROCESSING - THE C<END> BLOCK
  8093.  
  8094. Come here at the very end of processing. We want to go into a 
  8095. loop where we allow the user to enter commands and interact with the 
  8096. debugger, but we don't want anything else to execute. 
  8097.  
  8098. First we set the C<$finished> variable, so that some commands that
  8099. shouldn't be run after the end of program quit working.
  8100.  
  8101. We then figure out whether we're truly done (as in the user entered a C<q>
  8102. command, or we finished execution while running nonstop). If we aren't,
  8103. we set C<$single> to 1 (causing the debugger to get control again).
  8104.  
  8105. We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...">
  8106. message and returns control to the debugger. Repeat.
  8107.  
  8108. When the user finally enters a C<q> command, C<$fall_off_end> is set to
  8109. 1 and the C<END> block simply exits with C<$single> set to 0 (don't 
  8110. break, run to completion.).
  8111.  
  8112. =cut
  8113.  
  8114. END {
  8115.     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
  8116.     $fall_off_end = 1 unless $inhibit_exit;
  8117.  
  8118.     # Do not stop in at_exit() and destructors on exit:
  8119.     $DB::single = !$fall_off_end && !$runnonstop;
  8120.     DB::fake::at_exit() unless $fall_off_end or $runnonstop;
  8121. } ## end END
  8122.  
  8123. =head1 PRE-5.8 COMMANDS
  8124.  
  8125. Some of the commands changed function quite a bit in the 5.8 command 
  8126. realignment, so much so that the old code had to be replaced completely.
  8127. Because we wanted to retain the option of being able to go back to the
  8128. former command set, we moved the old code off to this section.
  8129.  
  8130. There's an awful lot of duplicated code here. We've duplicated the 
  8131. comments to keep things clear.
  8132.  
  8133. =head2 Null command
  8134.  
  8135. Does nothing. Used to 'turn off' commands.
  8136.  
  8137. =cut
  8138.  
  8139. sub cmd_pre580_null {
  8140.  
  8141.     # do nothing...
  8142. }
  8143.  
  8144. =head2 Old C<a> command.
  8145.  
  8146. This version added actions if you supplied them, and deleted them
  8147. if you didn't.
  8148.  
  8149. =cut
  8150.  
  8151. sub cmd_pre580_a {
  8152.     my $xcmd = shift;
  8153.     my $cmd  = shift;
  8154.  
  8155.     # Argument supplied. Add the action.
  8156.     if ($cmd =~ /^(\d*)\s*(.*)/) {
  8157.  
  8158.         # If the line isn't there, use the current line.
  8159.         $i = $1 || $line;
  8160.         $j = $2;
  8161.  
  8162.         # If there is an action ...
  8163.         if (length $j) {
  8164.  
  8165.             # ... but the line isn't breakable, skip it.
  8166.             if ($dbline[$i] == 0) {
  8167.                 print $OUT "Line $i may not have an action.\n";
  8168.             }
  8169.             else {
  8170.                 # ... and the line is breakable:
  8171.                 # Mark that there's an action in this file.
  8172.                 $had_breakpoints{$filename} |= 2;
  8173.  
  8174.                 # Delete any current action.
  8175.                 $dbline{$i} =~ s/\0[^\0]*//;
  8176.  
  8177.                 # Add the new action, continuing the line as needed.
  8178.                 $dbline{$i} .= "\0" . action($j);
  8179.             }
  8180.         } ## end if (length $j)
  8181.  
  8182.         # No action supplied.
  8183.         else {
  8184.             # Delete the action.
  8185.             $dbline{$i} =~ s/\0[^\0]*//;
  8186.             # Mark as having no break or action if nothing's left.
  8187.             delete $dbline{$i} if $dbline{$i} eq '';
  8188.         }
  8189.     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
  8190. } ## end sub cmd_pre580_a
  8191.  
  8192. =head2 Old C<b> command 
  8193.  
  8194. Add breakpoints.
  8195.  
  8196. =cut
  8197.  
  8198. sub cmd_pre580_b {
  8199.     my $xcmd    = shift;
  8200.     my $cmd     = shift;
  8201.     my $dbline = shift;
  8202.  
  8203.     # Break on load.
  8204.     if ($cmd =~ /^load\b\s*(.*)/) {
  8205.         my $file = $1;
  8206.         $file =~ s/\s+$//;
  8207.         &cmd_b_load($file);
  8208.     }
  8209.  
  8210.     # b compile|postpone <some sub> [<condition>]
  8211.     # The interpreter actually traps this one for us; we just put the 
  8212.     # necessary condition in the %postponed hash.
  8213.     elsif ($cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/) {
  8214.         # Capture the condition if there is one. Make it true if none.
  8215.         my $cond = length $3 ? $3 : '1';
  8216.  
  8217.         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
  8218.         # if it was 'compile'.
  8219.         my ($subname, $break) = ($2, $1 eq 'postpone');
  8220.  
  8221.         # De-Perl4-ify the name - ' separators to ::.
  8222.         $subname =~ s/\'/::/g;
  8223.  
  8224.         # Qualify it into the current package unless it's already qualified.
  8225.         $subname = "${'package'}::" . $subname
  8226.           unless $subname =~ /::/;
  8227.  
  8228.         # Add main if it starts with ::.
  8229.         $subname = "main" . $subname if substr($subname, 0, 2) eq "::";
  8230.  
  8231.         # Save the break type for this sub.
  8232.         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
  8233.     } ## end elsif ($cmd =~ ...
  8234.  
  8235.     # b <sub name> [<condition>]
  8236.     elsif ($cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/) {
  8237.         my $subname = $1;
  8238.         my $cond = length $2 ? $2 : '1';
  8239.         &cmd_b_sub($subname, $cond);
  8240.     }
  8241.  
  8242.     # b <line> [<condition>].
  8243.     elsif ($cmd =~ /^(\d*)\s*(.*)/) {
  8244.         my $i = $1 || $dbline;
  8245.         my $cond = length $2 ? $2 : '1';
  8246.         &cmd_b_line($i, $cond);
  8247.     }
  8248. } ## end sub cmd_pre580_b
  8249.  
  8250. =head2 Old C<D> command.
  8251.  
  8252. Delete all breakpoints unconditionally.
  8253.  
  8254. =cut
  8255.  
  8256. sub cmd_pre580_D {
  8257.     my $xcmd = shift;
  8258.     my $cmd  = shift;
  8259.     if ($cmd =~ /^\s*$/) {
  8260.         print $OUT "Deleting all breakpoints...\n";
  8261.  
  8262.         # %had_breakpoints lists every file that had at least one
  8263.         # breakpoint in it.
  8264.         my $file;
  8265.         for $file (keys %had_breakpoints) {
  8266.             # Switch to the desired file temporarily.
  8267.             local *dbline = $main::{ '_<' . $file };
  8268.  
  8269.             my $max = $#dbline;
  8270.             my $was;
  8271.  
  8272.             # For all lines in this file ...
  8273.             for ($i = 1 ; $i <= $max ; $i++) {
  8274.                 # If there's a breakpoint or action on this line ...
  8275.                 if (defined $dbline{$i}) {
  8276.                     # ... remove the breakpoint.
  8277.                     $dbline{$i} =~ s/^[^\0]+//;
  8278.                     if ($dbline{$i} =~ s/^\0?$//) {
  8279.                         # Remove the entry altogether if no action is there.
  8280.                         delete $dbline{$i};
  8281.                     }
  8282.                 } ## end if (defined $dbline{$i...
  8283.             } ## end for ($i = 1 ; $i <= $max...
  8284.  
  8285.             # If, after we turn off the "there were breakpoints in this file"
  8286.             # bit, the entry in %had_breakpoints for this file is zero, 
  8287.             # we should remove this file from the hash.
  8288.             if (not $had_breakpoints{$file} &= ~1) {
  8289.                 delete $had_breakpoints{$file};
  8290.             }
  8291.         } ## end for $file (keys %had_breakpoints)
  8292.  
  8293.         # Kill off all the other breakpoints that are waiting for files that
  8294.         # haven't been loaded yet.
  8295.         undef %postponed;
  8296.         undef %postponed_file;
  8297.         undef %break_on_load;
  8298.     } ## end if ($cmd =~ /^\s*$/)
  8299. } ## end sub cmd_pre580_D
  8300.  
  8301. =head2 Old C<h> command
  8302.  
  8303. Print help. Defaults to printing the long-form help; the 5.8 version 
  8304. prints the summary by default.
  8305.  
  8306. =cut
  8307.  
  8308. sub cmd_pre580_h {
  8309.     my $xcmd = shift;
  8310.     my $cmd  = shift;
  8311.  
  8312.     # Print the *right* help, long format.
  8313.     if ($cmd =~ /^\s*$/) {
  8314.         print_help($pre580_help);
  8315.     }
  8316.  
  8317.     # 'h h' - explicitly-requested summary. 
  8318.     elsif ($cmd =~ /^h\s*/) {
  8319.         print_help($pre580_summary);
  8320.     }
  8321.  
  8322.     # Find and print a command's help.
  8323.     elsif ($cmd =~ /^h\s+(\S.*)$/) {
  8324.         my $asked  = $1;                   # for proper errmsg
  8325.         my $qasked = quotemeta($asked);    # for searching
  8326.                                            # XXX: finds CR but not <CR>
  8327.         if ($pre580_help =~ /^
  8328.                               <?           # Optional '<'
  8329.                               (?:[IB]<)    # Optional markup
  8330.                               $qasked      # The command name
  8331.                             /mx) {
  8332.  
  8333.             while (
  8334.                 $pre580_help =~ /^
  8335.                                   (             # The command help:
  8336.                                    <?           # Optional '<'
  8337.                                    (?:[IB]<)    # Optional markup
  8338.                                    $qasked      # The command name
  8339.                                    ([\s\S]*?)   # Lines starting with tabs
  8340.                                    \n           # Final newline
  8341.                                   )
  8342.                                   (?!\s)/mgx)   # Line not starting with space
  8343.                                                 # (Next command's help)
  8344.             {
  8345.                 print_help($1);
  8346.             }
  8347.         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
  8348.  
  8349.         # Help not found.
  8350.         else {
  8351.             print_help("B<$asked> is not a debugger command.\n");
  8352.         }
  8353.     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
  8354. } ## end sub cmd_pre580_h
  8355.  
  8356. =head2 Old C<W> command
  8357.  
  8358. C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
  8359.  
  8360. =cut
  8361.  
  8362. sub cmd_pre580_W {
  8363.     my $xcmd = shift;
  8364.     my $cmd  = shift;
  8365.  
  8366.     # Delete all watch expressions.
  8367.     if ($cmd =~ /^$/) {
  8368.         # No watching is going on.
  8369.         $trace &= ~2;
  8370.         # Kill all the watch expressions and values.
  8371.         @to_watch = @old_watch = ();
  8372.     }
  8373.  
  8374.     # Add a watch expression.
  8375.     elsif ($cmd =~ /^(.*)/s) {
  8376.         # add it to the list to be watched.
  8377.         push @to_watch, $1;
  8378.  
  8379.         # Get the current value of the expression. 
  8380.         # Doesn't handle expressions returning list values!
  8381.         $evalarg = $1;
  8382.         my ($val) = &eval;
  8383.         $val = (defined $val) ? "'$val'" : 'undef';
  8384.  
  8385.         # Save it.
  8386.         push @old_watch, $val;
  8387.  
  8388.         # We're watching stuff.
  8389.         $trace |= 2;
  8390.  
  8391.     } ## end elsif ($cmd =~ /^(.*)/s)
  8392. } ## end sub cmd_pre580_W
  8393.  
  8394. =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
  8395.  
  8396. The debugger used to have a bunch of nearly-identical code to handle 
  8397. the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
  8398. C<cmd_prepost> unify all this into one set of code to handle the 
  8399. appropriate actions.
  8400.  
  8401. =head2 C<cmd_pre590_prepost>
  8402.  
  8403. A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
  8404. do something destructive. In pre 5.8 debuggers, the default action was to
  8405. delete all the actions.
  8406.  
  8407. =cut
  8408.  
  8409. sub cmd_pre590_prepost {
  8410.     my $cmd    = shift;
  8411.     my $line   = shift || '*';
  8412.     my $dbline = shift;
  8413.  
  8414.     return &cmd_prepost( $cmd, $line, $dbline );
  8415. } ## end sub cmd_pre590_prepost
  8416.  
  8417. =head2 C<cmd_prepost>
  8418.  
  8419. Actually does all the handling foe C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
  8420. Since the lists of actions are all held in arrays that are pointed to by
  8421. references anyway, all we have to do is pick the right array reference and
  8422. then use generic code to all, delete, or list actions.
  8423.  
  8424. =cut
  8425.  
  8426. sub cmd_prepost { my $cmd = shift;
  8427.  
  8428.     # No action supplied defaults to 'list'.
  8429.     my $line = shift || '?';
  8430.  
  8431.     # Figure out what to put in the prompt.
  8432.     my $which = '';
  8433.  
  8434.     # Make sure we have some array or another to address later.
  8435.     # This means that if ssome reason the tests fail, we won't be
  8436.     # trying to stash actions or delete them from the wrong place.
  8437.     my $aref  = [];
  8438.  
  8439.    # < - Perl code to run before prompt.
  8440.     if ( $cmd =~ /^\</o ) {
  8441.         $which = 'pre-perl';
  8442.         $aref  = $pre;
  8443.     }
  8444.  
  8445.     # > - Perl code to run after prompt.
  8446.     elsif ( $cmd =~ /^\>/o ) {
  8447.         $which = 'post-perl';
  8448.         $aref  = $post;
  8449.     }
  8450.  
  8451.     # { - first check for properly-balanced braces.
  8452.     elsif ( $cmd =~ /^\{/o ) {
  8453.         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
  8454.             print $OUT
  8455. "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
  8456.         }
  8457.  
  8458.         # Properly balanced. Pre-prompt debugger actions.
  8459.         else {
  8460.             $which = 'pre-debugger';
  8461.             $aref  = $pretype;
  8462.         }
  8463.     } ## end elsif ( $cmd =~ /^\{/o )
  8464.  
  8465.     # Did we find something that makes sense?
  8466.     unless ($which) {
  8467.         print $OUT "Confused by command: $cmd\n";
  8468.     }
  8469.  
  8470.     # Yes. 
  8471.     else {
  8472.         # List actions.
  8473.         if ( $line =~ /^\s*\?\s*$/o ) {
  8474.             unless (@$aref) {
  8475.                 # Nothing there. Complain.
  8476.                 print $OUT "No $which actions.\n";
  8477.             }
  8478.             else {
  8479.                 # List the actions in the selected list.
  8480.                 print $OUT "$which commands:\n";
  8481.                 foreach my $action (@$aref) {
  8482.                     print $OUT "\t$cmd -- $action\n";
  8483.                 }
  8484.             } ## end else
  8485.         } ## end if ( $line =~ /^\s*\?\s*$/o)
  8486.  
  8487.         # Might be a delete.
  8488.         else {
  8489.             if ( length($cmd) == 1 ) {
  8490.                 if ( $line =~ /^\s*\*\s*$/o ) {
  8491.                     # It's a delete. Get rid of the old actions in the 
  8492.                     # selected list..
  8493.                     @$aref = ();
  8494.                     print $OUT "All $cmd actions cleared.\n";
  8495.                 }
  8496.                 else {
  8497.                     # Replace all the actions. (This is a <, >, or {).
  8498.                     @$aref = action($line);
  8499.                 }
  8500.             } ## end if ( length($cmd) == 1)
  8501.             elsif ( length($cmd) == 2 ) { 
  8502.                 # Add the action to the line. (This is a <<, >>, or {{).
  8503.                 push @$aref, action($line);
  8504.             }
  8505.             else {
  8506.                 # <<<, >>>>, {{{{{{ ... something not a command.
  8507.                 print $OUT
  8508.                   "Confused by strange length of $which command($cmd)...\n";
  8509.             }
  8510.         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
  8511.     } ## end else
  8512. } ## end sub cmd_prepost
  8513.  
  8514.  
  8515. =head1 C<DB::fake>
  8516.  
  8517. Contains the C<at_exit> routine that the debugger uses to issue the
  8518. C<Debugged program terminated ...> message after the program completes. See
  8519. the C<END> block documentation for more details.
  8520.  
  8521. =cut
  8522.  
  8523. package DB::fake;
  8524.  
  8525. sub at_exit {
  8526.     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
  8527. }
  8528.  
  8529. package DB;    # Do not trace this 1; below!
  8530.  
  8531. 1;
  8532.  
  8533.