home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #20 / NN_1992_20.iso / spool / comp / unix / question / 11006 < prev    next >
Encoding:
Text File  |  1992-09-12  |  2.7 KB  |  104 lines
  1. Newsgroups: comp.unix.questions
  2. Path: sparky!uunet!wupost!zaphod.mps.ohio-state.edu!news.acns.nwu.edu!nucsrl!ddsw1!dattier
  3. From: dattier@ddsw1.mcs.com (David W. Tamkin)
  4. Subject: Re: SED GURUS: Some Newline Questions
  5. Message-ID: <BuHy8M.3EA@ddsw1.mcs.com>
  6. Keywords: sed newline
  7. Organization: Contributor Account at ddsw1, Chicago, Illinois  60657
  8. References: <1992Sep10.230603.1267@ncsu.edu>
  9. Date: Sun, 13 Sep 1992 03:12:21 GMT
  10. Lines: 92
  11.  
  12. fester@mamushka.ncsu.edu wrote in <1992Sep10.230603.1267@ncsu.edu>:
  13.  
  14. | Hi sed people.  For a project I'm working on, I'm trying to
  15. | figure out how to insert newlines in sed.  Here's the scenario:
  16. | 
  17. | 1)  In the input text, lines ending with a semicolon need to have 
  18. |     a right bracket and newline inserted:
  19.  
  20. What you show there are braces; the right bracket is "]".
  21.  
  22. | --before--
  23. | start
  24. | { THIS IS LINE 1;
  25. | { THIS IS LINE 2;
  26. | end
  27. | 
  28. | --after--
  29. | start
  30. | 
  31. | { THIS IS LINE 1; }
  32. | 
  33. | { THIS IS LINE 2; }
  34. | 
  35. | end
  36. | 
  37. | I've got this much:
  38. | 
  39. |    sed -e 's/;$/; \}/'
  40. |                   ^necessary?
  41. |   
  42. | Adding \n, \\n, or \\\n was fruitless.
  43.  
  44. You're adding a space and a right brace there.  (No, the right brace doesn't
  45. need escaping inside a text string.)  Do you want a space as well?  I'll
  46. assume not.
  47.  
  48. There are at least four ways to go:
  49.  
  50. # This assumes that the hold space, which starts out empty, will stay empty:
  51. sed '/;$/{
  52. G
  53. s/$/}/
  54. }'
  55.  
  56. [Append a newline and the hold space and then place a right brace at the
  57. right anchor.]
  58.  
  59. # This one must be strong-quoted or placed in a script file for sed -f:
  60. sed 's/;$/&\
  61. /'
  62.  
  63. [(Well, it could work weak-quoted if you use two backslashes.)  Place a
  64. newline and a right brace at the right anchor.]
  65.  
  66. # The same cautions to protect the trailing backslash apply to this one:
  67. sed '/;$/a\
  68. }'
  69. [Output a line consisting of a right brace after you finish with the line
  70. being processed.]
  71.  
  72. # If you don't need the hold space for anything else, keep a brace there:
  73. sed '1{
  74. h
  75. s/.*/}/
  76. x
  77. }
  78. /;$/G'
  79. [Put a right brace into the hold space and append it (with a separating
  80. newline) to every line otherwise ending in a semicolon.]
  81.  
  82. | 2)  Next, I need to delete a newline from text:
  83.  
  84. You need to use N to get both lines (with a separating embedded newline) into
  85. the pattern space at once: it's all in The Ferkakte Manual.  Then you can
  86. search for an embedded newline with \n (unfortunately, \n doesn't work in
  87. replacement strings).
  88.  
  89. To change every occurrence of 
  90.  
  91. pattern1             to          pattern1 pattern2
  92. pattern2
  93.  
  94. you can do something like this (just trust me):
  95.  
  96. sed 'N
  97. s/\(pattern1\)\n\(pattern2\)/\1 \2/
  98. $ b
  99. P
  100. D'
  101.  
  102. David W. Tamkin   Box 59297   Northtown Station, Illinois  60659-0297
  103. dattier@ddsw1.mcs.com    CompuServe: 73720,1570    MCI Mail: 426-1818
  104.