home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / sh0x / sh05.d64 / zufalls-blues (.txt) < prev   
Encoding:
Commodore BASIC  |  1995-03-30  |  1.8 KB  |  84 lines
  1. 10 REM---------------------------------
  2. 20 REM ZUFALLSTONFOLGE
  3. 30 REM MIT BLUES-SCHEMA
  4. 40 REM
  5. 50 REM AUSNUETZUNG ALLER DREI STIMMEN
  6. 60 REM ZUR KLANGVERBESSERUNG
  7. 70 REM
  8. 80 REM T. KRAETZIG           MAERZ 86
  9. 90 REM---------------------------------
  10. 100 DIM FL(25) :REM ARRAY F. FREQUENZEN
  11. 101 DIM FH(25)
  12. 102 DIM A(8,20):REM AUSWAHLMENGEN
  13. 104 DIM S(30)  :REM SCHEMA
  14. 110 S  =54272  :REM BASISADRESSE
  15. 130 :
  16. 140 REM TONLEITER-FREQUENZEN BERECHNEN
  17. 150 FAUS=110:H=2^(1/12)
  18. 160 FOR I=0 TO 25
  19. 170 :  F=INT(FAUS*17.0284+0.5)
  20. 172 :  FH(I)=INT(F/256)
  21. 174 :  FL(I)=F-256*FH(I)
  22. 180 :  FAUS=FAUS*H
  23. 190 NEXT I
  24. 200 :
  25. 210 REM PARAMETER FESTLEGEN
  26. 220 PW=2048       :REM PULSWEITE
  27. 230 C =32         :REM KURVENFORM
  28. 240 A=0:D=10:SU=0:R=9
  29. 250 FOR I=0 TO 14 STEP 7
  30. 255 : POKE S+I+2,PW AND 255
  31. 260 : POKE S+I+3,PW/256
  32. 265 : POKE S+I+5,16*A+D
  33. 270 : POKE S+I+6,16*SU+R
  34. 275 NEXT I
  35. 280 :
  36. 290 REM FILTER AUS UND LAUTSTAERKE MAX.
  37. 300 POKE S+23,0:POKE S+24,15
  38. 310 :
  39. 320 REM AUSW.MENGEN UND SCHEMA EINLESEN
  40. 325 READ I:A(0,0)=I
  41. 330 FOR K=1 TO I
  42. 335 :  READ J:A(K,0)=J
  43. 340 :  FOR L=1 TO J:READ A(K,L):NEXT L
  44. 350 NEXT K
  45. 355 READ I:S(0)=I
  46. 360 FOR K=1 TO I
  47. 365 :  READ S(K)
  48. 370 NEXT K
  49. 375 :
  50. 380 REM ZUFALLSTONFOLGE
  51. 385 L=0:O=0
  52. 390 FOR I=1 TO S(0)
  53. 395 :  J=S(I)
  54. 400 :  N=A(J,0)
  55. 405 :  FOR K=1 TO 8
  56. 410 :     ZZ=A(J,INT(RND(1)*N+1))
  57. 412 :     POKE S+L  ,FL(ZZ+O)
  58. 414 :     POKE S+L+1,FH(ZZ+O)
  59. 416 :     POKE S+L+4,C OR 1
  60. 420 :     FOR P=1 TO 40:NEXT
  61. 425 :     POKE S+L+4,C
  62. 430 :     FOR P=1 TO 40:NEXT
  63. 435 :     L=L+7:IF L=21 THEN L=0
  64. 440 :  NEXT K
  65. 445 NEXT I
  66. 450 O=O+1:IF O=4 THEN O=0
  67. 455 FOR P=1 TO 1150:NEXT
  68. 460 GOTO 390
  69. 500 REM--------------------------------
  70. 510 REM AUSWAHLMENGEN UND SCHEMA
  71. 520 REM--------------------------------
  72. 530 DATA  7
  73. 540 DATA  8,  0,4,7,10,12,16,19,22
  74. 550 DATA  8,  0,3,5,9, 12,15,17,21
  75. 560 DATA  7,  2,5,7,11,14,17,19
  76. 570 DATA  6,  0,0,4, 7, 7,10
  77. 580 DATA  4,  0,3,5,9
  78. 590 DATA  5,  2,5,7,7,11
  79. 610 DATA  2,  0,7
  80. 620 :
  81. 630 DATA 24,  7,1,2,1,3,2,1,3
  82. 640 DATA      4,4,5,4,6,5,4,6
  83. 650 DATA      7,1,2,1,3,2,1,3
  84.