home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
90xx
/
9010b.d64
/
array-clr
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
44 lines
1 REM *******************************
2 REM ********** ARRAY-CLR **********
3 REM *******************************
4 REM
5 REM LOESCHT EINZELNE(!) ARRAYS
6 REM
7 REM GESCHRIEBEN VON MICHAEL WANNKE
8 REM 9.JULI 1990
9 REM - VORFUEHRPROGRAMM -
10 PRINT"[147]"TAB(9)"ARRAY-CLR"
20 PRINTTAB(8)"[163][163][163][163][163][163][163][163][163][163][163]"
30 PRINT:PRINT
40 REM ******************************
50 DIM A$(10000) :NA$="A$"
60 REM ^^ ^^ HIER WIRD DER NAME DER EIGENEN VARIABLEN EINGESETZT
70 REM *******************************
75 F=FRE(0):IF F<0 THEN F=F+65536
80 PRINT"FREIER SPEICHER VOR AUFRUF VON ARRAYCLR:";F
90 TI$="000000":GOSUB 10000:T=INT(TI/.6+.5)/100
95 F=FRE(0):IF F<0 THEN F=F+65536
100 PRINT"... UND NACH "T" SEK. SIND"F"[146] BYTES FREI!"
110 END
140 :
9998 REM ES FOLGT 'ARRAY-CLR'
9999 :
10000 B1=ASC(NA$+CHR$(0))
10010 B2=ASC(MID$(NA$,2,1)+CHR$(0))
10020 B3=ASC(RIGHT$(NA$,1)+CHR$(0))
10030 IF B3>37 THEN B3=0
10040 IF B1<65 THEN RETURN
10045 IF B2=B3 THEN B2=0
10050 IF B3=37 THEN B1=B1+128:B2=B2+128:REM **** INTEGER ****
10060 IF B3=36 THEN B2=B2+128:REM **** STRING ****
10065 REM ***** DURCHSUCHEN DES BASICSPEICHERS
10070 I=0:XY=0:FOR I=PEEK(47)+256*PEEK(48) TO PEEK(49)+256*PEEK(50)
10080 IF B1=PEEK(I) AND B2=PEEK(I+1) GOTO 10110 :REM ARRAY IST GEFUNDEN!
10090 XY=I:I=I+PEEK(I+2)+256*PEEK(I+3)-1:IF XY<I THENNEXT
10100 RETURN :REM NICHT GEFUNDEN
10105 :
10110 B1=I:B2=PEEK(B1+2)+256*PEEK(B1+3)
10120 FORI=B1+B2 TO PEEK(49)+256*PEEK(50):POKEI-B2,PEEK(I):NEXT
10130 B1=I-B2-1:POKE50,B1/256:POKE49,B1-PEEK(50)*256
10140 RETURN