home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
92xx
/
9209.d64
/
t-puffer
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
756b
|
25 lines
10 PRINT"[147]":REM ORDNUNG INS BILD
20 IFPEEK(2)=1THEN220:REM FUER DEN 2. DURCHGANG
30 POKE2,1
40 PRINT"[147]"
50 GOTO80: DIE EINGEGEBENE ZEILE WIRD UEBERSPRUNGEN
60 X=12+34*1234-SQR(89)+12*12
70 RETURN
80 GETA$:REM EIN ZEICHEN EINGEBEN
90 PRINTA$;
100 IFA$<>CHR$(13)THEN80:REM ENDE, WENN RETURN GEDRUECKT WIRD
110 PRINT"[145][145][145][145]";:REM CURSOR NEU POSITIONEIEREN
120 POKE631,ASC("[148]"):REM ZWEI STELLEN FUER
130 POKE632,ASC("[148]"):REM ZEILENNUMMER EINFUEGEN
140 POKE633,ASC("1"):REM ERSTE ZIFFER DER ZEILENNUMMER
150 POKE634,ASC("5"):REM ZWEITE ZIFFER DER ZEILENNUMMER
160 POKE635,13:REM ENDE DER ZEILE
170 POKE636,ASC("R"):REM EINGABE VON
180 POKE637,ASC("[213]"):REM RUN SIMULIEREN
190 POKE638,13:REM ENDE DER EINGABE
200 POKE198,8:REM ACHT ZEICHEN IM PUFFER
210 STOP:REM IN DIREKTMODUS SCHALTEN
220 POKE2,0:REM FLAG WIEDER LOESCHEN
230 GOSUB60:REM EINGEGEBENE ZEILE AUSFUEHREN
240 PRINTX