Star Trek Starfleet Academy Mini Omnipedia/MINI_OMNI.ISO/pc/omni_v2.dxr/00422_FileParent.ls

Text File | 1996-04-15 | 3.4 KB | 147 lines

property iFileDelimiter, iToolsPath, iLauncherPath, iAssetsPath, iIntroPath, iUserDictPath, iMainMenuPath, iLastTextFileRead, iCFTPath, iCTwoPath, iDumpData

on birth me
  global iam, mpciopath, gDevelopmentmode, gRunFromCD, gPrintObjectPath
  set mpciopath to the pathName & "fileio.dll"
  mDetectSys(me)
  if iam = #mpc then
    set iFileDelimiter to "\"
  else
    set iFileDelimiter to ":"
  end if
  set iLastTextFileRead to EMPTY
  set iDumpData to EMPTY
  return me
end

on mGetFileDelimiter me
  return iFileDelimiter
end

on mFileIsHere me, pFileWithPath
  global theProblem, iam, mpciopath
  if iam = #mpc then
    openXLib(mpciopath)
  end if
  set vTempObj to FileIO(mnew, "read", pFileWithPath)
  if objectp(vTempObj) then
    vTempObj(mdispose)
    if iam = #mpc then
      closeXLib(mpciopath)
    end if
    return 1
  else
    if iam = #mpc then
      closeXLib(mpciopath)
    end if
    return 0
  end if
end

on mDetectSys me
  global iam
  if the machineType < 256 then
    set iam to #mac
  else
    set iam to #mpc
  end if
  if (iam = #mac) and not (the quickTimePresent) then
    alert("Sorry, this product requires the presence of the Quicktime‚Ñ¢ system extension in your extensions folder.")
    quit()
  end if
end

on mGetLastTextFile me
  return iLastTextFileRead
end

on mGetFile me, pFileWithPath
  global iam, mpciopath
  if iam = #mpc then
    openXLib(mpciopath)
  end if
  set vTempFile to FileIO(mnew, "READ", pFileWithPath)
  set vNewText to EMPTY
  if objectp(vTempFile) then
    set vNewText to vTempFile(mReadFile)
    set iLastTextFileRead to vTempFile(mFileName)
    vTempFile(mdispose)
  end if
  if iam = #mpc then
    closeXLib(mpciopath)
  end if
  return vNewText
end

on mGetAnyFile me
  global iam, mpciopath
  if iam = #mpc then
    openXLib(mpciopath)
  end if
  set vTempFile to FileIO(mnew, "?READ", "TXT")
  set vNewText to EMPTY
  if objectp(vTempFile) then
    set vNewText to vTempFile(mReadFile)
    set iLastTextFileRead to vTempFile(mFileName)
    vTempFile(mdispose)
  end if
  if iam = #mpc then
    closeXLib(mpciopath)
  end if
  return vNewText
end

on mSaveFile me, pTextString, pfilename
  global iam, mpciopath
  if iam = #mpc then
    openXLib(mpciopath)
  end if
  set vTempFile to FileIO(mnew, "read", pfilename)
  if objectp(vTempFile) then
    vTempFile(mDelete)
  end if
  set vTempFile to FileIO(mnew, "write", pfilename)
  if objectp(vTempFile) then
    vTempFile(mWriteString, pTextString)
    set iLastTextFileRead to vTempFile(mFileName)
    vTempFile(mdispose)
  end if
  if iam = #mpc then
    closeXLib(mpciopath)
  end if
end

on mSaveAsFile me, pTextString, pSuggestedname
  global iam, mpciopath
  if iam = #mpc then
    openXLib(mpciopath)
  end if
  if voidp(pSuggestedname) or (pSuggestedname = EMPTY) then
    set pSuggestedname to "Untitled"
  end if
  set vTempFile to FileIO(mnew, "?write", pSuggestedname)
  if objectp(vTempFile) then
    vTempFile(mWriteString, pTextString)
    set iLastTextFileRead to vTempFile(mFileName)
    vTempFile(mdispose)
  end if
  if iam = #mpc then
    closeXLib(mpciopath)
  end if
end

on mGetFolderFiles me, pFolderwithpath
  set vFound to 1
  set vList to []
  set vIndex to 1
  repeat while vFound
    set vFileName to getNthFileNameInFolder(pFolderwithpath, vIndex)
    set vFound to vFileName <> EMPTY
    add(vList, vFileName)
    set vIndex to vIndex + 1
  end repeat
  set vIndex to vIndex - 1
  deleteAt(vList, vIndex)
  return vList
end