home *** CD-ROM | disk | FTP | other *** search
/ io Programmo 9 / IOPROG_9.ISO / contrib / iis4 / iis4_07.cab / startftp.vbs < prev    next >
Encoding:
Text File  |  1997-08-28  |  1.7 KB  |  67 lines
  1. '------------------------------------------------------------------------------------------------
  2. '
  3. ' Usage: ASTStartFtpServers <--ADSPath|-a server1[,server2,server3...]>
  4. '                           [--help|-?]
  5. '
  6. ' SERVERx         ADSI Path to the server to be started
  7. '
  8. ' Example 1: ASTStartFtpServers --adspath 3,1
  9. '------------------------------------------------------------------------------------------------
  10.  
  11. ' Force explicit declaration of all variables.
  12. Option Explicit
  13.  
  14. On Error Resume Next
  15.  
  16. Dim oArgs, ArgNum, ArgServerList
  17.  
  18. Set oArgs = WScript.Arguments
  19. ArgNum = 0
  20. While ArgNum < oArgs.Count
  21.  
  22.     Select Case LCase(oArgs(ArgNum))
  23.         Case "--adspath","-a":
  24.             ArgNum = ArgNum + 1
  25.             ArgServerList=Split(oArgs(ArgNum), ",", -1)
  26.         Case "--help","-?":
  27.             Call DisplayUsage
  28.         Case Else:
  29.             Call DisplayUsage
  30.     End Select    
  31.  
  32.     ArgNum = ArgNum + 1
  33. Wend
  34.  
  35. If Not IsArray(ArgServerList) Then
  36.     Call DisplayUsage
  37. End If
  38.  
  39. Call ASTStartFtpServers(ArgServerList)
  40.  
  41. Sub ASTStartFtpServers(ServerList)
  42.     Dim ServerNum, oServer
  43.  
  44.     ServerNum = 0
  45.     While ServerNum <= UBound(ServerList)
  46.         Display "Starting " & ServerList(ServerNum) & "..."
  47.         Set oServer = GetObject("IIS://LocalHost/msftpsvc/" & ServerList(ServerNum))
  48.         oServer.Start
  49.         If Err <> 0 Then
  50.             Display "Couldn't start server " & ServerList(ServerNum) & "!"
  51.             WScript.Quit (1)
  52.         End If
  53.         ServerNum = ServerNum + 1
  54.     Wend 
  55. End Sub
  56.     
  57. Sub Display(Msg)
  58.     WScript.Echo Now & ". Error Code: " & Err & " --- " & Msg
  59. End Sub
  60.  
  61. Sub DisplayUsage
  62.     WScript.Echo "Usage: ASTStartFtpServers <--ADSPath|-a server1[,server2,server3...]>"
  63.     WScript.Echo "                          [--help|-?]"
  64.     WScript.Quit (1)
  65. End Sub
  66.  
  67.