home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #26 / NN_1992_26.iso / spool / comp / os / vms / 17643 < prev    next >
Encoding:
Internet Message Format  |  1992-11-08  |  9.0 KB
  1. Path: sparky!uunet!comp.vuw.ac.nz!zl2tnm!don
  2. From: don@zl2tnm.gen.nz
  3. Newsgroups: comp.os.vms
  4. Subject: Re: Modem dialer for vms
  5. Message-ID: <1992Nov8.215519.2099@zl2tnm.gen.nz>
  6. Date: 8 Nov 92 21:55:19 +1300
  7. References: <1992Nov4.111515.1@musctn.monsanto.com>
  8. Organization: The Wolery
  9. Lines: 347
  10.  
  11. In article <1992Nov4.111515.1@musctn.monsanto.com>, rewise@musctn.monsanto.com (Richard Wiseman - VAX/VMS CraftsPerson) writes:
  12. >     with VMS dec supplies a modem dialer program... But of course
  13. >     It only speaks DMCL.. 
  14. >     What I'am looking for is a modified version that can talk to a HAYES
  15. >     compatible modem...
  16. > 
  17. >     OPerating system VAX_VMS
  18. >     version 5.5-1
  19. >     Modem type   Generic HAYEs
  20.  
  21. Here's DTE_HAYES.MAR, again.  Someone bung this on an archive somewhere.
  22.  
  23.  
  24. Don Stokes, ZL2TNM (DS555)                       don@zl2tnm.gen.nz (home)
  25. Network Manager, Computing Services Centre           don@vuw.ac.nz (work)
  26. Victoria University of Wellington, New Zealand             +64-4-495-5052
  27.  
  28.         .title DTE_HAYES   SET HOST/DTE dialler for Hayes "AT" modems
  29. ;++
  30. ;
  31. ; DTE_HAYES -- Hayes compatible dialler module for SET HOST/DTE
  32. ;
  33. ; This module allows a modem that understands the Hayes "AT" command set
  34. ; to be used with SET HOST/DTE/DIAL.
  35. ;
  36. ; To set up, compile and link as follows:
  37. ;
  38. ;    $ MACRO DTE_HAYES
  39. ;    $ LINK/SHARE DTE_HAYES
  40. ;
  41. ; To use, place DTE_HAYES.EXE into SYS$SHARE: and issue the command:
  42. ;
  43. ;    $ SET HOST/DTE modem/DIAL=(MODEM_TYPE=HAYES,NUMBER=number)
  44. ;
  45. ; Alternatively, assign the logical DTE_DF03 to point to DTE_HAYES (it doesn't
  46. ; need to be in SYS$SHARE:) and just use SET HOST/DTE/DIAL=number, eg:
  47. ;
  48. ;    $ ASSIGN SYS$LOGIN:DTE_HAYES DTE_DF03
  49. ;    $ SET HOST/DTE modem/DIAL=NUMBER=number
  50. ;
  51. ; (This works because DTE_DF03 is the default dialler module loaded if the
  52. ; MODEM_TYPE keyword is left off SET HOST/DTE.)  If you don't have any
  53. ; DF03s, you may wish to assign the logical systemwide.
  54. ;
  55. ;
  56. ;
  57. ;    Don Stokes                30-Oct-1991
  58. ;    Network manager, 
  59. ;    Computer Services Centre,        Email: don@vuw.ac.nz
  60. ;    Victoria University of Wellington,     Home:  don@zl2tnm.gen.nz
  61. ;    New Zealand.                Phone: +64 4 495-5052
  62. ;
  63. ; No warranty or support of any kind is expressed or implied, but bugfixes,
  64. ; suggestions or job offers are always welcome.  Copyright remains with the
  65. ; author.
  66. ;
  67. ;--
  68.  
  69.         .sbttl Macros and things
  70.  
  71.         $STSDEF
  72.         $SHRDEF
  73. ;
  74. ; CALL macro - call a subroutine, pass parameters on stack
  75. ; Usage:    CALL routine [,p1...,p20]
  76. ;
  77.         .macro call routine,                    -
  78.                 p1,p2,p3,p4,p5,p6,p7,p8,p9,p10,p11,        -
  79.                 p12,p13,p14,p15,p16,p17,p18,p19,p20
  80.         .narg call.argc
  81.         call.argc = call.argc - 1
  82.         call.argn = 20
  83.         .irp call.argv, <p20,p19,p18,p17,p16,p15,p14,p13,p12,    -
  84.                  p11,p10,p9,p8,p7,p6,p5,p4,p3,p2,p1>
  85.             .if less_equal call.argn - call.argc
  86.                 pushal call.argv
  87.             .endc
  88.             call.argn = call.argn - 1
  89.         .endr
  90.         calls #call.argc, G^routine
  91.         .endm
  92.  
  93. ;
  94. ; WANTS -- check if R0 is greater than or equal to value, abort if not
  95. ;
  96.         .macro wants, okmin, ?L1
  97.         cmpl R0, #okmin
  98.         bgeq L1
  99.         brw failed
  100. L1:        .endm
  101.  
  102. ;
  103. ; Status macro.
  104. ; Every good MACRO program has one of these; this is no exception.
  105. ;
  106.         .macro status, cond, ?L1
  107.         blbs cond, L1
  108.         $EXIT_S cond
  109. L1:        .endm
  110.  
  111.  
  112.  
  113.         .sbttl Data areas
  114.         .psect DTE_RW, long,noexe,wrt,noshr
  115.  
  116. ;
  117. ; Workings:
  118. ;
  119. iosb:        .blkw 4                ; Dogsbody iosb
  120. waittime:    .blkl                ; Temp storage for WAIT
  121. expect_buffer:    .blkb 32            ; Expect fifo
  122. expect_buffer_l = .-expect_buffer
  123. timeout:    .ascid "Timed out"        ; Time out message
  124. rem$_facility    = ^X1FE                ; REM-?-TEXT, message
  125. rem$_text    = SHR$_TEXT!<REM$_FACILITY@16>
  126.  
  127.  
  128.  
  129. ;
  130. ; Script stuff
  131. ;
  132. cr = 13
  133.  
  134. send_init:    .ascid "ATQ0"<cr>
  135. send_dial:    .ascid "ATDT"
  136. send_cr:    .ascid <cr>
  137. send_reset:    .ascid "ATZ"<cr>
  138.  
  139. init_expects:    .address expect_error        ; ERROR, didn't like something
  140.         .address expect_ring        ; RING, Abandon ship!
  141.         .address expect_ok        ; OK
  142.         .long 0
  143.  
  144. dial_expects:                ; 1 - 7 = failed
  145.         .address expect_busy        ; BUSY, engaged
  146.         .address expect_nocarr        ; NO CARRIER, multitude of sins
  147.         .address expect_error        ; ERROR, didn't like something
  148.         .address expect_nodial        ; NO DIALTONE, out of order
  149.         .address expect_noans        ; NO ANSWER, noone home
  150.         .address expect_voice        ; VOICE, Biological moduation
  151.         .address expect_ring        ; RING, oops!
  152.                     ; 8 onwards = success
  153.         .address expect_c38k        ; 38400bps, if ever 8-)
  154.         .address expect_c19k        ; 19200bps, eg Trailblazers?
  155.         .address expect_c12k        ; 12000bps, eg Compuspec M9600
  156.         .address expect_c9600        ; 9600bps, usually V32
  157.         .address expect_c4800        ; 4800 bps
  158.         .address expect_c2400        ; 2400 bps, usually V22bis
  159.         .address expect_c1200a        ; 1200 bps, usually V22
  160.         .address expect_c1200b        ; 1200 bps with other messages
  161.         .address expect_c1200c        ; 1200 bps with other messages
  162.         .address expect_c1275        ; 1200/75, V23
  163.         .address expect_c7512        ; 75/1200, V23
  164.         .address expect_c300        ; 300, V21 (or Bell 103)
  165.         .address expect_connect        ; Straight CONNECT
  166.         .long 0
  167.  
  168. expect_ok:    .ascid "OK"
  169. expect_busy:    .ascid "BUSY"
  170. expect_nocarr:    .ascid "NO CARRIER"
  171. expect_noans:    .ascid "NO ANSWER"
  172. expect_error:    .ascid "ERROR"
  173. expect_nodial:    .ascid "NO DIALTONE"
  174. expect_voice:    .ascid "VOICE"
  175. expect_ring:    .ascid "RING"
  176. expect_c38k:    .ascid "CONNECT 38400"
  177. expect_c19k:    .ascid "CONNECT 19200"
  178. expect_c12k:    .ascid "CONNECT 12000"
  179. expect_c9600:    .ascid "CONNECT 9600"
  180. expect_c4800:    .ascid "CONNECT 4800"
  181. expect_c2400:    .ascid "CONNECT 2400"
  182. expect_c1200a:    .ascid "CONNECT 1200"<cr>    ; To avoid it looking like
  183. expect_c1200b:    .ascid "CONNECT 1200/"        ; CONNECT 12000.
  184. expect_c1200c:    .ascid "CONNECT 1200 "
  185. expect_c1275:    .ascid "CONNECT 1275"
  186. expect_c7512:    .ascid "CONNECT 7512"
  187. expect_c300:    .ascid "CONNECT 300"
  188. expect_connect:    .ascid "CONNECT"<cr>
  189.  
  190.  
  191.  
  192.  
  193.         .sbttl Linkage
  194. ;
  195. ; Linkage code
  196. ;
  197.         .psect DTE_RE, long,exe,nowrt,shr
  198.         .transfer DIAL_ROUTINE
  199.         .mask DIAL_ROUTINE
  200.         brb DIAL_ROUTINE+2
  201.  
  202.  
  203.         .sbttl Mainline
  204. ;
  205. ; Main routine
  206. ; 4(AP) = Dial string
  207. ; 8(AP) = channel to modem
  208. ;12(AP) = channel to terminal
  209. ;
  210.         .entry DIAL_ROUTINE,^m<>
  211. ;
  212. ; Initialise modem
  213. ;
  214.         call wait @#1000        ; Let modem settle from shock
  215.         call flush @8(AP)        ; of being asked to do something
  216.         call send @8(AP), send_init    ; Initialise modem
  217.         call expect, @8(AP), init_expects, @#5
  218.         wants 3                ; Either OK, ERROR or RING
  219.  
  220. ;
  221. ; Dial number
  222. ;
  223.         call wait @#2000        ; Let modem recover from init
  224.         call send @8(AP), send_dial    ; Send ATDT
  225.         call send @8(AP), @4(AP)    ; Send phone
  226.         call send @8(AP), send_cr    ; Send cr
  227.         call expect, @8(AP), dial_expects, @#60
  228.         wants 8                ; Wait for CONNECT something
  229.  
  230. ;
  231. ; Connected.  Display connect message and hand control back to DTEPAD.
  232. ;
  233.         call LIB$SIGNAL @#rem$_text!STS$K_SUCCESS, @#1, (R1)
  234.         movl #SS$_NORMAL, R0        ; TA DA!
  235.         ret
  236.  
  237. ;
  238. ; Report status and die.  R1 = reason.
  239. ;
  240. failed:        call LIB$SIGNAL @#rem$_text!STS$K_ERROR, @#1, (R1)
  241.         movl #rem$_text!STS$M_INHIB_MSG!STS$K_ERROR, R0
  242.         ret
  243.  
  244.  
  245.  
  246.  
  247.         .sbttl Routine to send characters to the modem
  248. ;
  249. ; SEND chan, string
  250. ;
  251. ; Sends one character at a time to modem.
  252. ;
  253.         .entry send, ^m<R2,R3>
  254.         movl 8(AP), R0            ; R0 = descriptor addr
  255.         movl 4(R0), R2            ; R2 = pointer
  256.         cvtwl (R0), R3            ; R3 = counter
  257.  
  258. 1$:        $QIOW_S chan=4(AP), iosb=iosb, -
  259.             func=#IO$_WRITEVBLK!IO$M_NOFORMAT, -
  260.             p1=(R2), p2=#1
  261.         status R0
  262.         status iosb
  263.  
  264.         call wait @#100
  265.         status R0
  266.  
  267.         incl R2
  268.         decl R3
  269.         bneq 1$
  270.  
  271.         ret
  272.  
  273.  
  274.         .sbttl Routine to flush the typeahead buffer
  275. ;
  276. ; FLUSH channel
  277. ;
  278. ; Flushes the typeahead
  279. ;
  280.         .entry flush, ^m<>
  281. 1$:        $QIOW_S chan=4(AP), iosb=iosb, -
  282.             func=#IO$_READVBLK!IO$M_PURGE!IO$M_TIMED,-
  283.             p1=expect_buffer, p2=#0, p3=#0
  284.         status R0
  285.         ret
  286.  
  287.  
  288.  
  289.         .sbttl Routine to read characters and match expected strings
  290. ;
  291. ; EXPECT chan, expect_address, timeout
  292. ;
  293. ; Expects strings to come in through the port.  expect_address is a pointer
  294. ; to an array of pointers to descriptors; zero address terminates the array.
  295. ; R0 at end gives index (plus one) of the string that matched, or zero if it
  296. ; timed out.  R1 points to string that matched or "Timed out" if timeout.
  297. ;
  298.         
  299.         .entry expect, ^m<R2,R3,R4,R5,R6,R7,R8>
  300. ;
  301. ; Read character
  302. ;
  303.         movc5 #0,#0,#0, #expect_buffer_l, expect_buffer
  304. 1$:        movc3 #31, expect_buffer+1, expect_buffer
  305.         $QIOW_S chan=4(AP), iosb=iosb, -
  306.             func=#IO$_READVBLK!IO$M_TIMED!IO$M_NOECHO, -
  307.             p1=expect_buffer+expect_buffer_l-1, p2=#1, p3=12(AP)
  308.         status R0
  309. ;
  310. ; Exit if timeout
  311. ;
  312.         cmpw iosb, #SS$_TIMEOUT
  313.         bneq 2$
  314.         movaq timeout, R1        ; R1 = timeout message
  315.         clrl R0                ; R0 = 0
  316.         ret
  317. 2$:        status R0
  318.  
  319. ;
  320. ; Search expect list for string in expect buffer
  321. ;
  322.         movl 8(AP), R7            ; R7 = base of expect list
  323.         clrl R8                ; R8 = index into expect list
  324. 4$:        movl (R7)[R8], R6        ; R6 = address of expect string
  325.         beql 5$                ; If zero get next character
  326.         cvtwl (R6), R1            ; R1 = length of string
  327.         subl3 R1, #expect_buffer_l, R2    ; R2 = position of candidate
  328.         movab expect_buffer, R0
  329.         cmpc R1, @4(R6), (R0)[R2]
  330.         beql 6$                ; compare expect with candidate
  331.         incl R8                ; R8 = next expect number
  332.         brb 4$
  333.  
  334. 5$:        brw 1$                ; No match, next please
  335.  
  336. ;
  337. ; If found, R1 = address of string, R0 = index (plus 1)
  338. ;
  339. 6$:        movl R6, R1
  340.         movl R8, R0
  341.         incl R0
  342.         ret
  343.  
  344.  
  345.  
  346.         .sbttl Routine to wait for a period of time
  347. ;
  348. ; WAIT miliseconds
  349. ;
  350.         .entry wait, ^m<>
  351.         cvtlf 4(AP), R0
  352.         mulf3 #0.001, R0, waittime
  353.         call LIB$WAIT waittime
  354.         ret
  355.  
  356.  
  357.         .end
  358.