home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / MAGAZINE / PCMAG / VOL9N05.ZIP / ATOF.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-10-26  |  4.6 KB  |  142 lines
  1.         title   ATOF - ASCII to Binary Floating Point
  2.         page    55,132
  3.  
  4. ; ATOF.ASM ---  Convert ASCII String to Binary 
  5. ;               Floating Point Number on 80x87 Stack
  6. ;               (also requires FALOG from FALOG.ASM)
  7. ;
  8. ; Copyright (C) 1989 Ziff Davis Communications
  9. ; PC Magazine * Ray Duncan
  10. ; 
  11. ; Call with:    DS:SI = address of string in the form
  12. ;               [sign][digits][.[digits]][E|e[sign][exp]]
  13. ;               leading blanks or tabs are ignored
  14. ;
  15. ; Returns:      ST(0) = binary floating point value
  16. ;               DS:SI = address+1 of terminator 
  17. ;
  18. ; Uses:         Nothing
  19. ;
  20. ; This routine gives no warning in the event of 
  21. ; overflow, and terminates on the first invalid character.
  22. ;
  23. ; Make sure coprocessor has been properly initialized
  24. ; with a previous call to INIT87!
  25.  
  26. blank   equ     20h             ; ASCII blank character
  27. tab     equ     09h             ; ASCII tab character
  28.  
  29. _DATA   segment word public 'DATA'
  30.  
  31. int10   dw      10              ; integer constant 10
  32. digit   dw      0               ; current converted digit
  33. places  dw      0               ; number of decimal places
  34.  
  35. _DATA   ends
  36.  
  37. _TEXT   segment word public 'CODE'
  38.  
  39.         assume  cs:_TEXT,ds:_DATA
  40.  
  41.         extrn   falog:near      ; we need FALOG routine 
  42.  
  43.         public  atof
  44. atof    proc    near            ; ASCII to floating point
  45.  
  46.         push    ax              ; save registers
  47.         push    cx
  48.         push    dx
  49.  
  50.         call    convert         ; convert mantissa
  51.  
  52.         neg     dx              ; save -1 * decimal places
  53.         mov     places,dx
  54.  
  55.         or      al,20h          ; fold char to lower case
  56.         cmp     al,'e'          ; is exponent present?
  57.         je      atof1           ; yes, jump
  58.  
  59.         fldz                    ; assume zero exponent
  60.         jmp     atof2
  61.  
  62. atof1:  call    convert         ; convert exponent
  63.  
  64. atof2:  fiadd   places          ; adjust exponent for 
  65.                                 ; dec. places in mantissa
  66.  
  67.         call    falog           ; raise 10 to power
  68.         fmul                    ; exponent * mantissa
  69.  
  70.         pop     dx              ; restore registers
  71.         pop     cx
  72.         pop     ax
  73.         ret                     ; return ST(0) = result
  74.  
  75. atof    endp
  76.  
  77. ;
  78. ; CONVERT:      Called by ATOF to convert ASCII number
  79. ;               with possible sign and/or decimal point
  80. ; Call with:    DS:SI = address of string
  81. ; Returns:      ST(0) = result
  82. ;               AL    = first unconvertable character
  83. ;               DX    = number of digits after decimal point
  84. ;               DS:SI = address+1 of character in AL
  85. ; Uses:         AH, CX
  86. ;
  87. convert proc    near            ; convert numeric field
  88.  
  89.         fldz                    ; initialize result
  90.         xor     cx,cx           ; initialize sign
  91.         mov     dx,-1           ; initialize decimal count
  92.  
  93. conv1:  lodsb                   ; scan off whitespace
  94.         cmp     al,blank        ; ignore leading blanks
  95.         je      conv1
  96.         cmp     al,tab          ; ignore leading tabs
  97.         je      conv1
  98.  
  99.         cmp     al,'+'          ; if + sign proceed
  100.         je      conv2
  101.         cmp     al,'-'          ; is it - sign?
  102.         jne     conv3           ; no, test if numeric
  103.         dec     cx              ; yes, set flag
  104.  
  105. conv2:  lodsb                   ; get next character
  106.  
  107. conv3:  cmp     al,'0'          ; is character valid?
  108.         jb      conv4           ; jump if not '0' to '9'
  109.         cmp     al,'9'
  110.         ja      conv4           ; jump if not '0' to '9'
  111.  
  112.         and     ax,0fh          ; isolate lower four bits
  113.         mov     digit,ax        ; and save digit value
  114.         fimul   int10           ; previous value * 10
  115.         fiadd   digit           ; accumulate new digit
  116.  
  117.         or      dx,dx           ; past decimal point?
  118.         js      conv2           ; no, convert next digit
  119.         inc     dx              ; yes, count digits
  120.         jmp     conv2           ; convert next digit
  121.  
  122. conv4:  cmp     al,'.'          ; is it decimal point?
  123.         jne     conv5           ; no, proceed
  124.         inc     dx              ; indicate decimal found
  125.         jmp     conv2           ; convert more digits
  126.  
  127. conv5:  jcxz    conv6           ; jump if result pos.
  128.         fchs                    ; make result negative
  129.  
  130. conv6:  or      dx,dx           ; decimal point found?
  131.         jns     conv7           ; yes, jump
  132.         xor     dx,dx           ; no, return zero places
  133.         
  134. conv7:  ret                     ; return ST(0) = result
  135.  
  136. convert endp
  137.  
  138. _TEXT   ends
  139.  
  140.         end
  141.  
  142.