home *** CD-ROM | disk | FTP | other *** search
/ io Programmo 23 / IOPROG_23.ISO / SOFT / ASM / OPTIMIZE.ZIP / LINE.ASM < prev    next >
Encoding:
Assembly Source File  |  1997-03-04  |  6.7 KB  |  149 lines
  1. ;███████████████1997 Nickolay CHirkov, rzv@si.moris.rosmail.com███████████████
  2. ;This program is example how to write very fast locally optimized code
  3. ;It is create lines in the raster of screen or in the memory block
  4. ;(max 64 Kbyte)
  5. ;The main procedure has tested in several types of machine (see table) in
  6. ;the cycle creating 100,000,000 pixels with defferent direction of lines
  7. ;and with length each of them 130 pixels
  8. ;╔═══════╦═══╦════════════════════╦══════════════════════════════════════════╗
  9. ;║  CPU  ║   ║ Video System       ║  Performance,time-sec/tact-per-pixel     ║
  10. ;║       ║   ║                    ╟──────────┬──────────┬──────────┬─────────╢
  11. ;║       ║   ║                    ║   *1     │   *2     │   *3     │   *4    ║
  12. ;╠═══════╬═══╬════════════════════╬══════════╪══════════╪══════════╪═════════╣
  13. ;║486DX2 ║66 ║VLB,CirrusLogic 5429║  19.25s  │  15.13s  │  10.40s  │  10.12s ║
  14. ;║       ║   ║                    ║  12.7t   │  9.98t   │  6.86t   │  6.68t  ║
  15. ;╟───────╫───╫────────────────────╫──────────┼──────────┼──────────┼─────────╢
  16. ;║486DX4 ║100║ PCI,Avance Logic   ║  10.51s  │  12.49s  │  8.8s    │  6.77s  ║
  17. ;║       ║   ║ ALG-2302 V.5.10.A  ║  10.51t  │  12.49t  │  8.8t    │  6.77t  ║
  18. ;╟───────╫───╫────────────────────╫──────────┼──────────┼──────────┼─────────╢
  19. ;║Pentium║100║  PCI,S3 TRIO 64    ║  15.79s  │  10.67s  │          │  4.24s  ║
  20. ;║       ║   ║                    ║  15.79t  │  10.67t  │          │  4.24t  ║
  21. ;╚═══════╩═══╩════════════════════╩══════════╧══════════╧══════════╧═════════╝
  22. ;  *1 - lines created into the video memory in standard VGA-mode 320*200*8bit
  23. ;  *2 - lines created into the base memory (Windows 95,DOS-mode)
  24. ;  *3 - lines created into the base memory (Windows 95,DOS-mode,without himem.sys)
  25. ;  *4 - without writing into the memory (Windows 95,DOS-mode)
  26.  
  27. ; For Masm
  28. .model small
  29. .stack 6                              ;needed for int-instruction
  30. .data
  31.  
  32. X0            dw    160               ;the coordinates of the line
  33. Y0            dw    100
  34. X1            dw    0
  35. Y1            dw    0
  36. VIDRAM        dw    0A000h            ;segment or selector of memory block where will be created the line
  37. COLOR         db    3
  38.  
  39. .code
  40. .286
  41. Begin:
  42.                 mov  ax,@DATA
  43.                 mov  ds,ax
  44.                 mov  ax,13h
  45.                 int  10h
  46.  
  47.                 call OutLine          ;near call the procedure which create the line
  48.  
  49.                 xor  ax,ax
  50.                 int  16h
  51.  
  52. EndOfProgram:   mov  ax,3h
  53.                 int  10h
  54.                 mov   ah,04Ch
  55.                 int   21h
  56.  
  57. ;------------------------------Line-------------------------------------------
  58. OutLine:        mov  bx,1             ;this value will be added to address register if the next pixels of line will be for X
  59. ;                mov  cx,X1
  60. ;                mov  di,X0
  61. ;                mov  ax,Y0
  62. ;                mov  si,Y1
  63.                 mov  di,[bx-1]        ;this instruction is smaller (only 3 byte) than mov di,X1(4 byte)
  64.                 mov  ax,[bx+1]
  65.                 mov  cx,[bx+3]
  66.                 mov  si,[bx+5]
  67.                 mov  bp,320           ;this is number of pixels in the raster on X-coordinate
  68.                 sub  cx,di            ;X1-X0
  69.                 jge  LinePlusX
  70.                 neg  cx               ;the length of line on X-coordinate must not be minus
  71.                 neg  bx               ;the line will goes to the left side of the screen and the address register will be reduced
  72. LinePlusX:      inc  cx               ;the length of line on X-coordinate is X1-X0+1
  73.                 sub  si,ax            ;the length of line on Y-coordinate is Y1-Y0
  74.                 mul  bp
  75.                 add  di,ax            ;the begin address of line on the screen is 320*Y0+X1
  76.                 test si,si
  77.                 jge  LinePlusY
  78.                 neg  si               ;the length of line on Y-coordinate must not be minus
  79.                 neg  bp               ;the line will goes to the top of the screen and the address register will be reduced
  80. LinePlusY:      inc  si               ;the length of line on X-coordinate is Y1-Y0+1
  81.                 cmp  cx,si            ;if length on X-coordinate is more than on Y-coordinate
  82.                 jge  LineXGY
  83.                 xchg cx,si
  84.                 xchg bp,bx
  85. LineXGY:        mov  ax,si            ;the begin value of estimated function is U=Max(Len(X),Len(Y))-Int(Min(Len(X),Len(Y))/2)-1
  86.                 mov  dx,cx            ;it is for more accurate view of line
  87.                 shr  ax,1             ;this instructions is mixed for better performance on Pentium
  88.                 add  bp,bx
  89.                 sub  dx,ax
  90.                 mov  ax,cx
  91.                 dec  dx
  92.                 shl  ax,6             ;it is number of pixels divided by 4 in ah
  93.                 mov  al,cl
  94.                 inc  ah
  95.                 sub  cx,si
  96.                 shl  al,7
  97.                 mov  al,COLOR
  98.                 push ds
  99.                 mov  ds,VIDRAM
  100.                 ja   LineStart1       ;if the rest from division the number of pixels of the line by 4 is 1
  101.                 jnz  LineStart3       ;is 3
  102.                 jc   LineStart2       ;is 2
  103.                 jmp  LineStart4       ;is 0
  104.  
  105. db       11     dup (?)               ;the address of the label LineStepX0 must be levelled on border of 16 byte for more performance
  106.  
  107. LineStepX0:     mov  [di],al          ;this is main cycle of creating the line on the screen raster
  108.                 add  di,bx            ;it is using Brezenghem's algorithm
  109. LineStart3:     sub  dx,si            ;this structure provides reduction the number of decrementing
  110.                 jge  LineStepX1       ;the loop-variable and number of jumps
  111. LineStepY1:     mov  [di],al
  112.                 add  di,bp
  113.                 add  dx,cx
  114.                 jl   LineStepY2
  115. LineStepX2:     mov  [di],al
  116.                 add  di,bx
  117. LineStart1:     sub  dx,si
  118.                 jge  LineStepX3
  119. LineStepY3:     mov  [di],al
  120.                 dec  ah
  121.                 jz   LineEnd
  122.                 add  di,bp
  123.                 add  dx,cx
  124.                 jge  LineStepX0
  125.  
  126. LineStepY0:     mov  [di],al
  127.                 add  di,bp
  128.                 add  dx,cx
  129.                 jl   LineStepY1
  130. LineStepX1:     mov  [di],al
  131.                 add  di,bx
  132. LineStart2:     sub  dx,si
  133.                 jge  LineStepX2
  134. LineStepY2:     mov  [di],al
  135.                 add  di,bp
  136.                 add  dx,cx
  137.                 jl   LineStepY3
  138. LineStepX3:     mov  [di],al
  139.                 add  di,bx
  140. LineStart4:     dec  ah
  141.                 jz   LineEnd
  142.                 sub  dx,si
  143.                 jl   LineStepY0
  144.                 jmp  LineStepX0
  145.  
  146. LineEnd:        pop  ds
  147.                 ret
  148.  
  149.         END   Begin