home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #26 / NN_1992_26.iso / spool / bit / listserv / ibmmain / 2584 < prev    next >
Encoding:
Internet Message Format  |  1992-11-08  |  10.1 KB
  1. Path: sparky!uunet!stanford.edu!bu.edu!wupost!sdd.hp.com!nigel.msen.com!emory!europa.asd.contel.com!paladin.american.edu!auvm!UTMARTN.BITNET!##09
  2. From: ##09@UTMARTN.BITNET (Larry Holder)
  3. Newsgroups: bit.listserv.ibm-main
  4. Subject: Upper/Lower Case Exit for CICS
  5. Message-ID: <06NOV92.17720943.0016.MUSIC@UTMARTN>
  6. Date: 6 Nov 92 22:24:29 GMT
  7. Sender: IBM Mainframe Discussion list <IBM-MAIN@RICEVM1.BITNET>
  8. Lines: 150
  9. Comments: Gated by NETNEWS@AUVM.AMERICAN.EDU
  10. In-Reply-To:  In reply to your message of FRI 06 NOV 1992 14:44:00 CST
  11.  
  12. > We run CICS 2.1.2 in MVS/ESA 4.2 amd we are looking for an exit to allow
  13. > upper and lower case transactions for a case tool project.  We have
  14. > checked the SHARE tape for CICS and were unable to find anything there.
  15. > Does anyone know of such an exit?  Please let me know. Thanks
  16.  
  17. Here's ours.  It is LINK'd to from any application.
  18. It works for both 1.7 and 2.1.
  19.  
  20. Larry Holder,  Sr. Programmer/Analyst            Bitnet: ##09@UTMARTN
  21. The University of Tennessee at Martin            Phone:  901-587-7890
  22. Martin, TN  38238                                Fax:    901-587-7841
  23.  
  24. Software: VM/ESA 1.0, VSE/ESA 1.1, CICS/VSE 2.1, COBOL-II, DL/I, SQL/DS
  25. Hardware: IBM 9221-150 with 9336 FBA dasd
  26. PSW:      (Personal Status Words): Saved by grace (Romans 1:16 & 8:38)
  27.  
  28. SOURCE CODE BEGINS...................
  29. ***********************************************************************
  30. *                                                                     *
  31. * PROGRAM NAME:  MIXCASE.                                             *
  32. *                                                                     *
  33. * TRANSID:       (NONE; INVOKED VIA CICS LINK).                       *
  34. *                                                                     *
  35. * AUTHOR:        LARRY HOLDER.                                        *
  36. *                                                                     *
  37. * INSTALLATION:  UNIVERSITY OF TENNESSEE AT MARTIN.                   *
  38. *                                                                     *
  39. * DATE WRITTEN:  FEBRUARY 28, 1990.                                   *
  40. *                                                                     *
  41. * PURPOSE:       CHANGE CASE FROM UPPER TO MIXED OR VICE-VERSA,       *
  42. *                OR INQUIRE ON CURRENT CASE SETTING.                -01
  43. *                                                                     *
  44. * SYSTEM NOTES:  VSE 3.1.2; CICS 1.7 (COMMAND LEVEL).                 *
  45. *                                                                     *
  46. *                TCTTE FIELD TCTEUCTB (INDEX FOR TRANSLATE TABLE),    *
  47. *                WHICH IS OFFSET +6B IN CICS 1.7, IS X'01' FOR        *
  48. *                UPPER-CASE TRANSLATION, AND X'00' FOR MIXED.         *
  49. *                                                                     *
  50. * INPUT:         CALLER MUST PASS 2 BYTE COMMAREA, CONTAINING:        *
  51. *                                                                     *
  52. *                1. A REQUEST CODE:                                   *
  53. *                   "U" UPPER CASE.                                   *
  54. *                   "M" MIXED CASE.                                   *
  55. *                   "Q" QUERY CURRENT CASE.                         -01
  56. *                                                                   -01
  57. *                2. A RESPONSE CODE:                                -01
  58. *                   " " (BLANK) MEANS CASE SET AS REQUESTED.        -01
  59. *                   "U" OR "M" IS RESPONSE TO QUERY REQUEST.        -01
  60. *                   "?" IS RESPONSE TO INVALID REQUEST.             -01
  61. *                                                                     *
  62. *---------------------------------------------------------------------*
  63. *                                                                     *
  64. * MAINTENANCE HISTORY:                                                *
  65. *                                                                     *
  66. * DATE      DESCRIPTION                                           II-NN
  67. *                                                                     *
  68. * 90-02-28  INITIAL VERSION COMPLETED.............................LH-00
  69. * 90-04-18  ADDED QUERY SUPPORT AND RESPONSE CODE.................LH-01
  70. *                                                                     *
  71. ***********************************************************************
  72.          EJECT
  73. ***********************************************************************
  74. *        REGISTER USEAGE                                              *
  75. ***********************************************************************
  76. *                                                                     *
  77. R0       EQU   0                                                      *
  78. R1       EQU   1                                                      *
  79. R2       EQU   2                                                      *
  80. R3       EQU   3                                                      *
  81. R4       EQU   4                                                      *
  82. R5       EQU   5                                                      *
  83. R6       EQU   6                                                      *
  84. DATAREG  EQU   7                       DATAREG                        *
  85. CODEREG  EQU   8                       CODEREG                        *
  86. EIBREG   EQU   9                       EIBREG                         *
  87. CAREG    EQU   10                      COMMAREA                       *
  88. TCTTEAR  EQU   11                      TCTTE                          *
  89. R12      EQU   12                      TCA                            *
  90. CSACBAR  EQU   13                      CSA                            *
  91. R14      EQU   14                                                     *
  92. R15      EQU   15                                                     *
  93. *                                                                     *
  94. ***********************************************************************
  95.          SPACE
  96. ***********************************************************************
  97. *        COMMAREA DSECT.                                              *
  98. ***********************************************************************
  99. *                                                                     *
  100. COMMAREA DSECT                                                        *
  101. REQCODE  DS    CL1                     REQUEST CODE.                  *
  102. RESPCODE DS    CL1                     RESPONSE CODE.               -01
  103. *                                                                     *
  104. ***********************************************************************
  105.          SPACE
  106.          DFHEISTG                      EIB DYNAMIC STORAGE
  107.          SPACE
  108.          PRINT NOGEN
  109.          COPY  DFHCSADS                COMMON SYSTEM AREA
  110.          SPACE
  111.          DFHTCA                        TASK CONTROL AREA (USER AREA)
  112.          SPACE
  113.          COPY  DFHTCTTE                TCT TERMINAL ENTRY
  114.          SPACE
  115.          PRINT GEN
  116. ***********************************************************************
  117. *        PROGRAM ENTRY.                                               *
  118. ***********************************************************************
  119. *                                                                     *
  120. MIXCASE  DFHEIENT CODEREG=CODEREG,DATAREG=DATAREG,EIBREG=EIBREG       *
  121. *                                                                     *
  122.          B     STRT                    BYPASS CONSTANTS...            *
  123.          DC    CL8'MIXCASE '                                          *
  124.          DC    CL8'04/18/90'           LAST CHG DATE.               -XX
  125. STRT     DS    0H                                                     *
  126.          EXEC  CICS ADDRESS CSA(CSACBAR).   R13 -> CSA.               *
  127. *                                                                     *
  128.          L     TCACBAR,CSACDTA         R12 -> TCA USER AREA.          *
  129.          L     TCTTEAR,TCAFCAAA        R11 -> TCT TERMINAL ENTRY.     *
  130. *                                                                     *
  131.          L     CAREG,DFHEICAP          ADDR THE COMMAREA.             *
  132.          USING COMMAREA,CAREG          (NOTIFY ASSEMBLER).            *
  133. *                                                                     *
  134.          CLI   REQCODE,C'U'            REQUEST UPPER CASE ?           *
  135.          BNE   NOTUPPER                ==> NO...                      *
  136.          MVI   TCTEUCTB,X'01'          SET UPPERCASE XLATE ON.        *
  137.          MVI   RESPCODE,C' '           SET RESPONSE TO BLANK.       -01
  138.          B     PGMEXIT                 ==> DONE.                      *
  139. NOTUPPER DS    0H                                                     *
  140.          CLI   REQCODE,C'M'            REQUEST MIXED CASE ?           *
  141.          BNE   NOTMIXED                ==> NO...                      *
  142.          MVI   TCTEUCTB,X'00'          SET UPPERCASE XLATE OFF.       *
  143.          MVI   RESPCODE,C' '           SET RESPONSE TO BLANK.       -01
  144.          B     PGMEXIT                 ==> DONE.                      *
  145. NOTMIXED DS    0H                                                     *
  146.          CLI   REQCODE,C'Q'            QUERY REQUEST ?              -01
  147.          BNE   NOTQUERY                ==> NO...                    -01
  148.          MVI   RESPCODE,C'U'           ASSUME UPPERCASE.            -01
  149.          CLI   TCTEUCTB,X'01'          CORRECT ?                    -01
  150.          BE    PGMEXIT                 ==> YES..DONE.               -01
  151.          MVI   RESPCODE,C'M'           THEN MUST BE MIXED CASE.     -01
  152.          B     PGMEXIT                 ==> DONE.                    -01
  153. NOTQUERY DS    0H                                                   -01
  154.          MVI   RESPCODE,C'?'           INDICATE CALLER'S ERROR.     -01
  155. PGMEXIT  DS    0H                                                     *
  156.          EXEC  CICS RETURN.            RETURN TO CALLER.              *
  157. *                                                                     *
  158.          LTORG ,                                                      *
  159. *                                                                     *
  160. ***********************************************************************
  161.          END   MIXCASE
  162.