home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 86xx / 8604.d64 / taktzyklen.src (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  79 lines
  1. 100 SYS9*4096
  2. 110 .OPT OO
  3. 120 ;
  4. 130 ;
  5. 140 ; TAKTZYKLEN EINES
  6. 150 ; MASCHINENPROGRAMMS MESSEN
  7. 160 ;
  8. 170 ;
  9. 180 ; VON  MARK RICHTERS
  10. 190 ;      ALLERSTR.4
  11. 200 ;      2806 OYTEN
  12. 210 ;      TEL. 04207/1870
  13. 220 ;
  14. 230 ;
  15. 240 *=$C000
  16. 250 ;
  17. 260 FAC      =$62   ;FLIESSKOMMA-AKKU
  18. 270 FRMNUM   =$AD8A ;AUSDRUCK HOLEN
  19. 280 CHKCOM   =$AEFD ;AUF KOMMA PRUEFEN
  20. 290 GETADR   =$B7F7 ;2-BYTE INTEGER
  21. 300 VICCTRL  =$D011 ;REG. FUER BS AUS
  22. 310 RASTER   =$D012 ;RASTER-ZEILE
  23. 320 TIMER    =$DD04 ;TIMER A LO-BYTE
  24. 330 CRA      =$DD0E ;TIMER A CONTROL
  25. 340 CRB      =$DD0F ;TIMER B CONTROL
  26. 350 ;---------------
  27. 360 JSR CHKCOM      ;STARTADRESSE DER
  28. 370 JSR FRMNUM      ;ZU MESSENDEN
  29. 380 JSR GETADR      ;ROUTINE HOLEN
  30. 390 STY JSUBR+1     ;UND ALS SPRUNG-
  31. 400 STA JSUBR+2     ;ADRESSE SPEICHERN
  32. 410 ;
  33. 420 SEI             ;IRQ SPERREN
  34. 430 LDA #%00001011  ;BILDSCHIRM AUS
  35. 440 STA VICCTRL
  36. 450 WAIT LDA RASTER ;WARTEN BIS BILD-
  37. 460 BNE WAIT        ;SCHIRM GANZ AUS
  38. 470 ;
  39. 480 LDX #3          ;BEIDE TIMER AUF
  40. 490 LDA #$FF        ;MAXIMALWERT
  41. 500 SETTIMER STA TIMER,X
  42. 510 DEX
  43. 520 BPL SETTIMER
  44. 530 ;
  45. 540 LDA #%00010001  ;TIMER KOPPELN,
  46. 550 LDX #%01010001  ;LADEN UND STARTEN
  47. 560 STX CRB
  48. 570 STA CRA
  49. 580 ;---------------
  50. 590 JSUBR JSR $FFFF ;SPRUNG AUF ROUTINE
  51. 600 ;---------------
  52. 610 LDY #0          ;BEIDE TIMER STOP
  53. 620 STY CRA
  54. 630 STY CRB
  55. 640 LDA #%00011011  ;BILDSCHIRM WIEDER
  56. 650 STA VICCTRL     ;AN
  57. 660 CLI             ;IRQ WIEDER FREI-
  58. 670 ;
  59. 680 SEC             ;4 TIMER-BYTES
  60. 690 LDA TIMER       ;UMRECHNEN
  61. 700 EOR #$FF        ;FUER AUFRUF BE-
  62. 710 SBC #11         ;NOETIGTE ZYKLEN
  63. 720 STA FAC+3       ;ABZIEHEN
  64. 730 LDX #3          ;UND DIE RESTLICHEN
  65. 740 ;
  66. 750 L1 LDA TIMER+1,Y;3 TIMER-WERTE
  67. 760 EOR #$FF        ;ANPASSEN
  68. 770 SBC #0
  69. 780 STA FAC-1,X
  70. 790 INY
  71. 800 DEX
  72. 810 BNE L1
  73. 820 ;
  74. 830 SEC
  75. 840 TXA             ;4 BYTE WERTEN
  76. 850 LDX #$A0        ;OHNE VORZEICHEN
  77. 860 JSR $BC4F       ;IN FLIESSKOMMAZAHL
  78. 870 JMP $BDD7       ;FAC AUSGEBEN/RTS
  79.