home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 11 / 11.iso / m / m111 / 2.img / GRPCT2.EXE / CDCMD.TXT < prev    next >
Encoding:
Text File  |  1990-02-26  |  7.3 KB  |  304 lines
  1. ;       CDCMD.TXT - GRASP 3.5 CD Command Routines - February 26, 1990
  2. ;
  3. ; This program file contains routines for controlling audio CD play on
  4. ; CDROM devices:
  5. ;
  6. ; CDINIT     checks whether cd-rom drive and driver are set up
  7. ; CDSTATUS   returns CD status information
  8. ; PRTSTATUS  analyzes CD status info and reports device capabilities
  9. ; CDPLAY     plays starting at a given track for a given time
  10. ; CDPLAYTO   plays from one track to a second track
  11. ; CDSTOP     stops play
  12. ; CDRESUME   resumes play from the last CDSTOP
  13. ; CDSEEK     moves the cd head to a given track
  14. ; CDTRACK    returns the location of a track
  15. ; CDEJECT    opens the drive door/tray
  16. ; CDCLOSE    closes the drive door/tray
  17. ;
  18. ; CDCMD      a general-purpose command routine which makes the call
  19. ;            (setting memory and issuing the interrupt) for the other
  20. ;            subroutines
  21. ; CDCHECK    reports any errors encountered by CDCMD
  22. ;
  23. ; Other commands supported by a given drive may be implemented by passing
  24. ; values to CDCMD. To determine the correct values, consult the reference
  25. ; or programming guide for your drive.
  26. ;
  27. ; Some older drives do not support all of the commands implemented here.
  28. ;
  29. ; Here's a small sample program that uses a CD player (you may want to
  30. ; comment this code out if you're going to merge this file with your own
  31. ; applications):
  32. ; 
  33.   cdinit            ;check whether CD driver is loaded
  34.   if !len(@drive)
  35.     text "CD ROM Driver not loaded"
  36.     waitkey
  37.     exit
  38.   endif
  39.   text "CD is drive "$@drive$":"$chr(10)$chr(10)
  40.   cdstatus                ;get drive status
  41.   prtstatus @0            ;print out drive status
  42.   cdplay 2 120            ;play track 2 for 120 seconds
  43.   waitkey                 ;wait for a keypress
  44.   cdstop                  ;stop playing
  45. exit
  46.  
  47. ;CDINIT
  48. ;
  49. ; Checks for CD driver software and sets drive name in global @drive.
  50. ;
  51. cdinit:
  52.   int 0x2f 0x1500,0
  53.   if @bx
  54.     global drive chr(@cx+asc("A")) ;set name of CD-ROM drive
  55.  
  56.   else
  57.     global drive ""
  58.   endif
  59.   return
  60.  
  61.  
  62. ; CDSTATUS
  63. ;
  64. ; Returns CD Drive status and sets global variables @first and @last.
  65. ;
  66. cdstatus:
  67.   local  buf ofs("123456")
  68.   local  bseg seg(@buf);
  69.   poke  @bseg @buf 10                   ;Audio Disk Info
  70.   cdcmd  3,@buf|(@bseg<<16),6           ;READ IOCTL Input
  71.   cdcheck  @0,cdstatus
  72.   global  first peek(@bseg,@buf+1)+0
  73.   global  last  peek(@bseg,@buf+2)+0
  74.   poke  @bseg @buf 6                    ;Device status
  75.   cdcmd  3,@buf|(@bseg<<16),5           ;READ IOCTL Input
  76.   cdcheck  @0,cdstatus
  77.   return  peekl(@bseg,@buf+1)
  78.  
  79.  
  80. ; PRTSTATUS
  81. ;
  82. ; Displays device characteristics and status.
  83. ;
  84. prtstatus:
  85.   if @1&1
  86.     text "Door Open"$chr(10)
  87.   else
  88.     text "Door Closed"$chr(10)
  89.   endif
  90.  
  91.   if @1&2
  92.     text "Door unlocked"$chr(10)
  93.   else
  94.     text "Door locked"$chr(10)
  95.   endif
  96.  
  97.   if @1&4
  98.     text "Supports cooked and raw reading"$chr(10)
  99.   else
  100.     text "Supports only cooked reading"$chr(10)
  101.   endif
  102.  
  103.   if @1&8
  104.     text "Read/write"$chr(10)
  105.   else
  106.     text "Read only"$chr(10)
  107.   endif
  108.  
  109.   if @1&16
  110.     text "Data read and plays audio/video tracks"$chr(10)
  111.   else
  112.     text "Data read only"$chr(10)
  113.   endif
  114.  
  115.   if @1&32
  116.     text "Supports ISO-9660 interleaving using interleave size and skip factor"$chr(10)
  117.   else
  118.     text "No interleaving"$chr(10)
  119.   endif
  120.  
  121.   if @1&128
  122.     text "Supports prefetching requests"$chr(10)
  123.   else
  124.     text "No Prefetching"$chr(10)
  125.   endif
  126.  
  127.   if @1&256
  128.     text "Supports audio channel manipulation"$chr(10)
  129.   else
  130.     text "No audio channel manipulation"$chr(10)
  131.   endif
  132.  
  133.   if @1&512
  134.     text "Supports HSG and Red Book addressing modes"$chr(10)
  135.   else
  136.     text "Supports HSG addressing mode"$chr(10)
  137.   endif
  138.  
  139.   if @1&2048
  140.     text "No disc is present in the drive"$chr(10)
  141.   else
  142.     text "Disc is present in the drive"$chr(10)
  143.   endif
  144.  
  145.   return
  146.  
  147.  
  148. ; CDPLAY TRACK NUM_SECONDS [MINUTES SECONDS FRAMES]
  149. ;
  150. ; Starts playing at TRACK for NUM_SECONDS duration.
  151. ; MINUTES, SECONDS, and FRAMES (which are a 1/75th of
  152. ; a second) are optional offsets into the specified track
  153. ; to begin playing.
  154. ;
  155. cdplay:
  156.   cdtrack  @1 @3 @4 @5
  157.   cdcmd  132,@0,@2*75
  158.   cdcheck  @0,cdplay
  159.   return
  160.  
  161.  
  162. ; CDPLAYTO TRACK MINUTES SECONDS FRAMES TRACK MINUTES SECONDS FRAMES
  163. ;
  164. ; Plays from one TRACK (at offset MINUTES SECONDS FRAMES into it)
  165. ; to the second TRACK (at the second offsets into it).
  166. ;
  167. cdplayto:
  168.   cdtrack  @1 @2 @3 @4
  169.   local  begin @0
  170.   cdtrack  @5 @6 @7 @8
  171.   local  end @0
  172.   cdcmd  132,@begin,@end-@begin
  173.   cdcheck  @0,cdplayto
  174.   return
  175.  
  176.  
  177. ; CDSTOP
  178. ;
  179. ; Stops playing immediately.
  180. ;
  181. cdstop:
  182.   cdcmd  133,0,0
  183.   cdcheck  @0,cdstop
  184.   return
  185.  
  186.  
  187. ; CDRESUME
  188. ;
  189. ; Resumes playing from the last CDSTOP.
  190. ;
  191. cdresume:
  192.   cdcmd  136,0,0
  193.   cdcheck  @0,cdresume
  194.   return
  195.  
  196.  
  197. ; CDSEEK TRACK [MINUTES SECONDS FRAMES]
  198. ;
  199. ; Moves the playing head to a given track to minimize startup time.
  200. ; Parameters are the same as CDPLAY.
  201. ;
  202. cdseek:
  203.   cdtrack @1 @2 @3 @4
  204.   cdcmd 131,@0,0
  205.   cdcheck  @0,cdseek
  206.   return
  207.  
  208.  
  209. ; CDTRACK TRACK MINUTES SECONDS FRAMES
  210. ;
  211. ; Returns the absolute sector number of a track.
  212. ;
  213. cdtrack:
  214.   local  buf ofs("1234567")
  215.   local  bseg seg(@buf);
  216.   poke  @bseg @buf 11                ;Get Audio Track Info
  217.   poke  @bseg @buf+1 @1              ;track number
  218.   cdcmd  3,@buf|(@bseg<<16),7        ;READ IOCTL Input
  219.   cdcheck  @0,cdtrack
  220.   return  peekl(@bseg,@buf+2)+(@2*60+@3)*75+@4  ;return track address
  221.  
  222.  
  223. ; CDEJECT
  224. ;
  225. ; Opens the CD drive's tray/door.
  226. ;
  227. cdeject:
  228.   local  buf ofs("1")
  229.   local  bseg seg(@buf);
  230.   poke  @bseg @buf 0                 ;Eject Disk
  231.   cdcmd  12,@buf|(@bseg<<16),1       ;WRITE IOCTL Output
  232.   cdcheck  @0,cdeject
  233.   return
  234.  
  235.  
  236. ; CDCLOSE
  237. ;
  238. ; Closes the CD's drive tray/door.
  239. ;
  240. cdclose:
  241.   local  buf ofs("1")
  242.   local  bseg seg(@buf);
  243.   poke  @bseg @buf 5                 ;Close Tray
  244.   cdcmd  12,@buf|(@bseg<<16),1       ;WRITE IOCTL Output
  245.   cdcheck  @0,cdclose
  246.   return
  247.  
  248.  
  249. ; CDCMD
  250. ;
  251. ; Sets up command data in memory and calls the CD player software.
  252. ;
  253. cdcmd:
  254.   local req ofs("12345678901234567890123456")
  255.   local rseg seg(@req)
  256.   poke  @rseg @req 13                ;param length
  257.   poke  @rseg @req+1 0               ;subunit
  258.   poke  @rseg @req+2 @1              ;command code
  259.   pokew @rseg @req+3 0               ;status
  260.   pokel @rseg @req+5 0 0             ;reserved
  261.   poke  @rseg @req+13 1              ;address mode
  262.   pokel @rseg @req+14 @2             ;begin
  263.   pokel @rseg @req+18 @3             ;length
  264.   pokel @rseg @req+22 0              ;reserved
  265.   int 0x2f 0x1510,@req,asc(@drive)-asc("A"),,,,,seg(@req)
  266.   if peek(@rseg,@req+4)&0x80
  267.     databegin
  268.       "Unknown Error"
  269.       "Write-protect violation"
  270.       "Unknown unit"
  271.       "Drive not Ready"
  272.       "Unknown command"
  273.       "CRC error"
  274.       "Bad drive request structure length"
  275.       "Seek Error"
  276.       "Unknown media"
  277.       "Sector not found"
  278.       "Printer out of paper"
  279.       "Write Fault"
  280.       "Read Fault"
  281.       "General failure"
  282.       "Reserved 1"
  283.       "Reserved 2"
  284.       "Invalid disk change"
  285.     dataend
  286.     if peek(@rseg,@req+3)<16
  287.       dataskip peek(@rseg,@req+3)+1
  288.     endif
  289.     return @
  290.   else
  291.     return ""
  292.   endif
  293.  
  294.  
  295. ; CDCHECK
  296. ;
  297. ; Reports any errors encountered by CDCMD.
  298. ; 
  299. cdcheck:
  300.   if @1!=""
  301.     text chr(10)$@2$": "$@1$chr(10)
  302.   endif
  303.   return
  304.