home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a065 / 1.img / TBEXS.EXE / TBEX05.PRG < prev    next >
Encoding:
Text File  |  1992-03-17  |  2.7 KB  |  101 lines
  1.     // Tbex05.prg
  2.     //
  3.     // Simple database browse with added cosmetics
  4.     // Shows record number and deleted
  5.     // Compile with /a /m /n /w
  6.     //
  7.     // Includes some footing text, DispBegin / DispEnd
  8.  
  9.     #include "Inkey.ch"
  10.  
  11.     // Default column separator
  12.     #define DEF_CSEP  " " + chr(179) + " "
  13.  
  14.     // Default heading separator
  15.     #define DEF_HSEP chr(205) + chr(209) + chr(205)
  16.  
  17.     // Default footing separator
  18.     #define DEF_FSEP chr(205) + chr(207) + chr(205)
  19.  
  20.  
  21.     FUNCTION Tbex05
  22.  
  23.     FIELD Lname, Fname, Addr1, Addr2, Addr3, Addr4 IN Tbdbf1
  24.  
  25.     LOCAL oTbr
  26.     LOCAL oTbc1 := TBColumnNew("Last name",  {|| Lname })
  27.     LOCAL oTbc2 := TBColumnNew("First name", {|| Fname })
  28.     LOCAL oTbc3 := TBColumnNew("Address 1",  {|| Addr1 })
  29.     LOCAL oTbc4 := TBColumnNew("Address 2",  {|| Addr2 })
  30.     LOCAL oTbc5 := TBColumnNew("Address 3",  {|| Addr3 })
  31.     LOCAL oTbc6 := TBColumnNew("Address 4",  {|| Addr4 })
  32.     LOCAL oTbc7 := TBColumnNew("Record #",   {|| Recno()})
  33.     LOCAL oTbc8 := TBColumnNew("Del",        {|| Deleted()})
  34.  
  35.     LOCAL nKey
  36.     LOCAL lExitRequested
  37.  
  38.       oTbr := TBrowseDb(1, 1, MaxRow() - 1, MaxCol() - 1)
  39.       
  40.       oTbr:colSep  := DEF_CSEP
  41.       oTbr:headSep := DEF_HSEP
  42.       oTbr:footSep := DEF_FSEP
  43.  
  44.       CLEAR SCREEN
  45.       @ 0, 0 TO MaxRow(), MaxCol()
  46.  
  47.       USE Tbdbf1
  48.  
  49.       oTbr:addColumn(oTbc8)
  50.       oTbr:addColumn(oTbc7)
  51.  
  52.       oTbc1:width := 20
  53.       oTbr:addColumn(oTbc1)
  54.  
  55.       oTbc2:width := 20
  56.       oTbr:addColumn(oTbc2)
  57.  
  58.       oTbc3:footing := "Col #3's footing text"
  59.       oTbr:addColumn(oTbc3)
  60.  
  61.       oTbc4:footing := "Col #4's footing text"
  62.       oTbr:addColumn(oTbc4)
  63.  
  64.       oTbr:addColumn(oTbc5)
  65.       oTbr:addColumn(oTbc6)
  66.  
  67.       lExitRequested := .F.
  68.       DO WHILE !lExitRequested
  69.         DispBegin()
  70.         DO WHILE !oTbr:stabilize()
  71.         ENDDO
  72.         DispEnd()
  73.  
  74.         nKey := InKey(0)
  75.  
  76.         DO CASE
  77.           CASE nKey == K_DOWN;       oTbr:down()
  78.           CASE nKey == K_UP;         oTbr:up()
  79.           CASE nKey == K_PGDN;       oTbr:pageDown()
  80.           CASE nKey == K_PGUP;       oTbr:pageUp()
  81.           CASE nKey == K_CTRL_PGUP;  oTbr:goTop()
  82.           CASE nKey == K_CTRL_PGDN;  oTbr:goBottom()
  83.           CASE nKey == K_RIGHT;      oTbr:right()
  84.           CASE nKey == K_LEFT;       oTbr:left()
  85.           CASE nKey == K_HOME;       oTbr:home()
  86.           CASE nKey == K_END;        oTbr:end()
  87.           CASE nKey == K_CTRL_LEFT;  oTbr:panLeft()
  88.           CASE nKey == K_CTRL_RIGHT; oTbr:panRight()
  89.           CASE nKey == K_CTRL_HOME;  oTbr:panHome()
  90.           CASE nKey == K_CTRL_END;   oTbr:panEnd()
  91.           CASE nKey == K_ESC;        lExitRequested := .T.
  92.         ENDCASE
  93.       ENDDO
  94.  
  95.     RETURN NIL
  96.  
  97.  
  98.  
  99.  
  100.  
  101.