home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 89xx / 8902c.d64 / auto-input (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  901b  |  43 lines
  1. 100 REM * AUTO-INPUT * 11/88
  2. 110 :
  3. 120 REM ---------------------------
  4. 130 REM  SIMULIERTES HAUPTPROGRAMM
  5. 140 REM ---------------------------
  6. 150 :
  7. 160 PRINT "[147]NAME    : ";
  8. 170 TM=1 : VO$="MATTHIAS ULLMANN"
  9. 180 GOSUB 1000
  10. 190 :
  11. 200 PRINT "STRASSE : ";
  12. 210 TM=3 : VO$="HELMHOLTZSTR. 53"
  13. 220 GOSUB 1000
  14. 230 :
  15. 240 PRINT "PLZ/ORT : ";
  16. 250 TM=5 : VO$="6200 WIESBADEN 1"
  17. 260 GOSUB 1000
  18. 270 :
  19. 280 PRINT "TELEFON : ";
  20. 290 TM=3 : VO$="" : REM KEINE VORGABE
  21. 300 GOSUB 1000
  22. 310 :
  23. 320 PRINT "CODENR. : ";
  24. 330 TM=1 : VO$="640815" : REM ZAHL
  25. 340 GOSUB 1000 : NA=VAL(NA$)
  26. 350 :
  27. 360 END
  28. 370 :
  29. 380 :
  30. 390 REM ---------------
  31. 400 REM  UNTERPROGRAMM
  32. 410 REM ---------------
  33. 420 :
  34. 1000 NA$=""
  35. 1010 PRINT" [146]"; : TI$="000000"
  36. 1020 GET A$ : IF A$="" THEN A$=CHR$(0) : IF TI/60<TM THEN 1020
  37. 1030 A=ASC(A$) : IF A=0 OR A=13 THEN 1070
  38. 1040 IF A=20 AND NA$<>"" THEN NA$=LEFT$(NA$,LEN(NA$)-1) : PRINT A$;
  39. 1050 IF A<32 OR A>90 THEN PRINT"[157]"; : GOTO 1010
  40. 1060 NA$=NA$+A$ : PRINT"[157]";A$; : GOTO 1010
  41. 1070 PRINT CHR$(20); : IF NA$="" THEN NA$=VO$ : PRINT NA$;
  42. 1080 PRINT : RETURN
  43.