home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh4x
/
sh45a.d64
/
hires4.ass
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
49 lines
10 REM ********************************
20 REM * *
30 REM * H I R E S 4 . A S S *
40 REM * TEST DER GRAFIKERWEITERUNG *
50 REM * HIRES 4 FUER DEN C64 *
60 REM * HEIMO PONNATH HAMBURG *
70 REM * *
80 REM ********************************
90 REM
100 REM ------- HAUPTPROGRAMM ---------
110 PRINTCHR$(147)
120 PRINT:PRINT:PRINT"DIESES PROGRAMM TESTET ALLE MODULE":PRINT"VON HIRES 4"
130 ZF=5:HF=0:REM ZEICHEN- UND HINTERGRUNDFARBE
140 SYS49152:HAN:REM GRAFIK EINSCHALTEN
150 LOE:REM BITMAP LOESCHEN
160 FAR,ZF,HF:REM FARBGEBUNG
170 L=1:REM LOESCHMARKE AUF PUNKT SETZEN STELLEN
180 FOR X=0 TO 319
190 :Y=50*SIN(X/20)+100
200 :PKT X,Y,L:REM PUNKTE SETZEN
210 NEXT X
220 L=0:REM LOESCHMARKE AUF PUNKT LOESCHEN STELLEN
230 FOR X=100 TO 200
240 :Y=50*SIN(X/20)+100
250 :PKT X,Y,L:REM PUNKTE LOESCHEN
260 NEXT X
270 HOF:REM TEXTMODUS EINSCHALTEN
280 PRINT:PRINT"DIE MODULE 2 BIS 6 SIND OK"
290 FOR I=0 TO 1000:NEXT I
300 HAN:REM GRAFIK WIEDER EINSCHALTEN
310 X1=160:Y1=100:R%=90:L=1
320 FOR A=0 TO 6.28 STEP .05
330 :X2=R%*COS(A)+160
340 :Y2=R%*SIN(A)+100
350 :LIN,X1,Y1,X2,Y2,L:REM LINIEN ZEICHNEN
360 NEXT A
370 HOF:REM TEXTMODUS EINSCHALTEN
380 PRINT:PRINT"AUCH DAS MODUL 7 ARBEITET"
390 FOR I=0 TO 1000:NEXT I
400 HAN:REM GRAFIK EINSCHALTEN
410 XM=160:YM=100:R=95:L=1
420 CIR,XM,YM,R,L:REM KREIS ZEICHNEN
430 FOR I=0 TO 1000:NEXT I
440 HOF:AUS:REM TEXTMODUS UND ERWEITERUNG ABSCHALTEN
450 PRINT:PRINT"AUCH DAS MODUL 8 FUNKTIONIERT."
460 POKE52,160:POKE56,160:REM BASICZEIGER ZURUECKSTELLEN
470 CLR
480 END