home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
s85xx
/
s8507a.d64
/
mailbox
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
28KB
|
1,329 lines
1 REM *************************************************************************
2 REM ********************* MASTER MAILBOX PROGRAMM V3.0 *********************
3 REM ********************* (C) 1985 COPYRIGHT BY M.C.S. *********************
4 REM *************************** 2000 HAMBURG 76 ***************************
5 REM *************************** LESSINGSTRASSE 2 ***************************
6 REM *************************************************************************
7 :
8 POKE650,128:GOTO19
9 :
10 REM -- FLOPPY INITIALISIEREN -----------------------------------------------
11 :
12 CLOSE15
13 OPEN15,8,15,"I"
14 CLOSE15
15 RETURN
16 :
17 REM -- [ML] ROUTINE LADEN --------------------------------------------------
18 :
19 X=17:PRINTCHR$(14)CHR$(8)CHR$(147)CHR$(X)CHR$(X)CHR$(158)
20 PRINT" [205]ASTER-[205]AILBOX-[211]YSTEM VERS.3.0"
21 GOSUB12
22 PRINTCHR$(X)" ([195]) 1985 [215]RITTEN BY [[212][200][215]] OF [205].[195].[211]."
23 FA=0
24 GOSUB115
25 IFA=2THEN127
26 IFPEEK(49152)<>169ANDA=0THENA=1:LOAD"[ML]*",8,1
27 PRINTCHR$(17)"[194]ITTE [196]ATENDISKETTE EINLEGEN"CHR$(17)
28 PRINT"[207][203] [202]"CHR$(157)CHR$(157)CHR$(157);:INPUTX$
29 IFX$="N"THENEND
30 IFX$<>"[202]"THEN19
31 :
32 REM -- PROGRAMM INITIALISIEREN ---------------------------------------------
33 :
34 PRINTCHR$(X)"**** [211][217][211][212][197][205] [194][207][207][212][197][206] ****"CHR$(X)
35 IFPEEK(828)<8THEN41
36 OPEN15,8,15,"V"
37 PRINT"[214]ALIDATE"
38 FA=2
39 GOSUB115
40 POKE828,0
41 GOSUB12
42 CLOSE3:CLR
43 OPEN3,3
44 POKE49800,240
45 SYS49152
46 TE=56577
47 SI=54272
48 C=56584
49 MX=50
50 U%=400
51 DIMTE$(40)
52 DIMM$(50)
53 DIMU%(400)
54 BE$=CHR$(7)
55 LI$=CHR$(10)
56 CR$=CHR$(13)
57 XN$=CHR$(17)
58 XF$=CHR$(19)
59 XE$=CHR$(24)
60 RU$=BE$+"*"
61 GA=1
62 T2=1
63 BE=2
64 LI=1
65 DX=1
66 LM=1500
67 LL=100
68 D=2
69 UB$="[199]AST"
70 C$="[195][207][205][205][193][206][196] ->"
71 PO=-1
72 FI$="A-INDEX"
73 GOSUB299
74 INPUT#8,DA$,AN$,NR$,AK$
75 CLOSE8
76 AN=VAL(AN$)
77 GOSUB421
78 FI$="M-INDEX"
79 GOSUB299
80 FORI=1TOMX
81 INPUT#8,M$(I)
82 NEXT
83 CLOSE8
84 NR=VAL(NR$)
85 CLOSE1:OPEN1,0
86 S$=" "
87 S$=S$+S$
88 J$(1)="[211]ONNTAG"
89 J$(2)="[205]ONTAG"
90 J$(3)="[196]IENSTAG"
91 J$(4)="[205]ITTWOCH"
92 J$(5)="[196]ONNERSTAG"
93 J$(6)="[198]REITAG"
94 J$(7)="[211]AMSTAG"
95 J$(0)=J$(7)
96 O$(1)="[207][206]"
97 O$(2)="[207][198][198]"
98 RL$=CR$+LI$
99 Q$=XN$+XN$+XN$+XN$+XN$+XN$+XN$+XN$
100 A=2
101 FORI=0TO3
102 POKE830+I,0
103 NEXT
104 REM -- INDEXFELD USER RELATIV DATEI ---------------------------------------
105 GOSUB417
106 RE=60
107 FORBL=U%-NR+1TOU%
108 GOSUB427
109 GET#8,U$
110 U%(BL)=ASC(U$)
111 NEXT
112 GOSUB421
113 GOTO19
114 REM -- FARBE SETZEN -------------------------------------------------------
115 POKE53280,FA
116 POKE53281,FA
117 RETURN
118 REM -- NUR GROSSCHRIFFT FUER RS232 ----------------------------------------
119 POKE49398,196
120 RETURN
121 REM -- GROSS UND KLEINSCHRIFFT RS232 --------------------------------------
122 POKE49398,195
123 RETURN
124 :
125 REM -- WARTESCHLEIFE FUER ANRUFER -----------------------------------------
126 :
127 PRINTXF$XN$Q$
128 GOSUB173
129 PRINT"[193]NRUFE "RIGHT$(S$+AN$,10)
130 PE=0
131 ME=0
132 UX$=""
133 PRINT"[193]NZAHL [213]SER "RIGHT$(S$+NR$,10)
134 PRINT"[205][211][199] "AK$
135 AN=AN+1
136 AN$=STR$(AN)
137 NR$=STR$(NR)
138 PRINTXF$Q$Q$"'[212]'IME '[196]'ATUM '[211]'TART '[197]'NDE"
139 GOSUB205
140 TI$=UR$
141 GOSUB171
142 POKETE,255:REM RELAIS AN PB1 AUSSCHALTEN
143 DY=0
144 GOSUB313
145 GOSUB163
146 PRINT
147 GETE$:IFE$=""THEN143
148 IFE$="T"THENGOSUB163:GOTO158
149 IFE$="D"THENGOSUB171:GOTO165
150 IFE$="E"THENGOSUB267:END
151 IFE$="S"THEN435
152 GOSUB205
153 TI$=UR$
154 GOTO143
155 :
156 REM -- EIN/AUSGABE UND BERECHNUNG DER UHRZEIT UND DES DATUMS --------------
157 :
158 X$=CHR$(157)+CHR$(157)+CHR$(157)+CHR$(157):X$=X$+X$
159 PRINTX$;:INPUTUR$
160 GOSUB195
161 TI$=UR$
162 GOTO143
163 PRINTXF$Q$"[213]HRZEIT "TI$;
164 RETURN
165 PRINTCHR$(145)"[196]ATUM HEUTE ";
166 INPUTDA$
167 DX=1
168 GOSUB173
169 GOSUB171
170 GOTO143
171 PRINTXF$XN$Q$LEFT$(J$(Z)+S$,10)"DEN "DA$
172 RETURN
173 TA=VAL(LEFT$(DA$,2))
174 MO=VAL(MID$(DA$,4,2))
175 JA=VAL(RIGHT$(DA$,4))
176 IFDX=1THENDX=0:GOTO181
177 TA=TA+1
178 IFTA>31THENTA=1:MO=MO+1:IFMO>12THENMO=1:JA=JA+1
179 IFMO=2THENIFTA>28THENIFJA/4<>INT(JA/4)THENMO=3:TA=1
180 IFTA>30AND(MO=4ORMO=6ORMO=9ORMO=11)THEN177
181 K=INT(.6+(1/MO))
182 R=JA-K
183 O=MO+12*K
184 P=R/100
185 Z=(INT(13*(O+1)/5))+(INT((5*R)/4))-(INT(P))+(INT(P/4))+TA
186 Z=(Z-(7*INT(Z/7)))
187 TA$=STR$(TA)
188 IFLEN(TA$)=2THENTA$=" 0"+RIGHT$(TA$,1)
189 MO$=STR$(MO)
190 IFLEN(MO$)=2THENMO$=" 0"+RIGHT$(MO$,1)
191 JA$=STR$(JA)
192 IFLEN(JA$)=2THENJA$=" 0"+RIGHT$(JA$,1)
193 DA$=RIGHT$(TA$,2)+"."+RIGHT$(MO$,2)+"."+RIGHT$(JA$,4)
194 RETURN
195 POKEC+7,PEEK(C+7)AND127
196 POKEC+6,PEEK(C+6)OR128
197 H=VAL(LEFT$(UR$,2))
198 M=VAL(MID$(UR$,3,2))
199 S=VAL(RIGHT$(UR$,2))
200 IFH>11THENH=H+68
201 POKEC+3,16*INT(H/10)+H-INT(H/10)*10
202 POKEC+2,16*INT(M/10)+M-INT(M/10)*10
203 POKEC+1,16*INT(S/10)+S-INT(S/10)*10
204 POKEC,0:RETURN
205 H=PEEK(C+3)
206 M=PEEK(C+2)
207 S=PEEK(C+1)
208 SX=PEEK(C)
209 FL=1
210 IF(HAND128)=128THENH=H-128:FL=0
211 IFFL=1THEN214
212 IFH=18THEN215
213 H=H+18
214 IFH=18ANDFL=1THENH=0
215 UR$=""
216 V=H
217 GOSUB226
218 GOSUB228
219 V=M
220 GOSUB226
221 GOSUB228
222 V=S
223 GOSUB226
224 GOSUB228
225 RETURN
226 V=INT(V/16)*10+V-INT(V/16)*16
227 RETURN
228 V$=STR$(V)
229 IFLEN(V$)=2THENV$=" 0"+RIGHT$(V$,1)
230 IFH=>18ANDM=>0ANDFL=0ANDPEEK(706)=1THENPOKE706,0
231 IFH=>0ANDM=>0ANDFL=1ANDPEEK(706)=0THEN233
232 GOTO237
233 POKE706,1
234 GOSUB173
235 DX=1
236 IFDY=0THENGOSUB171
237 UR$=UR$+RIGHT$(V$,2)
238 RETURN
239 K$=STR$(XX)
240 YY=LEN(K$)
241 K$=RIGHT$(K$,YY-1)
242 IFYY=1THENRETURN
243 IFYY=2THENK$="00"+K$
244 IFYY=3THENK$="0"+K$
245 RETURN
246 :
247 REM -- DIALOG BEENDEN (LOGOFF) --------------------------------------------
248 :
249 POKE53280,7
250 GOSUB308
251 GOSUB616
252 GOSUB308
253 GOSUB613
254 GOSUB1097
255 GOSUB679
256 GOSUB309
257 GOSUB513
258 GOSUB604
259 GOSUB268
260 A$=""
261 GOSUB1123
262 LO=0
263 GOTO34
264 :
265 REM -- MAILBOX BEENDEN (DIRECT) -------------------------------------------
266 :
267 PRINTQ$"[205]AILBOX BEENDEN"
268 X=PEEK(828)
269 X=X+1
270 POKE828,X
271 :
272 REM -- DATEN SICHERN ------------------------------------------------------
273 :
274 GOSUB421
275 OPEN8,8,2,"@:A-INDEX,S,W"
276 PRINTRL$"[201]NTERNER [195]HECK...."
277 PRINT#8,DA$;CR$;STR$(AN);CR$;STR$(NR);CR$;AK$;CR$
278 GOSUB421
279 OPEN8,8,2,"@:M-INDEX,S,W"
280 FORI=1TOMX
281 PRINT#8,M$(I)
282 NEXT
283 GOSUB421
284 RETURN
285 :
286 REM -- CONTROL ABFRAGE ----------------------------------------------------
287 :
288 GET#1,X$
289 GET#2,Y$
290 IFX$=""ANDY$=""AND(EX=0OREX=2)THENRETURN
291 IFX$=XF$ORY$=XF$THENEX=1:PRINT"XOFF":GOSUB327
292 IFX$=XN$ORY$=XN$THENEX=0:PRINT"XON":GOSUB327
293 IFX$=XE$ORY$=XE$THENEX=2:PRINT"XEND":GOSUB327
294 GOSUB353
295 GOTO288
296 :
297 REM -- TEXTAUSGABE FLOPPY > RS232 -----------------------------------------
298 :
299 GOSUB421
300 OPEN8,8,0,FI$+",S,R"
301 RETURN
302 PRINT#D,RL$
303 GOSUB299
304 SYS49665
305 GOSUB308
306 GOSUB421
307 RETURN
308 PRINT#3," ";:PRINT#D,RL$;:RETURN
309 PRINT#3," ";:PRINT#D,RL$:RETURN
310 :
311 REM -- KLINGELABFRAGE & START WENN PB3 = 1 (DEZ.8) IST --------------------
312 :
313 IF(PEEK(TE)AND8)=8THENRETURN
314 POKETE,255-2:REM RELAIS AN PB1 EINSCHALTEN
315 PRINT#D,RL$;
316 TN=225
317 GOSUB1059
318 GOTO435
319 :
320 REM -- ON/OFF BELL --------------------------------------------------------
321 :
322 BE=BE+1
323 IFBE=3THENBE=1
324 PRINT#D,"[194][197][204][204] "O$(BE);RL$
325 RETURN
326 IFBE=2THENRETURN
327 PRINT#D,BE$;
328 RETURN
329 :
330 REM -- ON/OFF LINEFEED ----------------------------------------------------
331 :
332 LI=LI+1
333 IFLI=>3THENLI=1
334 IFLI=1THENRL$=CR$+LI$
335 IFLI=2THENRL$=CR$
336 PRINT#D,"[204][201][206][197][198][197][197][196] "O$(LI);RL$
337 RETURN
338 :
339 REM -- DETECT ABFRAGE AN PB4 (DEZ.16) IST PB4 = 1 DANN DETECT VORHANDEN ---
340 :
341 IFCO=1THENRETURN
342 IF(PEEK(TE)AND16)=0THENRETURN
343 IFE2>=4THEN256
344 E1=E1+1
345 IFE1>130THENE1=0:E2=E2+1:GOSUB347:E$="":X$=CR$:RETURN
346 RETURN
347 PRINT#D,RL$RL$"[194][201][212][212][197] [196][197][206] [200][207][197][210][197][210] [198][197][211][212][197][210] [201][206] [196][197][206] [203][207][208][208][204][197][210] [208][210][197][211][211][197][206]!";
348 PRINT#D,RL$"[200]INW."STR$(E2)RL$RL$
349 RETURN
350 :
351 REM -- TIMEOUT/TIMELIMIT --------------------------------------------------
352 :
353 IFCO=1THENRETURN
354 GOSUB342
355 IFGA=1ANDVAL(TI$)>LMTHENT=12:GOSUB1179:GOTO256
356 T1=T1+1
357 IFT1>2000THENT1=1000:GOTO359
358 RETURN
359 IFT2=0THEN256
360 T=11
361 GOSUB1179
362 FORI=1TO40
363 PRINT#D,BE$;"!";
364 NEXT
365 T2=0
366 E$=""
367 X$=CR$
368 RETURN
369 IFX1>1THENX1=X1+1:IFX1>350THENE$="":X$=CR$:GOTO399
370 GOTO377
371 :
372 REM -- GET SCHLEIFE 1 -----------------------------------------------------
373 :
374 E$=""
375 GOSUB326
376 GET#2,X$
377 GET#2,X$
378 GOSUB353
379 IFX$=""THEN382
380 GET#1,Y$
381 IFY$=""THEN399
382 GET#1,X$
383 IFX$=""THENPRINTCHR$(159)"[175]"CHR$(157)CHR$(158);:GOTO369
384 :
385 REM -- INTERNE BEFEHLE ----------------------------------------------------
386 :
387 REM -- DIRECT VERBINDUNG VOM SYSOP ----------------------------------------
388 IFX$=CHR$(133)THENTT$=TI$:CE=1:CO=1:GOSUB597:E$="":RETURN
389 REM -- ADRESSE AUSGEBEN VOM SYSOP -----------------------------------------
390 IFX$="[176]"THENGOSUB1101:GOTO382
391 REM -- DETECT ABFRAGE UNTERDRUECKEN ---------------------------------------
392 IFX$=CHR$(136)THENPRINT"DETECT EIN":CO=0:POKE49800,240:GOTO382
393 IFX$=CHR$(140)THENPRINT"DETECT AUS":CO=1:POKE49800,208:GOTO382
394 REM -- DIALOG BEENDEN VOM SYSOP -------------------------------------------
395 IFX$=CHR$(178)THEN250
396 :
397 REM -- STRING ZUSAMMENSETZTEN ---------------------------------------------
398 :
399 X=ASC(X$)
400 IFX<>13THEN406
401 T1=0
402 LL=100
403 GOSUB308
404 PE=0
405 RETURN
406 IFCE=1ANDX$=XE$THENGOSUB308:RETURN
407 IFX=17ORX=19THEN377
408 IFCE=0THENIF(X=8ORX=20)ANDLEN(E$)>0THENE$=LEFT$(E$,LEN(E$)-1):GOTO413
409 IFLEN(E$)=>LLTHENGOSUB327:GOTO377
410 IFCE=0THENIFE$=""AND(X=8ORX=20)THENGOSUB327:GOTO377
411 IFCE=0THENE$=E$+X$
412 IFPE=1THENX$=RU$
413 PRINT#D,X$;:GOTO377
414 :
415 REM -- RELATIVE DATEI OEFFNEN ---------------------------------------------
416 :
417 GOSUB421
418 OPEN15,8,15
419 OPEN8,8,2,"USER"
420 RETURN
421 CLOSE8
422 GOSUB12
423 RETURN
424 :
425 REM -- RECORDNUMMER FUER RELATIVE DATEI -----------------------------------
426 :
427 HB=INT(BL/256)
428 LB=BL-HB*256
429 X$=CHR$(2)+CHR$(LB)+CHR$(HB)+CHR$(1+RE)
430 PRINT#15,"P"+X$
431 RETURN
432 :
433 REM -- ANRUFER ERKANNT UND START DES MAILBOX DIALOGES ---------------------
434 :
435 PRINTCHR$(147)Q$" [211]TART "XN$XN$
436 CO=1
437 X1=10
438 FORI=1TO2000
439 NEXT
440 PRINT#D,RL$RL$RL$"[205].[195].[211].->";
441 GET#2,X$,X$
442 GOSUB374
443 GOSUB1088
444 CO=0
445 X1=0
446 TI$="000000"
447 :
448 REM -- MAILBOX-MENUES -----------------------------------------------------
449 :
450 PRINT#D,RL$
451 GOSUB119
452 GOSUB1170
453 ONMEGOTO456,458
454 PRINT#D,"- [200][193][213][208][212][205][197][206][213][197] -";
455 GOSUB460
456 PRINT#D,"- [201][206][198][207]-[205][197][206][213][197] -";
457 GOSUB460
458 PRINT#D,"- [205][193][201][204][194][207][216]-[205][197][206][213][197] -";
459 GOSUB460
460 IFPO=1ANDCT=0THENPRINT#D," [208][210][207][198][201] -";RL$;:IFGA=1THENPO=-1:GOTO450
461 IFPO=1THEN472
462 :
463 REM -- MAILBOX-BEFEHLE ----------------------------------------------------
464 :
465 PRINT#D,RL$
466 ONMEGOTO469,471
467 PRINT#D,"[200][197][204][208]-[205][193]-[201][206]-[213][201][196]-[211][207][210]-[208][210][207]-[194][197]-[204][198]-[212][201]-[204][207][199][207][198][198]"RL$;
468 GOTO472
469 PRINT#D,"[200][197][204][208]-[210][201]-[193][203]-[193][204]-[195][204]-[212][197][204]-[205][193]-[200][205]"RL$;
470 GOTO472
471 PRINT#D,"[200][197][204][208]-[206][213]-[213][204]-[213][201][196][193]-[208][205][197]-[208][205][204]-[205][197]-[205][204]-[201][206]-[200][205]"RL$;
472 PRINT#D,RL$
473 IFGA=1THENGOSUB523
474 PRINT#D,C$;
475 GOSUB374
476 IFE$=""THEN474
477 :
478 REM -- BEFEHLE AUSWERTEN --------------------------------------------------
479 :
480 X$=LEFT$(E$,2)
481 X=LEN(E$)
482 IFX>1THENSU$=RIGHT$(E$,X-2)
483 Y$=LEFT$(E$,4)
484 X=LEN(E$)
485 IFX>3THENZ$=RIGHT$(E$,X-4)
486 IFE$="[200][197][204][208]"ORE$="?"THENGOSUB1286:GOTO450
487 IFE$="[200][205]"THENME=0:GOTO450
488 IFE$="[201][206]"THENME=1:GOTO450
489 IFE$="[205][193]"THENME=2:GOTO450
490 IFY$="[213][201][196] "THENGOSUB804:SE=1:GOTO450
491 IFX$="[213][204]"THENGOSUB744:GOTO450
492 IFE$="[206][213]"THENGOSUB626:GOTO450
493 IFE$="[204][207][199][207][198][198]"ORE$="[197][206][196][197]"THENLO=1:GOTO249
494 IFE$="[213][201][196][193]"THENB$=X1$:GOSUB529:GOTO450
495 IFE$="[208][205][197]"THENMF=2:GOSUB869:GOTO450
496 IFE$="[208][205][204]"THENGOSUB857:GOTO450
497 IFE$="[204][198]"THENGOSUB309:GOSUB332:GOSUB308:GOTO474
498 IFE$="[210][201]"THENFI$="RI":GOTO511
499 IFE$="[212][201]"THENGOSUB308:GOSUB613:GOSUB616:GOSUB308:GOTO474
500 IFE$="[205][204]"THENFI$="MESSAGE":GOTO511
501 IFE$="[205][197]"THENFB$="N MESSAGE":MF=1:AU$="[207]EFF. [205]ESSAGE":GOSUB894:GOTO59
502 IFE$="[195][204]"THENFI$="CL":GOTO511
503 IFE$="[211][207][210]"THENGOSUB562:GOTO450
504 IFE$="[193][203]"THENFI$="AK":GOTO511
505 IFE$="[193][204]"THENFI$="AL":GOTO511
506 IFE$="[212][197][204]"THENFI$="TEL":GOTO511
507 IFE$="[194][197]"THENGOSUB309:GOSUB322:GOSUB308:GOTO474
508 IFE$="[208][210][207]"THENGOSUB531:GOTO450
509 GOSUB515
510 GOTO472
511 GOSUB302
512 GOTO450
513 PRINT#D,RL$"[196][198][213][197] [197][206][196]...."RL$;
514 RETURN
515 ER=ER+1
516 PRINT#D,RL$"?>"E$"<?"RL$;
517 RETURN
518 PRINT#D,RL$"[196][197][201][206] [213][211][197][210] [201][196] [201][211][212] [193][203][212][201][214]"RL$
519 RETURN
520 :
521 REM -- AUSGABE TIMELIMIT FUER GAESTE --------------------------------------
522 :
523 A1=INT(TI/60)
524 A2=INT(A1/60)
525 A1=A1-A2*60
526 J$=STR$(14-A2)+" M."+STR$(59-A1)
527 PRINT#D,RL$"[212]IMELIMIT :"J$" S."RL$
528 RETURN
529 IFGA=0THENAE=1:GOSUB653:AE=0:RETURN
530 GOTO532
531 IFGA=0THENPO=-PO:RETURN
532 PRINT#D,RL$"[198][213][206][203][212][201][207][206] [199][197][211][208][197][210][210][212]"RL$
533 RETURN
534 :
535 REM -- USER SUCHEN IM INDEXFELD UND IN DER RELATIVEN DATEI ----------------
536 :
537 FU=0
538 GOSUB417
539 UD$=LEFT$(UA$,1)
540 FORBL=U%-NR+1TOU%
541 RE=60
542 IFUD$<>CHR$(U%(BL))THEN554
543 GOSUB427
544 INPUT#8,U$
545 IFU$<>UA$THEN554
546 IF(FX=2ORFX=4)ANDXL=BLTHEN554
547 IFFX=2ANDU$=UA$THENRE=0:GOSUB427:GOSUB730:FU=1:GOTO556
548 IFFX=4ANDU$=UA$THENFU=1:GOTO556
549 RE=0
550 GOSUB427
551 GOSUB730
552 IFFX=1ANDCO$=CX$THENFU=1:GOTO556
553 IFFX=3THENFU=1:GOTO556
554 NEXT
555 FU=0
556 GOSUB421
557 RE=0
558 RETURN
559 :
560 REM -- BENUTZER RUFT DEN SYSOP --------------------------------------------
561 :
562 T=5
563 GOSUB1179
564 TT$=TI$
565 FORI=1TO10
566 PRINT#D,RU$;
567 TN=180
568 GOSUB1059
569 FORJ=1TO100
570 RU=RU+1
571 IFRU=30THENRU=1:FA=0:GOSUB115
572 IFRU=15THENFA=2:GOSUB115
573 GET#1,X$
574 GET#2,Y$
575 IFX$=""ANDY$=""THEN578
576 IFY$=XE$ORX$=XE$THENFA=0:GOSUB115:RETURN
577 IFX$="J"THEN588
578 NEXT
579 NEXT
580 T=6
581 GOSUB1179
582 FA=0
583 GOSUB115
584 RETURN
585 :
586 REM -- USER - SYSOP DIALOG ------------------------------------------------
587 :
588 T=7
589 GOSUB1179
590 GOSUB1170
591 PRINT#D,"-->";
592 FA=0
593 CE=1
594 CO=1
595 TT$=TI$
596 GOSUB115
597 LL=100
598 GOSUB374
599 IFX$=XE$THENCO=0:CE=0:TI$=TT$:RETURN
600 GOTO597
601 :
602 REM -- CHECK INDEX FELD FUER PERS. MSG ------------------------------------
603 :
604 FORI=1TOMX
605 IFPP$=M$(I)THENM$(I)="LOES"
606 NEXT:RETURN
607 :
608 REM -- AUSGABE TIME/DATUM/ONLINE ------------------------------------------
609 :
610 GOSUB205
611 TE$=LEFT$(UR$,2)+"."+MID$(UR$,3,2)+"."+RIGHT$(UR$,2)
612 RETURN
613 GOSUB610
614 PRINT#D,J$(Z)" DEN "DA$" / "TE$" [213]HR"
615 RETURN
616 M$=MID$(TI$,3,2)
617 SE$=RIGHT$(TI$,2)
618 GOSUB308
619 PRINT#D,"[207]NLINE : "M$" MIN. UND "SE$" SEC.";RL$;
620 RETURN
621 PRINT#D,RL$"[197]INEN [205]OMENT BITTE.."RL$
622 RETURN
623 :
624 REM -- NEUER USER EINTRAG -------------------------------------------------
625 :
626 IFSE=1ORFH=>3THENGOSUB532:RETURN
627 IFSP=1THENGOSUB518:RETURN
628 IFE2>1ORER>3THENT=10:GOSUB1179:RETURN
629 T=8
630 GOSUB1179
631 PRINT#D,"[215]IE IST [196]EIN [206]AME >";
632 L=18
633 GOSUB374
634 IFLEN(E$)>0THENX1$=E$
635 A$=LEFT$(E$,1)
636 FORI=1TO64
637 IFE$=""ORA$=CHR$(I)THENX1$=B$:RETURN
638 NEXT
639 UB$=E$
640 PRINT#D,"[214]ON WO RUFST [196]U AN >";
641 L=18
642 GOSUB374
643 IFLEN(E$)>0THENX2$=E$
644 PRINT#D,"[196]EIN [210]ECHNERSYSTEM >";
645 L=10
646 GOSUB374
647 IFLEN(E$)>0THENX3$=E$
648 GB=1
649 PRINT#D,"[196]EIN [208]ERS.[208]ASSWORT >";
650 L=10
651 GOSUB374
652 IFLEN(E$)>0THENX4$=E$
653 GOSUB309
654 IFGB=0ANDSP=0THENGOSUB532:GB=0:RETURN
655 :
656 REM -- USER DATEN AENDERN -------------------------------------------------
657 :
658 PRINT#D,"[206]AME >"UB$;RL$;
659 PRINT#D,"[211]TADT >"X2$;RL$;
660 PRINT#D,"[211]YSTEM >"X3$;RL$;
661 PRINT#D,"[208]ASSW. >"X4$;RL$;
662 PRINT#D,RL$"[198]ERTIG/[207]K [202]/[217]/[206] >";
663 GOSUB374
664 IFE$=""ORE$="[217]"ORE$="[202]"THEN712
665 IFE$<>"[206]"THENGOSUB677:GOTO662
666 PRINT#D,RL$"[203]ORREKTUR [202]/[217]/[206] >";
667 GOSUB374
668 IFE$="[217]"ORE$="[202]"THENGOSUB308:GOTO631
669 IFE$="[206]"THEN712
670 GOSUB677
671 GOTO666
672 UN$=X1$
673 ST$=X2$
674 RS$=X3$
675 CO$=X4$
676 RETURN
677 PRINT#D,RL$"'[202]'A / '[217]'ES ODER/OR '[206]'O !!"RL$;
678 RETURN
679 IFX1$=""ORX2$=""ORX3$=""ORX4$=""ORE2>3THENRETURN
680 IFLO=1ANDXL>0THENBL=XL:GOSUB672:GOSUB417:GOSUB708:RETURN
681 GOTO700
682 GOSUB610
683 U$=LEFT$(LEFT$(DA$,6)+RIGHT$(DA$,2),8)+TE$
684 XY=1
685 XX=SR
686 GOSUB239
687 U$=U$+" "+K$
688 XX=LI
689 GOSUB239
690 U$=U$+K$
691 XX=PO+1
692 GOSUB239
693 U$=U$+K$
694 XX=BE
695 GOSUB239
696 U$=U$+K$+LEFT$(ST$+S$,19)
697 XY=0
698 U$=U$+LEFT$(RS$+S$,10)+LEFT$(CO$+S$,10)+LEFT$(UN$+S$,19)
699 RETURN
700 GOSUB417
701 NR=NR+1
702 IFNR>U%THENNR=U%
703 BL=U%-NR+1
704 UN$=X1$
705 ST$=X2$
706 RS$=X3$
707 CO$=X4$
708 GOSUB682
709 GOSUB427
710 PRINT#8,U$
711 RETURN
712 IFSP=0ANDAE=0THEN716
713 IFSP=1ANDAE=0THENRETURN
714 IFSP=1ANDAE=1THEN716
715 RETURN
716 GOSUB621
717 PRINT#D,RL$;
718 UA$=LEFT$(X1$+S$,19)
719 CX$=LEFT$(X4$+S$,10)
720 IFX1$=""ORX2$=""ORX3$=""ORX4$=""THEN682
721 FX=4
722 GOSUB537
723 IFAE=1ANDFU=0THENPRINT#D,RL$"[207][203] [196]ATEN GEAENDERT"RL$:GOSUB1054:AE=0:RETURN
724 IFAE=0ANDFU=0THENT=9:GOSUB1179:SP=1:RETURN
725 PRINT#D,RL$"[196]IESER [206]AME IST LEIDER SCHON BELEGT !"RL$
726 X1$=B$
727 UB$=UC$
728 GOSUB1054
729 GOTO658
730 INPUT#8,U$
731 D$=LEFT$(U$,8)
732 I$=MID$(U$,9,8)
733 S1=VAL(MID$(U$,19,1))
734 S2=VAL(MID$(U$,20,1))-1
735 S3=VAL(MID$(U$,21,1))
736 RS$=MID$(U$,41,10)
737 S4=VAL(MID$(U$,18,1))
738 ST$=MID$(U$,22,19)
739 CO$=MID$(U$,51,10)
740 UN$=MID$(U$,61,19)
741 RETURN
742 REM -- USERLISTE ANZEIGEN -------------------------------------------------
743 :
744 Z$=LEFT$(SU$,1)
745 PRINT#D,RL$"[197]INGETRAGENE USER BEI [205].[195].[211]."RL$
746 GOSUB417
747 SU=0
748 RE=0
749 W$=""
750 V=LEN(SU$)
751 O$=MID$(SU$,3,V)
752 UA$=LEFT$(O$+S$,19)
753 IFSP=0THENPRINT#D,RL$"[196]IE [193]USGABE IST FUER [199]AESTE BEGRENZT"RL$:GOTO755
754 IFZ$="[193]"THENPRINT#D,RL$"[193]NZAHL [213]SER ZUR [218]EIT : "NR$;RL$;:GOTO766
755 W=0
756 W$=RIGHT$(SU$,1)
757 IFSP=0THENZ$="[206]":SS=1:SU$="":GOTO760
758 SS=LEN(SU$)
759 IFZ$=""THENA$="[193]LLE "+NR$+" [213]SER ANZEIGEN ":GOTO768
760 IFZ$="[206]"ANDSS=1THENA$="[206]ACH NAMEN SUCHEN":SU=1:L=18:RE=60:GOTO768
761 IFZ$="[206]"ANDW$<>"*"ANDSS>1THENPRINT#D,"[206]ACH [206]AMEN SUCHEN"RL$:W$="/":GOTO773
762 IFZ$="[206]"ANDW$="*"ANDSS>1THENA$="[206]ACH [206]AMEN SUCHEN":SU=1:L=18:GOTO768
763 IFZ$="[196]"ANDSS>1THENA$="[206]ACH [196]ATUM SUCHEN":SU=2:L=8:GOTO768
764 IFZ$="[210]"ANDSS>1THENA$="[206]ACH [210]ECHNER SUCHEN":SU=3:L=10:GOTO768
765 IFZ$="[211]"ANDSS>1THENA$="[206]ACH [211]TADT SUCHEN":SU=4:L=18:GOTO768
766 GOSUB421
767 RETURN
768 IFZ$="[206]"ANDW$="*"THENO$=LEFT$(O$,LEN(O$)-1)
769 V=LEN(O$)
770 IFV>LTHENGOSUB421:W$=""
771 IFSS<>1THENPRINT#D,RL$A$RL$:GOTO773
772 GOTO777
773 PRINT#D,"[213]SER -------------- [211]YSTEM ------------ [211]TADT ------------- [196]ATUM"
774 PRINT#D,RL$
775 IFW$="/"THENFX=3:GOSUB537:IFFU=0THENT=13:GOSUB1179:RETURN
776 IFW$="/"ANDFU=1THENUS$=U$:RE=0:SS=0:GOTO787
777 FORBL=U%-NR+1TOU%
778 GOSUB427
779 INPUT#8,US$
780 GOSUB288
781 IFEX=2THEN795
782 IFSU=1ANDMID$(US$,61,V)<>O$THEN796
783 IFSU=2ANDLEFT$(US$,V)<>O$THEN796
784 IFSU=3ANDMID$(US$,41,V)<>O$THEN796
785 IFSU=4ANDMID$(US$,22,V)<>O$THEN796
786 IFRE>0THENPRINT#D,US$;:IFSP=0THENSU=0
787 IFRE=0THENPRINT#D,MID$(US$,61,19);
788 IFW<3ANDRE>0THENPRINT#D," ";
789 IFSS=1THEN791
790 PRINT#D," "MID$(US$,41,10)" "MID$(US$,22,19)" "LEFT$(US$,8);
791 IFSS<>1THENPRINT#D,RL$;
792 IFW$="/"THENPRINT#D,RL$;:RETURN
793 GOSUB288
794 IFSS=1THENW=W+1:IFW=4THENW=0:A$="":PRINT#D,RL$;
795 IFEX=2THENEX=0:GOSUB421:RE=0:PRINT#D,RL$:RETURN
796 T1=0
797 NEXT
798 RE=0
799 GOSUB421
800 RETURN
801 :
802 REM -- USER ID (UID) PRUEFEN ----------------------------------------------
803 :
804 IFFH=3THENGOSUB532:RETURN
805 IFSP=1THENGOSUB518:RETURN
806 Y=0
807 X=LEN(Z$)
808 IFZ$=""THEN450
809 FORI=1TOX
810 IFY=0ANDMID$(Z$,I,1)=","THENY=I:E$=RIGHT$(Z$,X-I):GOTO813
811 NEXT
812 IFY=0THENY=20
813 UA$=LEFT$(Z$,Y-1)
814 UB$=UA$
815 UA$=LEFT$(UA$+S$,19)
816 UC$=UB$
817 IFY<>20THEN823
818 PRINT#D,RL$"[208][193][211][211][215][207][210][212] >";
819 PE=1
820 GOSUB374
821 PE=0
822 IFE$=""THENRETURN
823 CX$=LEFT$(E$+S$,10)
824 GOSUB621
825 SP=0
826 GA=1
827 FX=1
828 GOSUB537
829 IFFU=1THEN833
830 PRINT#D,RL$"[213]NBEKANNTER [206]AME/[208]ASSWORT"RL$
831 FH=FH+1
832 RETURN
833 GOSUB309
834 SP=1
835 GOSUB1076
836 PRINT#D,RL$"[196]EIN LETZTER [193]NRUF ERFOLGTE"RL$;
837 XL=BL
838 PRINT#D,"AM "D$" UM "I$;RL$;
839 LI=S1
840 PO=S2
841 BE=S3
842 GA=0
843 SW=0
844 GOSUB324
845 GOSUB334
846 PP$=UN$+CO$
847 X1$=UN$
848 X2$=ST$
849 X3$=RS$
850 X4$=CO$
851 GOSUB857
852 GOSUB1054
853 RETURN
854 :
855 REM -- CHECK PERS. MESSAGE ------------------------------------------------
856 :
857 FORI=1TOMX
858 IFPP$=M$(I)THENSW=1:GOSUB863
859 NEXT
860 IFSW=0THENPRINT#D,RL$"[203]EINE [208]ERS. [205]ESSAGE FUER [196]ICH VORHANDEN"RL$
861 IFSW=1THENPRINT#D,RL$"[196]AS WAREN ALLE PERS. [205]ESSAGE FUER DICH"RL$
862 RETURN
863 PRINT#D,RL$"[208]ERS. [205]ESSAGE FUER [196]ICH.."
864 FI$="P"+STR$(I)
865 GOSUB302
866 RETURN
867 REM -- EINGABE PERS. MESSAGE ----------------------------------------------
868 :
869 FORI=1TOMX
870 IFM$(I)="LOES"THEN875
871 NEXT
872 T=1
873 GOSUB1179
874 RETURN
875 GOSUB308
876 IFPO=-1THENT=2:GOSUB1179
877 PRINT#D,"[208]ERS. [205][211][199] FUER >";
878 GOSUB374
879 IFE$=""THENRETURN
880 AU$=E$
881 UA$=LEFT$(E$+S$,19)
882 OK=0
883 GOSUB621
884 FX=2
885 GOSUB537
886 IFFU=0THENGOSUB309:T=13:GOSUB1179:GOTO877
887 OK=1
888 P$=UN$+CO$
889 GOSUB421
890 GOTO895
891 :
892 REM -- TEXT EDITOR --------------------------------------------------------
893 :
894 IFPEEK(830+MF)>3THENT=4:GOSUB1179:RETURN
895 YZ=0
896 GOSUB308
897 TZ=1
898 FORI=1TO40
899 TE$(I)=""
900 NEXT
901 TY=1
902 IFPO=-1THENT=3:GOSUB1179
903 PRINT#D,RL$"- [212][197][216][212]-[197][196][201][212][207][210] -"RL$
904 PRINT#D,"[196]EINE [197]INGABE FUER "AU$RL$
905 EO=0
906 ONGAGOSUB523
907 PRINT#D,RL$"[200][197][204][208]-[197]-[193]-[204]-[211][208]-[197][195][200][207] ("O$(EO+1)")-[205][193]"RL$
908 GOSUB119
909 IFTZ<YZTHENTZ=SZ
910 PRINT#D,RL$C$;
911 GOSUB374
912 IFE$=""THEN910
913 EE$=LEFT$(E$,1)
914 LX=VAL(RIGHT$(E$,LEN(E$)-1))
915 IFE$="?"OR"[200][197][204][208]"=E$THENT=14:GOSUB1179:GOTO908
916 IFEE$="[193]"THENGOSUB960:GOTO907
917 IFE$="[197][195][200][207]"THEN924
918 IFEE$="[204]"THENGOSUB974:GOSUB308:GOTO907
919 IFEE$="[197]"THENONTYGOTO927,996
920 IFE$="[205][193]"THENOG=2:GOTO1004
921 IFE$="[211][208]"THENOG=1:GOTO1004
922 GOSUB515
923 GOTO910
924 EO=EO+1
925 IFEO=2THENEO=0
926 GOTO907
927 GOSUB122
928 PRINT#D,RL$;
929 XZ=TZ
930 TY=2
931 IFEO=0THENGOSUB955
932 E$=""
933 IFTZ=>41THENTZ=40:GOTO907
934 GOSUB341
935 GET#2,X$
936 IFX$=""THEN938
937 GOTO940
938 GET#1,X$
939 IFX$=""THENPRINTCHR$(159)"_"CHR$(157)CHR$(158);:GOTO934
940 X=ASC(X$)
941 IFX=24ORX=27THENGOSUB309:GOSUB308:GOTO905
942 IFX=17ORX=19THEN934
943 IF(X=8ORX=20)ANDLEN(E$)>0THENE$=LEFT$(E$,LEN(E$)-1):GOTO949
944 IFLEN(E$)=>70THENGOSUB327:IFLEN(E$)=>79THENGOSUB308:GOTO951
945 IFLEN(E$)<1AND(X=8ORX=20)THENGOSUB327:GOTO934
946 IFX=13THEN951
947 E$=E$+X$
948 IFEO=1THENPRINTX$;
949 IFEO=0THENPRINT#D,X$;
950 GOTO934
951 IFE$="..."ORE$="[197][206][196]"THENPRINT#D,RL$:EO=0:GOTO905
952 TE$(TZ)=E$
953 TZ=TZ+1
954 GOTO927
955 A$=STR$(XZ)
956 A=LEN(A$)
957 IFA=2THENA$=MID$(A$,2,1):PRINT#D,"0"+A$+">";
958 IFA=3THENPRINT#D,MID$(A$,2,2)+">";
959 RETURN
960 PRINT#D,RL$
961 IFLX=0THEN967
962 IFLX<0ORLX>40THENRETURN
963 XZ=LX
964 GOSUB971
965 PRINT#D,RL$
966 RETURN
967 FORXZ=1TOTZ
968 GOSUB971
969 NEXT
970 RETURN
971 GOSUB955
972 PRINT#D,TE$(XZ);RL$;
973 RETURN
974 PRINT#D,RL$"[204]OESCHEN ? >";
975 GOSUB374
976 IFE$=""THEN974
977 IFE$<>"[202]"ANDE$<>"[217]"THENRETURN
978 IFLX=0THEN983
979 IFLX<0ORLX>40THENRETURN
980 I=LX
981 GOTO991
982 RETURN
983 FORI=1TOTZ
984 GOSUB994
985 NEXT
986 PRINT#D,RL$"[193]LLE [218]EILEN GELOESCHT"RL$
987 TZ=1
988 YZ=1
989 SZ=1
990 GOTO993
991 GOSUB994
992 PRINT#D,RL$"[218]EILE"+STR$(I)" GELOESCHT"RL$
993 RETURN
994 TE$(I)=""
995 RETURN
996 SW=SW+1
997 IFSW=1THENX=0
998 YZ=TZ
999 IFLX=0THENYZ=0:TZ=1:GOTO927
1000 IFLX<0ORLX>40THEN910
1001 SZ=TZ
1002 TZ=LX
1003 GOTO927
1004 LX=0
1005 FORI=1TOTZ
1006 LX=LX+LEN(TE$(I))
1007 NEXT
1008 IFLX>10THENONOGGOTO1016,1011
1009 A$="[203]EIN [212]EXT ZUM [193]BSPEICHERN VORHANDEN !"
1010 GOTO1013
1011 A$="[196]EIN [212]EXT IST NOCH IM [197]DITOR !"
1012 OG=0
1013 IFOG=2THEN450
1014 PRINT#D,RL$A$RL$
1015 GOTO908
1016 GOSUB621
1017 GOSUB610
1018 AK$=DA$+" / "+LEFT$(TE$,5)
1019 BK$=CR$+UB$+" / "+AK$+CR$+CR$
1020 GOSUB421
1021 IFOK=1THEN1042
1022 X=PEEK(830+MF)
1023 X=X+1
1024 POKE830+MF,X
1025 FI$="@:"+FB$+",S,W"
1026 IFX>1THENFI$=FB$+",S,A"
1027 GOSUB12
1028 GOSUB1118
1029 OPEN8,8,2,FI$
1030 BC$=CR$+CR$+"-[206][197][216][212]-"+CR$+CHR$(14)+CR$
1031 PRINT#8,BK$;
1032 FORJ=1TOTZ
1033 PRINT#8,TE$(J)
1034 NEXT
1035 PRINT#8,BC$;
1036 CLOSE8
1037 GOSUB1106
1038 PRINT#D,RL$"[196]EIN [205][211][199] WURDE ABGESPEICHERT"RL$;
1039 IFOK=1THENOK=0:GOSUB308:RETURN
1040 PRINT#D,"UND IST BEIM NAECHSTEN [193]NRUF ABRUFBAR"RL$
1041 GOTO450
1042 FORI=1TOMX
1043 IFM$(I)=P$THENFA$="P":FB$=",S,A":GOTO1049
1044 NEXT
1045 FORI=1TOMX
1046 IFM$(I)="LOES"THENM$(I)=P$:FA$="@:P":FB$=",S,W":GOTO1049
1047 NEXT
1048 GOTO869
1049 GOSUB12
1050 GOSUB1118
1051 OPEN8,8,2,FA$+STR$(I)+FB$
1052 GOTO1031
1053 REM -- USER ERKANNT UND ANZEIGEN -----------------------------------------
1054 UX$=UB$
1055 GOSUB309
1056 C$=UX$+"->"
1057 RETURN
1058 REM -- TON AUSGABE -------------------------------------------------------
1059 POKESI,TN
1060 POKESI+1,TN
1061 POKESI+5,11
1062 POKESI+6,10
1063 POKESI+24,15
1064 POKESI+7,TN+3
1065 POKESI+8,TN+3
1066 POKESI+12,10
1067 POKESI+13,11
1068 POKESI+4,32
1069 POKESI+4,33
1070 POKESI+11,32
1071 POKESI+11,33
1072 RETURN
1073 :
1074 REM -- BEGRUESSUNG DES ERKANNTEN USERS -----------------------------------
1075 :
1076 GOSUB205
1077 A$="[200]ALLO"
1078 TT=VAL(UR$)
1079 IFTT>1ANDTT<90000THENA$="[199]UTEN [205]ORGEN"
1080 IFTT>90000ANDTT<180000THENA$="[199]UTEN [212]AG"
1081 IFTT>190000ANDTT<235959THENA$="[199]UTEN [193]BEND"
1082 IFTT>120000ANDTT<140000THENA$="[205]AHLZEIT"
1083 PRINT#D,RL$RL$A$" "UB$;RL$;
1084 RETURN
1085 :
1086 REM -- MAILBOX BEGRUESSUNG (START) ---------------------------------------
1087 :
1088 GOSUB308
1089 GOSUB205
1090 TE$=LEFT$(UR$,2)+":"+MID$(UR$,3,2)
1091 IFE$="*"THEND=3:GOTO1094
1092 IFE$="."THEN1094
1093 FI$="BILD":GOSUB302
1094 PRINT#D,RL$"[196]U BIST DER "+AN$". [193]NRUFER"
1095 PRINT#D,"AM "DA$" UM "TE$" [213]HR"RL$;
1096 RETURN
1097 PRINT#D,RL$"[212]SCHUESS AND [194]YE BYE "UX$RL$;
1098 PRINT#D,RL$RL$"[194]IS ZUM NAECHSTEN MAL"RL$
1099 RETURN
1100 REM -- ADRESSE VOM SYSOP (M.C.S........) ---------------------------------
1101 PRINT#D,RL$"[[212][200][215]]"RL$;
1102 PRINT#D,"2000 [200]AMBURG 70"RL$;
1103 PRINT#D,"[193]UF DEM [203]OENIGSLANDE 43"RL$
1104 RETURN
1105 REM -- FEHLER ABFRAGE FLOPPY ---------------------------------------------
1106 INPUT#15,E,EE$,EX1,EX2
1107 IFE<1THENRETURN
1108 PRINTXN$"[198][204][207][208][208][217] [197][210][210][207][210]";E;EE$;EX1;EX2
1109 FORI=1TO50
1110 IFI>25THENTN=100:FA=2:GOSUB115:GOSUB1059
1111 IFI<25THENTN=70:FA=10:GOSUB115:GOSUB1059
1112 NEXT
1113 GETX$
1114 IFX$=""THEN1109
1115 IFX$="W"THENRETURN
1116 IFX$="S"THENEND
1117 GOTO1109
1118 CLOSE15
1119 OPEN15,8,15:RETURN
1120 :
1121 REM -- TEXT IN MESSAGE EINBINDEN (AUTOUPDATE) ----------------------------
1122 :
1123 PRINTCHR$(147)XN$"[195]HECKING [213]PDATE"XN$
1124 GOSUB12
1125 FA$="MESSAGE"
1126 FORI=0TO3
1127 IFPEEK(830+I)=0THENNEXT:RETURN
1128 GOSUB12
1129 OPEN15,8,15,"V"
1130 PRINT"[214]ALIDATE"XN$XN$
1131 GOSUB1106
1132 CLOSE15
1133 POKE828,0
1134 OPEN15,8,15,"R:"+FA$+"R"+"="+FA$
1135 GOSUB1106
1136 CLOSE15
1137 Q=0
1138 E$=""
1139 CX=0
1140 OPEN15,8,15,"R:"+FA$+"=N "+FA$
1141 GOSUB1106
1142 CLOSE15
1143 OPEN5,8,6,FA$+",S,A"
1144 OPEN8,8,0,FA$+"R,S,R"
1145 SR=ST
1146 IFSR>0THEN1159
1147 GET#8,X$
1148 IFX$=""THEN1145
1149 IFX$=CR$THEN1152
1150 E$=E$+X$
1151 GOTO1145
1152 Q=Q+LEN(E$)
1153 PRINTCHR$(145)"[205]ESSAGE FILE "RIGHT$(" "+STR$(Q),6)
1154 IFQ>17000THEN1159
1155 IFQ>15000ANDE$="-[206][197][216][212]-"THEN1159
1156 PRINT#5,E$;CHR$(13);
1157 E$=""
1158 GOTO1145
1159 PRINT#5,"-[197][206][196]-";CR$;
1160 CLOSE5
1161 CLOSE8
1162 OPEN15,8,15
1163 GOSUB1106
1164 CLOSE15
1165 OPEN15,8,15,"S:N "+FA$+","+FA$+"R"
1166 CLOSE15
1167 NEXT
1168 RETURN
1169 REM -- TON AUSSCHALTEN ---------------------------------------------------
1170 POKESI,0
1171 POKESI+1,0
1172 POKESI+7,0
1173 POKESI+8,0
1174 POKESI+24,0
1175 RETURN
1176 :
1177 REM -- MAILBOX TEXTE -----------------------------------------------------
1178 :
1179 PRINT#D,RL$
1180 CMDD
1181 ONTGOTO1186,1191,1194,1199,1204,1208,1214
1182 IFT>7THENT=T-7
1183 ONTGOTO1218,1227,1236,1245,1256,1266,1278
1184 PRINT#2,RL$
1185 RETURN
1186 PRINT"[197]S KOENNEN ZUR [218]EIT KEINE PERS. [205][211][199]"RL$;
1187 PRINT"ABGESPEICHERT WERDEN !"RL$;
1188 PRINT"[194]ITTE NIMM DEN [207]EFFENDLICHEN [212]EIL."RL$;
1189 PRINT"[196]AS [211]YSTEM"RL$
1190 RETURN
1191 PRINT"**** [208]ERSOENLICHE [205]ESSAGE EINGABE ****"RL$;
1192 PRINT"[194]ITTE DEN [206]AMEN DES [213]SERS ANGEBEN"RL$
1193 RETURN
1194 PRINT"[205]AXIMAL 40 [218]EILEN A'80 [218]EICHEN"RL$;
1195 PRINT"[197]INGABE MIT '[197]' ODER MIT '[215]' BEGINNEN"RL$;
1196 PRINT"[205]IT [195]TRL/[216] / [197][211][195] / [197][206][196] ODER MIT ..."RL$;
1197 PRINT"KANN DIE EINGABE ABGEBROCHEN WERDEN."RL$
1198 RETURN
1199 PRINT"[196]ER [213]PDATESPEICHER IST VOLL!"RL$;
1200 PRINT"[206]EUE [212]EXTE KOENNEN ERST BEIM"RL$;
1201 PRINT"NAECHSTEN [193]NRUF ANGENOMMEN WERDEN."RL$;
1202 PRINT"[196]AS [211]YSTEM"RL$
1203 RETURN
1204 PRINT"[211][217][211][212][197][205] [207][208][197][210][193][212][197][210] [210][213][198][197][206]"RL$;
1205 PRINT"[194][201][212][212][197] [215][193][210][212][197][206] [207][196][197][210] [205][201][212] [195]TRL/[216] [193][194][194][210][197][195][200][197][206]"RL$;
1206 PRINT".......... <[197][206][196]"RL$;
1207 RETURN
1208 PRINT"[211][207][210][210][217] [197][210] [201][211][212] [218][213][210] [218][197][201][212] [206][201][195][200][212] [193][206][215][197][211][197][206][196]."RL$;
1209 PRINT"[214][197][210][211][213][195][200] [197][211] [194][201][212][212][197] [211][208][193][197][212][197][210] [206][207][195][200] [205][193][204] [207][196][197][210]"RL$;
1210 PRINT"[200][201][206][212][197][210][204][193][211][211][197] [197][201][206][197] [208][197][210][211]. [205][197][211][211][193][199][197] [213][206][212][197][210]"RL$;
1211 PRINT">>>>> *[211][217][211][207][208] ODER [[212][200][215]] <<<<<"RL$;
1212 PRINT"[196]AS [211]YSTEM."RL$
1213 RETURN
1214 PRINT"[200]URRA ...... [197]R IST ANWESEND !!"RL$;
1215 PRINT"[218]UM [205]ENUE KOMMST WIEDER MIT [195]TRL/[216]"RL$;
1216 PRINT"WENN [196]U MIT DEM [199]ESPRAECH FERTIG BIST."RL$
1217 RETURN
1218 PRINT"[196]U HAST DIE MOEGLICHKEIT DICH HIER"RL$;
1219 PRINT"EINZUTRAGEN UM [205]ITBENUTZTER DER"RL$;
1220 PRINT"[205].[195].[211]. - [194][207][216] ZU WERDEN."RL$;
1221 PRINT"[193]LLE [193]NGABEN ERFOLGEN FREIWILLIG"RL$;
1222 PRINT"UND WERDEN NICHT WEITER VERWENDET."RL$;
1223 PRINT"[194]ITTE ACHTE AUF [213]EBERTRAGUNGSFEHLER UND"RL$;
1224 PRINT"[194][201][212][212][197] NUR ERNSTGEMEINTE [197]INTRAGUNGEN"RL$;
1225 PRINT"VORNEHMEN !!"RL$
1226 RETURN
1227 PRINT"[207]K. [215]ENN [196]U DIE [194]OX SPAETER MIT [204][207][199][207][198][198]"RL$;
1228 PRINT"VERLAESST WIRD DER [210]ECHNER [196]ICH IN DIE"RL$;
1229 PRINT"[213]SERLISTE EINTRAGEN."RL$;
1230 PRINT"[194]EIM NAECHSTEN [193]NRUF VON [196]IR MUSST"RL$;
1231 PRINT"[196]U DICH BITTE MIT [213][201][196] [206]AME UND [196]EINEM"RL$;
1232 PRINT"[208]ASSWORT EINLOGGEN DAMIT [196]U [196]EINE [208]ERS."RL$;
1233 PRINT"[205]ESSAGE LESEN KANNST."RL$;
1234 PRINT"[196]AS [211]YSTEM."RL$
1235 RETURN
1236 PRINT"[196]U HAST ZU VIELE [213]EBERTRAGUNGSFEHLER"RL$;
1237 PRINT"[193]US [211]ICHERHEITSGRUENDEN DIE [196]IR"RL$;
1238 PRINT"SICHERLICH EINLEUCHTEN MUSS ICH"RL$;
1239 PRINT"[196]IR LEIDER DIE [198]UNKTION SPERREN."RL$;
1240 PRINT"[214]ERSUCH ES BITTE NOCH MAL MIT EINER"RL$;
1241 PRINT"BESSEREN [212]ELEFONLEITUNG ODER"RL$;
1242 PRINT"UEBERPRUEFE [196]EINEN [203]OPPLER EINMAL."RL$;
1243 PRINT"[196]AS [211]YSTEM."RL$
1244 RETURN
1245 PRINT"[201][211][212] [196][193][211] [200][201][197][210] [211][207] [204][193][206][199][215][197][201][204][201][199] [196][193][211] [196][213] [200][201][197][210]"RL$;
1246 PRINT"[197][201][206][208][197][206][206][211][212] ????"RL$;
1247 PRINT"[215]ENN ICH VON [196]IR WEITER NICHTS HOEREN"RL$;
1248 PRINT"SOLLTE SEHE ICH MICH GEZWUNGEN DIE"RL$;
1249 PRINT"[214]ERBINDUNG VON MEINER [211]EITE ZU [213]NTER-"RL$;
1250 PRINT"BRECHEN."RL$;
1251 PRINT"[211]CHLIESSLICH WOLLEN AUCH ANDERE IN DIE [194]OX."RL$;
1252 PRINT"[193][204][211][207] [203][207][205][205] [201][206] [196][201][197] [200][213][198][197][206] !!!!"RL$;
1253 PRINT"[196][193][211] [215][193][210] [196][201][197] [193][204][204][197][210][204][197][212][218][212][197] [215][193][210][206][213][206][199] !!"RL$;
1254 PRINT"[196]AS [211]YSTEM."RL$
1255 RETURN
1256 PRINT"[212][201][205][197][207][213][212] [208][197][210][201][207][196] [197][216][208][201][210][197][196]"RL$;
1257 PRINT"----------------------"RL$;
1258 PRINT"[196]U HAST LEIDER [196]EIN [218]EITLIMIT UEBER-"RL$;
1259 PRINT"SCHRITTEN !!!!!!"RL$;
1260 PRINT"[200]ABE BITTE VERSTAENDNIS DAFUER DAS ICH"RL$;
1261 PRINT"DIE [214]ERBINDUNG VON MEINER [211]EITE AB-"RL$;
1262 PRINT"BRECHE UM AUCH ANDEREN [213]SERN DIE [199]ELE-"RL$;
1263 PRINT"GENHEIT ZU GEBEN HIER ANZURUFEN."RL$;
1264 PRINT"[211]O LONG...... [196]AS [211]YSTEM."RL$
1265 RETURN
1266 PRINT"[211]ORRY DIESER [213]SER IST SO BEI MIR NICHT"RL$;
1267 PRINT"EINGETRAGEN."RL$;
1268 PRINT"[211]UCHE DOCH MAL MIT DEM [194]EFEHL [213][204][206] [206][193][205][197]*"RL$;
1269 PRINT"IM [205][193][201][204][194][207][216][205][197][206][213][197] NACH DEM [213]SER ABER GIB"RL$;
1270 PRINT"NUR DIE [193]NFANGS [194]UCHSTABEN UND '*'"RL$;
1271 PRINT"([202]OKER) AN."RL$;
1272 PRINT"[211]OLLTE ER IMMER NOCH NICHT GEFUNDEN"RL$;
1273 PRINT"WERDEN SO IST DIESER [213]SER NOCH NICHT"RL$;
1274 PRINT"BEI MIR EINGETRAGEN."RL$;
1275 PRINT"[196]AS [211]YSTEM."RL$
1276 RETURN
1277 REM -- HELPLISTEN --------------------------------------------------------
1278 PRINT"[197]XX [197]INGABE"RL$;
1279 PRINT"[193]XX [193]NZEIGEN"RL$;
1280 PRINT"[204]XX [204]OESCHEN"RL$;
1281 PRINT"XX [218]EILE"RL$;
1282 PRINT"[211][208] [211]PEICHERN"RL$;
1283 PRINT"[197][195][200][207] "+O$(EO+1)RL$;
1284 PRINT"[205][193] [205]AILBOXMENUE"RL$
1285 RETURN
1286 PRINT#D,RL$
1287 CMDD
1288 ONMEGOTO1321,1302
1289 REM -- HELP HAUPTMENUE ---------------------------------------------------
1290 PRINT"[200]ELP GIBT DIESE [204]ISTE AUS"RL$;
1291 PRINT"[205][193] [205]AILBOX-MENUE"RL$;
1292 PRINT"[201][206] [201]NFO-MENUE"RL$;
1293 PRINT"[213][201][196] [213]SER [201][196]"RL$;
1294 PRINT"[211][207][210] [211]YSTEM [207]PERATER RUFEN"RL$;
1295 PRINT"[208][210][207] [208]ROFIUMSCHALTUNG"RL$;
1296 PRINT"[194][197] [194]ELL ON/OFF"RL$;
1297 PRINT"[204][198] [204]INEFEED ON/OFF"RL$;
1298 PRINT"[212][201] [212]IME/[196]ATUM/[207]NLINE"RL$;
1299 PRINT"[204][207][199][207][198][198] [214]ERBINDUNG BEENDEN"RL$;
1300 PRINT#D:RETURN
1301 REM -- HELP MAILBOXMENUE -------------------------------------------------
1302 PRINT"[200]ELP GIBT DIESE [204]ISTE AUS"RL$;
1303 PRINT"[206][213] [206]EUER [213]SER EINTRAG"RL$;
1304 PRINT"[213][204] [213]SERLISTE GESAMMT"RL$;
1305 PRINT"[213][204][193] [193]NZAHL [213]SER"RL$;
1306 PRINT"[213][204][206] [206]UR [206]AMEN ANZEIGEN"RL$;
1307 PRINT"[213][204][206] .... [206]ACH [206]AMEN SUCHEN"RL$;
1308 PRINT"[213][204][206] ...* MIT [202]OKER"RL$;
1309 PRINT"[213][204][211] .... [206]ACH [211]TADT SUCHEN"RL$;
1310 PRINT"[213][204][210] .... [206]ACH [210]ECHNER SUCHEN"RL$;
1311 PRINT"[213][204][196] .... [206]ACH [196]ATUM SUCHEN"RL$;
1312 PRINT"[213][201][196][193] [213]SER [196]ATEN AENDERN"RL$;
1313 PRINT"[208][205][197] [208]ERS. [205]ESSAGE EINGABE"RL$;
1314 PRINT"[208][205][204] [208]ERS. [205]ESSAGE LESEN"RL$;
1315 PRINT"[205][197] [205]ESSAGE EINGABE"RL$;
1316 PRINT"[205][204] [205]ESSAGE LESEN"RL$;
1317 PRINT"[201][206] [201]NFOMENUE"RL$;
1318 PRINT"[200][205] [200]AUPTMENUE"RL$;
1319 PRINT#D:RETURN
1320 REM -- HELP INFOMENUE ----------------------------------------------------
1321 PRINT"[200]ELP GIBT DIESE [204]ISTE AUS"RL$;
1322 PRINT"[210][201] [210]ECHNER [201]NFO"RL$;
1323 PRINT"[193][203] [193]KTUELLES"RL$;
1324 PRINT"[193][204] [193]LLGEMEINES"RL$;
1325 PRINT"[195][204] [195]LUBINFOS"RL$;
1326 PRINT"[205][193] [205]AILBOXMENUE"RL$;
1327 PRINT"[200][205] [200]AUPTMENUE"RL$;
1328 PRINT#D:RETURN