home *** CD-ROM | disk | FTP | other *** search
/ io Programmo 23 / IOPROG_23.ISO / SOFT / ASM / BCDASM.ZIP / BCDASM / AWK / PROTO.AWK < prev   
Encoding:
AWK Script  |  1997-06-03  |  3.0 KB  |  110 lines
  1. # 
  2. # AWK script to output prototype definitions for assembly language
  3. # procedures declared with PROC. Optionally output interface-
  4. # related assembler directives.  Morten Elling, Mar 1996, May 1997.
  5. #
  6. # Usage: awk -f proto.awk [LIST2=1 [IDEAL=1]] file.asm [>output.fil]
  7. #    LIST2=1: output lines with certain assembler directives
  8. #    IDEAL=1: assume Ideal syntax for LIST2 directives
  9. #
  10. #
  11. # Note: Understands TASM and MASM's extended PROC syntax, also
  12. #    in TASM's Ideal mode, but is otherwise ignorant.
  13. # ToDo:    Strip ARG equate if present (TASM only).
  14.  
  15.  
  16. #### Make set array from string
  17. function zsplit(str, arr     ,i, j ,temp) {    # i,j,temp = locals
  18.     j = split(str, temp);
  19.     for (i = 1; i <= j; i++)  arr[temp[i]] = 1;
  20. }
  21.  
  22.  
  23. BEGIN { # Initialize
  24.  
  25.     # Lines with specified directives are output if LIST2 > 0
  26.     if (IDEAL) {    # Keyword is 1st token on a line
  27.     list1dir = "model public global extrn procdesc proctype typedef";
  28.     list2dir = "";
  29.     } else {
  30.     list1dir = "model .model public global extrn externdef" \
  31.            " extern dosseg ";
  32.     list2dir = "procdesc proctype typedef proto";
  33.     }
  34.     zsplit(list1dir, list1set);
  35.     zsplit(list2dir, list2set);
  36. }
  37. { # Main loop begins
  38.  
  39. ##### Skip comments
  40. if ($0 ~ /^;/)  next;
  41.  
  42. ##### Combine "\"-ended lines to one
  43. if (prevLn != "") {
  44.     sub(/^[ \t]+/, "");        # Left-trim
  45.     $0 = prevLn " " $0;         # Append to previous line
  46.     prevLn = "";
  47. }
  48.     gsub(/;.*$/, "");        # Remove ";" thru eol
  49. if ($0 ~ /\\.*$/) {            # Remove "\" thru eol
  50.     gsub(/\\.*$/, "");
  51.     prevLn = $0;
  52.     next;                # Skip to next line
  53. }
  54. tok1 = tolower($1);
  55. tok2 = tolower($2);
  56.  
  57. ##### Support for TASM's separate-line ARG
  58. if (inProc) {
  59.     if (tok1 == "uses")  next;    # Skip to next line
  60.     if (tok1 == "local") next;
  61.     inProc = 0;
  62.     if (tok1 == "arg") {
  63.        gsub(/\t/, " ");        # Replace tabs with spaces
  64.        $1 = "";            # Strip off "ARG"
  65.        # Append args to prototype
  66.        protos[count] = protos[count] " " $0;
  67.        next;
  68.     }
  69. }
  70. inProc = 0;
  71.  
  72. ##### Output optional extras
  73. if (LIST2) {
  74.     if (tok1 in list1set) print;
  75.     if (tok2 in list2set) print;
  76. }
  77.  
  78. ##### Handle PROC
  79. if ( tok2 == "proc" || tok1 == "proc" ) {
  80.    # Support for MASM's comma-ended multi-line arg construct
  81.     if ( match($0, /,[ \t]*$/) ) {
  82.         prevLn = $0;
  83.         next;
  84.     }
  85.  
  86.    # Do string replacements
  87.     # print $0            # Un-comment for debug output
  88.     gsub(/\t/, " ");        # Replace tabs with spaces
  89.     # Replace " uses uses_list," with ""
  90.     if (!sub(/ (U|u)(S|s)(E|e)(S|s) [ a-zA-Z]*,/, "", $0 ))
  91.          sub(/ (U|u)(S|s)(E|e)(S|s) [ a-zA-Z]*$/, "", $0 );
  92.     # TASM only: strip off " returns arg_list" at eol
  93.     sub(/ (R|r)(E|e)(T|t)(U|u)(R|r)(N|n)(S|s) [ a-zA-Z0-9_$?:]+$/, "", $0);
  94.     # Replace "proc" with "procdesc"
  95.     if (tok1 == "proc")
  96.        { $1 = "procdesc\t" }    # Ideal syntax
  97.     else if (length($1) < 7)
  98.        { $2 = "\t\tprocdesc" }
  99.     else { $2 = "\tprocdesc" };
  100.  
  101.    # Remember prototype definition
  102.     protos[++count] = $0;
  103.     inProc = 1;            # Flag looking for "ARG"
  104. }
  105. } ##### Main loop ends
  106. END {
  107.     printf("; procdesc equ proto\n");
  108.     for (i = 1; i <= count; i++)
  109.        printf("%s\n", protos[i]);    # Output results
  110. } # eof