home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
90xx
/
9008a.d64
/
schneeflocke
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
753b
|
22 lines
100 REM SCHNEEFLOCKENKURVE
110 IF FLAG=0 THEN FLAG=1:LOAD "GRAPHTOOL.OBJ",8,1
120 INPUT "WIE OFT ZERTEILEN : ";TM
130 SYS49152:SYS49158,1,0:REM GRAPHIK INITIALISIEREN
140 X1=0:Y1=100:REM ANFANGSPUNKT
150 L=300:GR=0:REM LAENGE UND AUSRICHTUNG DER STRECKE
160 GOSUB 190:REM REKURSION BEGINNEN
170 GETA$:IFA$=""THEN170
180 SYS49155:GOTO120
190 L(I)=L:GR(I)=GR:TM(I)=TM:I=I+1:REM WERTE RETTEN
200 TM=TM-1: IF TM < 0 THEN 260:REM VERZWEIGE, BEI MAXIMALER REKURSIONTIEFE
210 L=L/3:GOSUB 190
220 GR=GR+60:GOSUB 190:REM AUSRICHTUNG UM 60 GRAD VERAENDERN UND ZEICHNEN
230 GR=GR-120:GOSUB 190
240 GR=GR+60:GOSUB 190
250 GOTO290
260 X0=X1:Y0=Y1:BO=GR*2*(null)/360
270 X1=X0+COS(BO)*L:Y1=Y0-SIN(BO)*L:REM NEUE KOORDINATEN BERECHNEN
280 SYS49173,X0,Y0,X1,Y1:REM UND ZEICHNEN
290 I=I-1:L=L(I):GR=GR(I):TM=TM(I):REM ALTE WERTE WIEDERHERSTELLEN
300 RETURN