home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh2x
/
sh24b.d64
/
texto-fox
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
848b
|
37 lines
100 REM TEXTO-FOX
110 REM
120 REM 01.03.87 BY P.ENGELS
130 REM ---------------------
140 REM
150 PRINTCHR$(14)"[147][212]EXTOMAT -> [208]RINT[198]OX"CHR$(13)" [212]EXTKONVERTER"
160 INPUT"[209]UELL-[212]EXT:";QF$:QF$=QF$+",P,R"
170 INPUT" [218]IEL-[212]EXT:";ZF$:ZF$=ZF$+",P,W"
180 OPEN1,8,3,QF$
190 OPEN2,8,4,ZF$
200 PRINT#2,CHR$(84);:REM TEXT-KENNUNG
210 :
220 GET#1,A$:IFA$=""THENA$=CHR$(0)
230 A=ASC(A$):B=0
240 IF(A>64)AND(A<91)THENB=A+32:GOTO370:REM KLEIN
250 IF(A>192)AND(A<219)THENB=A-128:GOTO370:REM GROSS
260 IF(A>31)AND(A<65)THENB=A:GOTO370:REM ZIFFERN & ZEICHEN
270 IFA=160THENB=127:REM SHIFT SPACE
280 IFA=95THENB=13:REM ABSATZ
290 IFA=169THENB=91:REM AE
300 IFA=168THENB=92:REM OE
310 IFA=170THENB=93:REM UE
320 IFA=165THENB=123:REM AE
330 IFA=161THENB=124:REM OE
340 IFA=166THENB=125:REM UE
350 IFA=167THENB=126:REM SZ
360 :
370 IFA=95 THEN PRINT CHR$(13);:GOTO390
380 PRINTCHR$(A);
390 IFST=2GOTO430:REM FILE-ENDE
400 IF B=0GOTO220
410 PRINT#2,CHR$(B);:GOTO220
420 :
430 PRINT#2,CHR$(0);CHR$(0)
440 CLOSE1:CLOSE2
450 PRINT:PRINT:PRINT" [212]EXT IST KONVERTIERT !![146]"