home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
92xx
/
9212a.d64
/
eci++_ascii
< prev
next >
Wrap
Text File
|
1995-03-30
|
4KB
|
135 lines
;***************************************
;* >>>>> THE PERFECT ECI-ROUTINE <<<<< *
;* >>>>> WRITTEN IN AUGUST '92 <<<<< *
;* >>>>> BY MR.PERFECT <<<<< *
;* *
;* BASED ON THE ECI-SPLITTER *
;* WRITTEN BY UWE MICHEL *
;***************************************
+LINES =$02 ;ANZAHL DER ECI-ZEILEN
;******** SOURCE (PROFESSIONAL-ASS!) ***
.SETPC $C000 ;STARTADRESSE
LDA #1 ;CHAR-COLOR
STA 646 ;WEISS
JSR $E544 ;CLEAR SCREEN
LDA #21 ;ECI UEBER 21
STA LINES ;RASTERZEILEN
LDX #0 ;SCHWARZEN
STX $D020 ;BORDER UND
STX $D021 ;SCREEN
LDA #$F5 ;BITMUSTER
+CLRL1 STA $4000,X ;FUER FLI-
STA $4100,X ;DARSTELLUNG
INX ;FESTLEGEN
BNE CLRL1 ;...
LDY #TABLEN ;$D018
LDA #$10 ;WERTETABELLE
+MAKETAB1 STA TAB-1,Y ;FUER
DEY ;'ZICK-ZACK'
CLC ;EFFEKT
ADC #$10 ;GENERIEREN
BVC MAKETAB1
LDA #$60
+MAKETAB2 STA TAB-1,Y
DEY
BEQ MAKECOL0
SEC
SBC #$10
BNE MAKETAB2
LDA #$20
BNE MAKETAB1
+MAKECOL0 LDX #39 ;COLOR-TABELLEN
+MAKECOL1 LDA COLORS+0,X ;ANLEGEN
STA $4400,X
LDA COLORS+1,X
STA $4800,X
LDA COLORS+2,X
STA $4C00,X
LDA COLORS+3,X
STA $5000,X
LDA COLORS+4,X
STA $5400,X
LDA COLORS+5,X
STA $5800,X
LDA COLORS+6,X
STA $5C00,X
DEX
BPL MAKECOL1
SEI ;INTERRUPT SPERREN
LDA #$C8 ;NORMALER 40-ZEICHEN
STA $D016 ;BILDSCHIRM
LDA #$7F ;IRQ-MASKE FUER
STA $DC0D ;CIA LOESCHEN
LDA #$01 ;NUR RASTERINTERRUPT
STA $D01A ;ZULASSEN
LDA #$32 ;UND ZWAR IN ZEILE
STA $D012 ;$32
LDX #<ECI ;IRQ-VEKTOR AUF
LDY #>ECI ;ECI-ROUTINE
STX $0314 ;VERBIEGEN
STY $0315 ;...
CLI ;INTERRUPT ZULASSEN
+ENDE RTS ;RETURN
;******** INTERRUPT-ROUTINEN ***********
+ECI INC $D019 ;IRQ LOESCHEN
DEC $DD00 ;VIC-BANK=$4000
CLC ;AKKU-STARTWERT
LDA #$33 ;FESTLEGEN
LDY LINES ;ANZAHL HOLEN
BEQ NOECI ;KEIN ECI ?
+MLOOP LDX TAB,Y ;FLI UEBER
STA $D011 ;Y RASTERZEILEN
STX $D018 ;LEGEN
ADC #1 ;NEUEN $D011-
AND #%00110111 ;WERT BERECHNEN
DEY ;SCHON FERTIG ?
BNE MLOOP ;NEIN, NOCHMAL
+NOECI LDA #$70 ;BILDSCHIRM
STA $D011 ;SCHWARZ
+WL1 LDA $D012 ;AUF NAECHSTE
AND #%00000111 ;BILDSCHIRM-
BNE WL1 ;ZEILE WARTEN
INC $DD00 ;VIC-BANK UND
LDX #$16 ;FARBRAM WIEDER
STX $D018 ;NORMALISIEREN
LDA #$19 ;SCREEN WIEDER
STA $D011 ;EINSCHALTEN
LDX #TABLEN ;ECI-TABELLE
+MOVETAB LDA TAB-1,X ;VERSCHIEBEN
STA TAB,X ;.
DEX ; .
BNE MOVETAB ; .
LDA TAB+TABLEN ; .
STA TAB ; .
JMP $EA31 ;UND TSCHUESS!
;******** TABELLEN *********************
+COLORS .B $17,$7F,$FC,$C8,$8B,$B9,$90
.B $06,$60,$09,$92,$28,$8A,$AF
.B $F7,$71,$17,$7F,$FA,$A8,$82
.B $29,$90,$09,$90,$09,$9B,$B8
.B $B8,$8C,$CF,$F7,$71,$17,$7F
.B $FC,$C8,$8B,$B9,$90,$06,$6B
.B $B4,$4E,$EF,$F7,$71,$0C,$00
+TAB .B $00 ;TABELLE WIRD GENERIERT
+TABLEN = 204 ;FUER MAX. 204 ZEILEN
.ENDSOURCE