home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / s85xx / s8505.d64 / error-changer (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  65 lines
  1. 110 REM *****************************
  2. 130 REM *                           *
  3. 140 REM * E R R O R - C H A N G E R *
  4. 150 REM *                           *
  5. 151 REM *          C 64             *
  6. 152 REM *                           *
  7. 160 REM *     BY ANDREAS KNIPP      *
  8. 170 REM *                           *
  9. 180 REM *****************************
  10. 190 REM
  11. 200 POKE53280,4:POKE53281,6:GOTO 250
  12. 250 PRINT"[147]WAEHLBARE FEHLERMELDUNGEN BY A.KNIPP KPS":DIMT$(40):FZ=1
  13. 260 T$(30)="BREAK ERROR"
  14. 270 T$(31)="READY.":HI=256
  15. 280 FORI=49152TO49232
  16. 300 READX:POKEI,X:NEXT
  17. 310 POKE768,139:POKE769,227:REM FEHLERMELDUNGEN AUF ROM  STELLEN.
  18. 320 LV=41372:SV=49293:VA=49233
  19. 330 FORLV=41373TO41767:REM EINLESEN DER ALTEN FEHLERMELDUNGEN
  20. 340 T$(FZ)=T$(FZ)+CHR$(PEEK(LV)AND127):IFPEEK(LV)<127THEN370
  21. 350 T$(FZ)=T$(FZ)+" ERROR":PRINTT$(FZ)
  22. 360 FZ=FZ+1
  23. 370 NEXTLV:FZ=FZ+1:REM PLATZ FUER READYMELDUNG
  24. 380 FORI=1TOFZ:REM MOEGLICHKEIT DER AENDERUNG
  25. 390 PRINT""T$(I)CHR$(13)"[145]";:INPUTT$(I)
  26. 400 IFLEN(T$(I))<2THEN390
  27. 410 NEXTI
  28. 420 INPUT"ALLES RICHTIG J/N";AR$:IFAR$<>"J"THEN380
  29. 430 FORJ=1TOFZ-1:REM NEUE FM IN DEN SPEICHER SCHREIBEN
  30. 440 FORI=1TOLEN(T$(J))-1
  31. 450 POKESV+I-1,ASC(MID$(T$(J),I,1))
  32. 460 NEXTI
  33. 470 POKESV+I-1,ASC(MID$(T$(J),I,1))+128
  34. 480 A=SV:GOSUB690:POKEVA+1,AH%:POKEVA,AL%
  35. 490 VA=VA+2:SV=SV+I:NEXTJ
  36. 500 POKESV,13
  37. 510 FORJ=1TOLEN(T$(31)):POKESV+J,ASC(MID$(T$(31),J,1)):NEXT:REM READY
  38. 520 POKESV+J,13:A=SV:GOSUB690:POKE49220,AL%:POKE49222,AH%:POKESV+J+1,0
  39. 530 SYS 49152
  40. 540 INPUT"SPEICHERUNG J/N";S$:IFS$="N"THENEND
  41. 550 IFS$<>"J"THEN540
  42. 560 SA=49152:AE=SV+J+2
  43. 570 PRINT"GERAETENUMMER";
  44. 580 PRINT"   FLOPPY = Z.B.  8                        DATASETTE =    1";
  45. 590 INPUT DN
  46. 600 A$="@:FEHLER.OBJ":A%=LEN(A$)
  47. 610 A=681:GOSUB690:POKE183,A%:POKE187,AL%:POKE188,AH%
  48. 620 FORI=1TOA%:POKE680+I,ASC(MID$(A$,I)):NEXT:REM FILENAME
  49. 630 A=SA:GOSUB690:POKE251,AL%:POKE252,AH%:REM STARTADRESSE
  50. 640 A=AE:GOSUB690:POKE781,AL%:POKE782,AH%:REM ENDADRESSE
  51. 650 POKE186,DN:POKE780,251:SYS65496:REM SAVE:DN = DEVICENUMMER
  52. 660 PRINT"SPEICHERUNG ERFOLGTE UNTER "CHR$(34)"FEHLER.OBJ"CHR$(34)
  53. 670 PRINT"ABSOLUT LADEN UND MIT SYS 49152 STARTEN"
  54. 680 END
  55. 690 AH%=A/HI:AL%=A-AH%*HI
  56. 700 RETURN
  57. 710 DATA169,11,160,192,141,0,3,140,1,3,96,138
  58. 720 DATA16,3,76,67,192,10,170,189,79,192,133,34
  59. 730 DATA189,80,192,133,35,32,204,255,169,0,133,19
  60. 740 DATA32,215,170,32,69,171,160,0,177,34,72,41
  61. 750 DATA127,32,71,171,200,104,16,244,32,122,166,164
  62. 760 DATA58,200,240,3,32,194,189,169,187,160,194,76
  63. 770 DATA 120,164
  64. 780 DATA169,139,160,227,76,4,192
  65.