Amiga ISO Collection/AmigaUtilCD1.iso/GFX/Misc/ASTUDIO1.LHA/ArtStudio/ArtStudio_Install

Text File | 1996-03-17 | 5.3 KB | 307 lines

; $VER: ArtStudio_Install 2.000 (17.03.96)
; Script to install ArtStudio Version 2.0

(complete 0)
(user 1)

(if (> (* 37 65536) (getversion "exec.library" (resident)))
        (abort #wrong-kick)
)

(welcome)
(set old_level @user-level)

(user 2)
(set target (askdir
        (prompt "Wählen Sie ein Verzeichnis, wo Sie ArtStudio "
                "installieren möchten. Ein Verzeichnis mit den "
                "Namen ArtStudio wird automatisch angelegt!"
                )
        (help #which-dir-help)
        (default "Work:")
))
(user old_level)

(set @default-dest target)

(set ArtStudioDir        (tackon target "ArtStudio"))

(set WAS
      (askoptions
      (prompt "Welche Programme sollen installier werden?\n\n"
              "Die komplette Installation benötigt ca. 3 MB "
              "freien Festplattenspeicher!")
      (help   @askchoice-help)
      (choices "ArtStudio Hauptprogramm"
          "ArtStudio Tools"
          "Beispiel Dateien"
          "Beispiel Bilder")
      (default 15)
      )
)

(set LoaderDir        (tackon ArtStudioDir "Loader"))
(set ViewerDir        (tackon ArtStudioDir "Viewer"))
(set SaverDir        (tackon ArtStudioDir "Saver"))
(set RexxDir        (tackon ArtStudioDir "Rexx"))
(set ColorDir        (tackon ArtStudioDir "Color"))
(set ToolsDir        (tackon ArtStudioDir "Tools"))

(If (IN WAS 0)
 (
  (if ( < (exists ArtStudioDir (noreq) ) 2)
    (makedir ArtStudioDir
        (prompt "Creating ArtStudio directory...")
        (help @makedir-help)
        (infos)
    )
  )

  (complete 10)

  (if ( < (exists LoaderDir (noreq) ) 2)
    (makedir LoaderDir
        (prompt "Creating Loader directory...")
;        (help @makedir-help)
    )
  )

  (complete 11)

  (if ( < (exists ViewerDir (noreq) ) 2)
    (makedir ViewerDir
        (prompt "Creating Viewer directory...")
;        (help @makedir-help)
    )
  )

  (complete 12)

  (if ( < (exists RexxDir (noreq) ) 2)
    (makedir RexxDir
        (prompt "Creating Rexx directory...")
;        (help @makedir-help)
    )
  )

  (complete 13)

  (if ( < (exists ColorDir (noreq) ) 2)
    (makedir ColorDir
        (prompt "Creating Color directory...")
;        (help @makedir-help)
    )
  )

  (complete 14)

  (if ( < (exists SaverDir (noreq) ) 2)
    (makedir SaverDir
        (prompt "Creating Saver directory...")
;        (help @makedir-help)
    )
  )

  (complete 15)

  (if ( < (exists ToolsDir (noreq) ) 2)
    (makedir ToolsDir
        (prompt "Creating Tools directory...")
;        (help @makedir-help)
    )
  )

  (complete 16)

  (copyfiles
    (prompt "Installing ArtStudio release 2.0 main program...")
    (help @copyfiles-help)
    (source "ArtStudio")
    (dest ArtStudioDir)
    (confirm)
  )

  (complete 30)

  (copyfiles
    (prompt "Installing ArtStudio Icon...")
    (help @copyfiles-help)
    (source "ArtStudio.info")
    (dest ArtStudioDir)
    (confirm)
  )

  (complete 35)

  (copyfiles
    (prompt "Installing loader...")
    (help @copyfiles-help)
    (source "Loader/")
    (dest LoaderDir)
    (all)
    (confirm)
  )

  (complete 40)

  (copyfiles
    (prompt "Installing saver...")
    (help @copyfiles-help)
    (source "Saver/")
    (dest SaverDir)
    (all)
    (confirm)
  )

  (complete 45)

  (copyfiles
    (prompt "Installing viewers...")
    (help @copyfiles-help)
    (source "Viewer/")
    (dest ViewerDir)
    (all)
    (confirm)
  )

  (complete 50)

  (copyfiles
    (prompt "Installing ARexx files...")
    (help @copyfiles-help)
    (source "Rexx/")
    (dest RexxDir)
    (all)
    (confirm)
  )

  (complete 55)

  (copyfiles
    (prompt "Installing color files...")
    (help @copyfiles-help)
    (source "Color/")
    (dest ColorDir)
    (all)
    (confirm)
  )

  (complete 60)

  (copyfiles
    (prompt "Installing Guide-File...")
    (help @copyfiles-help)
    (source "ArtStudio.guide")
    (dest ArtStudioDir)
    (infos)
    (confirm)
   )

  (tooltype
    (dest ("%s/ArtStudio.guide" ArtStudioDir))
    (setdefaulttool "MultiView")
    (setstack 10000)
    (noposition)
  )

  (complete 63)

  (startup "ArtStudio"
    (prompt ("\nAdding the ArtStudio assignment to s:user-startup - it currently looks like this:\n\n%s\n\n" (cat "assign ArtStudio: " ArtStudioDir) ) )
    (help @startup-help)
    (command (cat "assign ArtStudio: " ArtStudioDir))
  )

 )
)

  (complete 65)

(If (IN WAS 1)
 (

  (copyfiles
    (prompt "Installing Tools...")
    (help @copyfiles-help)
    (source "Tools/")
    (dest ToolsDir)
        (all)
        (infos)
    (confirm)
  )

 )
)

(If (IN WAS 2)
 (
  (set DataBaseDir (askdir
        (prompt "Wählen Sie ein Verzeichnis, wo Sie die "
                "Basedateien installieren möchten."
                )
        (help #which-dir-help)
        (default "Work:")
  ))

  (complete 75)

  (copyfiles
    (prompt "Installing DataBase...")
    (help @copyfiles-help)
    (source "BaseDatei/")
    (dest DataBaseDir)
    (all)
    (confirm)
  )
 )
)

(If (IN WAS 3)
 (
  (set ImageDir (askdir
        (prompt "Wählen Sie ein Verzeichnis, wo Sie die "
                "Bilder installieren möchten."
                )
        (help #which-dir-help)
        (default "Work:")
  ))

  (complete 80)

  (copyfiles
    (prompt "Installing Images...")
    (help @copyfiles-help)
    (source "Images/")
    (dest ImageDir)
    (all)
    (confirm)
  )

  (complete 85)

  (startup "ASDisk4"
    (prompt ("\nAdding the ArtStudioDisk4 assignment to s:user-startup - it currently looks like this:\n\n%s\n\n" (cat "assign ArtStudioDisk4: " ImageDir) ) )
    (help @startup-help)
    (command (cat "assign ArtStudioDisk4: " ImageDir))
  )
 )
)

(If (IN WAS 0)
 (

  (complete 90)

  (copylib
    (prompt "Checking and updating ASL.library, if needed...")
    (help @copylib-help)
    (source "libs/asl.library")
    (dest "libs:")
    (confirm)
  )

 )
)

(complete 100)