Shocking The Web CD-ROM/SHOCK_CD.ISO/pc/tutorial/devglry/maricopa/source/quizzer.dir/00002.ls

Text File | 1996-04-18 | 4.5 KB | 129 lines

on startMovie
  global gAnimDirection, gURL
  set gAnimDirection to 1
  puppetSprite(11, 1)
  set gURL to "http://www.mcli.dist.maricopa.edu/alan/nojava/quiz/"
end

on makeQuiz
  global gTotQuiz, gQuizList, gQuizOrder, gScore, gMissed, gPassingScore
  set gScore to 0
  set gMissed to []
  set gTotQuiz to numberOfQuestions()
  set gPassingScore to setPassingScore()
  set gQuizList to []
  repeat with i = 1 to gTotQuiz
    add(gQuizList, birth(script "quizMother", i))
  end repeat
  set gQuizOrder to birth(script "randmother", gTotQuiz)
end

on newQuiz
  global gTotQuiz, gQuizOrder, gFirstAnswer
  updateItemCounter(gQuizOrder)
  set gFirstAnswer to 1
  set the locV of sprite 6 to 500
  put the currentItem of gQuizOrder && "of" && gTotQuiz into field "counter"
  if the currentItem of gQuizOrder > gTotQuiz then
    goResults()
  else
    put getaProp(currQuestionInfo(), #ans1) into field "ans1"
    put getaProp(currQuestionInfo(), #ans2) into field "ans2"
    put getaProp(currQuestionInfo(), #ans3) into field "ans3"
    put getaProp(currQuestionInfo(), #ans4) into field "ans4"
    put getaProp(currQuestionInfo(), #question) into field "question"
    put getaProp(currQuestionInfo(), #topic) into field "topic"
    set the locH of sprite 10 to -500
    shuffleAnswers()
    updateStage()
  end if
end

on checkAnswer
  global gTotQuiz, gQuizList, gQuizOrder, gFirstAnswer, gScore, gMissed
  set clickedAnswer to char 4 of the name of cast the castNum of sprite the clickOn
  do("put getaprop( currQuestionInfo(), #fb" & value(clickedAnswer) & ")       into field" && QUOTE & "feedback" & QUOTE)
  set the locH of sprite 10 to 265
  updateStage()
  if gFirstAnswer then
    if clickedAnswer = getaProp(currQuestionInfo(), #correct) then
      set gScore to gScore + 1
    else
      if getOne(gMissed, getaProp(currQuestionInfo(), #topic)) = 0 then
        add(gMissed, getaProp(currQuestionInfo(), #topic))
      end if
    end if
    set gFirstAnswer to 0
    set the locV of sprite 6 to 223
    updateStage()
  end if
end

on goResults
  global gScore, gMissed, gTotQuiz, gPassingScore
  set cursor to 4
  repeat with i = 2 to 6
    puppetSprite(i, 0)
  end repeat
  puppetSprite(10, 0)
  set userScore to integer(gScore * 100 / gTotQuiz)
  put " " into field "results"
  put "You scored" && gScore && "correct on the first try" && "out of a total of" && gTotQuiz && "questions, or" && userScore & "%." & RETURN & RETURN into field "results"
  if userScore >= gPassingScore then
    put "Since you exceeded " & gPassingScore & "%, you have passed the requirements" && "for this quiz." & RETURN & RETURN & "CONGRATULATIONS!" & RETURN & RETURN & "Are you ready to receive your certificate?" after field "results"
  else
    put "Since you scored less than " & gPassingScore & "%, you should review the information" && "for this unit. You may now redo the self check (click on the arrow button)" & RETURN & "----------------" & RETURN & "TOPICS to REVIEW" & RETURN & "(You may wish to write down the topics you missed)" & RETURN & RETURN after field "results"
    repeat with i in gMissed
      put "  *" && i & RETURN after field "results"
    end repeat
  end if
  put EMPTY before line 1 of field "results"
  set cursor to -1
  go("results")
end

on shuffleAnswers
  set answerOrder to the randomList of birth(script "randmother", 4)
  repeat with i = 1 to 4
    set the locH of sprite (getAt(answerOrder, i) + 1) to 5
    set the locV of sprite (getAt(answerOrder, i) + 1) to 70 + (30 * value(i))
  end repeat
end

on animQuestionMark spriteNum, firstCast, lastCast, hOffset
  global gAnimDirection
  if the castNum of sprite spriteNum = lastCast then
    set gAnimDirection to -1
  else
    if the castNum of sprite spriteNum = firstCast then
      set gAnimDirection to 1
    end if
  end if
  set the castNum of sprite spriteNum to the castNum of sprite spriteNum + gAnimDirection
  set the locH of sprite spriteNum to the locH of sprite spriteNum + hOffset
  if the locH of sprite spriteNum > 500 then
    set the locH of sprite spriteNum to -100
  end if
  set the locV of sprite spriteNum to 150 + integer(50 * sin(the locH of sprite spriteNum * PI / 112))
  set the foreColor of sprite spriteNum to random(256)
  updateStage()
end

on currQuestionInfo
  global gQuizList
  return the quizParam of getAt(gQuizList, currQuestionNumber())
end

on currQuestionNumber
  global gQuizOrder
  return getAt(the randomList of gQuizOrder, the currentItem of gQuizOrder)
end

on numberOfQuestions
  return value(item 1 of line 1 of field "qText")
end

on setPassingScore
  return value(item 2 of line 1 of field "qText")
end