home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / PROG / MISC / FPC355_5.ZIP / TCOM96.ZIP / TCOM / DEBUGGER / CDBG.SEQ next >
Encoding:
Text File  |  1991-04-09  |  14.4 KB  |  395 lines
  1. \\ CDBG96.SEQ       A debugger for 80c196                    by Mike Mayo
  2. Adapted from CODEBUG.SEQ, a CODE debugger for F-PC by Tom Zimmer
  3. ─────────────────────────────────────────────────────────────────────────────
  4. $Header:   F:/tcom/debugger/logs/cdbg.sev   1.6   23 Apr 1991 11:00:24   MikeM  $
  5. ─────────────────────────────────────────────────────────────────────────────
  6.  
  7. This file contains a simple debugger for Intel 80c196 to allow debugging
  8. a Forth program compiled by TCOM96.
  9.  
  10. It uses the COM port of a PC to communicate with the serial port
  11. of the 80c196.
  12. Code in the target supports several commands,
  13. e.g. fetch, store, call-subroutine.
  14. It also has code to handle breakpoint traps.
  15.  
  16. Limited operations are supported while in the debugger,
  17. read the screen while debugging and press F1 for some help.
  18.  
  19. ─────────────────────────────────────────────────────────────────────────────
  20. $Log:   F:/tcom/debugger/logs/cdbg.sev  $
  21. \ 
  22. \    Rev 1.6   23 Apr 1991 11:00:24   MikeM
  23. \ Improved
  24. ─────────────────────────────────────────────────────────────────────────────
  25. {
  26.  
  27. anew cdbgwords
  28.  
  29. target          \ set target byte fetch for disassembler
  30.  
  31. }
  32. ─────────────────────────────────────────────────────────────────────────────
  33.   Words to allow setting the debugging registers
  34. ─────────────────────────────────────────────────────────────────────────────
  35. {
  36.  
  37. : reg!          ( a1 | <name> -- )      \ defining word to make register
  38.                                         \ assignment words
  39.                 create , does> @ ! ;
  40.  
  41. : reg@          ( a1 | <name> -- )      \ defining word to make register
  42.                                         \ fetch words
  43.                 create , does> @ @ ;
  44.  
  45.  
  46. fload break96   \ target-specific breakpoint definitions
  47.  
  48. }
  49. ─────────────────────────────────────────────────────────────────────────────
  50.   Some handy debugging utilities
  51. ─────────────────────────────────────────────────────────────────────────────
  52. {
  53.  
  54. : dbeeol ( -- ) \ fill the screen with spaces to the end of the box
  55.         #out @ rboxcol
  56.         < if    rboxcol 1- sp>col
  57.         else    cols 1- sp>col
  58.         then
  59.         ;
  60.  
  61. : .dbheader ( -- ) \ draw outline of debugging screen
  62.         >norm
  63.         0 dbtop rboxcol 1- rows box&fill
  64.         at? 1+ dplace 2!
  65.         ." \1 Addr   Instruction                  Data  Code          "
  66.         rboxcol dbtop cols 1- rows box&fill
  67.         at? 2+ rplace 2!
  68.         at? 1- at
  69.         ." \3  80c196 State  \0"
  70.         ;
  71.  
  72. : .code ( a1 n1 -- ) \ show a string of code numbers that are in the target
  73.         0max bounds
  74.         ?do  i dt@ H.4  loop  ;
  75.  
  76. : Forth-command ( -- ) \ Provide for one forth command line
  77.         savescr
  78.         savecursor cursor-on
  79.         0 rows 3 - 2>r
  80.         2r@ at                  \ place it at the bottom of the debug window
  81.         rboxcol sp>col cr
  82.         rboxcol sp>col cr
  83.         rboxcol sp>col
  84.         2r> at
  85.         ." \1 Ready for a \`Forth\` command " cr
  86.         ."  ok" cr
  87.         query interpret         \ get and execute a Forth command line
  88.         cr ." \2 Press a key "
  89.         key drop
  90.         restcursor
  91.         restscr ;
  92.  
  93. }
  94. ─────────────────────────────────────────────────────────────────────────────
  95.   Display current instruction followed by data stack
  96. ─────────────────────────────────────────────────────────────────────────────
  97. {
  98.  
  99. 0 value ipprev \ used for holding the address of the prior instruction
  100.  
  101. : show-inst ( -- ) \ disassemble and show one instruction
  102.         save> base  hex
  103.         at?  dbeeol  at         \ blank the line
  104.         cp @ dup>r              \ get instruction address
  105.         space h.4 inst          \ disassemble instruction
  106.         44 #line @ at           \ jump to code column
  107.         r> cp @ over - 2 min .code      \ show code
  108.         restore> base
  109.         >norm  ;
  110.  
  111. : .inst ( -- ) \ display the next instruction to single-step
  112.         trapadr-@ cp !
  113.         next-break if >rev else >ATTRIB3 then
  114.         show-inst
  115.         cp @ !> nextinline
  116.         ;
  117.  
  118. : .ninst ( n -- ) \ display the nth instruction after the next to single-step
  119.         1+ next-break
  120.         = if    >attrib3
  121.                 cp @  !> nextinline    \ set up for "run to" option
  122.           then
  123.         show-inst  ;
  124.  
  125. : .pinst ( -- ) \ display the last executed instruction
  126.         ipprev 0=
  127.         if      dbeeol
  128.         else    ipprev cp !  show-inst
  129.         then
  130.         ;
  131. }
  132. ─────────────────────────────────────────────────────────────────────────────
  133.   Break point registers and control words.
  134.   Allow setting, removing, and displaying the current break point.
  135. ─────────────────────────────────────────────────────────────────────────────
  136. {
  137. #trapbytes 2+ value #breakbytes
  138. create breakregs    #breakbytes #breakregs * allot
  139.        breakregs    #breakbytes #breakregs * erase
  140. 0 value breakreg        \ breakpoint selector, 0 <= breakreg < #breakregs
  141.  
  142. : breakaddr ( -- a ) \ return pointer to the target address of
  143.                      \ the breakpoint selected by breakreg.
  144.         breakreg
  145.         0max #breakregs 1- min
  146.         #breakbytes *
  147.         breakregs + ;
  148.  
  149. : breaksave ( -- a ) \ return pointer to the target image of
  150.                      \ the breakpoint selected by breakreg.
  151.         breakaddr 2+ ;
  152.  
  153. : ?breakset ( n -- f ) \ return true flag f if breakpoint n is set.
  154.                        \ In addition it selects breakpoint n for
  155.                        \ subsequent use of breakaddr and breaksave
  156.         !> breakreg
  157.         breakaddr @ 0<> ;
  158.  
  159. : unbreak ( n -- ) \ remove break point n
  160.         ?breakset       \ if break register is set
  161.         if              \ restore words at break point
  162.                 breakaddr @  breaksave  tunbreak
  163.                 breakaddr off   \ make address = 0, to indicate
  164.                                 \ breakpoint no longer set
  165.         then  ;
  166.  
  167. : unbreak-all ( -- ) \ remove all break points
  168.         #breakregs 0 do  i unbreak  loop ;
  169.  
  170. : setbreak ( break-address n -- ) \ set breakpoint n
  171.         unbreak                 \ clear breakpoint
  172.         breakaddr !             \ save target-address of breakpoint
  173.         breaksave breakaddr @ tsetbreak   \ save instructions at breakpoint
  174.         ;                                 \ and set trap
  175.  
  176. : .breaks ( -- ) \ display the current break points
  177.         cr
  178.         0
  179.         #breakregs
  180.         0 do    breakaddr @
  181.                 ?dup if ." Break point " i .
  182.                         ." set at " h. ." h"
  183.                         1+ cr
  184.                      then
  185.                 loop
  186.         0= if ." No break point set"  then
  187.         ;
  188.  
  189. }
  190. ─────────────────────────────────────────────────────────────────────────────
  191.   Set a trap after the next instruction, return from the prior trap,
  192.   then receive the next trap
  193. ─────────────────────────────────────────────────────────────────────────────
  194. {
  195. 0 value waiting-at-break  \ flag to show the target is waiting in a breakpoint
  196.  
  197. : receive-trap ( -- )   \ wait till it hits the next breakpoint
  198.                         \ at which time it sends a 't' followed by the SP
  199.                         \ and we copy the machine image from its stack.
  200.  
  201.         begin   key? if  key $1b = if Forth-command then  then
  202.                 com-cnt 0<> if  getbyte 't' =
  203.                           else  false
  204.                           then
  205.                 until      \ wait for the trap call to happen
  206.  
  207.         getword                 \ get the trap stack address
  208.         read-break-stack        \ now read in all the stacked items
  209.         unbreak-all             \ restore memory at the break location(s)
  210.         on> waiting-at-break    \ flag the target is waiting in a breakpoint
  211.         ;
  212.  
  213. : gofromtrap ( -- ) \ Make the target return from a trap
  214.                     \ First put (modified) values back into target
  215.         restore-break-stack
  216.         untrap                  \ excute from previous breakpoint
  217.         off> waiting-at-break   \ flag the target is no longer waiting
  218.         ;
  219.  
  220. : exec>trap ( -- ) \ make the target return from a trap,
  221.                    \  and wait for the next trap.
  222.         gofromtrap              \ excute from previous breakpoint
  223.         receive-trap            \ wait till it hits the next breakpoint
  224.                                 \ and get all the data
  225.         ;
  226.  
  227. : one-step ( -- ) \ execute the next instruction
  228.         TRAPADR-@ !> ipprev     \ present instruction will be the previous
  229.         next-break
  230.         0= if
  231.                 branch-type
  232.                 case
  233.                         0 of    nextinline   0 setbreak   endof
  234.                         1 of    nextonbranch 0 setbreak   endof
  235.                         2 of    nextinline   0 setbreak
  236.                                 nextonbranch 1 setbreak   endof
  237.                         3 of    nextonbranch 0 setbreak   endof
  238.                 drop endcase
  239.            else
  240.                 nextinline 0 setbreak
  241.            then
  242.         off> next-break
  243.         exec>trap
  244.         ;
  245.  
  246. : one-step/skip ( -- ) \ execute to the next instruction in line
  247.                        \ i.e. do not nest into CALLs
  248.         TRAPADR-@ !> ipprev     \ present instruction will be the previous
  249.         next-break
  250.         0= if
  251.                 branch-type
  252.                 case
  253.                         0 of    nextinline   0 setbreak   endof
  254.                         1 of    nextonbranch 0 setbreak   endof
  255.                         2 of    nextinline   0 setbreak
  256.                                 nextonbranch 1 setbreak   endof
  257.                         3 of    nextinline   0 setbreak   endof
  258.                 drop endcase
  259.            else
  260.                 nextinline 0 setbreak
  261.            then
  262.         off> next-break
  263.         exec>trap
  264.         ;
  265.  
  266. }
  267. ─────────────────────────────────────────────────────────────────────────────
  268.   Show the current registers,
  269.   and a series of instructions as they will be executed.
  270. ─────────────────────────────────────────────────────────────────────────────
  271. {
  272. defer abrowse   \ to enter the browser with a specific address
  273. 0 value browse-addr
  274.  
  275. : show_debug    ( -- )
  276.         .regs
  277.         dplace 2@ at
  278.         .pinst dcr .inst dcr        \ show past and present instructions
  279.         at? 2>r
  280.         1 dbtop at
  281.         next-break
  282.                 if  ." \3 Press \4 Space \3  to run to highlighted instruction "
  283.               else
  284.                         branch-type 3
  285.                         = if
  286.                                 ." \4 Space \3 next in line \0────"
  287.                                 ." \4 Enter \3 enter subroutine "
  288.                         else
  289.                                 ." \3 Press \4 Space "
  290.                                 ." \3 to execute highlighted instruction "
  291.                         then
  292.               then
  293.         2r> at
  294.         rows  dbtop -  5 -
  295.         0 do   i .ninst dcr    loop
  296.         next-break
  297.                 if      nextinline !> browse-addr
  298.               else      trapadr-@  !> browse-addr
  299.               then
  300.         abrowse    \ show source listing
  301.         ;
  302.  
  303. : set_register  ( -- )
  304.         savescr
  305.         savecursor cursor-on
  306.         0 rows 1- 2dup at cols 1- sp>col at
  307.         ." \1 { In the form e.g. $23 =W0 } command: "
  308.         query interpret \ user may modify a register
  309.         restcursor
  310.         restscr
  311.         .regs           \ redisplay the registers
  312.         ;
  313.  
  314. : up_dbline ( -- ) \ move the breakpoint up one instruction
  315.         next-break 1- 0max !> next-break
  316.         next-break 1 = if off> next-break then      \ skip 1
  317.         show_debug
  318.         ;
  319.  
  320. : down_dbline ( -- ) \ move the breakpoint down one instruction
  321.         next-break 0= if incr> next-break then      \ skip 1
  322.         incr> next-break
  323.         show_debug
  324.         ;
  325. }
  326. ─────────────────────────────────────────────────────────────────────────────
  327.   Additional MINI help for the debugger.
  328. ─────────────────────────────────────────────────────────────────────────────
  329. {
  330. : debug_help     ( -- )
  331. \        savecursor cursor-off savescr
  332.         0 5 59 19 box&fill
  333.         bcr ."   Debugger commands:" bcr
  334.         bcr ."   \1 SPACE \0 = Go to highlighted instruction"
  335.         bcr ."   \1 F \0     = Forth command line"
  336.         bcr ."   \1 R \0     = Set a Register ( Forth command line )"
  337.         bcr ."   \1 Enter \0 = Nest into a CALL"
  338. \        bcr ."   \1 F2 \0    = Switch to full-screen browse"
  339.         bcr ."   \1 Esc \0   = Pull-down menus"
  340.         bcr
  341.         bcr ."   \1 Press ESC to continue, or SPACE for more help "
  342.         key $1B
  343.   <> if
  344.         0 5 59 19 box&fill
  345.         bcr ."   After \1 R \0 = Set a Register ( FORTH command line )"
  346.         bcr ."   Using \`<number> =W0\` will set W0 to <number>."
  347.         bcr ."   Examples of registers that can be set...."
  348.         bcr ."   =W0  =W2  =TTOS  =TTOS2  =flags"
  349.         bcr ."   Or use T! TC! tedit etc. to change target memory."
  350.         bcr bcr ." \S10\1 Press ANY key to continue " key drop
  351.      then
  352. \        restscr restcursor
  353.         ;
  354.  
  355.  
  356. : DB-endfunc  \ ( To be done when leaving the debugger )
  357.                 \ Maybe let the target run if it is waiting at a breakpoint
  358.         waiting-at-break
  359.         if      \ if the target is waiting in a breakpoint
  360.                 10 dbtop rows + 2/ 60 over 2+ box&fill
  361.                 ."   \2 Do you wish to let the TMS320 run? \3 (Y/N) "
  362.                 begin
  363.                         key upc
  364.                         case
  365.                                 'Y' of  true  true   endof
  366.                                 'N' of  false true   endof
  367.                                 beep drop false
  368.                                 endcase
  369.                         until
  370.                 if gofromtrap then      \ run from the breakpoint
  371.         then
  372.         ;
  373. }
  374. ─────────────────────────────────────────────────────────────────────────────
  375.   The main trace loop.
  376.   It single-steps through instructions
  377. ─────────────────────────────────────────────────────────────────────────────
  378. {
  379.  
  380. : dsteps ( -- ) \  This is the debugger.
  381.                 \  It is to be used after setting a breakpoint
  382.                 \  and causing it to be executed in the target.
  383.         dbtop !> browselines
  384.         0 ?breakset if
  385.                         0 dbtop rboxcol rows 1- box&fill
  386.                         ." \2 Waiting for target-trap "  bcr
  387.                         ." \1 Press \3 ESC \1 for options \0   "
  388.                         receive-trap
  389.                    then
  390.         .dbheader
  391.         show_debug
  392.         on> showingdebug
  393.         ;
  394.  
  395.