home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #26 / NN_1992_26.iso / spool / comp / database / informix / 2356 < prev    next >
Encoding:
Internet Message Format  |  1992-11-09  |  3.1 KB
  1. Path: sparky!uunet!destroyer!sol.ctr.columbia.edu!emory!emory!not-for-mail
  2. From: dave.snyder@snide.com (Dave Snyder)
  3. Newsgroups: comp.databases.informix
  4. Subject: Re: defer interrupt
  5. Date: 9 Nov 1992 19:43:07 -0500
  6. Organization: Mailing List Gateway
  7. Lines: 94
  8. Sender: walt@mathcs.emory.edu
  9. Distribution: world
  10. Message-ID: <1dn0irINNnsc@emory.mathcs.emory.edu>
  11. Reply-To: dave.snyder@snide.com (Dave Snyder)
  12. NNTP-Posting-Host: emory.mathcs.emory.edu
  13. X-Informix-List-ID: <list.1578>
  14.  
  15. Quoting Kristjan Gaukur Kristjansson...
  16. } 
  17. } I'm currently trying to figure out how to properly use 'defer interrupt'
  18. } and 'options sql interrupt on' to stop sql queries.
  19. } 
  20. } I know I have to check on int_flag everywhere but when I try to use it
  21. } with 'foreach' loops then I don't seem to have much control over when
  22. } it's detected.
  23. } 
  24. } Are there any guidelines out there on the best use of this feature or
  25. } something that helps me better to understand this.
  26. } (F.ex. should I rather use open,fetch,close than foreach.  Shall I use it
  27. } after every possible SQL-statement or just some.)
  28. } 
  29. This is how I write my query functions.  It seems to work pretty good too.
  30.  
  31. Here --------- Snip Here --------- Snip Here --------- Snip Here --------- Snip
  32. FUNCTION qry_address()
  33.     DEFINE  q_txt CHAR(512)
  34.     DEFINE  w_rowid INTEGER
  35.  
  36.     DISPLAY "QUERY:  ESCAPE queries.  INTERRUPT discards query.  ARROW keys move cursor.", "" AT 1,1
  37.     DISPLAY "Searches the active database table.", "" AT 2,1
  38.     MESSAGE ""
  39.  
  40.     CLEAR FORM
  41.     LET int_flag = FALSE
  42.     CONSTRUCT BY NAME q_txt ON address.* HELP 2
  43.  
  44.     IF int_flag THEN
  45.         RETURN
  46.     END IF
  47.  
  48.     LET q_txt = "SELECT address.ROWID FROM address WHERE ", q_txt CLIPPED
  49.  
  50.     WHENEVER ERROR CONTINUE
  51.     OPTIONS SQL INTERRUPT ON
  52.     MESSAGE "Searching ..."
  53.  
  54.     PREPARE q_sid FROM q_txt
  55.     IF STATUS THEN
  56.         CALL err_print(STATUS)
  57.         OPTIONS SQL INTERRUPT OFF
  58.         RETURN
  59.     END IF
  60.  
  61.     DECLARE q_curs CURSOR FOR q_sid
  62.     IF STATUS THEN
  63.         CALL err_print(STATUS)
  64.         OPTIONS SQL INTERRUPT OFF
  65.         RETURN
  66.     END IF
  67.  
  68.     LET q_cnt = 0
  69.     FOREACH q_curs INTO w_rowid
  70.         LET q_cnt = q_cnt + 1
  71.         IF s_rowid_s(q_cnt) != 0 THEN
  72.             ERROR " Memory allocation error, out of memory  "
  73.             OPTIONS SQL INTERRUPT OFF
  74.             RETURN
  75.         END IF
  76.         CALL w_rowid_s(q_cnt, w_rowid)
  77.  
  78.         IF int_flag THEN
  79.             EXIT FOREACH
  80.         END IF
  81.     END FOREACH
  82.  
  83.     OPTIONS SQL INTERRUPT OFF
  84.     WHENEVER ERROR STOP
  85.  
  86.     MESSAGE ""
  87.     IF int_flag THEN
  88.         ERROR " Statement interrupted by user  "
  89.         SLEEP 1
  90.     END IF
  91.  
  92.     IF q_cnt = 0 THEN
  93.         ERROR " There are no rows satisfying the conditions  "
  94.         LET q_cur = 0
  95.     ELSE
  96.         MESSAGE q_cnt, " rows(s) found"
  97.         LET q_cur = 1
  98.     END IF
  99. END FUNCTION
  100.  
  101.  
  102. Here --------- Snip Here --------- Snip Here --------- Snip Here --------- Snip
  103.  
  104. DAS
  105. -- 
  106. David Snyder @ Snide Computer Services - Folcroft, PA          Current Release
  107.                                                                is db4glgen-3.7
  108. UUCP:  ..!uunet!das13!dave   INTERNET:  dave.snyder@snide.com
  109.