home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh2x
/
sh26a.d64
/
miniterm
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
48 lines
10 REM ********************************
20 REM * MINITERM *
30 REM * *
40 REM * EIN PROGRAMM ZUM *
50 REM * AUSPROBIEREN VON *
60 REM * MAILBOXEN *
70 REM * *
80 REM ********************************
85 :
90 REM EINGABE DER PARAMETER
95 :
100 INPUT"DATENBITS (8/7) 8[157][157][157][157] ";DB
110 INPUT"PARITY (N/E/O) N[157][157][157][157] ";PA$
120 INPUT"STOP-BITS (1/2) 1[157][157][157][157] "; SB
125 :
130 REM PARAMETER SETZEN
135 :
140 SR=6+(SB-1)*2^7+ABS(DB-8)*2^5
150 BR=ABS(PA$<>"N")*2^5+ABS(PA$<>"O"ANDPA$<>"N")*2^6
155 :
160 REM KANAL OEFFNEN
165 :
170 OPEN 2,2,3,CHR$(SR)+CHR$(BR)
175 GOSUB 1000
180 GET#2,A$:PRINT"[147]ONLINE ..."
485 :
490 REM SENDEN UND EMPFANGEN DER DATEN
495 :
500 GET B$:IFB$<>""THEN PRINT#2,CHR$(T%(ASC(B$+CHR$(0))));
510 GET#2,C$
520 PRINT CHR$(F%(ASC(C$+CHR$(0))));
530 GOTO 500
985 :
990 : REM STANDARD-ASCII HERSTELLEN
995 :
1000 DIM F%(255),T%(255)
1010 FORJ=32TO64:T%(J)=J:NEXT
1020 T%(13)=13:T%(20)=8
1030 FORJ=65TO90:K=J+32:T%(J)=K:NEXT
1040 FORJ=91TO95:T%(J)=J:NEXT
1050 FORJ=193TO218:K=J-128:T%(J)=K:NEXT
1055 T%(24)=24:T%(19)=19:T%(3)=3
1060 T%(17)=17:T%(146)=16:T%(133)=16
1070 FORJ=0TO255:K=T%(J)
1080 IFK<>0THEN F%(K)=J:F%(K+128)=J
1090 NEXT
1110 RETURN