home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
89xx
/
8911a.d64
/
source.16kvdcram
< prev
next >
Wrap
Text File
|
1995-03-30
|
2KB
|
76 lines
ORG 53100
;----------------------------------------------
;16K VDC RAM - TOOL BY KLAUS HEGEMANN 1989
;----------------------------------------------
:ZERO = 251
JSR $AEFD ;VDC ANFG.
JSR $A96B
LDA $14
LDX $15
STA LOW+1
STX HIGH+1
JSR ZEROSET
JSR $AEFD ;ANFG.
JSR $A96B
LDA $14
LDX $15
STA ZERO
STX ZERO+1
JSR $AEFD ;ENDE
JSR $B7EB
CPX #0
BNE WRITE
:READ JSR VDCGET
LDY #0
STA (ZERO),Y
JSR ERHOEHERER
JMP READ
:WRITE LDY #0
LDA (ZERO),Y
LDY #31
JSR VDCPUT
JSR ERHOEHERER
JMP WRITE
:ERHOEHERER LDA ZERO
CLC
ADC #1
STA ZERO
BCC NOPLUS
INC ZERO+1
:NOPLUS LDA ZERO
CMP $14
BNE LOAD
LDA ZERO+1
CMP $15
BNE LOAD
PLA
PLA
:LOAD RTS
:VDCGET LDY #31
STY $D600
:GWAIT BIT $D600
BPL GWAIT
LDA $D601
RTS
:ZEROSET LDA #80
LDY #1
JSR VDCPUT
LDA #47
LDY #28
JSR VDCPUT
:HIGH LDA #0
LDY #18
JSR VDCPUT
:LOW LDA #0
INY
:VDCPUT STY $D600
:PWAIT BIT $D600
BPL PWAIT
STA $D601
RTS