home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
92xx
/
9204a.d64
/
sideborder.seq
< prev
next >
Wrap
Text File
|
1995-03-30
|
3KB
|
100 lines
*= $1000 ;STARTADR BEI
;VISASS \BA $1000
;***************************************
;* SIDEBORDER SPRITES (W) BY PIT IN 92 *
;***************************************
SEI ;IRQ SPERREN
JSR SPRITES ;SPRITES SETZEN
LDA #$F9 ;RASTER-IRQ BEI
STA $D012 ;$F9
LDA #$01 ;NUR RASTER-IRQ
STA $D01A ;ZULASSEN
LDA #$7D ;TIMER
STA $DC0D ;SETZEN
LDA #<START ;IRQ-VEKTOREN
STA $0314 ;AUF "START"
LDA #>START ;VERBIEGEN
STA $0315 ;
CLI ;IRQ FREIGEBEN
RTS ;AB INS BASIC
;---------------------------------------
START LDA #%00010011;UP/DOWN-BORDER
STA $D011 ;AUSSCHALTEN
LDA $D021 ;FARBEN
STA $D020 ;SETZEN
NOP ;8 ZYKLEN
NOP ;WARTEN
NOP ;
NOP ;
LDX #$31 ;
LDY #$08 ;----------------
RZYAUS DEY ;
BNE RZYAUS ; RASTER
CONTI NOP ; ZYKLEN
NOP ; AUSGLEICH
NOP ;
DEC $D016 ;SCROLL-REG
INC $D016 ;SCHALTEN
NOP ;
NOP ; RASTER
NOP ; ZYKLEN
NOP ; AUSGLEICH
NOP ;
NOP ;
NOP ; RASTER
NOP ; ZYKLEN
NOP ; AUSGLEICH
NOP ;
BIT $00 ;----------------
DEX ;
BNE CONTI ;
LDA #$00 ;RASTER-IRQ
STA $D012 ;AUF ZEILE $00
LDA #<READY ;UND IRQ
STA $0314 ;AUF NAECHSTE
LDY #>READY ;ROUTINE
STY $0315 ;
LDA $D019 ;IRR(IRQ REQ REG)
STA $D019 ;LOESCHEN
JMP $EA31 ;UND ALTER IRQ
;---------------------------------------
READY LDA #$1B ;UP/DOWN-BORDERS
STA $D011 ;ANSCHALTEN
LDA #$F9 ;UND RASTER-IRQ
STA $D012 ;WIEDER AUF $F9
LDA #<START ;IRQ WIEDER
STA $0314 ;AUF DIE ALTE
LDY #>START ;ROUTINE
STY $0315 ;VERBIEGEN
LDA $D019 ;IRR
STA $D019 ;LOESCHEN
JMP $EA31 ;UND ALTER IRQ
;---------------------------------------
SPRITES LDX #$00 ;ZAEHLER AUF $00
SPR1 LDA SPRDATES,X;SPR-POSITIONEN
STA $D000,X ;HOLEN UND IN
STA $D027,X ;POS+FARB-REG
INX ;SCHREIBEN
CPX #$11 ;(MSB-BYTE $D010)
BNE SPR1 ;
LDA #$00 ;SPRITEBLOCKPOINT
STA $07F8 ;AUF $00 (ZEROP)
STA $D021 ;
LDA #$FF ;ALLE SPRITES
STA $D015 ;ANSCHALTEN
RTS ;UND ZURUECK
;------POSITIONS TABELLE----------------
SPRDATES .BYTE $01,$FA,$21,$FA;POS 0-7
.BYTE $81,$FA,$A1,$FA
.BYTE $C1,$FA,$E1,$FA
.BYTE $41,$FA,$61,$FA
.BYTE %11000000 ;MSB
;---------------------------------------