home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / GFX / Raytracing / Objects / TAI-HFX1.LHA / hfx / dbc / PUT.REXX < prev   
Encoding:
OS/2 REXX Batch file  |  1995-04-12  |  2.9 KB  |  115 lines
  1. /*
  2. ** DBC/PUT.REXX
  3. **
  4. ** $VER: DBC/PUT.REXX 1.0.0 (01.04.96)
  5. **
  6. ** This ARexx script is for use with Hollywood FX.  
  7. ** This script converts RGB images from LightWave
  8. ** to the Digital Broadcaster as a JStream.
  9. **
  10. ** This script requires ADPro v2.5.0 (or higher).
  11. **
  12. ** Copyright © 1995 Synergy International, Incorporated
  13. ** All Rights Reserved
  14. ** 
  15. ** The following copyright notice applies to the Locate-ADPro
  16. ** code included in this script:
  17. **
  18. ** Copyright © 1991-1993 ASDG, Incorporated
  19. ** All Rights Reserved
  20. */
  21.  
  22. OPTIONS RESULTS
  23.  
  24. /******************************************************/
  25. /* User Settings                                      */
  26. /******************************************************/
  27.  
  28. Appender = "Producer:Tools/AppendJPEG"
  29. RefJStream = "Video:jref.jst"
  30. Horz = 720                      
  31. Vert = 480                    /* Change to 576 for PAL */
  32.  
  33. /******************************************************/
  34. /* Start of Script                                    */
  35. /******************************************************/
  36.  
  37. PARSE ARG inname ',' outname
  38.  
  39. Quality = "QUALITY 16 TABLES " || RefJStream
  40.  
  41. tmp = RIGHT(outname, LENGTH(outname) - 5)       /* Remove DBC#: at front of name */
  42. tmp2 = LEFT(tmp, LENGTH(tmp) - 4)               /* Remove .jst at end of name */
  43. field0 = "T:" || tmp2 || ".jf0"                
  44. field1 = "T:" || tmp2 || ".jf1"
  45. field = "T:" || tmp2
  46.  
  47. /*** Check if ADPro is loaded, if not try to load ***/
  48.  
  49. CALL Locate_ADPro
  50.  
  51. /*** Could not load ADPro, exit script ***/
  52.  
  53. IF (RESULT = 0) THEN
  54.   EXIT 10
  55.  
  56. /******************************************************************************/
  57.  
  58. ADDRESS "ADPro"
  59.  
  60. /*** Load image to convert ***/
  61.  
  62. LOAD_TYPE "REPLACE"
  63. LOADER "UNIVERSAL" inname
  64.  
  65. /*** Scale it to proper size and de-interlace it***/
  66.  
  67. ABS_SCALE Horz Vert
  68. OPERATOR "DEINTERLACE"
  69.  
  70. SAVER "TEMP" "XXX" "RAW"
  71. OPERATOR "CROP_IMAGE" Horz (Vert / 2) 0 0
  72. SAVER "JPEG" field1 "RAW" /* Quality */
  73.  
  74. LOADER "TEMP" "XXX"
  75. OPERATOR "CROP_IMAGE" Horz (Vert / 2) 0 (Vert / 2)
  76. SAVER "JPEG" field0 "RAW" /* Quality */
  77.  
  78. ADDRESS COMMAND
  79. Appender outname field
  80. delete field0
  81. delete field1
  82.  
  83. EXIT (0)
  84.  
  85. /******************************************************************************/
  86.   
  87. /*** Locate_ADPro function provided by ASDG, Inc. ***/
  88.  
  89. Locate_ADPro:
  90.    Max_Seconds_To_Load = 60
  91.    Flag = 0
  92.    LibName = 'rexxsupport.library'
  93.  
  94.    IF (POS( LibName, SHOW( 'Libraries' ) ) = 0) THEN
  95.       ADDLIB( LibName, 0, -30, 0 )
  96.    IF (POS( LibName, SHOW( 'Libraries' ) ) = 0) THEN
  97.       RETURN 0
  98.  
  99.    IF (STATEF( 'ADPRO:' ) = "") THEN
  100.       RETURN 0
  101.  
  102.    TIME( 'R' )
  103.    DO WHILE (TIME( 'E' ) < Max_Seconds_To_Load) & (POS( 'ADPro', SHOW( 'Ports' ) ) = 0)
  104.       IF (Flag = 0) THEN DO
  105.          /* Set whatever command line arguments you want. */
  106.          ADDRESS COMMAND 'Run < NIL: > NIL: ADPRO:ADPro MINIMIZED'
  107.          Flag = 1
  108.       END
  109.       ADDRESS COMMAND 'Wait 1'
  110.    END
  111.    IF (POS( 'ADPro', SHOW( 'Ports' ) ) = 0) THEN
  112.       RETURN 0
  113.    ELSE
  114.       RETURN 1
  115.