home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
s85xx
/
s8506a.d64
/
pic-loader
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
938b
|
26 lines
10 REM*******************************
20 REM* *
30 REM* LADEN VON HI-EDDI-BILDERN *
40 REM* IN BASICPROGRAMMEN *
50 REM* *
60 REM*******************************
100 INPUT"FILENAME";N$
110 POKE781,8:REM GERAETEADRESSE
120 POKE782,0:REM SEKUNDAERADRESSE
130 SYS65466:REM FILEPARAMETER SETZEN
140 POKE780,LEN(N$)
150 POKE781,192:POKE782,2:REM POINTER AUF FILENAMEN
160 FORI=1TOLEN(N$):POKE703+I,ASC(MID$(N$,I)):NEXT:REM FILENAME
170 SYS65469:REM NAMENSPARAMETER SETZEN
180 POKE780,0:REM LOAD-FLAG
190 POKE781,0:POKE782,224:REM ADRESSE=$E000
200 SYS65493:REM LOAD
210 REM GRAFIK EINSCHALTEN
220 M1=PEEK(56576):POKE56576,M1 AND 252:REM VIC-ADRESSBEREICH AB $C000
230 M2=PEEK(53272):POKE53272,8:REM VIDEORAM- UND GRAFIK-ADRESSEN
240 M3=PEEK(53265):POKE53265,M3OR32:REM HIRES EINSCHALTEN
250 F=16*7+6:REM 16*VORDERGRUNDFARBE+HINTERGRUNDFARBE
260 FORI=49152TO50152:POKEI,F:NEXT
270 POKE198,0:WAIT198,1:REM AUF TASTE WARTEN
280 POKE56576,M1:POKE53272,M2:POKE53265,M3:REM WIEDER NORMALZUSTAND