home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a065 / 1.img / TBEXS.EXE / TBEX09.PRG < prev    next >
Encoding:
Text File  |  1992-03-17  |  2.5 KB  |  85 lines
  1.     // Tbex09.prg
  2.     //
  3.     // Simple database browse with added cosmetics
  4.     // Compile with /a /m /n /w
  5.     //
  6.     // K_F6 allows user to select field name to add to display
  7.  
  8.     #include "Inkey.ch"
  9.  
  10.     // Default column separator
  11.     #define DEF_CSEP  " " + chr(179) + " "
  12.  
  13.     // Default heading separator
  14.     #define DEF_HSEP chr(205) + chr(209) + chr(205)
  15.  
  16.     // Default footing separator
  17.     #define DEF_FSEP chr(205) + chr(207) + chr(205)
  18.  
  19.  
  20.     FUNCTION Tbex09
  21.  
  22.     FIELD Lname, Fname, Addr1, Addr2, Addr3, Addr4 IN Tbdbf1
  23.  
  24.     LOCAL oTbr  := TBrowseDb(1, 1, MaxRow() - 1, MaxCol() - 1)
  25.     LOCAL oTbc1 := TBColumnNew("Last name",  {|| Lname })
  26.     LOCAL nKey
  27.     LOCAL lExitRequested
  28.     LOCAL aFieldNames
  29.     LOCAL nFieldNum
  30.     LOCAL cSaveScr
  31.     LOCAL oTbcTemp
  32.  
  33.       oTbr:colSep  := DEF_CSEP
  34.       oTbr:headSep := DEF_HSEP
  35.       oTbr:footSep := DEF_FSEP
  36.  
  37.       CLEAR SCREEN
  38.       @ 0, 0 TO MaxRow(), MaxCol()
  39.  
  40.       USE Tbdbf1
  41.  
  42.       aFieldNames := Array(Fcount())
  43.       Afields(aFieldNames)
  44.  
  45.       oTbc1:width := 20
  46.       oTbr:addColumn(oTbc1)
  47.  
  48.       lExitRequested := .F.
  49.       DO WHILE !lExitRequested
  50.         DO WHILE !oTbr:stabilize()
  51.         ENDDO
  52.         nKey := InKey(0)
  53.  
  54.         DO CASE
  55.           CASE nKey == K_F6
  56.             cSaveScr  := SaveScreen(10, 60, 20, 71)
  57.             @ 10, 60 TO 20, 71
  58.             nFieldNum := Achoice(11, 61, 19, 70, aFieldNames)
  59.             RestScreen(10, 60, 20, 71, cSaveScr)
  60.             IF nFieldNum > 0
  61.               oTbcTemp := TBColumnNew(aFieldnames[nFieldNum], ;
  62.                                       FieldBlock(aFieldNames[nFieldNum]))
  63.               oTbr:addColumn(oTbcTemp)
  64.             ENDIF
  65.  
  66.           CASE nKey == K_DOWN;       oTbr:down()
  67.           CASE nKey == K_UP;         oTbr:up()
  68.           CASE nKey == K_PGDN;       oTbr:pageDown()
  69.           CASE nKey == K_PGUP;       oTbr:pageUp()
  70.           CASE nKey == K_CTRL_PGUP;  oTbr:goTop()
  71.           CASE nKey == K_CTRL_PGDN;  oTbr:goBottom()
  72.           CASE nKey == K_RIGHT;      oTbr:right()
  73.           CASE nKey == K_LEFT;       oTbr:left()
  74.           CASE nKey == K_HOME;       oTbr:home()
  75.           CASE nKey == K_END;        oTbr:end()
  76.           CASE nKey == K_CTRL_LEFT;  oTbr:panLeft()
  77.           CASE nKey == K_CTRL_RIGHT; oTbr:panRight()
  78.           CASE nKey == K_CTRL_HOME;  oTbr:panHome()
  79.           CASE nKey == K_CTRL_END;   oTbr:panEnd()
  80.           CASE nKey == K_ESC;        lExitRequested := .T.
  81.         ENDCASE
  82.       ENDDO
  83.  
  84.     RETURN NIL
  85.