home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh9x
/
sh91a.d64
/
fox-master
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
47 lines
100 REM FOX-MASTER
110 REM
120 REM 02.03.87 BY P.ENGELS
130 REM ----------------------
140 REM
150 PRINTCHR$(14)"[147][208]RINT[198]OX -> [205]ASTER[212]EXT"CHR$(13)" [212]EXTKONVERTER"
160 INPUT"[209]UELL-[212]EXT:";QF$:QF$=QF$+",P,R"
170 INPUT" [218]IEL-[212]EXT:";ZF$:ZF$=ZF$+",P,W"
180 OPEN1,8,3,QF$
190 OPEN2,8,4,ZF$:PRINT#2,CHR$(0)CHR$(08);:REM START-KENNUNG
200 PRINT:PRINT
210 GET#1,A$:REM TEXT-KENNUNG UEBERLESEN
220 GET#1,A$:IFA$=""THENA$=CHR$(0)
230 A=ASC(A$):B=0
240 IF(A>96)AND(A<123)THENB=A-96:GOTO370:REM KLEIN
250 IF(A>31)AND(A<91)THENB=A:GOTO370:REM ZIFFERN,ZEICHEN,GROSSBUCHST.
260 IFA=2THENGOTO540:REM FORMATZEILE IGNORIEREN
270 IFA=127THENB=32:REM SHIFT SPACE
280 IFA=13THENB=142:REM ABSATZ
290 IFA=91THENB=91:REM AE
300 IFA=92THENB=92:REM OE
310 IFA=93THENB=93:REM UE
320 IFA=123THENB=27:REM AE
330 IFA=124THENB=28:REM OE
340 IFA=125THENB=29:REM UE
350 IFA=126THENB=30:REM SZ
360 :
370 IF(A>31)OR(A=13)THENPRINTCHR$(A);
380 IFST=2GOTO440:REM FILE-ENDE
390 IFB=0THEN220
400 PRINT#2,CHR$(B);
410 SZ=SZ+1:REM SPALTENZAEHLER
420 IFB=142THENGOSUB480:REM ZEILE AUFFUELLEN
430 GOTO220
440 PRINT#2,CHR$(0)CHR$(0):REM ENDE
450 CLOSE1:CLOSE2
460 PRINT:PRINT"[212]EXT IST KONVERTIERT !![146]":END
470 :
480 IFSZ> 79THENPRINT#2," ";
490 IFSZ>159THENPRINT#2," ";
500 IFSZ>319THENPRINT#2," ";
510 IFSZ>399THENPRINT#2," ";
520 FORZ=SZTO79*(INT(SZ/79)+1):PRINT#2," ";:NEXT:SZ=0:RETURN:REM AUFFUELLEN
530 :
540 GET#1,A$:IFASC(A$)<>13GOTO540:ZEILE UEBERLESEN
550 GOTO220