home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 92xx / 9204a.d64 / sideborder.seq < prev    next >
Text File  |  1995-03-30  |  3KB  |  100 lines
  1.          *= $1000      ;STARTADR BEI
  2.                        ;VISASS \BA $1000
  3. ;***************************************
  4. ;* SIDEBORDER SPRITES (W) BY PIT IN 92 *
  5. ;***************************************
  6.  
  7.          SEI           ;IRQ SPERREN
  8.          JSR SPRITES   ;SPRITES SETZEN
  9.          LDA #$F9      ;RASTER-IRQ BEI
  10.          STA $D012     ;$F9
  11.          LDA #$01      ;NUR RASTER-IRQ
  12.          STA $D01A     ;ZULASSEN
  13.          LDA #$7D      ;TIMER
  14.          STA $DC0D     ;SETZEN
  15.          LDA #<START   ;IRQ-VEKTOREN
  16.          STA $0314     ;AUF "START"
  17.          LDA #>START   ;VERBIEGEN
  18.          STA $0315     ;
  19.          CLI           ;IRQ FREIGEBEN
  20.          RTS           ;AB INS BASIC
  21. ;---------------------------------------
  22. START    LDA #%00010011;UP/DOWN-BORDER
  23.          STA $D011     ;AUSSCHALTEN
  24.          LDA $D021     ;FARBEN
  25.          STA $D020     ;SETZEN
  26.          NOP           ;8 ZYKLEN
  27.          NOP           ;WARTEN
  28.          NOP           ;
  29.          NOP           ;
  30.          LDX #$31      ;
  31.          LDY #$08      ;----------------
  32. RZYAUS   DEY           ;
  33.          BNE RZYAUS    ; RASTER
  34. CONTI    NOP           ;    ZYKLEN
  35.          NOP           ;       AUSGLEICH
  36.          NOP           ;
  37.          DEC $D016     ;SCROLL-REG
  38.          INC $D016     ;SCHALTEN
  39.          NOP           ;
  40.          NOP           ; RASTER
  41.          NOP           ;    ZYKLEN
  42.          NOP           ;       AUSGLEICH
  43.          NOP           ;
  44.          NOP           ;
  45.          NOP           ; RASTER
  46.          NOP           ;    ZYKLEN
  47.          NOP           ;       AUSGLEICH
  48.          NOP           ;
  49.          BIT $00       ;----------------
  50.          DEX           ;
  51.          BNE CONTI     ;
  52.  
  53.          LDA #$00      ;RASTER-IRQ
  54.          STA $D012     ;AUF ZEILE $00
  55.          LDA #<READY   ;UND IRQ
  56.          STA $0314     ;AUF NAECHSTE
  57.          LDY #>READY   ;ROUTINE
  58.          STY $0315     ;
  59.  
  60.          LDA $D019     ;IRR(IRQ REQ REG)
  61.          STA $D019     ;LOESCHEN
  62.          JMP $EA31     ;UND ALTER IRQ
  63. ;---------------------------------------
  64. READY    LDA #$1B      ;UP/DOWN-BORDERS
  65.          STA $D011     ;ANSCHALTEN
  66.  
  67.          LDA #$F9      ;UND RASTER-IRQ
  68.          STA $D012     ;WIEDER AUF $F9
  69.  
  70.          LDA #<START   ;IRQ WIEDER
  71.          STA $0314     ;AUF DIE ALTE
  72.          LDY #>START   ;ROUTINE
  73.          STY $0315     ;VERBIEGEN
  74.          LDA $D019     ;IRR
  75.          STA $D019     ;LOESCHEN
  76.          JMP $EA31     ;UND ALTER IRQ
  77. ;---------------------------------------
  78. SPRITES  LDX #$00      ;ZAEHLER AUF $00
  79. SPR1     LDA SPRDATES,X;SPR-POSITIONEN
  80.          STA $D000,X   ;HOLEN UND IN
  81.          STA $D027,X   ;POS+FARB-REG
  82.          INX           ;SCHREIBEN
  83.          CPX #$11      ;(MSB-BYTE $D010)
  84.          BNE SPR1      ;
  85.          LDA #$00      ;SPRITEBLOCKPOINT
  86.          STA $07F8     ;AUF $00 (ZEROP)
  87.          STA $D021     ;
  88.          LDA #$FF      ;ALLE SPRITES
  89.          STA $D015     ;ANSCHALTEN
  90.          RTS           ;UND ZURUECK
  91.  
  92. ;------POSITIONS TABELLE----------------
  93. SPRDATES .BYTE $01,$FA,$21,$FA;POS 0-7
  94.          .BYTE $81,$FA,$A1,$FA
  95.          .BYTE $C1,$FA,$E1,$FA
  96.          .BYTE $41,$FA,$61,$FA
  97.          .BYTE %11000000  ;MSB
  98. ;---------------------------------------
  99.  
  100.