home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a065 / 1.img / TBEXS.EXE / TB02.PRG next >
Encoding:
Text File  |  1992-03-17  |  2.6 KB  |  86 lines
  1.     // Tb02.prg
  2.     //
  3.     // Simple database browse with added cosmetics
  4.     // Compile with /a /m /n /w
  5.  
  6.     #include "Inkey.ch"
  7.  
  8.     // Default column separator
  9.     #define DEF_CSEP  " " + chr(179) + " "
  10.  
  11.     // Default heading separator
  12.     #define DEF_HSEP chr(205) + chr(209) + chr(205)
  13.  
  14.     // Default footing separator
  15.     #define DEF_FSEP chr(205) + chr(207) + chr(205)
  16.  
  17.  
  18.     FUNCTION Tb02
  19.  
  20.     FIELD Lname, Fname, Addr1, Addr2, Addr3, Addr4, Wphone IN Tbdbf1
  21.  
  22.     LOCAL oTbr  := TBrowseDb(1, 1, MaxRow() - 1, MaxCol() - 1)
  23.     LOCAL oTbc1 := TBColumnNew("Last name",  {|| Lname })
  24.     LOCAL oTbc2 := TBColumnNew("First name", {|| Fname })
  25.     LOCAL oTbc3 := TBColumnNew("Address 1",  {|| Addr1 })
  26.     LOCAL oTbc4 := TBColumnNew("Address 2",  {|| Addr2 })
  27.     LOCAL oTbc5 := TBColumnNew("Address 3",  {|| Addr3 })
  28.     LOCAL oTbc6 := TBColumnNew("Address 4",  {|| Addr4 })
  29.     LOCAL oTbc7 := TBColumnNew("Work phone", ;
  30.                                {|| Transform(Wphone, "(999) 999-9999") })
  31.     LOCAL nKey
  32.     LOCAL lExitRequested
  33.  
  34.       oTbr:colSep  := DEF_CSEP
  35.       oTbr:headSep := DEF_HSEP
  36.       oTbr:footSep := DEF_FSEP
  37.  
  38.       CLEAR SCREEN
  39.       @ 0, 0 TO MaxRow(), MaxCol()
  40.  
  41.       USE Tbdbf1
  42.  
  43.       oTbc1:width := 20
  44.       oTbr:addColumn(oTbc1)
  45.  
  46.       oTbc2:width := 20
  47.       oTbr:addColumn(oTbc2)
  48.  
  49.       oTbr:addColumn(oTbc3)
  50.       oTbr:addColumn(oTbc4)
  51.       oTbr:addColumn(oTbc5)
  52.       oTbr:addColumn(oTbc6)
  53.       oTbr:addColumn(oTbc7)
  54.  
  55.       oTbr:freeze := 1
  56.       lExitRequested := .F.
  57.       DO WHILE !lExitRequested
  58.         IF oTbr:colPos <= oTbr:freeze
  59.           oTbr:deHilite()
  60.           oTbr:colPos := oTbr:freeze + 1
  61.         ENDIF
  62.         DO WHILE !oTbr:stabilize()
  63.         ENDDO
  64.         nKey := InKey(0)
  65.  
  66.         DO CASE
  67.           CASE nKey == K_DOWN;       oTbr:down()
  68.           CASE nKey == K_UP;         oTbr:up()
  69.           CASE nKey == K_PGDN;       oTbr:pageDown()
  70.           CASE nKey == K_PGUP;       oTbr:pageUp()
  71.           CASE nKey == K_CTRL_PGUP;  oTbr:goTop()
  72.           CASE nKey == K_CTRL_PGDN;  oTbr:goBottom()
  73.           CASE nKey == K_RIGHT;      oTbr:right()
  74.           CASE nKey == K_LEFT;       oTbr:left()
  75.           CASE nKey == K_HOME;       oTbr:home()
  76.           CASE nKey == K_END;        oTbr:end()
  77.           CASE nKey == K_CTRL_LEFT;  oTbr:panLeft()
  78.           CASE nKey == K_CTRL_RIGHT; oTbr:panRight()
  79.           CASE nKey == K_CTRL_HOME;  oTbr:panHome()
  80.           CASE nKey == K_CTRL_END;   oTbr:panEnd()
  81.           CASE nKey == K_ESC;        lExitRequested := .T.
  82.         ENDCASE
  83.       ENDDO
  84.  
  85.     RETURN NIL
  86.