home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / TEXT / INFO / XFDISK.ZIP / RGBTEST.BAS < prev    next >
Encoding:
BASIC Source File  |  1991-08-29  |  3.7 KB  |  116 lines
  1. 100 ' RGBTEST.BAS
  2. 110 '
  3. 120 ' ╔═══════════════════════════════════════════════════════════════════════╗
  4. 130 ' ║    A program to test your monitor.  Display a RED, BLUE, GREEN, or    ║
  5. 140 ' ║    WHITE background and toggle between colors by pressing any key;    ║
  6. 150 ' ║    OR display horizontal or vertical RED, BLUE, GREEN and WHITE       ║
  7. 160 ' ║    color bars.  If run under GWBASIC, toggle the border color by      ║
  8. 170 ' ║    pressing any key.  Press the ESC key to exit to the menu from      ║
  9. 180 ' ║    any screen.                                                        ║
  10. 190 ' ║                                                                       ║
  11. 200 ' ║ Written by:  Dennis W. Person                  Date:  August 29, 1991 ║
  12. 210 ' ║              6828 Devonshire Drive                                    ║
  13. 220 ' ║              Canton, Michigan  48187-2613                             ║
  14. 230 ' ╚═══════════════════════════════════════════════════════════════════════╝
  15. 240 '
  16. 1000 KEY OFF
  17. 1010 COLOR 7,0,0:CLS
  18. 1020 PRINT "Choose one of the following tests:"
  19. 1030 PRINT
  20. 1040 PRINT "  [ 1 ] toggle red, green, blue, and white backgrounds"
  21. 1050 PRINT "  [ 2 ] horizontal stripes at ½ text lines"
  22. 1060 PRINT "  [ 3 ] horizontal stripes at 3 text lines"
  23. 1070 PRINT "  [ 4 ] vertical stripes at 1 character"
  24. 1080 PRINT "  [ 5 ] vertical stripes at 4 characters"
  25. 1090 PRINT
  26. 1100 PRINT "  [ Q ] quit"
  27. 1110 A$=INKEY$:IF A$="" GOTO 1110
  28. 1120 IF A$="Q" OR A$="q" GOTO 1190
  29. 1130 IF A$="1" THEN GOSUB 1220:GOTO 1010
  30. 1140 IF A$="2" THEN GOSUB 1340:GOTO 1010
  31. 1150 IF A$="3" THEN GOSUB 1530:GOTO 1010
  32. 1160 IF A$="4" THEN GOSUB 1710:GOTO 1010
  33. 1170 IF A$="5" THEN GOSUB 1860:GOTO 1010
  34. 1180 IF A$<>CHR$(27) GOTO 1110
  35. 1190 COLOR 7,0,0:CLS
  36. 1200 SYSTEM
  37. 1210 '
  38. 1220 COLOR 0,0,0:CLS
  39. 1230 FOR I%=1 TO 4
  40. 1240   IF I%=1 THEN COLOR ,4,4
  41. 1250   IF I%=2 THEN COLOR ,2,2
  42. 1260   IF I%=3 THEN COLOR ,1,1
  43. 1270   IF I%=4 THEN COLOR ,7,7
  44. 1280   CLS
  45. 1290   GOSUB 1670:IF A$="" GOTO 1320
  46. 1300 NEXT I%
  47. 1310 GOTO 1230
  48. 1320 RETURN
  49. 1330 '
  50. 1340 COLOR 0,0,0:CLS
  51. 1350 FOR I%=1 TO 22 STEP 3
  52. 1360   LOCATE I%  ,1:COLOR 2,4:PRINT STRING$(80,220);
  53. 1370   LOCATE I%+1,1:COLOR 4,1:PRINT STRING$(80,220);
  54. 1380   LOCATE I%+2,1:COLOR 1,2:PRINT STRING$(80,220);
  55. 1390 NEXT I%
  56. 1400 LOCATE I%,1:COLOR 2,4:PRINT STRING$(80,220);
  57. 1410 '
  58. 1420 FOR I%=1 TO 5
  59. 1430   GOSUB 1670:IF A$="" GOTO 1510
  60. 1440   IF I%=1 THEN COLOR ,,4
  61. 1450   IF I%=2 THEN COLOR ,,2
  62. 1460   IF I%=3 THEN COLOR ,,1
  63. 1470   IF I%=4 THEN COLOR ,,7
  64. 1480   IF I%=5 THEN COLOR ,,0
  65. 1490 NEXT I%
  66. 1500 GOTO 1420
  67. 1510 RETURN
  68. 1520 '
  69. 1530 COLOR 0,0,0:CLS
  70. 1540 FOR I%=1 TO 25 STEP 3
  71. 1550   IF I%=1  OR I%=16 THEN COLOR ,4
  72. 1560   IF I%=4  OR I%=19 THEN COLOR ,2
  73. 1570   IF I%=7  OR I%=22 THEN COLOR ,1
  74. 1580   IF I%=10 OR I%=25 THEN COLOR ,7
  75. 1590   IF I%=13 THEN COLOR ,0
  76. 1600   IF I%>15 THEN J%=I%-2 ELSE J%=I%
  77. 1610   LOCATE J%,1:PRINT STRING$(80,32);
  78. 1620   LOCATE J%+1,1:PRINT STRING$(80,32);
  79. 1630   LOCATE J%+2,1:PRINT STRING$(80,32);
  80. 1640 NEXT I%
  81. 1650 GOTO 1420
  82. 1660 '
  83. 1670 A$=INKEY$:IF A$="" GOTO 1670
  84. 1680 IF A$=CHR$(27) THEN A$=""
  85. 1690 RETURN
  86. 1700 '
  87. 1710 COLOR 0,0,0:CLS
  88. 1720 FOR I%=1 TO 25
  89. 1730   FOR J%=0 TO 19
  90. 1740     FOR K%=1 TO 4
  91. 1750       IF K%=1 THEN COLOR ,4
  92. 1760       IF K%=2 THEN COLOR ,2
  93. 1770       IF K%=3 THEN COLOR ,1
  94. 1780       IF K%=4 THEN COLOR ,7
  95. 1790       LOCATE I%,J%*4+K%
  96. 1800       PRINT " ";
  97. 1810     NEXT K%
  98. 1820   NEXT J%
  99. 1830 NEXT I%
  100. 1840 GOTO 1420
  101. 1850 '
  102. 1860 COLOR 0,0,0:CLS
  103. 1870 FOR I%=1 TO 25
  104. 1880   LOCATE I%,1
  105. 1890   FOR J%=1 TO 5
  106. 1900     FOR K%=1 TO 4
  107. 1910       IF K%=1 THEN COLOR ,4
  108. 1920       IF K%=2 THEN COLOR ,2
  109. 1930       IF K%=3 THEN COLOR ,1
  110. 1940       IF K%=4 THEN COLOR ,7
  111. 1950       PRINT "    ";
  112. 1960     NEXT K%
  113. 1970  NEXT J%
  114. 1980 NEXT I%
  115. 1990 GOTO 1420
  116.