home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a065 / 1.img / TBEXS.EXE / TBEX11.PRG < prev    next >
Encoding:
Text File  |  1992-03-17  |  2.5 KB  |  85 lines
  1.     // Tbex11.prg
  2.     //
  3.     // Simple database browse with added cosmetics
  4.     // Compile with /a /m /n /w
  5.     // Displays negative AcBal fields in red
  6.  
  7.     #include "Inkey.ch"
  8.  
  9.     // Default column separator
  10.     #define DEF_CSEP  " " + chr(179) + " "
  11.  
  12.     // Default heading separator
  13.     #define DEF_HSEP chr(205) + chr(209) + chr(205)
  14.  
  15.     // Default footing separator
  16.     #define DEF_FSEP chr(205) + chr(207) + chr(205)
  17.  
  18.  
  19.     FUNCTION Tbex11
  20.  
  21.     FIELD Lname, Fname, Addr1, Addr2, Addr3, Addr4, AcBal IN Tbdbf1
  22.  
  23.     LOCAL oTbr  := TBrowseDb(1, 1, MaxRow() - 1, MaxCol() - 1)
  24.     LOCAL oTbc1 := TBColumnNew("Last name",  {|| Lname })
  25.     LOCAL oTbc2 := TBColumnNew("First name", {|| Fname })
  26.     LOCAL oTbc3 := TBColumnNew("Address 1",  {|| Addr1 })
  27.     LOCAL oTbc4 := TBColumnNew("Address 2",  {|| Addr2 })
  28.     LOCAL oTbc5 := TBColumnNew("Address 3",  {|| Addr3 })
  29.     LOCAL oTbc6 := TBColumnNew("Address 4",  {|| Addr4 })
  30.     LOCAL oTbc7 := TBColumnNew("Balance  ",  {|| AcBal })
  31.     LOCAL nKey
  32.     LOCAL lExitRequested
  33.  
  34.       oTbr:colSep  := DEF_CSEP
  35.       oTbr:headSep := DEF_HSEP
  36.       oTbr:footSep := DEF_FSEP
  37.  
  38.       oTbr:colorSpec := "W/N,N/W,N,N.N/W,R/N,N/R"
  39.  
  40.       CLEAR SCREEN
  41.       @ 0, 0 TO MaxRow(), MaxCol()
  42.  
  43.       USE Tbdbf1
  44.  
  45.       oTbc1:width := 20
  46.       oTbr:addColumn(oTbc1)
  47.  
  48.       oTbc2:width := 20
  49.       oTbr:addColumn(oTbc2)
  50.  
  51.       oTbr:addColumn(oTbc3)
  52.       oTbr:addColumn(oTbc4)
  53.       oTbr:addColumn(oTbc5)
  54.       oTbr:addColumn(oTbc6)
  55.  
  56.       oTbc7:colorBlock := {|nBal| iif(nBal < 0, {6, 7}, {1, 2}) }
  57.       oTbr:addColumn(oTbc7)
  58.  
  59.       lExitRequested := .F.
  60.       DO WHILE !lExitRequested
  61.         DO WHILE !oTbr:stabilize()
  62.         ENDDO
  63.         nKey := InKey(0)
  64.  
  65.         DO CASE
  66.           CASE nKey == K_DOWN;       oTbr:down()
  67.           CASE nKey == K_UP;         oTbr:up()
  68.           CASE nKey == K_PGDN;       oTbr:pageDown()
  69.           CASE nKey == K_PGUP;       oTbr:pageUp()
  70.           CASE nKey == K_CTRL_PGUP;  oTbr:goTop()
  71.           CASE nKey == K_CTRL_PGDN;  oTbr:goBottom()
  72.           CASE nKey == K_RIGHT;      oTbr:right()
  73.           CASE nKey == K_LEFT;       oTbr:left()
  74.           CASE nKey == K_HOME;       oTbr:home()
  75.           CASE nKey == K_END;        oTbr:end()
  76.           CASE nKey == K_CTRL_LEFT;  oTbr:panLeft()
  77.           CASE nKey == K_CTRL_RIGHT; oTbr:panRight()
  78.           CASE nKey == K_CTRL_HOME;  oTbr:panHome()
  79.           CASE nKey == K_CTRL_END;   oTbr:panEnd()
  80.           CASE nKey == K_ESC;        lExitRequested := .T.
  81.         ENDCASE
  82.       ENDDO
  83.  
  84.     RETURN NIL
  85.