home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
91xx
/
9109a.d64
/
hires-druck
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
957b
|
25 lines
100 REM ********************************
110 REM * *
120 REM * HIRESBILDAUSGABE AUF DRUCKER *
130 REM * *
140 REM ********************************
150 INPUT"BASIS (X*8192) ";BASIS:REM EINGABE DER BASIS
160 OPEN 1,4,4:REM EROEFFNEN DES DRUCKERS MIT LINEARKANAL =>SEKUNDAERADRESSE 4
170 PRINT#1,CHR$(27);"3";CHR$(24);:REM ZEILENVORSCHUB AUF 24/216
180 DIM BYTE(7)
185 FOR J=0 TO24:REM ZEILEN 1-25
186 PRINT#1,CHR$(27);"K";CHR$(64);CHR$(1);:REM SENDEN DES CODES FUER HIRES EIN
187 FOR K=0 TO 39:REM BLOECKE 1-39
190 FOR I=0 TO 7:REM AKTUELLER BLOCK UMRECHNEN
200 BYTE(I)=PEEK(BASIS+J*320+K*8+I)
210 NEXT I
220 FOR I=0 TO 7:REM 7 BYTES VERTIKAL
230 OUTPUT=0:FOR I0=0 TO 7
240 OUTPUT=OUTPUT-((BYTE(I0)AND 2^(7-I))>0)*2^(7-I0):NEXT I0
250 PRINT#1,CHR$(OUTPUT);:NEXT I:REM BLOCK AUSGEBEN, ENDE BLOCKUMRECHNUNG
260 NEXT K:REM ENDE BLOECKE EINER REIHE
270 PRINT#1,CHR$(10):REM ZEILENVORSCHUB
280 NEXT J:REM ENDE SCHLEIFE EINER REIHE
290 PRINT#1,CHR$(27)"2":REM ZEILENVORSCHUB WIEDER AUF 1/6 BRINGEN
300 CLOSE 1:REM SCHLIESSEN DRUCKERKANAL