NetNews Usenet Archive 1992 #20/NN_1992_20.iso/spool/comp/os/vms/15037

Internet Message Format | 1992-09-14 | 3.4 KB

Path: sparky!uunet!cis.ohio-state.edu!pacific.mps.ohio-state.edu!linac!att!ucbvax!UH01.Colorado.EDU!DWING
From: [e-mail] (Dan Wing)
Newsgroups: comp.os.vms
Subject: Re: %BACKUP-E-NOMSG, Message number 00A38012 ???
Message-ID: <[e-mail]>
Date: 14 Sep 92 23:31:58 GMT
Sender: [e-mail]
Distribution: world
Organization: The Internet
Lines: 91

Brent Sterner, <[e-mail]>, writes:

>   OK, I've been doing other work for too long.  I have a user who
>   complained that backup produced the following diagnostics:
>
>     %BACKUP-E-NOMSG, Message number 00A38012
>    and
>     %BACKUP-W-NOMSG, Message number 00A38410
>
>   So I pumped the numbers through the DCL f$message lexical, and the
>   messages are indeed exactly what the user reported.  So, what is wrong
>   (and what is *really* going on)?  Hints would be appreciated.  A clear
>   resolution would be met with his eternal gratitude.  Chow,  b.

The BACKUP error messages are in SYS$MESSAGE:SYSMGTMSG:

  $ SET MESSAGE SYS$MESSAGE:SYSMGTMSG
  $ WRITE SYS$OUTPUT F$MESSAGE(%X0A38410)
  %BACKUP-W-ACCONFLICT, !AS is open for write by another user
  $ WRITE SYS$OUTPUT F$MESSAGE(%X0A38012)
  %BACKUP-E-OPENOUT, error opening !AS as output

You can avoid the anoyying "Message number nnnn" messages by lowering the
users' FILLM (in SYSUAF) to something smaller than CHANNELCNT (in SYSGEN).
There's a DSNlink article that recommends FILLM be at least 15 less than
CHANNELCNT.

If this is really a "user", you may want to (or you may not want to!) tune
their username to use BACKUP efficiently per the VMS V5.2 release notes.

Also see attached .COM file.

-Dan Wing, [e-mail] or [e-mail] (DGW11)
 Systems Programmer, University Hospital, Denver


$! MESSAGE.COM - get text of a message number
$!
$! P1 = message number (integer)
$!
$! Sample usage:
$!   @TRYMSG %X0000002A
$!
$!  EDIT DATE  EDIT  BY   DESCRIPTION
$!  ---------  ----  ---  ---------------------------------------
$!   2-SEP-92  102   DGW  Handle and display errors caused by
$!                        "%SYSTEM-F-IVSECIDCTL".
$!  13-AUG-92  101   DGW  Added SET MESSAGE/DELETE (per David P. Murphy,
$!                        <[e-mail]>) to remove effect of SET
$!                        MESSAGEs.
$!  13-AUG-92  100   DGW  Documented, upcased, added 'no message found'.
$!
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$
$
$  IF F$TYPE(P1) .NES. "INTEGER"
$  THEN
$    WRITE SYS$OUTPUT "P1 must be an INTEGER"
$    GOTO DONE
$  ENDIF
$
$  P1 = F$INTEGER(P1)
$  WRITE SYS$OUTPUT F$FAO("Searching for all messages with value %X!XL",P1)
$  MESSAGE_FOUND = 0
$
$LOOP:
$  FILENAME = F$SEARCH("SYS$MESSAGE:*.EXE;")
$  IF FILENAME .EQS. "" THEN GOTO DONE
$
$  WRITE SYS$OUTPUT F$FAO("!5* Checking !AS", FILENAME)
$  DEFINE/USER_MODE SYS$OUTPUT NLA0:    ! ignore "%SYSTEM-F-IVSECIDCTL" errors
$  DEFINE/USER_MODE SYS$ERROR NLA0:
$  SET noON
$  SET MESSAGE 'FILENAME'
$  IF .NOT. $STATUS THEN WRITE SYS$OUTPUT "(Error using above file: ", F$MESSAGE($STATUS), ")"
$  SET ON
$  TEXT = F$MESSAGE('P1')
$
$  IF F$EXTRACT(0,7,TEXT) .EQS. "%NONAME" THEN GOTO LOOP
$  IF F$LOCATE("-NOMSG,",TEXT) .NE. F$LENGTH(TEXT) THEN GOTO LOOP
$  WRITE SYS$OUTPUT TEXT
$  WRITE SYS$OUTPUT ""
$  MESSAGE_FOUND = 1
$  GOTO LOOP
$
$DONE:
$  IF .NOT. MESSAGE_FOUND THEN WRITE SYS$OUTPUT -
     F$FAO("No messages found in SYS$MESSAGE for %X!XL",P1)
$  SET MESSAGE/DELETE
$  EXIT