home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
90xx
/
9006a.d64
/
renumber
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
788b
|
21 lines
1 INPUT"NAME";NA$:INPUT"WEITE";ZA:INPUT"ANFANG";ZE:INPUT"VON";VO:INPUT"BIS";BI
2 DIMZN(1500):Y=ZE:FORZ=1TO2:IFZ=2THENOPEN2,8,2,"@:R."+NA$+",P,W":PRINT#2,D$;
3 S=65536:BI=BI-(BI=0)*(S+BI):OPEN1,8,4,NA$+",P,R":GOSUB19:D$=CHR$(Z1)+CHR$(A)
4 GOSUB19:N=N+1:IFN>1THENONZGOSUB18,20:IFZN=0THENCLOSE1:NEXTZ:CLOSE2:END
5 GOSUB19:P=(ZN<VO)+(ZN>BI):ONZGOSUB6,8:GOTO4
6 GOSUB16:IFA>0THEN6
7 ZN(ZZ)=ABS(ZE+P*(ZE+ZN))+ZN*S:ZZ=ZZ+1:ZE=ZE+(P+1)*ZA:RETURN
8 Q=Y+P*(Y-ZN):PRINT#2,CHR$(Q-INT(Q/256)*256);CHR$(INT(Q/256));:Y=Y+(P+1)*ZA
9 GOSUB17:PRINT#2,A$;:IFA=137ORA=138ORA=141ORA=155ORA=167THEN11
10 ON-(A=0)+1GOTO9,18
11 GOSUB17:IFA>47ANDA<58THENB$=B$+A$:GOTO11
12 IFB$=""THENPRINT#2,A$;:GOTO9
13 ZU=-(A=44)-(A=171)-(A=0)*2+1
14 FORC=0TOZZ-1:IFVAL(B$)<>INT(ZN(C)/S)THENNEXTC:PRINTZN:CLOSE1:CLOSE2:END
15 B$="":PRINT#2,MID$(STR$(ZN(C)-INT(ZN(C)/S)*S),2);A$;:ONZUGOTO9,11,18
16 GET#1,A$:A=ASC(A$+CHR$(0)):A$=CHR$(A):RETURN
17 GOSUB16:IFA=32THENPRINT#2,A$;:GOTO17
18 RETURN
19 GOSUB16:Z1=A:GOSUB16:ZN=Z1+256*A:RETURN
20 PRINT#2,CHR$(Z1);CHR$(A);:RETURN