home *** CD-ROM | disk | FTP | other *** search
/ Superpower (Alt) / SUPERPOWER.iso / q / patch / mbq067 / combat.qc < prev    next >
Encoding:
Text File  |  1996-08-19  |  6.8 KB  |  311 lines
  1.  
  2. void() T_MissileTouch;
  3. void() info_player_start;
  4. void(entity targ, entity attacker) ClientObituary;
  5.  
  6. void() monster_death_use;
  7.  
  8. //============================================================================
  9.  
  10. /*
  11. ============
  12. CanDamage
  13.  
  14. Returns true if the inflictor can directly damage the target.  Used for
  15. explosions and melee attacks.
  16. ============
  17. */
  18. float(entity targ, entity inflictor) CanDamage =
  19. {
  20. // bmodels need special checking because their origin is 0,0,0
  21.     if (targ.movetype == MOVETYPE_PUSH)
  22.     {
  23.         traceline(inflictor.origin, 0.5 * (targ.absmin + targ.absmax), TRUE, self);
  24.         if (trace_fraction == 1)
  25.             return TRUE;
  26.         if (trace_ent == targ)
  27.             return TRUE;
  28.         return FALSE;
  29.     }
  30.     
  31.     traceline(inflictor.origin, targ.origin, TRUE, self);
  32.     if (trace_fraction == 1)
  33.         return TRUE;
  34.     traceline(inflictor.origin, targ.origin + '15 15 0', TRUE, self);
  35.     if (trace_fraction == 1)
  36.         return TRUE;
  37.     traceline(inflictor.origin, targ.origin + '-15 -15 0', TRUE, self);
  38.     if (trace_fraction == 1)
  39.         return TRUE;
  40.     traceline(inflictor.origin, targ.origin + '-15 15 0', TRUE, self);
  41.     if (trace_fraction == 1)
  42.         return TRUE;
  43.     traceline(inflictor.origin, targ.origin + '15 -15 0', TRUE, self);
  44.     if (trace_fraction == 1)
  45.         return TRUE;
  46.  
  47.     return FALSE;
  48. };
  49.  
  50.  
  51. /*
  52. ============
  53. Killed
  54. ============
  55. */
  56. void(entity targ, entity attacker) Killed =
  57. {
  58.     local entity oself;
  59.  
  60.     oself = self;
  61.     self = targ;
  62.     
  63.     if (self.health < -99)
  64.         self.health = -99;              // don't let sbar look bad if a player
  65.  
  66.     if (self.movetype == MOVETYPE_PUSH || self.movetype == MOVETYPE_NONE)
  67.     {       // doors, triggers, etc
  68.         self.th_die ();
  69.         self = oself;
  70.         return;
  71.     }
  72.  
  73.     self.enemy = attacker;
  74.  
  75. // bump the monster counter
  76.     if (self.flags & FL_MONSTER)
  77.     {
  78.         killed_monsters = killed_monsters + 1;
  79.         WriteByte (MSG_ALL, SVC_KILLEDMONSTER);
  80.     }
  81.  
  82.     ClientObituary(self, attacker);
  83.  
  84.     self.takedamage = DAMAGE_NO;
  85.     self.touch = SUB_Null;
  86.  
  87.     monster_death_use();
  88.     self.th_die ();
  89.     
  90.     self = oself;
  91. };
  92.  
  93.  
  94. /*
  95. ============
  96. T_Damage
  97.  
  98. The damage is coming from inflictor, but get mad at attacker
  99. This should be the only function that ever reduces health.
  100. ============
  101. */
  102. void(entity targ, entity inflictor, entity attacker, float damage) T_Damage=
  103. {
  104.     local   vector  dir;
  105.     local   entity  oldself;
  106.     local   entity  found;
  107.     local   float   save;
  108.     local   float   take;
  109.  
  110.     if (targ.classname == "bomb")
  111.         {
  112.         if (targ.items2 & IT2_MEGAPOWER)
  113.             targ.health = 10;
  114.         else
  115.             targ.health = 1;
  116.         return;
  117.         }
  118.  
  119.     if (targ.classname == "tripwire")
  120.     {        
  121.         targ.health = 5;
  122.         return;
  123.     }
  124.  
  125.     if (!targ.takedamage)
  126.         return;
  127.  
  128. // used by buttons and triggers to set activator for target firing
  129.     damage_attacker = attacker;
  130.  
  131. // check for quad damage powerup on the attacker
  132.     if (teamplay == 6 && attacker.super_damage_finished > time)
  133.     {
  134.         damage = damage * numplayers;
  135.     }
  136.     else
  137.     {
  138.         if (attacker.super_damage_finished > time)
  139.             damage = damage * 4;
  140.     }
  141.     if (teamplay == 7 && world_flag)
  142.         damage = 0;
  143.  
  144. // save damage based on the target's armor level
  145.  
  146.     save = ceil(targ.armortype*damage);
  147.     if (save >= targ.armorvalue)
  148.     {
  149.         save = targ.armorvalue;
  150.         targ.armortype = 0;     // lost all armor
  151.         targ.items = targ.items - (targ.items & (IT_ARMOR1 | IT_ARMOR2 | IT_ARMOR3));
  152.     }
  153.     
  154.     targ.armorvalue = targ.armorvalue - save;
  155.     take = ceil(damage-save);
  156.  
  157. // add to the damage total for clients, which will be sent as a single
  158. // message at the end of the frame
  159. // FIXME: remove after combining shotgun blasts?
  160.     if (targ.flags & FL_CLIENT)
  161.     {
  162.         targ.dmg_take = targ.dmg_take + take;
  163.         targ.dmg_save = targ.dmg_save + save;
  164.         targ.dmg_inflictor = inflictor;
  165.     }
  166.  
  167. // figure momentum add
  168.     if ( (inflictor != world) && (targ.movetype == MOVETYPE_WALK) )
  169.     {
  170.         dir = targ.origin - (inflictor.absmin + inflictor.absmax) * 0.5;
  171.         dir = normalize(dir);
  172.         targ.velocity = targ.velocity + dir*damage*8;
  173.     }
  174.  
  175. // check for godmode or invincibility
  176.     if (targ.flags & FL_GODMODE)
  177.         return;
  178.     if (targ.invincible_finished >= time)
  179.     {
  180.         if (self.invincible_sound < time)
  181.         {
  182.             sound (targ, CHAN_ITEM, "items/protect3.wav", 1, ATTN_NORM);
  183.             self.invincible_sound = time + 2;
  184.         }
  185.         return;
  186.     }
  187.  
  188. // team play damage avoidance
  189.     if ( (teamplay == 1 || teamplay == 7) && (targ.team > 0)&&(targ.team == attacker.team) )
  190.         return;
  191.         
  192. // do the damage
  193.     targ.health = targ.health - take;
  194.             
  195.     if (targ.health <= 0)
  196.     {
  197.         Killed (targ, attacker);
  198.         return;
  199.     }
  200.  
  201. // react to the damage
  202.     oldself = self;
  203.     self = targ;
  204.  
  205.     if ( (self.flags & FL_MONSTER) && attacker != world)
  206.     {
  207.     // get mad unless of the same class (except for soldiers)
  208.         if (self != attacker && attacker != self.enemy)
  209.         {
  210.             if ( (self.classname != attacker.classname) 
  211.             || (self.classname == "monster_army" ) )
  212.             {
  213.                 if (self.enemy.classname == "player")
  214.                     self.oldenemy = self.enemy;
  215.                 self.enemy = attacker;
  216.                 FoundTarget ();
  217.             }
  218.         }
  219.     }
  220.  
  221.     if (self.th_pain)
  222.     {
  223.         self.th_pain (attacker, take);
  224.     // nightmare mode monsters don't go into pain frames often
  225.         if (skill == 3)
  226.             self.pain_finished = time + 5;          
  227.     }
  228.  
  229.     self = oldself;
  230. };
  231.  
  232. /*
  233. ============
  234. T_RadiusDamage
  235. ============
  236. */
  237. void(entity inflictor, entity attacker, float damage, entity ignore) T_RadiusDamage =
  238. {
  239.     local   float   points;
  240.     local   entity  head;
  241.     local   vector  org;
  242.  
  243.     head = findradius(inflictor.origin, damage+40);
  244.     
  245.     while (head)
  246.     {
  247.         if (head != ignore)
  248.         {
  249.             if (head.takedamage)
  250.             {
  251.                 org = head.origin + (head.mins + head.maxs)*0.5;
  252.                 points = 0.5*vlen (inflictor.origin - org);
  253.                 if (points < 0)
  254.                     points = 0;
  255.                 points = damage - points;
  256.                 if (head == attacker)
  257.                     points = points * 0.5;
  258.                 if (points > 0)
  259.                 {
  260.                     if (CanDamage (head, inflictor))
  261.                     {       // shambler takes half damage from all explosions
  262.                         if (head.classname == "monster_shambler")                                               
  263.                             T_Damage (head, inflictor, attacker, points*0.5);
  264.                         else
  265.                             T_Damage (head, inflictor, attacker, points);
  266.                     }
  267.                 }
  268.             }
  269.         }
  270.         head = head.chain;
  271.     }
  272. };
  273.  
  274. /*
  275. ============
  276. T_BeamDamage
  277. ============
  278. */
  279. void(entity attacker, float damage) T_BeamDamage =
  280. {
  281.     local   float   points;
  282.     local   entity  head;
  283.     
  284.     head = findradius(attacker.origin, damage+40);
  285.     
  286.     while (head)
  287.     {
  288.         if (head.takedamage)
  289.         {
  290.             points = 0.5*vlen (attacker.origin - head.origin);
  291.             if (points < 0)
  292.                 points = 0;
  293.             points = damage - points;
  294.             if (head == attacker)
  295.                 points = points * 0.5;
  296.             if (points > 0)
  297.             {
  298.                 if (CanDamage (head, attacker))
  299.                 {
  300.                     if (head.classname == "monster_shambler")                                               
  301.                         T_Damage (head, attacker, attacker, points*0.5);
  302.                     else
  303.                         T_Damage (head, attacker, attacker, points);
  304.                 }
  305.             }
  306.         }
  307.         head = head.chain;
  308.     }
  309. };
  310.  
  311.