home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / GFX / Misc / PWP522.DMS / in.adf / Rexx / ToADPro.pwx < prev    next >
Encoding:
Text File  |  1994-10-27  |  2.7 KB  |  138 lines
  1. /* $VER: ToADPro.pwx 1.1 (23.5.94)
  2. **
  3. ** Überträgt das aktuelle Foto an Art Department Professional,
  4. ** indem eine temporäre Bilddatei erzeugt wird, die zu laden
  5. ** ADPro angewiesen wird. Nachdem die Bilddatei geladen ist,
  6. ** wird sie wieder gelöscht. Hinweis: ADPro muß bereits
  7. ** geladen und aktiv sein, bevor dieses Programm benutzt
  8. ** werden kann.
  9. **
  10. ** Geschrieben von Olaf Barthel
  11. */
  12.  
  13. /* Hier wird der Name der temporären Bilddatei festgelegt.
  14.  * Die Datei unter "T:ADProTempFile" anzulegen, ist keine
  15.  * ideale Lösung, da die Speicherung in der Ram-Disk
  16.  * geschieht. Es wird empfohlen, die Datei auf einer Festplatte
  17.  * mit genügend freiem Speicherplatz anzulegen.
  18.  */
  19.  
  20. tempfile = "T:ADProTempFile"
  21.  
  22. /* Befehlsergebnisse zugänglich machen. */
  23.  
  24. options results
  25.  
  26. /* Fehler sollten abgefangen werden. */
  27.  
  28. options failat 100
  29.  
  30. /* Ist ADPro verfügbar? */
  31.  
  32. if ~show(ports,"ADPro") then do
  33.     requestnotify "ADPro ist nicht aktiv!"
  34.     exit
  35. end
  36.  
  37. /* Der Name des gerade aktiven Projektes wird abgefragt.
  38.  * Hinweis: der SELECT-Befehl muß in Anführungszeichen
  39.  * stehen, da er sonst als ARexx-interner Befehl
  40.  * interpretiert wird.
  41.  */
  42.  
  43. 'select'
  44.  
  45. if rc > 0 then do
  46.  
  47.     if rc = 5 then do
  48.  
  49.         /* Es ist kein Projekt aktiv. */
  50.  
  51.         requestnotify "Es ist kein Projekt aktiv"
  52.     end; else do
  53.  
  54.         /* Fehlernummer auslesen. */
  55.  
  56.         fault photoworx.lasterror
  57.  
  58.         /* Fehlermeldung ausgeben. */
  59.  
  60.         requestnotify result
  61.     end
  62.  
  63.     exit 0
  64. end
  65.  
  66. currentproject = result
  67.  
  68. /* Das aktuelle Projekt wird als IFF-ILBM Datei
  69.  * abgespeichert.
  70.  */
  71.  
  72. saveas project currentproject name tempfile format ilbmtruecolour force
  73.  
  74. /* Soweit alles in Ordnung? */
  75.  
  76. if rc > 0 then do
  77.     /* Fehlernummer auslesen. */
  78.  
  79.     fault photoworx.lasterror
  80.  
  81.     /* Fehlermeldung ausgeben. */
  82.  
  83.     requestnotify result
  84.  
  85.     exit 0
  86. end
  87.  
  88. /* Ab jetzt wird ADPro angesprochen. */
  89.  
  90. address "ADPro"
  91.  
  92. /* Als Lademodul wird "IFF" ausgewählt. */
  93.  
  94. lformat "iff"
  95.  
  96. /* Das vorher aktive Lademodul wird vermerkt. */
  97.  
  98. oldlformat = adpro_result
  99.  
  100. /* Die Bilddatei wird geladen. */
  101.  
  102. load tempfile
  103.  
  104. /* Wurde das Bild korrekt geladen? */
  105.  
  106. if rc = 0 then do
  107.  
  108.     /* Die Temporäre Datei wird wieder gelöscht. */
  109.  
  110.     address command "delete " || tempfile || " " || tempfile || ".info"
  111.  
  112.     /* Das vorher aktive Lademodul wird wiederhergestellt. */
  113.  
  114.     lformat oldlformat
  115. end; else do
  116.  
  117.     /* Fehlernummer auslesen. */
  118.  
  119.     oldresult = result
  120.     oldrc = rc
  121.  
  122.     /* Das vorher aktive Lademodul wird wiederhergestellt. */
  123.  
  124.     lformat oldlformat
  125.  
  126.     /* PhotoworX Pro wird wieder angesprochen. */
  127.  
  128.     address
  129.  
  130.     /* Die Temporäre Datei wird wieder gelöscht. */
  131.  
  132.     address command "delete " || tempfile || " " || tempfile || ".info"
  133.  
  134.     /* Der Fehler wird gemeldet. */
  135.  
  136.     requestnotify "Der ADPro LOAD-Befehl meldete RC=" || oldrc || " und RESULT=" || oldresult
  137. end
  138.